sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.99.1],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63        armv6-apple-darwin|armv7-apple-darwin|i386-apple-darwin)
  64                 CFLAGS="$CFLAGS -DTARGET_OS_IPHONE "
  65                 build_tests=no
  66                 ios_found=yes
  67         ;;
  68         x86_64-apple-darwin*|i686-apple-darwin*)
  69                 MSPLUGINS_CFLAGS=""
  70                 dnl use macport installation
  71                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  72                 build_macos=yes
  73         ;;
  74
  75 esac
  76
  77 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  78 AC_SUBST(CONSOLE_FLAGS)
  79 AC_SUBST(GUI_FLAGS)
  80
  81 dnl localization tools
  82 IT_PROG_INTLTOOL([0.40], [no-xml])
  83
  84 AM_CONDITIONAL(BUILD_TESTS,test x$build_tests != xno)
  85 dnl Initialize libtool
  86 LT_INIT([win32-dll shared disable-static])
  87
  88 AC_CONFIG_COMMANDS([libtool-hacking],[
  89 if test "$mingw_found" = "yes" ; then
  90         echo "Hacking libtool to work with mingw..."
  91         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  92         cp -f ./libtool.tmp ./libtool
  93         rm -f ./libtool.tmp
  94 fi
  95 ],[mingw_found=$mingw_found])
  96
  97 dnl Add the languages which your application supports here.
  98 PKG_PROG_PKG_CONFIG
  99 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
 100 AC_SUBST(ALL_LINGUAS)
 101 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
 102
 103 if test "$mingw_found" != "yes" ; then
 104 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 105 AM_GNU_GETTEXT([external])
 106 LIBS="$LIBS $LIBINTL"
 107 else
 108         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 109         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 110         LIBS="$LIBS -lintl"
 111 fi
 112
 113 GETTEXT_PACKAGE=linphone
 114 AC_SUBST(GETTEXT_PACKAGE)
 115 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 116 dnl AC_CHECK_LIB(intl,libintl_gettext)
 117
 118 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 119
 120 AC_ARG_ENABLE(x11,
 121                           [  --disable-x11    Disable X11 support],
 122                           [case "${enableval}" in
 123                           yes) enable_x11=true ;;
 124                           no)  enable_x11=false ;;
 125                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 126                           esac],[enable_x11=true])
 127
 128 dnl conditionnal build of console interface.
 129 AC_ARG_ENABLE(console_ui,
 130       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 131       [case "${enableval}" in
 132         yes) console_ui=true ;;
 133         no)  console_ui=false ;;
 134         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 135       esac],[console_ui=true])
 136
 137 dnl conditionnal build of gtk interface.
 138 AC_ARG_ENABLE(gtk_ui,
 139       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 140       [case "${enableval}" in
 141         yes) gtk_ui=true ;;
 142         no)  gtk_ui=false ;;
 143         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 144       esac],[gtk_ui=true])
 145
 146 if test "$gtk_ui" = "true" ; then
 147         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 148         if test "$enable_x11" = "false" ; then
 149                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 150                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 151         fi
 152 else
 153         echo "GTK interface compilation is disabled."
 154 fi
 155
 156
 157 dnl os-specific problems not handled by existing macros.
 158 case "$host_os" in
 159         *freebsd*)
 160                 LDFLAGS="$LDFLAGS -pthread"
 161                 ;;
 162 esac
 163
 164 case "$host_cpu" in
 165         *arm*)
 166                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 167                 use_arm_toolchain=yes
 168                 ;;
 169 esac
 170
 171 AC_ARG_WITH( configdir,
 172       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 173       [ configdir=${withval}],[ configdir="Linphone" ])
 174
 175 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 176
 177 AC_ARG_ENABLE(relativeprefix,
 178       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 179       [case "${enableval}" in
 180         yes) relativeprefix=yes ;;
 181         no)  relativeprefix=no ;;
 182         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 183       esac],[relativeprefix=guess])
 184
 185 AC_ARG_ENABLE(date,
 186       [  --enable-date    Use build date in internal version number],
 187       [case "${enableval}" in
 188         yes) use_date=yes ;;
 189         no)  use_date=no ;;
 190         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 191       esac],[use_date=no])
 192
 193 if test x$use_date =  xyes ; then
 194         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 195 fi
 196
 197
 198 dnl enable ipv6 support
 199 AC_ARG_ENABLE(ipv6,
 200       [  --enable-ipv6    Turn on ipv6 support],
 201       [case "${enableval}" in
 202         yes)  ipv6=true;;
 203         no)   ipv6=false;;
 204         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 205       esac],[ipv6=true])
 206 IPV6_CFLAGS=
 207 if test x$ipv6 = xtrue ; then
 208         IPV6_CFLAGS=-DINET6
 209 fi
 210 AC_SUBST(IPV6_CFLAGS)
 211
 212 dnl enable truespeech codec support
 213 AC_ARG_ENABLE(truespeech,
 214       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 215       [case "${enableval}" in
 216         yes)  truespeech=true;;
 217         no)   truespeech=false;;
 218         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 219       esac],[truespeech=false])
 220 TRUESPEECH_CFLAGS=
 221 if test x$truespeech = xtrue ; then
 222         TRUESPEECH_CFLAGS=-DTRUESPEECH
 223 fi
 224 AC_SUBST(TRUESPEECH_CFLAGS)
 225 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 226
 227 AC_ARG_ENABLE(nonstandard-gsm,
 228       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 229       [case "${enableval}" in
 230         yes) exotic_gsm=yes
 231         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 232          ;;
 233         no)  exotic_gsm=no ;;
 234         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 235       esac],[exotic_gsm=no])
 236
 237
 238 dnl support for RSVP (by Vincent Maury)
 239 AC_ARG_ENABLE(rsvp,
 240 [  --enable-rsvp           enable support for QoS reservations.],
 241 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 242 should be compiled.]) )
 243
 244 if test "x${prefix}" = "xNONE"; then
 245         package_prefix=${ac_default_prefix}
 246 else
 247         package_prefix=${prefix}
 248 fi
 249
 250 if test "$relativeprefix" = "guess" ; then
 251         if test "$mingw_found" = "yes" ; then
 252                 relativeprefix="yes"
 253         fi
 254 fi
 255
 256 if test "$relativeprefix" = "yes" ; then
 257         dnl allow binaries to install everywhere
 258         package_prefix="."
 259 fi
 260
 261 dnl Set PACKAGE_LOCALE_DIR in config.h.
 262 DATADIRNAME=share
 263 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 264
 265 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 266
 267 dnl Set PACKAGE_SOUND_DIR in config.h.
 268 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 269
 270
 271 dnl check if we have the getifaddrs() sytem call
 272 AC_CHECK_FUNCS(getifaddrs)
 273
 274 dnl check for osip2
 275 LP_CHECK_OSIP2
 276
 277 dnl conditionnal build for ssl
 278 AC_ARG_ENABLE(ssl,
 279                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 280                 [case "${enableval}" in
 281                 yes) build_ssl=true ;;
 282                 no)  build_ssl=false ;;
 283                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 284                 esac],[build_ssl=false])
 285
 286 if test "$build_ssl" = "true"; then
 287         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 288 fi
 289 dnl setup flags for exosip library
 290 LP_SETUP_EXOSIP
 291
 292 if test "$console_ui" = "true" ; then
 293 dnl check gnu readline
 294 LP_CHECK_READLINE
 295 else
 296 echo "Console interface compilation is disabled."
 297 fi
 298
 299 AC_WORDS_BIGENDIAN
 300
 301 dnl normaly this should only by done by mediastreamer2/configure.ac
 302 dnl but to workaround bugs when cross-compiling for arm-linux,
 303 dnl we need to have SPEEX_LIBS defined
 304 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 305 dnl since top-level configure --help will not print them.
 306
 307 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 308
 309 dnl conditionnal build of video support
 310 AC_ARG_ENABLE(video,
 311                 [  --enable-video    Turn on video support compiling],
 312                 [case "${enableval}" in
 313                 yes) video=true ;;
 314                 no)  video=false ;;
 315                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 316                 esac],[video=true])
 317
 318 AC_ARG_WITH( ffmpeg,
 319                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 320                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 321
 322 if test "$video" = "true"; then
 323
 324         if test "$enable_x11" = "true"; then
 325                 AC_CHECK_HEADERS(X11/Xlib.h)
 326                 if test "$build_macos" = "yes"; then
 327                         X11_LIBS="-L/usr/X11/lib -lX11"
 328                 else
 329                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 330                 fi
 331                 AC_SUBST(X11_LIBS)
 332         fi
 333         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 334 fi
 335
 336 AC_ARG_ENABLE(alsa,
 337       [  --enable-alsa    Turn on alsa native support compiling],
 338       [case "${enableval}" in
 339         yes) alsa=true ;;
 340         no)  alsa=false ;;
 341         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 342       esac],[alsa=true])
 343
 344 AC_ARG_ENABLE(artsc,
 345       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 346       [case "${enableval}" in
 347         yes) artsc=true ;;
 348         no)  artsc=false ;;
 349         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 350       esac],[artsc=false])
 351
 352 AC_ARG_ENABLE(portaudio,
 353       [  --enable-portaudio    Turn on portaudio native support compiling],
 354       [case "${enableval}" in
 355         yes) portaudio=true ;;
 356         no)  portaudio=false ;;
 357         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 358       esac],[portaudio=false])
 359
 360 dnl build console if required
 361 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 362 dnl special things for arm-linux cross compilation toolchain
 363 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 364 dnl compilation of gtk user interface
 365 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 366 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 367
 368 dnl check getenv
 369 AH_TEMPLATE([HAVE_GETENV])
 370 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 371
 372 dnl
 373 AC_MSG_CHECKING([for sighandler_t])
 374 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 375 has_sighandler_t=yes,has_sighandler_t=no)
 376 AC_MSG_RESULT($has_sighandler_t)
 377 if test "$has_sighandler_t" = "yes" ; then
 378     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 379 fi
 380
 381 ##################################################
 382 # Stricter build options (after external packages)
 383 ##################################################
 384
 385
 386 AC_ARG_ENABLE(strict,
 387         AC_HELP_STRING([--enable-strict],
 388                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 389         strictness="${enableval}"],[strictness=yes]
 390 )
 391
 392 STRICT_OPTIONS="-Wall "
 393
 394 if test "$GCC$strictness" = "yesyes" ; then
 395         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 396         CFLAGS="$CFLAGS -fno-strict-aliasing"
 397 fi
 398
 399 AC_SUBST(STRICT_OPTIONS)
 400
 401 top_srcdir=`dirname $0`
 402
 403 AC_ARG_ENABLE([external-mediastreamer],
 404       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 405       [enable_external_mediastreamer=no])
 406
 407 AS_CASE($enable_external_mediastreamer,
 408                 [yes],[
 409                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 410                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 411                         ],
 412                 [no],[
 413                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 414                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 415                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 416                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 417 dnl need to temporary change quotes to allow square brackets
 418                         changequote(<<, >>)
 419                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 420                         changequote([, ])
 421                         MS2_DIR=mediastreamer2
 422                         ],
 423         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 424
 425 AC_SUBST(MEDIASTREAMER_CFLAGS)
 426 AC_SUBST(MEDIASTREAMER_LIBS)
 427 AC_SUBST([MS2_VERSION])
 428 AC_SUBST([MS2_DIR])
 429
 430 dnl check for db2html (docbook) to generate html user manual
 431 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 432 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 433
 434 dnl for external use of linphone libs
 435 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 436 LINPHONE_LIBS="-L${libdir} -llinphone"
 437
 438 if test x$mingw_found = xyes ; then
 439         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 440 fi
 441 AC_SUBST(LINPHONE_CFLAGS)
 442 AC_SUBST(LINPHONE_LIBS)
 443
 444 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 445
 446 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 447 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 448 AC_SUBST(LINPHONE_PLUGINS_DIR)
 449
 450 AC_ARG_ENABLE(external-ortp,
 451       [  --enable-external-ortp    Use external oRTP library],
 452       [case "${enableval}" in
 453         yes) external_ortp=true ;;
 454         no)  external_ortp=false ;;
 455         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 456       esac],[external_ortp=false])
 457
 458 if test "$external_ortp" = 'true'; then
 459         PKG_CHECK_MODULES([ORTP], [ortp])
 460         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 461 else
 462         AC_CONFIG_SUBDIRS( oRTP )
 463         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 464         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 465         if test x$ac_cv_c_bigendian = xyes ; then
 466                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 467         fi
 468         ORTP_DIR=oRTP
 469         changequote(<<, >>)
 470         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 471         changequote([, ])
 472 fi
 473 AC_SUBST(ORTP_CFLAGS)
 474 AC_SUBST(ORTP_LIBS)
 475 AC_SUBST([ORTP_VERSION])
 476 AC_SUBST([ORTP_DIR])
 477
 478 AC_ARG_ENABLE(tests_enabled,
 479       [  --disable-tests    Disable compilation of tests],
 480       [case "${enableval}" in
 481         yes) tests_enabled=true ;;
 482         no)  tests_enabled=false ;;
 483         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 484       esac],[tests_enabled=false])
 485 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 486
 487 dnl ##################################################
 488 dnl # Check for doxygen
 489 dnl ##################################################
 490
 491 AC_PATH_PROG(DOXYGEN,doxygen,false)
 492 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 493
 494
 495 AC_CONFIG_FILES([
 496 Makefile
 497 build/Makefile
 498 build/macos/Makefile
 499 build/macos/Info-linphone.plist
 500 m4/Makefile
 501 po/Makefile.in
 502 pixmaps/Makefile
 503 coreapi/Makefile
 504 coreapi/help/Makefile
 505 coreapi/help/Doxyfile
 506 gtk/Makefile
 507 console/Makefile
 508 share/Makefile
 509 share/C/Makefile
 510 share/fr/Makefile
 511 share/it/Makefile
 512 share/ja/Makefile
 513 share/cs/Makefile
 514 share/linphone.pc
 515 share/linphone.desktop
 516 scripts/Makefile
 517 linphone.spec
 518 linphone.iss
 519 ])
 520
 521 AC_OUTPUT
 522
 523 echo "Linphone build configuration ended."
 524
 525 if test x$gtk_ui = xtrue ; then
 526         echo "* GTK interface will be compiled."
 527 fi
 528 if test x$console_ui = xtrue ; then
 529         echo "* Console interface will be compiled."
 530 fi
 531
 532 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 533