sjero.net Git - linphone/blob - m4/osip.m4

   1 dnl -*- autoconf -*-
   2 AC_DEFUN([LP_CHECK_OSIP2],[
   3
   4 AC_ARG_WITH( osip,
   5       [  --with-osip      Set prefix where osip can be found (ex:/usr or /usr/local)[default=/usr] ],
   6       [ osip_prefix=${withval}],[ osip_prefix=/usr ])
   7
   8
   9 osip_pkgconfig=true
  10 osip_pkgconfig_file=libosip2
  11
  12 PKG_CHECK_MODULES(OSIP, $osip_pkgconfig_file >= 3.3.0, ,osip_pkgconfig=false)
  13
  14 if test $osip_pkgconfig = false; then
  15
  16         if test "$osip_prefix" != "/usr" ; then
  17                 OSIP_CFLAGS="-I${osip_prefix}/include"
  18         fi
  19
  20 dnl check osip2 headers
  21         CPPFLAGS_save=$CPPFLAGS
  22         CPPFLAGS=$OSIP_CFLAGS
  23         AC_CHECK_HEADER([osip2/osip.h], ,AC_MSG_ERROR([Could not find osip2 headers !]))
  24         CPPFLAGS=$CPPFLAGS_save
  25
  26 dnl check for osip2 libs
  27         if test "$osip_prefix" != "/usr" ; then
  28                 OSIP_LIBS="-L$osip_prefix/lib"
  29         fi
  30         OSIP_LIBS="$OSIP_LIBS -losipparser2"
  31         LDFLAGS_save=$LDFLAGS
  32         LDFLAGS=$OSIP_LIBS
  33         LIBS_save=$LIBS
  34         case "$target_os" in
  35                 *mingw*)
  36                         osip_aux_libs=
  37                         ;;
  38                 *)
  39                         osip_aux_libs=-lpthread
  40                         ;;
  41         esac
  42         OSIP_LIBS="$OSIP_LIBS $osip_aux_libs"
  43         AC_CHECK_LIB(osip2,osip_init, , AC_MSG_ERROR([Could not find osip2 library !]),[-losipparser2 $osip_aux_libs ])
  44         AC_CHECK_LIB(osipparser2,osip_message_init, , AC_MSG_ERROR([Could not find osipparser2 library !]),[$osip_aux_libs])
  45         LDFLAGS=$LDFLAGS_save
  46         LIBS=$LIBS_save
  47 fi
  48
  49 AC_SUBST(OSIP_CFLAGS)
  50 AC_SUBST(OSIP_LIBS)
  51
  52 ])