sjero.net Git - linphone/blob - m4/osip.m4

   1 dnl -*- autoconf -*-
   2 AC_DEFUN([LP_CHECK_OSIP2],[
   3
   4 AC_ARG_WITH( osip,
   5       [  --with-osip      Set prefix where osip can be found (ex:/usr or /usr/local)[default=/usr] ],
   6       [ osip_prefix=${withval}],[ osip_prefix=/usr ])
   7
   8 dnl FC6's compat-osip2 headers live into "/usr/include/osip2-2.2.2",
   9 dnl while  libraries are "/usr/lib/libosipparser2-2.2.2.so*".
  10 AC_ARG_WITH( osip-version,dnl
  11 AC_HELP_STRING([--with-osip-version=VERSION],
  12         [Set osip legacy version @<:@empty@:>@]),
  13         [osip_legacy_version="-${withval}"],
  14         [osip_legacy_version=""])
  15
  16 osip_pkgconfig=true
  17 osip_pkgconfig_file=libosip2
  18 if test -n "$osip_legacy_version"; then
  19         osip_pkgconfig_file=libosip2${osip_legacy_version}
  20 fi
  21
  22 PKG_CHECK_MODULES(OSIP, $osip_pkgconfig_file >= 3.0.0, ,osip_pkgconfig=false)
  23
  24 if test $osip_pkgconfig = false; then
  25
  26         if test -z "$osip_legacy_version"; then
  27                 OSIP_CFLAGS="-I${osip_prefix}/include"
  28         else
  29                 OSIP_CFLAGS="-I${osip_prefix}/include/osip2${osip_legacy_version}"
  30         fi
  31
  32 dnl check osip2 headers
  33         CPPFLAGS_save=$CPPFLAGS
  34         CPPFLAGS=$OSIP_CFLAGS
  35         AC_CHECK_HEADER([osip2/osip.h], ,AC_MSG_ERROR([Could not find osip2 headers !]))
  36         CPPFLAGS=$CPPFLAGS_save
  37
  38 dnl check for osip2 libs
  39         OSIP_LIBS="-L$osip_prefix/lib -losipparser2${osip_legacy_version}"
  40         LDFLAGS_save=$LDFLAGS
  41         LDFLAGS=$OSIP_LIBS
  42         LIBS_save=$LIBS
  43         case "$target_os" in
  44                 *mingw*)
  45                         osip_aux_libs=
  46                         ;;
  47                 *)
  48                         osip_aux_libs=-lpthread
  49                         ;;
  50         esac
  51         OSIP_LIBS="$OSIP_LIBS $osip_aux_libs"
  52         AC_CHECK_LIB(osip2${osip_legacy_version},osip_init, , AC_MSG_ERROR([Could not find osip2 library !]),[-losipparser2${osip_legacy_version} $osip_aux_libs ])
  53         AC_CHECK_LIB(osipparser2${osip_legacy_version},osip_message_init, , AC_MSG_ERROR([Could not find osipparser2 library !]),[$osip_aux_libs])
  54         LDFLAGS=$LDFLAGS_save
  55         LIBS=$LIBS_save
  56 fi
  57
  58 AC_SUBST(OSIP_CFLAGS)
  59 AC_SUBST(OSIP_LIBS)
  60
  61 ])