sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.99.1],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target_os in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63         *darwin*)
  64                 dnl use macport installation
  65                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  66                 build_macos=yes
  67         ;;
  68 esac
  69
  70 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  71 AC_SUBST(CONSOLE_FLAGS)
  72 AC_SUBST(GUI_FLAGS)
  73
  74 dnl localization tools
  75 IT_PROG_INTLTOOL([0.40], [no-xml])
  76
  77 dnl Initialize libtool
  78 LT_INIT([win32-dll shared disable-static])
  79
  80 AC_CONFIG_COMMANDS([libtool-hacking],[
  81 if test "$mingw_found" = "yes" ; then
  82         echo "Hacking libtool to work with mingw..."
  83         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  84         cp -f ./libtool.tmp ./libtool
  85         rm -f ./libtool.tmp
  86 fi
  87 ],[mingw_found=$mingw_found])
  88
  89 dnl Add the languages which your application supports here.
  90 PKG_PROG_PKG_CONFIG
  91 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  92 AC_SUBST(ALL_LINGUAS)
  93 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  94
  95 if test "$mingw_found" != "yes" ; then
  96 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  97 AM_GNU_GETTEXT([external])
  98 LIBS="$LIBS $LIBINTL"
  99 else
 100         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 101         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 102         LIBS="$LIBS -lintl"
 103 fi
 104
 105 GETTEXT_PACKAGE=linphone
 106 AC_SUBST(GETTEXT_PACKAGE)
 107 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 108 dnl AC_CHECK_LIB(intl,libintl_gettext)
 109
 110 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 111
 112 AC_ARG_ENABLE(x11,
 113                           [  --disable-x11    Disable X11 support],
 114                           [case "${enableval}" in
 115                           yes) enable_x11=true ;;
 116                           no)  enable_x11=false ;;
 117                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 118                           esac],[enable_x11=true])
 119
 120 dnl conditionnal build of console interface.
 121 AC_ARG_ENABLE(console_ui,
 122       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 123       [case "${enableval}" in
 124         yes) console_ui=true ;;
 125         no)  console_ui=false ;;
 126         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 127       esac],[console_ui=true])
 128
 129 dnl conditionnal build of gtk interface.
 130 AC_ARG_ENABLE(gtk_ui,
 131       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 132       [case "${enableval}" in
 133         yes) gtk_ui=true ;;
 134         no)  gtk_ui=false ;;
 135         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 136       esac],[gtk_ui=true])
 137
 138 if test "$gtk_ui" = "true" ; then
 139         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 140         if test "$enable_x11" = "false" ; then
 141                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 142                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 143         fi
 144 else
 145         echo "GTK interface compilation is disabled."
 146 fi
 147
 148
 149 dnl os-specific problems not handled by existing macros.
 150 case "$host_os" in
 151         *freebsd*)
 152                 LDFLAGS="$LDFLAGS -pthread"
 153                 ;;
 154 esac
 155
 156 case "$host_cpu" in
 157         *arm*)
 158                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 159                 use_arm_toolchain=yes
 160                 ;;
 161 esac
 162
 163 AC_ARG_WITH( configdir,
 164       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 165       [ configdir=${withval}],[ configdir="Linphone" ])
 166
 167 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 168
 169 AC_ARG_ENABLE(relativeprefix,
 170       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 171       [case "${enableval}" in
 172         yes) relativeprefix=yes ;;
 173         no)  relativeprefix=no ;;
 174         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 175       esac],[relativeprefix=no])
 176
 177 AC_ARG_ENABLE(date,
 178       [  --enable-date    Use build date in internal version number],
 179       [case "${enableval}" in
 180         yes) use_date=yes ;;
 181         no)  use_date=no ;;
 182         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 183       esac],[use_date=no])
 184
 185 if test x$use_date =  xyes ; then
 186         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 187 fi
 188
 189
 190 dnl enable ipv6 support
 191 AC_ARG_ENABLE(ipv6,
 192       [  --enable-ipv6    Turn on ipv6 support],
 193       [case "${enableval}" in
 194         yes)  ipv6=true;;
 195         no)   ipv6=false;;
 196         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 197       esac],[ipv6=true])
 198 IPV6_CFLAGS=
 199 if test x$ipv6 = xtrue ; then
 200         IPV6_CFLAGS=-DINET6
 201 fi
 202 AC_SUBST(IPV6_CFLAGS)
 203
 204 dnl enable truespeech codec support
 205 AC_ARG_ENABLE(truespeech,
 206       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 207       [case "${enableval}" in
 208         yes)  truespeech=true;;
 209         no)   truespeech=false;;
 210         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 211       esac],[truespeech=false])
 212 TRUESPEECH_CFLAGS=
 213 if test x$truespeech = xtrue ; then
 214         TRUESPEECH_CFLAGS=-DTRUESPEECH
 215 fi
 216 AC_SUBST(TRUESPEECH_CFLAGS)
 217 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 218
 219 AC_ARG_ENABLE(nonstandard-gsm,
 220       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 221       [case "${enableval}" in
 222         yes) exotic_gsm=yes
 223         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 224          ;;
 225         no)  exotic_gsm=no ;;
 226         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 227       esac],[exotic_gsm=no])
 228
 229
 230 dnl support for RSVP (by Vincent Maury)
 231 AC_ARG_ENABLE(rsvp,
 232 [  --enable-rsvp           enable support for QoS reservations.],
 233 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 234 should be compiled.]) )
 235
 236 if test "x${prefix}" = "xNONE"; then
 237         package_prefix=${ac_default_prefix}
 238 else
 239         package_prefix=${prefix}
 240 fi
 241
 242
 243 if test "$relativeprefix" = "yes" ; then
 244         dnl allow binaries to install everywhere
 245         package_prefix="."
 246 fi
 247
 248 dnl Set PACKAGE_LOCALE_DIR in config.h.
 249 DATADIRNAME=share
 250 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 251
 252 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 253
 254 dnl Set PACKAGE_SOUND_DIR in config.h.
 255 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 256
 257
 258 dnl check if we have the getifaddrs() sytem call
 259 AC_CHECK_FUNCS(getifaddrs)
 260
 261 dnl check for osip2
 262 LP_CHECK_OSIP2
 263
 264 dnl conditionnal build for ssl
 265 AC_ARG_ENABLE(ssl,
 266                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 267                 [case "${enableval}" in
 268                 yes) build_ssl=true ;;
 269                 no)  build_ssl=false ;;
 270                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 271                 esac],[build_ssl=false])
 272
 273 if test "$build_ssl" = "true"; then
 274         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 275 fi
 276 dnl setup flags for exosip library
 277 LP_SETUP_EXOSIP
 278
 279 if test "$console_ui" = "true" ; then
 280 dnl check gnu readline
 281 LP_CHECK_READLINE
 282 else
 283 echo "Console interface compilation is disabled."
 284 fi
 285
 286 AC_WORDS_BIGENDIAN
 287
 288 dnl normaly this should only by done by mediastreamer2/configure.ac
 289 dnl but to workaround bugs when cross-compiling for arm-linux,
 290 dnl we need to have SPEEX_LIBS defined
 291 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 292 dnl since top-level configure --help will not print them.
 293
 294 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 295
 296 dnl conditionnal build of video support
 297 AC_ARG_ENABLE(video,
 298                 [  --enable-video    Turn on video support compiling],
 299                 [case "${enableval}" in
 300                 yes) video=true ;;
 301                 no)  video=false ;;
 302                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 303                 esac],[video=true])
 304
 305 AC_ARG_WITH( ffmpeg,
 306                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 307                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 308
 309 if test "$video" = "true"; then
 310
 311         if test "$enable_x11" = "true"; then
 312                 AC_CHECK_HEADERS(X11/Xlib.h)
 313                 if test "$build_macos" = "yes"; then
 314                         X11_LIBS="-L/usr/X11/lib -lX11"
 315                 else
 316                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 317                 fi
 318                 AC_SUBST(X11_LIBS)
 319         fi
 320         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 321 fi
 322
 323 AC_ARG_ENABLE(alsa,
 324       [  --enable-alsa    Turn on alsa native support compiling],
 325       [case "${enableval}" in
 326         yes) alsa=true ;;
 327         no)  alsa=false ;;
 328         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 329       esac],[alsa=true])
 330
 331 AC_ARG_ENABLE(artsc,
 332       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 333       [case "${enableval}" in
 334         yes) artsc=true ;;
 335         no)  artsc=false ;;
 336         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 337       esac],[artsc=false])
 338
 339 AC_ARG_ENABLE(portaudio,
 340       [  --enable-portaudio    Turn on portaudio native support compiling],
 341       [case "${enableval}" in
 342         yes) portaudio=true ;;
 343         no)  portaudio=false ;;
 344         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 345       esac],[portaudio=false])
 346
 347 dnl build console if required
 348 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 349 dnl special things for arm-linux cross compilation toolchain
 350 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 351 dnl compilation of gtk user interface
 352 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 353 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 354
 355 dnl check getenv
 356 AH_TEMPLATE([HAVE_GETENV])
 357 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 358
 359 dnl
 360 AC_MSG_CHECKING([for sighandler_t])
 361 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 362 has_sighandler_t=yes,has_sighandler_t=no)
 363 AC_MSG_RESULT($has_sighandler_t)
 364 if test "$has_sighandler_t" = "yes" ; then
 365     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 366 fi
 367
 368 ##################################################
 369 # Stricter build options (after external packages)
 370 ##################################################
 371
 372
 373 AC_ARG_ENABLE(strict,
 374         AC_HELP_STRING([--enable-strict],
 375                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 376         strictness="${enableval}"],[strictness=yes]
 377 )
 378
 379 STRICT_OPTIONS="-Wall "
 380
 381 if test "$GCC$strictness" = "yesyes" ; then
 382         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 383         CFLAGS="$CFLAGS -fno-strict-aliasing"
 384 fi
 385
 386 AC_SUBST(STRICT_OPTIONS)
 387
 388 top_srcdir=`dirname $0`
 389
 390 AC_ARG_ENABLE([external-mediastreamer],
 391       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 392       [enable_external_mediastreamer=no])
 393
 394 AS_CASE($enable_external_mediastreamer,
 395                 [yes],[
 396                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 397                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 398                         ],
 399                 [no],[
 400                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 401                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 402                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 403                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 404 dnl need to temporary change quotes to allow square brackets
 405                         changequote(<<, >>)
 406                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 407                         changequote([, ])
 408                         MS2_DIR=mediastreamer2
 409                         ],
 410         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 411
 412 AC_SUBST(MEDIASTREAMER_CFLAGS)
 413 AC_SUBST(MEDIASTREAMER_LIBS)
 414 AC_SUBST([MS2_VERSION])
 415 AC_SUBST([MS2_DIR])
 416
 417 dnl check for db2html (docbook) to generate html user manual
 418 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 419 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 420
 421 dnl for external use of linphone libs
 422 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 423 LINPHONE_LIBS="-L${libdir} -llinphone"
 424
 425 if test x$mingw_found = xyes ; then
 426         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 427 fi
 428 AC_SUBST(LINPHONE_CFLAGS)
 429 AC_SUBST(LINPHONE_LIBS)
 430
 431 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 432
 433 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 434 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 435 AC_SUBST(LINPHONE_PLUGINS_DIR)
 436
 437 AC_ARG_ENABLE(external-ortp,
 438       [  --enable-external-ortp    Use external oRTP library],
 439       [case "${enableval}" in
 440         yes) external_ortp=true ;;
 441         no)  external_ortp=false ;;
 442         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 443       esac],[external_ortp=false])
 444
 445 if test "$external_ortp" = 'true'; then
 446         PKG_CHECK_MODULES([ORTP], [ortp])
 447         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 448 else
 449         AC_CONFIG_SUBDIRS( oRTP )
 450         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 451         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 452         if test x$ac_cv_c_bigendian = xyes ; then
 453                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 454         fi
 455         ORTP_DIR=oRTP
 456         changequote(<<, >>)
 457         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 458         changequote([, ])
 459 fi
 460 AC_SUBST(ORTP_CFLAGS)
 461 AC_SUBST(ORTP_LIBS)
 462 AC_SUBST([ORTP_VERSION])
 463 AC_SUBST([ORTP_DIR])
 464
 465 dnl ##################################################
 466 dnl # Check for doxygen
 467 dnl ##################################################
 468
 469 AC_PATH_PROG(DOXYGEN,doxygen,false)
 470 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 471
 472
 473 AC_CONFIG_FILES([
 474 Makefile
 475 build/Makefile
 476 build/macos/Makefile
 477 build/macos/Info-linphone.plist
 478 m4/Makefile
 479 po/Makefile.in
 480 pixmaps/Makefile
 481 coreapi/Makefile
 482 coreapi/help/Makefile
 483 coreapi/help/Doxyfile
 484 gtk/Makefile
 485 console/Makefile
 486 share/Makefile
 487 share/C/Makefile
 488 share/fr/Makefile
 489 share/it/Makefile
 490 share/ja/Makefile
 491 share/cs/Makefile
 492 share/linphone.pc
 493 share/linphone.desktop
 494 scripts/Makefile
 495 linphone.spec
 496 linphone.iss
 497 ])
 498
 499 AC_OUTPUT
 500
 501 echo "Linphone build configuration ended."
 502
 503 if test x$gtk_ui = xtrue ; then
 504         echo "* GTK interface will be compiled."
 505 fi
 506 if test x$console_ui = xtrue ; then
 507         echo "* Console interface will be compiled."
 508 fi
 509
 510 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 511