sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.3],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44
  45 case $target_os in
  46         *mingw32ce)
  47         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  48         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  49         LIBS="$LIBS -lws2 -liphlpapi"
  50                 mingw_found=yes
  51                 mingwce_found=yes
  52                 ;;
  53         *mingw*)
  54                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  55                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  56                 LIBS="$LIBS -lws2_32"
  57                 GUI_FLAGS="-mwindows"
  58                 CONSOLE_FLAGS="-mconsole"
  59                 mingw_found=yes
  60         ;;
  61         *darwin*)
  62                 dnl use macport installation
  63                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  64                 build_macos=yes
  65         ;;
  66 esac
  67
  68 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  69 AC_SUBST(CONSOLE_FLAGS)
  70 AC_SUBST(GUI_FLAGS)
  71
  72 dnl localization tools
  73 IT_PROG_INTLTOOL([0.40], [no-xml])
  74
  75 dnl Initialize libtool
  76 LT_INIT([win32-dll shared disable-static])
  77
  78 AC_CONFIG_COMMANDS([libtool-hacking],[
  79 if test "$mingw_found" = "yes" ; then
  80         echo "Hacking libtool to work with mingw..."
  81         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  82         cp -f ./libtool.tmp ./libtool
  83         rm -f ./libtool.tmp
  84 fi
  85 ],[mingw_found=$mingw_found])
  86
  87 dnl Add the languages which your application supports here.
  88 PKG_PROG_PKG_CONFIG
  89 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  90 AC_SUBST(ALL_LINGUAS)
  91 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  92
  93 if test "$mingw_found" != "yes" ; then
  94 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  95 AM_GNU_GETTEXT([external])
  96 LIBS="$LIBS $LIBINTL"
  97 else
  98         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
  99         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 100         LIBS="$LIBS -lintl"
 101 fi
 102
 103 GETTEXT_PACKAGE=linphone
 104 AC_SUBST(GETTEXT_PACKAGE)
 105 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 106 dnl AC_CHECK_LIB(intl,libintl_gettext)
 107
 108 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 109
 110 AC_ARG_ENABLE(x11,
 111                           [  --disable-x11    Disable X11 support],
 112                           [case "${enableval}" in
 113                           yes) enable_x11=true ;;
 114                           no)  enable_x11=false ;;
 115                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 116                           esac],[enable_x11=true])
 117
 118 dnl conditionnal build of console interface.
 119 AC_ARG_ENABLE(console_ui,
 120       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 121       [case "${enableval}" in
 122         yes) console_ui=true ;;
 123         no)  console_ui=false ;;
 124         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 125       esac],[console_ui=true])
 126
 127 dnl conditionnal build of gtk interface.
 128 AC_ARG_ENABLE(gtk_ui,
 129       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 130       [case "${enableval}" in
 131         yes) gtk_ui=true ;;
 132         no)  gtk_ui=false ;;
 133         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 134       esac],[gtk_ui=true])
 135
 136 if test "$gtk_ui" = "true" ; then
 137         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 138         if test "$enable_x11" = "false" ; then
 139                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 140                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 141         fi
 142 else
 143         echo "GTK interface compilation is disabled."
 144 fi
 145
 146
 147 dnl os-specific problems not handled by existing macros.
 148 case "$host_os" in
 149         *freebsd*)
 150                 LDFLAGS="$LDFLAGS -pthread"
 151                 ;;
 152 esac
 153
 154 case "$host_cpu" in
 155         *arm*)
 156                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 157                 use_arm_toolchain=yes
 158                 ;;
 159 esac
 160
 161 AC_ARG_WITH( configdir,
 162       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 163       [ configdir=${withval}],[ configdir="Linphone" ])
 164
 165 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 166
 167 AC_ARG_ENABLE(relativeprefix,
 168       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 169       [case "${enableval}" in
 170         yes) relativeprefix=yes ;;
 171         no)  relativeprefix=no ;;
 172         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 173       esac],[relativeprefix=auto])
 174
 175 AC_ARG_ENABLE(date,
 176       [  --enable-date    Use build date in internal version number],
 177       [case "${enableval}" in
 178         yes) use_date=yes ;;
 179         no)  use_date=no ;;
 180         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 181       esac],[use_date=no])
 182
 183 if test x$use_date =  xyes ; then
 184         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 185 fi
 186
 187
 188 dnl enable ipv6 support
 189 AC_ARG_ENABLE(ipv6,
 190       [  --enable-ipv6    Turn on ipv6 support],
 191       [case "${enableval}" in
 192         yes)  ipv6=true;;
 193         no)   ipv6=false;;
 194         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 195       esac],[ipv6=true])
 196 IPV6_CFLAGS=
 197 if test x$ipv6 = xtrue ; then
 198         IPV6_CFLAGS=-DINET6
 199 fi
 200 AC_SUBST(IPV6_CFLAGS)
 201
 202 dnl enable truespeech codec support
 203 AC_ARG_ENABLE(truespeech,
 204       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 205       [case "${enableval}" in
 206         yes)  truespeech=true;;
 207         no)   truespeech=false;;
 208         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 209       esac],[truespeech=false])
 210 TRUESPEECH_CFLAGS=
 211 if test x$truespeech = xtrue ; then
 212         TRUESPEECH_CFLAGS=-DTRUESPEECH
 213 fi
 214 AC_SUBST(TRUESPEECH_CFLAGS)
 215 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 216
 217 AC_ARG_ENABLE(nonstandard-gsm,
 218       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 219       [case "${enableval}" in
 220         yes) exotic_gsm=yes
 221         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 222          ;;
 223         no)  exotic_gsm=no ;;
 224         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 225       esac],[exotic_gsm=no])
 226
 227
 228 dnl support for RSVP (by Vincent Maury)
 229 AC_ARG_ENABLE(rsvp,
 230 [  --enable-rsvp           enable support for QoS reservations.],
 231 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 232 should be compiled.]) )
 233
 234 if test "x${prefix}" = "xNONE"; then
 235         package_prefix=${ac_default_prefix}
 236 else
 237         package_prefix=${prefix}
 238 fi
 239
 240 if test "$relativeprefix" = "auto" ; then
 241         case $target_os in
 242                 *darwin*)
 243                 if test "$enable_x11" = "false" ; then
 244                         relativeprefix=yes
 245                 fi
 246                 ;;
 247                 *mingw*)
 248                 relativeprefix=yes
 249                 ;;
 250         esac
 251 fi
 252
 253 if test "$relativeprefix" = "yes" ; then
 254         dnl allow binaries to install everywhere
 255         package_prefix="."
 256 fi
 257
 258 dnl Set PACKAGE_LOCALE_DIR in config.h.
 259 DATADIRNAME=share
 260 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 261
 262 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 263
 264 dnl Set PACKAGE_SOUND_DIR in config.h.
 265 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 266
 267
 268 dnl check if we have the getifaddrs() sytem call
 269 AC_CHECK_FUNCS(getifaddrs)
 270
 271 dnl check for osip2
 272 LP_CHECK_OSIP2
 273
 274 dnl conditionnal build for ssl
 275 AC_ARG_ENABLE(ssl,
 276                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 277                 [case "${enableval}" in
 278                 yes) build_ssl=true ;;
 279                 no)  build_ssl=false ;;
 280                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 281                 esac],[build_ssl=false])
 282
 283 if test "$build_ssl" = "true"; then
 284         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 285 fi
 286 dnl setup flags for exosip library
 287 LP_SETUP_EXOSIP
 288
 289 if test "$console_ui" = "true" ; then
 290 dnl check gnu readline
 291 LP_CHECK_READLINE
 292 else
 293 echo "Console interface compilation is disabled."
 294 fi
 295
 296 AC_WORDS_BIGENDIAN
 297
 298 dnl normaly this should only by done by mediastreamer2/configure.ac
 299 dnl but to workaround bugs when cross-compiling for arm-linux,
 300 dnl we need to have SPEEX_LIBS defined
 301 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 302 dnl since top-level configure --help will not print them.
 303
 304 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 305
 306 dnl conditionnal build of video support
 307 AC_ARG_ENABLE(video,
 308                 [  --enable-video    Turn on video support compiling],
 309                 [case "${enableval}" in
 310                 yes) video=true ;;
 311                 no)  video=false ;;
 312                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 313                 esac],[video=true])
 314
 315 AC_ARG_WITH( ffmpeg,
 316                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 317                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 318
 319 if test "$video" = "true"; then
 320
 321         if test "$enable_x11" = "true"; then
 322                 AC_CHECK_HEADERS(X11/Xlib.h)
 323                 if test "$build_macos" = "yes"; then
 324                         X11_LIBS="-L/usr/X11/lib -lX11"
 325                 else
 326                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 327                 fi
 328                 AC_SUBST(X11_LIBS)
 329         fi
 330         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 331 fi
 332
 333 AC_ARG_ENABLE(alsa,
 334       [  --enable-alsa    Turn on alsa native support compiling],
 335       [case "${enableval}" in
 336         yes) alsa=true ;;
 337         no)  alsa=false ;;
 338         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 339       esac],[alsa=true])
 340
 341 AC_ARG_ENABLE(artsc,
 342       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 343       [case "${enableval}" in
 344         yes) artsc=true ;;
 345         no)  artsc=false ;;
 346         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 347       esac],[artsc=false])
 348
 349 AC_ARG_ENABLE(portaudio,
 350       [  --enable-portaudio    Turn on portaudio native support compiling],
 351       [case "${enableval}" in
 352         yes) portaudio=true ;;
 353         no)  portaudio=false ;;
 354         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 355       esac],[portaudio=false])
 356
 357 dnl build console if required
 358 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 359 dnl special things for arm-linux cross compilation toolchain
 360 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 361 dnl compilation of gtk user interface
 362 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 363 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 364
 365 dnl check getenv
 366 AH_TEMPLATE([HAVE_GETENV])
 367 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 368
 369 dnl
 370 AC_MSG_CHECKING([for sighandler_t])
 371 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 372 has_sighandler_t=yes,has_sighandler_t=no)
 373 AC_MSG_RESULT($has_sighandler_t)
 374 if test "$has_sighandler_t" = "yes" ; then
 375     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 376 fi
 377
 378 ##################################################
 379 # Stricter build options (after external packages)
 380 ##################################################
 381
 382
 383 AC_ARG_ENABLE(strict,
 384         AC_HELP_STRING([--enable-strict],
 385                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 386         strictness="${enableval}"],[strictness=yes]
 387 )
 388
 389 STRICT_OPTIONS="-Wall "
 390
 391 if test "$GCC$strictness" = "yesyes" ; then
 392         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 393         CFLAGS="$CFLAGS -fno-strict-aliasing"
 394 fi
 395
 396 AC_SUBST(STRICT_OPTIONS)
 397
 398 top_srcdir=`dirname $0`
 399
 400 AC_ARG_ENABLE([external-mediastreamer],
 401       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 402       [enable_external_mediastreamer=no])
 403
 404 AS_CASE($enable_external_mediastreamer,
 405                 [yes],[
 406                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 407                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 408                         ],
 409                 [no],[
 410                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 411                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 412                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 413                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 414 dnl need to temporary change quotes to allow square brackets
 415                         changequote(<<, >>)
 416                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 417                         changequote([, ])
 418                         MS2_DIR=mediastreamer2
 419                         ],
 420         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 421
 422 AC_SUBST(MEDIASTREAMER_CFLAGS)
 423 AC_SUBST(MEDIASTREAMER_LIBS)
 424 AC_SUBST([MS2_VERSION])
 425 AC_SUBST([MS2_DIR])
 426
 427 dnl check for db2html (docbook) to generate html user manual
 428 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 429 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 430
 431 dnl for external use of linphone libs
 432 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 433 LINPHONE_LIBS="-L${libdir} -llinphone"
 434
 435 if test x$mingw_found = xyes ; then
 436         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 437 fi
 438 AC_SUBST(LINPHONE_CFLAGS)
 439 AC_SUBST(LINPHONE_LIBS)
 440
 441 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 442
 443 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 444 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 445 AC_SUBST(LINPHONE_PLUGINS_DIR)
 446
 447 AC_ARG_ENABLE(external-ortp,
 448       [  --enable-external-ortp    Use external oRTP library],
 449       [case "${enableval}" in
 450         yes) external_ortp=true ;;
 451         no)  external_ortp=false ;;
 452         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 453       esac],[external_ortp=false])
 454
 455 if test "$external_ortp" = 'true'; then
 456         PKG_CHECK_MODULES([ORTP], [ortp])
 457         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 458 else
 459         AC_CONFIG_SUBDIRS( oRTP )
 460         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 461         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 462         if test x$ac_cv_c_bigendian = xyes ; then
 463                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 464         fi
 465         ORTP_DIR=oRTP
 466         changequote(<<, >>)
 467         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 468         changequote([, ])
 469 fi
 470 AC_SUBST(ORTP_CFLAGS)
 471 AC_SUBST(ORTP_LIBS)
 472 AC_SUBST([ORTP_VERSION])
 473 AC_SUBST([ORTP_DIR])
 474
 475 dnl ##################################################
 476 dnl # Check for doxygen
 477 dnl ##################################################
 478
 479 AC_PATH_PROG(DOXYGEN,doxygen,false)
 480 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 481
 482
 483 AC_CONFIG_FILES([
 484 Makefile
 485 build/Makefile
 486 build/macos/Makefile
 487 build/macos/Info-linphone.plist
 488 m4/Makefile
 489 po/Makefile.in
 490 pixmaps/Makefile
 491 coreapi/Makefile
 492 coreapi/help/Makefile
 493 coreapi/help/Doxyfile
 494 gtk/Makefile
 495 console/Makefile
 496 share/Makefile
 497 share/C/Makefile
 498 share/fr/Makefile
 499 share/it/Makefile
 500 share/ja/Makefile
 501 share/cs/Makefile
 502 share/linphone.pc
 503 share/linphone.desktop
 504 scripts/Makefile
 505 linphone.spec
 506 linphone.iss
 507 ])
 508
 509 AC_OUTPUT
 510
 511 echo "Linphone build configuration ended."
 512
 513 if test x$gtk_ui = xtrue ; then
 514         echo "* GTK interface will be compiled."
 515 fi
 516 if test x$console_ui = xtrue ; then
 517         echo "* Console interface will be compiled."
 518 fi
 519
 520 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 521