sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.2],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44
  45 case $target_os in
  46         *mingw32ce)
  47         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  48         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  49         LIBS="$LIBS -lws2 -liphlpapi"
  50                 mingw_found=yes
  51                 mingwce_found=yes
  52                 ;;
  53         *mingw*)
  54                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  55                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  56                 LIBS="$LIBS -lws2_32"
  57                 GUI_FLAGS="-mwindows"
  58                 CONSOLE_FLAGS="-mconsole"
  59                 mingw_found=yes
  60         ;;
  61         *darwin*)
  62                 dnl use macport installation
  63                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  64                 build_macos=yes
  65         ;;
  66 esac
  67
  68 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  69 AC_SUBST(CONSOLE_FLAGS)
  70 AC_SUBST(GUI_FLAGS)
  71
  72 dnl localization tools
  73 IT_PROG_INTLTOOL([0.40], [no-xml])
  74
  75 dnl Initialize libtool
  76 AC_LIBTOOL_WIN32_DLL
  77 AC_PROG_LIBTOOL
  78 AM_PROG_LIBTOOL
  79 AC_ENABLE_SHARED(yes)
  80 AC_ENABLE_STATIC(no)
  81
  82
  83 AC_CONFIG_COMMANDS([libtool-hacking],[
  84 if test "$mingw_found" = "yes" ; then
  85         echo "Hacking libtool to work with mingw..."
  86         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  87         cp -f ./libtool.tmp ./libtool
  88         rm -f ./libtool.tmp
  89 fi
  90 ],[mingw_found=$mingw_found])
  91
  92 dnl Add the languages which your application supports here.
  93 PKG_PROG_PKG_CONFIG
  94 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN"
  95 AC_SUBST(ALL_LINGUAS)
  96 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  97
  98 if test "$mingw_found" != "yes" ; then
  99 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 100 AM_GNU_GETTEXT([external])
 101 LIBS="$LIBS $LIBINTL"
 102 else
 103         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 104         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 105         LIBS="$LIBS -lintl"
 106 fi
 107
 108 GETTEXT_PACKAGE=linphone
 109 AC_SUBST(GETTEXT_PACKAGE)
 110 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 111 dnl AC_CHECK_LIB(intl,libintl_gettext)
 112
 113 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 114
 115 dnl conditionnal build of console interface.
 116 AC_ARG_ENABLE(console_ui,
 117       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 118       [case "${enableval}" in
 119         yes) console_ui=true ;;
 120         no)  console_ui=false ;;
 121         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 122       esac],[console_ui=true])
 123
 124 dnl conditionnal build of gtk interface.
 125 AC_ARG_ENABLE(gtk_ui,
 126       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 127       [case "${enableval}" in
 128         yes) gtk_ui=true ;;
 129         no)  gtk_ui=false ;;
 130         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 131       esac],[gtk_ui=true])
 132
 133
 134 if test "$gtk_ui" = "true" ; then
 135         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 136         if test "$build_macos" = "yes" ; then
 137                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 138         fi
 139 else
 140         echo "GTK interface compilation is disabled."
 141 fi
 142
 143
 144 dnl os-specific problems not handled by existing macros.
 145 case "$host_os" in
 146         *freebsd*)
 147                 LDFLAGS="$LDFLAGS -pthread"
 148                 ;;
 149 esac
 150
 151 case "$host_cpu" in
 152         *arm*)
 153                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 154                 use_arm_toolchain=yes
 155                 ;;
 156 esac
 157
 158 AC_ARG_WITH( configdir,
 159       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 160       [ configdir=${withval}],[ configdir="Linphone" ])
 161
 162 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 163
 164 AC_ARG_ENABLE(relativeprefix,
 165       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 166       [case "${enableval}" in
 167         yes) relativeprefix=yes ;;
 168         no)  relativeprefix=no ;;
 169         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 170       esac],[relativeprefix=auto])
 171
 172 AC_ARG_ENABLE(date,
 173       [  --enable-date    Use build date in internal version number],
 174       [case "${enableval}" in
 175         yes) use_date=yes ;;
 176         no)  use_date=no ;;
 177         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 178       esac],[use_date=no])
 179
 180 if test x$use_date =  xyes ; then
 181         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 182 fi
 183
 184
 185 dnl enable ipv6 support
 186 AC_ARG_ENABLE(ipv6,
 187       [  --enable-ipv6    Turn on ipv6 support],
 188       [case "${enableval}" in
 189         yes)  ipv6=true;;
 190         no)   ipv6=false;;
 191         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 192       esac],[ipv6=true])
 193 IPV6_CFLAGS=
 194 if test x$ipv6 = xtrue ; then
 195         IPV6_CFLAGS=-DINET6
 196 fi
 197 AC_SUBST(IPV6_CFLAGS)
 198
 199 dnl enable truespeech codec support
 200 AC_ARG_ENABLE(truespeech,
 201       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 202       [case "${enableval}" in
 203         yes)  truespeech=true;;
 204         no)   truespeech=false;;
 205         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 206       esac],[truespeech=false])
 207 TRUESPEECH_CFLAGS=
 208 if test x$truespeech = xtrue ; then
 209         TRUESPEECH_CFLAGS=-DTRUESPEECH
 210 fi
 211 AC_SUBST(TRUESPEECH_CFLAGS)
 212 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 213
 214 AC_ARG_ENABLE(nonstandard-gsm,
 215       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 216       [case "${enableval}" in
 217         yes) exotic_gsm=yes
 218         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 219          ;;
 220         no)  exotic_gsm=no ;;
 221         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 222       esac],[exotic_gsm=no])
 223
 224
 225 dnl support for RSVP (by Vincent Maury)
 226 AC_ARG_ENABLE(rsvp,
 227 [  --enable-rsvp           enable support for QoS reservations.],
 228 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 229 should be compiled.]) )
 230
 231 if test "x${prefix}" = "xNONE"; then
 232         package_prefix=${ac_default_prefix}
 233 else
 234         package_prefix=${prefix}
 235 fi
 236
 237
 238
 239 if test "$relativeprefix" = "auto" ; then
 240         case $target_os in
 241                 *darwin*)
 242                 relativeprefix=yes
 243                 ;;
 244                 *mingw*)
 245                 relativeprefix=yes
 246                 ;;
 247         esac
 248 fi
 249
 250 if test "$relativeprefix" = "yes" ; then
 251         dnl allow binaries to install everywhere
 252         package_prefix="."
 253 fi
 254
 255 dnl Set PACKAGE_LOCALE_DIR in config.h.
 256 DATADIRNAME=share
 257 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 258
 259 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 260
 261 dnl Set PACKAGE_SOUND_DIR in config.h.
 262 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 263
 264
 265 dnl check if we have the getifaddrs() sytem call
 266 AC_CHECK_FUNCS(getifaddrs)
 267
 268 dnl check for osip2
 269 LP_CHECK_OSIP2
 270
 271 dnl conditionnal build for ssl
 272 AC_ARG_ENABLE(ssl,
 273                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 274                 [case "${enableval}" in
 275                 yes) build_ssl=true ;;
 276                 no)  build_ssl=false ;;
 277                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 278                 esac],[build_ssl=false])
 279
 280 if test "$build_ssl" = "true"; then
 281         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 282 fi
 283 dnl setup flags for exosip library
 284 LP_SETUP_EXOSIP
 285
 286 if test "$console_ui" = "true" ; then
 287 dnl check gnu readline
 288 LP_CHECK_READLINE
 289 else
 290 echo "Console interface compilation is disabled."
 291 fi
 292
 293 AC_WORDS_BIGENDIAN
 294
 295 dnl normaly this should only by done by mediastreamer2/configure.ac
 296 dnl but to workaround bugs when cross-compiling for arm-linux,
 297 dnl we need to have SPEEX_LIBS defined
 298 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 299 dnl since top-level configure --help will not print them.
 300
 301 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 302
 303 dnl conditionnal build of video support
 304 AC_ARG_ENABLE(video,
 305                 [  --enable-video    Turn on video support compiling],
 306                 [case "${enableval}" in
 307                 yes) video=true ;;
 308                 no)  video=false ;;
 309                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 310                 esac],[video=true])
 311
 312 AC_ARG_WITH( ffmpeg,
 313                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 314                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 315
 316 AC_ARG_ENABLE(x11,
 317                           [  --disable-x11    Disable X11 support],
 318                           [case "${enableval}" in
 319                           yes) enable_x11=true ;;
 320                           no)  enable_x11=false ;;
 321                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 322                           esac],[enable_x11=true])
 323
 324 if test "$video" = "true"; then
 325
 326         if test "$enable_x11" = "true"; then
 327                 AC_CHECK_HEADERS(X11/Xlib.h)
 328                 AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 329                 AC_SUBST(X11_LIBS)
 330         fi
 331         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 332 fi
 333
 334 AC_ARG_ENABLE(alsa,
 335       [  --enable-alsa    Turn on alsa native support compiling],
 336       [case "${enableval}" in
 337         yes) alsa=true ;;
 338         no)  alsa=false ;;
 339         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 340       esac],[alsa=true])
 341
 342 AC_ARG_ENABLE(artsc,
 343       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 344       [case "${enableval}" in
 345         yes) artsc=true ;;
 346         no)  artsc=false ;;
 347         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 348       esac],[artsc=false])
 349
 350 AC_ARG_ENABLE(portaudio,
 351       [  --enable-portaudio    Turn on portaudio native support compiling],
 352       [case "${enableval}" in
 353         yes) portaudio=true ;;
 354         no)  portaudio=false ;;
 355         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 356       esac],[portaudio=false])
 357
 358 dnl build console if required
 359 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 360 dnl special things for arm-linux cross compilation toolchain
 361 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 362 dnl compilation of gtk user interface
 363 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 364 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 365
 366 dnl check getenv
 367 AH_TEMPLATE([HAVE_GETENV])
 368 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 369
 370 dnl
 371 AC_MSG_CHECKING([for sighandler_t])
 372 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 373 has_sighandler_t=yes,has_sighandler_t=no)
 374 AC_MSG_RESULT($has_sighandler_t)
 375 if test "$has_sighandler_t" = "yes" ; then
 376     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 377 fi
 378
 379 ##################################################
 380 # Stricter build options (after external packages)
 381 ##################################################
 382
 383
 384 AC_ARG_ENABLE(strict,
 385         AC_HELP_STRING([--enable-strict],
 386                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 387         strictness="${enableval}"],[strictness=yes]
 388 )
 389
 390 if test "$GCC$strictness" = "yesyes" ; then
 391         STRICT_OPTIONS="-Wall "
 392         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 393         CFLAGS="$CFLAGS -fno-strict-aliasing"
 394 fi
 395
 396 AC_SUBST(STRICT_OPTIONS)
 397
 398 top_srcdir=`dirname $0`
 399
 400 AC_ARG_ENABLE([external-mediastreamer],
 401       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 402       [enable_external_mediastreamer=no])
 403
 404 AS_CASE($enable_external_mediastreamer,
 405                 [yes],[
 406                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 407                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 408                         AM_CONDITIONAL(EXTERNAL_MEDIASTREAMER, [true])],
 409                 [no],[
 410                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 411                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 412                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 413                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 414 dnl need to temporary change quotes to allow square brackets
 415                         changequote(<<, >>)
 416                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 417                         changequote([, ])
 418                         AM_CONDITIONAL(EXTERNAL_MEDIASTREAMER, [false])],
 419         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 420
 421 AC_SUBST(MEDIASTREAMER_CFLAGS)
 422 AC_SUBST(MEDIASTREAMER_LIBS)
 423 AC_SUBST([MS2_VERSION])
 424
 425 dnl check for db2html (docbook) to generate html user manual
 426 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 427 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 428
 429 dnl for external use of linphone libs
 430 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 431 LINPHONE_LIBS="-L${libdir} -llinphone"
 432
 433 if test x$mingw_found = xyes ; then
 434         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 435 fi
 436 AC_SUBST(LINPHONE_CFLAGS)
 437 AC_SUBST(LINPHONE_LIBS)
 438
 439 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 440
 441 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 442 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 443 AC_SUBST(LINPHONE_PLUGINS_DIR)
 444
 445 AC_ARG_ENABLE(external-ortp,
 446       [  --enable-external-ortp    Use external oRTP library],
 447       [case "${enableval}" in
 448         yes) external_ortp=true ;;
 449         no)  external_ortp=false ;;
 450         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 451       esac],[external_ortp=false])
 452
 453 if test "$external_ortp" = 'true'; then
 454         PKG_CHECK_MODULES([ORTP], [ortp])
 455         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 456 else
 457         AC_CONFIG_SUBDIRS( oRTP )
 458         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 459         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 460         if test x$ac_cv_c_bigendian = xyes ; then
 461                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 462         fi
 463         changequote(<<, >>)
 464         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 465         changequote([, ])
 466 fi
 467 AC_SUBST(ORTP_CFLAGS)
 468 AC_SUBST(ORTP_LIBS)
 469 AC_SUBST([ORTP_VERSION])
 470
 471 AM_CONDITIONAL(EXTERNAL_ORTP, [test "$external_ortp" = 'true'])
 472
 473 dnl ##################################################
 474 dnl # Check for doxygen
 475 dnl ##################################################
 476
 477 AC_PATH_PROG(DOXYGEN,doxygen,false)
 478 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 479
 480
 481 AC_OUTPUT([
 482 Makefile
 483 build/Makefile
 484 build/macos/Makefile
 485 build/macos/Info-linphone.plist
 486 m4/Makefile
 487 po/Makefile.in
 488 pixmaps/Makefile
 489 coreapi/Makefile
 490 coreapi/help/Makefile
 491 coreapi/help/Doxyfile
 492 gtk/Makefile
 493 console/Makefile
 494 share/Makefile
 495 share/C/Makefile
 496 share/fr/Makefile
 497 share/it/Makefile
 498 share/ja/Makefile
 499 share/cs/Makefile
 500 share/linphone.pc
 501 share/linphone.desktop
 502 scripts/Makefile
 503 linphone.spec
 504 linphone.iss
 505 ])
 506
 507 echo "Linphone build configuration ended."
 508
 509 if test x$gtk_ui = xtrue ; then
 510         echo "* GTK interface will be compiled."
 511 fi
 512 if test x$console_ui = xtrue ; then
 513         echo "* Console interface will be compiled."
 514 fi
 515
 516 echo "Now type 'make' to compile, and then 'make install' as root to install it."