sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.3],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44
  45 case $target_os in
  46         *mingw32ce)
  47         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  48         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  49         LIBS="$LIBS -lws2 -liphlpapi"
  50                 mingw_found=yes
  51                 mingwce_found=yes
  52                 ;;
  53         *mingw*)
  54                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  55                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  56                 LIBS="$LIBS -lws2_32"
  57                 GUI_FLAGS="-mwindows"
  58                 CONSOLE_FLAGS="-mconsole"
  59                 mingw_found=yes
  60         ;;
  61         *darwin*)
  62                 dnl use macport installation
  63                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  64                 build_macos=yes
  65         ;;
  66 esac
  67
  68 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  69 AC_SUBST(CONSOLE_FLAGS)
  70 AC_SUBST(GUI_FLAGS)
  71
  72 dnl localization tools
  73 IT_PROG_INTLTOOL([0.40], [no-xml])
  74
  75 dnl Initialize libtool
  76 LT_INIT([win32-dll shared disable-static])
  77
  78 AC_CONFIG_COMMANDS([libtool-hacking],[
  79 if test "$mingw_found" = "yes" ; then
  80         echo "Hacking libtool to work with mingw..."
  81         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  82         cp -f ./libtool.tmp ./libtool
  83         rm -f ./libtool.tmp
  84 fi
  85 ],[mingw_found=$mingw_found])
  86
  87 dnl Add the languages which your application supports here.
  88 PKG_PROG_PKG_CONFIG
  89 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  90 AC_SUBST(ALL_LINGUAS)
  91 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  92
  93 if test "$mingw_found" != "yes" ; then
  94 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  95 AM_GNU_GETTEXT([external])
  96 LIBS="$LIBS $LIBINTL"
  97 else
  98         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
  99         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 100         LIBS="$LIBS -lintl"
 101 fi
 102
 103 GETTEXT_PACKAGE=linphone
 104 AC_SUBST(GETTEXT_PACKAGE)
 105 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 106 dnl AC_CHECK_LIB(intl,libintl_gettext)
 107
 108 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 109
 110 dnl conditionnal build of console interface.
 111 AC_ARG_ENABLE(console_ui,
 112       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 113       [case "${enableval}" in
 114         yes) console_ui=true ;;
 115         no)  console_ui=false ;;
 116         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 117       esac],[console_ui=true])
 118
 119 dnl conditionnal build of gtk interface.
 120 AC_ARG_ENABLE(gtk_ui,
 121       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 122       [case "${enableval}" in
 123         yes) gtk_ui=true ;;
 124         no)  gtk_ui=false ;;
 125         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 126       esac],[gtk_ui=true])
 127
 128 if test "$gtk_ui" = "true" ; then
 129         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 130         if test "$enable_x11" = "false" ; then
 131                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 132                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 133         fi
 134 else
 135         echo "GTK interface compilation is disabled."
 136 fi
 137
 138
 139 dnl os-specific problems not handled by existing macros.
 140 case "$host_os" in
 141         *freebsd*)
 142                 LDFLAGS="$LDFLAGS -pthread"
 143                 ;;
 144 esac
 145
 146 case "$host_cpu" in
 147         *arm*)
 148                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 149                 use_arm_toolchain=yes
 150                 ;;
 151 esac
 152
 153 AC_ARG_WITH( configdir,
 154       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 155       [ configdir=${withval}],[ configdir="Linphone" ])
 156
 157 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 158
 159 AC_ARG_ENABLE(relativeprefix,
 160       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 161       [case "${enableval}" in
 162         yes) relativeprefix=yes ;;
 163         no)  relativeprefix=no ;;
 164         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 165       esac],[relativeprefix=auto])
 166
 167 AC_ARG_ENABLE(date,
 168       [  --enable-date    Use build date in internal version number],
 169       [case "${enableval}" in
 170         yes) use_date=yes ;;
 171         no)  use_date=no ;;
 172         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 173       esac],[use_date=no])
 174
 175 if test x$use_date =  xyes ; then
 176         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 177 fi
 178
 179
 180 dnl enable ipv6 support
 181 AC_ARG_ENABLE(ipv6,
 182       [  --enable-ipv6    Turn on ipv6 support],
 183       [case "${enableval}" in
 184         yes)  ipv6=true;;
 185         no)   ipv6=false;;
 186         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 187       esac],[ipv6=true])
 188 IPV6_CFLAGS=
 189 if test x$ipv6 = xtrue ; then
 190         IPV6_CFLAGS=-DINET6
 191 fi
 192 AC_SUBST(IPV6_CFLAGS)
 193
 194 dnl enable truespeech codec support
 195 AC_ARG_ENABLE(truespeech,
 196       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 197       [case "${enableval}" in
 198         yes)  truespeech=true;;
 199         no)   truespeech=false;;
 200         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 201       esac],[truespeech=false])
 202 TRUESPEECH_CFLAGS=
 203 if test x$truespeech = xtrue ; then
 204         TRUESPEECH_CFLAGS=-DTRUESPEECH
 205 fi
 206 AC_SUBST(TRUESPEECH_CFLAGS)
 207 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 208
 209 AC_ARG_ENABLE(nonstandard-gsm,
 210       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 211       [case "${enableval}" in
 212         yes) exotic_gsm=yes
 213         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 214          ;;
 215         no)  exotic_gsm=no ;;
 216         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 217       esac],[exotic_gsm=no])
 218
 219
 220 dnl support for RSVP (by Vincent Maury)
 221 AC_ARG_ENABLE(rsvp,
 222 [  --enable-rsvp           enable support for QoS reservations.],
 223 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 224 should be compiled.]) )
 225
 226 if test "x${prefix}" = "xNONE"; then
 227         package_prefix=${ac_default_prefix}
 228 else
 229         package_prefix=${prefix}
 230 fi
 231
 232
 233 AC_ARG_ENABLE(x11,
 234                           [  --disable-x11    Disable X11 support],
 235                           [case "${enableval}" in
 236                           yes) enable_x11=true ;;
 237                           no)  enable_x11=false ;;
 238                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 239                           esac],[enable_x11=true])
 240
 241
 242
 243 if test "$relativeprefix" = "auto" ; then
 244         case $target_os in
 245                 *darwin*)
 246                 if test "$enable_x11" = "false" ; then
 247                         relativeprefix=yes
 248                 fi
 249                 ;;
 250                 *mingw*)
 251                 relativeprefix=yes
 252                 ;;
 253         esac
 254 fi
 255
 256 if test "$relativeprefix" = "yes" ; then
 257         dnl allow binaries to install everywhere
 258         package_prefix="."
 259 fi
 260
 261 dnl Set PACKAGE_LOCALE_DIR in config.h.
 262 DATADIRNAME=share
 263 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 264
 265 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 266
 267 dnl Set PACKAGE_SOUND_DIR in config.h.
 268 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 269
 270
 271 dnl check if we have the getifaddrs() sytem call
 272 AC_CHECK_FUNCS(getifaddrs)
 273
 274 dnl check for osip2
 275 LP_CHECK_OSIP2
 276
 277 dnl conditionnal build for ssl
 278 AC_ARG_ENABLE(ssl,
 279                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 280                 [case "${enableval}" in
 281                 yes) build_ssl=true ;;
 282                 no)  build_ssl=false ;;
 283                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 284                 esac],[build_ssl=false])
 285
 286 if test "$build_ssl" = "true"; then
 287         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 288 fi
 289 dnl setup flags for exosip library
 290 LP_SETUP_EXOSIP
 291
 292 if test "$console_ui" = "true" ; then
 293 dnl check gnu readline
 294 LP_CHECK_READLINE
 295 else
 296 echo "Console interface compilation is disabled."
 297 fi
 298
 299 AC_WORDS_BIGENDIAN
 300
 301 dnl normaly this should only by done by mediastreamer2/configure.ac
 302 dnl but to workaround bugs when cross-compiling for arm-linux,
 303 dnl we need to have SPEEX_LIBS defined
 304 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 305 dnl since top-level configure --help will not print them.
 306
 307 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 308
 309 dnl conditionnal build of video support
 310 AC_ARG_ENABLE(video,
 311                 [  --enable-video    Turn on video support compiling],
 312                 [case "${enableval}" in
 313                 yes) video=true ;;
 314                 no)  video=false ;;
 315                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 316                 esac],[video=true])
 317
 318 AC_ARG_WITH( ffmpeg,
 319                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 320                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 321
 322 if test "$video" = "true"; then
 323
 324         if test "$enable_x11" = "true"; then
 325                 AC_CHECK_HEADERS(X11/Xlib.h)
 326                 AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 327                 AC_SUBST(X11_LIBS)
 328         fi
 329         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 330 fi
 331
 332 AC_ARG_ENABLE(alsa,
 333       [  --enable-alsa    Turn on alsa native support compiling],
 334       [case "${enableval}" in
 335         yes) alsa=true ;;
 336         no)  alsa=false ;;
 337         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 338       esac],[alsa=true])
 339
 340 AC_ARG_ENABLE(artsc,
 341       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 342       [case "${enableval}" in
 343         yes) artsc=true ;;
 344         no)  artsc=false ;;
 345         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 346       esac],[artsc=false])
 347
 348 AC_ARG_ENABLE(portaudio,
 349       [  --enable-portaudio    Turn on portaudio native support compiling],
 350       [case "${enableval}" in
 351         yes) portaudio=true ;;
 352         no)  portaudio=false ;;
 353         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 354       esac],[portaudio=false])
 355
 356 dnl build console if required
 357 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 358 dnl special things for arm-linux cross compilation toolchain
 359 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 360 dnl compilation of gtk user interface
 361 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 362 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 363
 364 dnl check getenv
 365 AH_TEMPLATE([HAVE_GETENV])
 366 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 367
 368 dnl
 369 AC_MSG_CHECKING([for sighandler_t])
 370 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 371 has_sighandler_t=yes,has_sighandler_t=no)
 372 AC_MSG_RESULT($has_sighandler_t)
 373 if test "$has_sighandler_t" = "yes" ; then
 374     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 375 fi
 376
 377 ##################################################
 378 # Stricter build options (after external packages)
 379 ##################################################
 380
 381
 382 AC_ARG_ENABLE(strict,
 383         AC_HELP_STRING([--enable-strict],
 384                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 385         strictness="${enableval}"],[strictness=yes]
 386 )
 387
 388 if test "$GCC$strictness" = "yesyes" ; then
 389         STRICT_OPTIONS="-Wall "
 390         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 391         CFLAGS="$CFLAGS -fno-strict-aliasing"
 392 fi
 393
 394 AC_SUBST(STRICT_OPTIONS)
 395
 396 top_srcdir=`dirname $0`
 397
 398 AC_ARG_ENABLE([external-mediastreamer],
 399       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 400       [enable_external_mediastreamer=no])
 401
 402 AS_CASE($enable_external_mediastreamer,
 403                 [yes],[
 404                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 405                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 406                         ],
 407                 [no],[
 408                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 409                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 410                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 411                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 412 dnl need to temporary change quotes to allow square brackets
 413                         changequote(<<, >>)
 414                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 415                         changequote([, ])
 416                         MS2_DIR=mediastreamer2
 417                         ],
 418         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 419
 420 AC_SUBST(MEDIASTREAMER_CFLAGS)
 421 AC_SUBST(MEDIASTREAMER_LIBS)
 422 AC_SUBST([MS2_VERSION])
 423 AC_SUBST([MS2_DIR])
 424
 425 dnl check for db2html (docbook) to generate html user manual
 426 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 427 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 428
 429 dnl for external use of linphone libs
 430 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 431 LINPHONE_LIBS="-L${libdir} -llinphone"
 432
 433 if test x$mingw_found = xyes ; then
 434         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 435 fi
 436 AC_SUBST(LINPHONE_CFLAGS)
 437 AC_SUBST(LINPHONE_LIBS)
 438
 439 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 440
 441 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 442 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 443 AC_SUBST(LINPHONE_PLUGINS_DIR)
 444
 445 AC_ARG_ENABLE(external-ortp,
 446       [  --enable-external-ortp    Use external oRTP library],
 447       [case "${enableval}" in
 448         yes) external_ortp=true ;;
 449         no)  external_ortp=false ;;
 450         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 451       esac],[external_ortp=false])
 452
 453 if test "$external_ortp" = 'true'; then
 454         PKG_CHECK_MODULES([ORTP], [ortp])
 455         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 456 else
 457         AC_CONFIG_SUBDIRS( oRTP )
 458         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 459         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 460         if test x$ac_cv_c_bigendian = xyes ; then
 461                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 462         fi
 463         ORTP_DIR=oRTP
 464         changequote(<<, >>)
 465         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 466         changequote([, ])
 467 fi
 468 AC_SUBST(ORTP_CFLAGS)
 469 AC_SUBST(ORTP_LIBS)
 470 AC_SUBST([ORTP_VERSION])
 471 AC_SUBST([ORTP_DIR])
 472
 473 dnl ##################################################
 474 dnl # Check for doxygen
 475 dnl ##################################################
 476
 477 AC_PATH_PROG(DOXYGEN,doxygen,false)
 478 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 479
 480
 481 AC_CONFIG_FILES([
 482 Makefile
 483 build/Makefile
 484 build/macos/Makefile
 485 build/macos/Info-linphone.plist
 486 m4/Makefile
 487 po/Makefile.in
 488 pixmaps/Makefile
 489 coreapi/Makefile
 490 coreapi/help/Makefile
 491 coreapi/help/Doxyfile
 492 gtk/Makefile
 493 console/Makefile
 494 share/Makefile
 495 share/C/Makefile
 496 share/fr/Makefile
 497 share/it/Makefile
 498 share/ja/Makefile
 499 share/cs/Makefile
 500 share/linphone.pc
 501 share/linphone.desktop
 502 scripts/Makefile
 503 linphone.spec
 504 linphone.iss
 505 ])
 506
 507 AC_OUTPUT
 508
 509 echo "Linphone build configuration ended."
 510
 511 if test x$gtk_ui = xtrue ; then
 512         echo "* GTK interface will be compiled."
 513 fi
 514 if test x$console_ui = xtrue ; then
 515         echo "* Console interface will be compiled."
 516 fi
 517
 518 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 519