sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.5.99.0],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=5 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_SUBST([docdir], [${datadir}/doc])
  36 AC_CONFIG_HEADERS(config.h)
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_C_INLINE
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63        armv6-apple-darwin|armv7-apple-darwin|i386-apple-darwin|armv7s-apple-darwin)
  64                 CFLAGS="$CFLAGS -DTARGET_OS_IPHONE "
  65                 build_tests=no
  66                 ios_found=yes
  67         ;;
  68         x86_64-apple-darwin*|i686-apple-darwin*)
  69         MSPLUGINS_CFLAGS=""
  70                 dnl use macport installation
  71                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  72                 build_macos=yes
  73         ;;
  74
  75 esac
  76
  77 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  78 AC_SUBST(CONSOLE_FLAGS)
  79 AC_SUBST(GUI_FLAGS)
  80
  81 dnl localization tools
  82 IT_PROG_INTLTOOL([0.40], [no-xml])
  83
  84 AM_CONDITIONAL(BUILD_TESTS,test x$build_tests != xno)
  85 dnl Initialize libtool
  86 LT_INIT([win32-dll shared disable-static])
  87
  88 AC_CONFIG_COMMANDS([libtool-hacking],[
  89 if test "$mingw_found" = "yes" ; then
  90         echo "Hacking libtool to work with mingw..."
  91         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  92         cp -f ./libtool.tmp ./libtool
  93         rm -f ./libtool.tmp
  94 fi
  95 ],[mingw_found=$mingw_found])
  96
  97 dnl Add the languages which your application supports here.
  98 PKG_PROG_PKG_CONFIG
  99 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW he"
 100 AC_SUBST(ALL_LINGUAS)
 101 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
 102
 103 if test "$mingw_found" != "yes" ; then
 104         dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 105
 106         dnl AM_GNU_GETTEXT pollutes CPPFLAGS: workaround this.
 107         CPPFLAGS_save=$CPPFLAGS
 108         AM_GNU_GETTEXT([external])
 109         AC_SUBST(INTLLIBS)
 110         CPPFLAGS=$CPPFLAGS_save
 111         LIBS="$LIBS $LIBINTL"
 112 else
 113         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 114         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 115         LIBS="$LIBS -lintl"
 116 fi
 117
 118 GETTEXT_PACKAGE=linphone
 119 AC_SUBST(GETTEXT_PACKAGE)
 120 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext package name])
 121 dnl AC_CHECK_LIB(intl,libintl_gettext)
 122
 123 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 124
 125 AC_ARG_ENABLE(x11,
 126       [AS_HELP_STRING([--disable-x11], [Disable X11 support (default=no)])],
 127       [case "${enableval}" in
 128         yes) enable_x11=true ;;
 129         no)  enable_x11=false ;;
 130         *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 131       esac],[enable_x11=true])
 132
 133 dnl conditionnal build of console interface.
 134 AC_ARG_ENABLE(console_ui,
 135       [AS_HELP_STRING([--enable-console_ui=[yes/no]], [Turn on or off compilation of console interface (default=yes)])],
 136       [case "${enableval}" in
 137         yes) console_ui=true ;;
 138         no)  console_ui=false ;;
 139         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 140       esac],[console_ui=true])
 141
 142 dnl conditionnal build of tools.
 143 AC_ARG_ENABLE(tools,
 144       [AS_HELP_STRING([--enable-tools=[yes/no]], [Turn on or off compilation of console interface (default=yes)])],
 145       [case "${enableval}" in
 146         yes) build_tools=true ;;
 147         no)  build_tools=false ;;
 148         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tools) ;;
 149       esac],[build_tools=check])
 150
 151 dnl check libxml2 (needed for tools)
 152 if test "$build_tools" != "false" ; then
 153         PKG_CHECK_MODULES(LIBXML2, [libxml-2.0],[],
 154         [
 155                 if test "$build_tools" = "true" ; then
 156                         AC_MSG_ERROR([Could not found libxml2, tools cannot be compiled.])
 157                 else
 158                         build_tools=false
 159                 fi
 160         ])
 161 fi
 162
 163 AM_CONDITIONAL(BUILD_TOOLS, test x$build_tools != xfalse)
 164 if test "$build_tools" != "false" ; then
 165    build_tools=true
 166    AC_DEFINE(BUILD_TOOLS, 1, [Define if tools enabled] )
 167 fi
 168
 169 dnl conditionnal build of gtk interface.
 170 AC_ARG_ENABLE(gtk_ui,
 171       [AS_HELP_STRING([--enable-gtk_ui=[yes/no]], [Turn on or off compilation of gtk interface (default=yes)])],
 172       [case "${enableval}" in
 173         yes) gtk_ui=true ;;
 174         no)  gtk_ui=false ;;
 175         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 176       esac],[gtk_ui=true])
 177
 178 if test "$gtk_ui" = "true" ; then
 179         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.18.0 gthread-2.0)
 180         if test "$enable_x11" = "false" ; then
 181                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 182                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 183         fi
 184 else
 185         echo "GTK interface compilation is disabled."
 186 fi
 187
 188 AC_ARG_ENABLE(notify,
 189       [AS_HELP_STRING([--enable-notify=[yes/no]], [Enable libnotify support (default=yes)])],
 190       [case "${enableval}" in
 191         yes) notify=true ;;
 192         no)  notify=false ;;
 193         *) AC_MSG_ERROR(bad value ${enableval} for --enable-notify) ;;
 194       esac],[notify=true])
 195
 196 dnl conditionnal build of the notify library
 197 if test "$gtk_ui" = "true" ; then
 198         if test "$notify" = "true"; then
 199                 PKG_CHECK_MODULES([NOTIFY4], [libnotify >= 0.7.0 ], [found_notify4=yes], foo=bar)
 200                 case "$found_notify4" in
 201                   yes)
 202                                 AC_SUBST(NOTIFY4_CFLAGS)
 203                                 AC_SUBST(NOTIFY4_LIBS)
 204                                 AC_DEFINE([HAVE_NOTIFY4],[1],[NOTIFY4 support])
 205                 esac
 206
 207                 PKG_CHECK_MODULES([NOTIFY1], [libnotify < 0.7.0], [found_notify1=yes], foo=bar)
 208                 case "$found_notify1" in
 209                   yes)
 210                                 AC_SUBST(NOTIFY1_CFLAGS)
 211                                 AC_SUBST(NOTIFY1_LIBS)
 212                                 AC_DEFINE([HAVE_NOTIFY1],[1],[NOTIFY1 support])
 213                 esac
 214         else
 215                                 NotifyNotification *n;
 216                 echo "Libnotify support is disabled."
 217         fi
 218 fi
 219
 220 dnl os-specific problems not handled by existing macros.
 221 case "$host_os" in
 222         *freebsd*)
 223                 LDFLAGS="$LDFLAGS -pthread"
 224                 ;;
 225 esac
 226
 227 case "$host_cpu" in
 228         *arm*)
 229                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 230                 use_arm_toolchain=yes
 231                 ;;
 232 esac
 233
 234 AC_ARG_WITH(configdir,
 235       [AS_HELP_STRING([--with-configdir], [Set a APPDATA subdir where linphone is supposed to find its config (windows only)])],
 236       [ configdir=${withval}],[ configdir="Linphone" ])
 237
 238 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 239
 240 AC_ARG_ENABLE(relativeprefix,
 241       [AS_HELP_STRING([--enable-relativeprefix], [Build a linphone that finds its resources relatively to the directory where it is installed])],
 242       [case "${enableval}" in
 243         yes) relativeprefix=yes ;;
 244         no)  relativeprefix=no ;;
 245         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 246       esac],[relativeprefix=guess])
 247
 248 AC_ARG_ENABLE(date,
 249       [AS_HELP_STRING([--enable-date], [Use build date in internal version number])],
 250       [case "${enableval}" in
 251         yes) use_date=yes ;;
 252         no)  use_date=no ;;
 253         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 254       esac],[use_date=no])
 255
 256 if test x$use_date =  xyes ; then
 257         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 258 fi
 259
 260
 261 dnl enable ipv6 support
 262 AC_ARG_ENABLE(ipv6,
 263       [AS_HELP_STRING([--enable-ipv6], [Turn on ipv6 support])],
 264       [case "${enableval}" in
 265         yes)  ipv6=true;;
 266         no)   ipv6=false;;
 267         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 268       esac],[ipv6=true])
 269 IPV6_CFLAGS=
 270 if test x$ipv6 = xtrue ; then
 271         IPV6_CFLAGS=-DINET6
 272 fi
 273 AC_SUBST(IPV6_CFLAGS)
 274
 275 dnl enable timestamp support
 276 AC_ARG_ENABLE(ntp-timestamp,
 277       [AS_HELP_STRING([--enable-ntp-timestamp], [Turn on NTP timestamping on received packet])],
 278       [case "${enableval}" in
 279         yes)  ntptimestamp=true;;
 280         no)   ntptimestamp=false;;
 281         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ntp-timestamp) ;;
 282       esac],[ntptimestamp=false])
 283
 284 AC_ARG_ENABLE(debug,
 285       [AS_HELP_STRING([--enable-debug=[yes/no]], [Enables the display of traces showing the execution of the library. (default=yes)])],
 286       [case "${enableval}" in
 287         yes) debug_enabled=yes;;
 288         no) debug_enabled=no;;
 289         *) AC_MSG_ERROR("Bad value for --enable-debug");;
 290       esac],[debug_enabled=no])
 291
 292 dnl enable truespeech codec support
 293 AC_ARG_ENABLE(truespeech,
 294       [AS_HELP_STRING([--enable-truespeech], [Turn on TrueSpeech support (x86 only)])],
 295       [case "${enableval}" in
 296         yes)  truespeech=true;;
 297         no)   truespeech=false;;
 298         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 299       esac],[truespeech=false])
 300 TRUESPEECH_CFLAGS=
 301 if test x$truespeech = xtrue ; then
 302         TRUESPEECH_CFLAGS=-DTRUESPEECH
 303 fi
 304 AC_SUBST(TRUESPEECH_CFLAGS)
 305 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 306
 307 AC_ARG_ENABLE(nonstandard-gsm,
 308       [AS_HELP_STRING([--enable-nonstandard-gsm], [Enable GSM codec at nonstandard rates (11025hz, 16000hz)])],
 309       [case "${enableval}" in
 310         yes) exotic_gsm=yes
 311          AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 312          ;;
 313         no)  exotic_gsm=no ;;
 314         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 315       esac],[exotic_gsm=no])
 316
 317
 318 dnl support for RSVP (by Vincent Maury)
 319 AC_ARG_ENABLE(rsvp,
 320 [AS_HELP_STRING([--enable-rsvp], [Enable support for QoS reservations.])],
 321 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 322 should be compiled.]) )
 323
 324 if test "x${prefix}" = "xNONE"; then
 325         package_prefix=${ac_default_prefix}
 326 else
 327         package_prefix=${prefix}
 328 fi
 329
 330 if test "$relativeprefix" = "guess" ; then
 331         if test "$mingw_found" = "yes" ; then
 332                 relativeprefix="yes"
 333         fi
 334 fi
 335
 336 if test "$relativeprefix" = "yes" ; then
 337         dnl allow binaries to install everywhere
 338         package_prefix="."
 339 fi
 340
 341 dnl Set PACKAGE_LOCALE_DIR in config.h.
 342 DATADIRNAME=share
 343 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 344
 345 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 346
 347 dnl Set PACKAGE_SOUND_DIR in config.h.
 348 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 349
 350
 351 dnl check if we have the getifaddrs() sytem call
 352 AC_CHECK_FUNCS(getifaddrs)
 353
 354 dnl check for osip2
 355 LP_CHECK_OSIP2
 356
 357 dnl conditionnal build for ssl
 358 AC_ARG_ENABLE(ssl,
 359       [AS_HELP_STRING([--enable-ssl], [Turn on ssl support compiling. Required for sip tls. (default=false)])],
 360       [case "${enableval}" in
 361         yes) build_ssl=true ;;
 362         no)  build_ssl=false ;;
 363         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 364       esac],[build_ssl=false])
 365
 366 if test "$build_ssl" = "true"; then
 367         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 368 fi
 369 dnl setup flags for exosip library
 370 LP_SETUP_EXOSIP
 371
 372 dnl check exosip support of DSCP in exosip
 373 AC_MSG_CHECKING([for DSCP support in exosip])
 374 AC_TRY_COMPILE([#include <eXosip2/eXosip.h>],
 375 [int dscp=0;eXosip_set_option(EXOSIP_OPT_SET_DSCP,&dscp);],
 376 has_exosip_dscp=yes,has_exosip_dscp=no)
 377 AC_MSG_RESULT($has_exosip_dscp)
 378 if test "$has_exosip_dscp" = "yes" ; then
 379     AC_DEFINE( HAVE_EXOSIP_DSCP, 1, [Define if exosip dscp available] )
 380 fi
 381
 382
 383 if test "$console_ui" = "true" ; then
 384 dnl check gnu readline
 385 LP_CHECK_READLINE
 386 else
 387 echo "Console interface compilation is disabled."
 388 fi
 389
 390 AC_WORDS_BIGENDIAN
 391
 392 AC_ARG_ENABLE([speex],
 393               AS_HELP_STRING([--disable-speex], [Disable speex support]),
 394               [], [enable_speex=yes])
 395 if test "x$enable_speex" = "xyes"; then
 396         dnl normaly this should only by done by mediastreamer2/configure.ac
 397         dnl but to workaround bugs when cross-compiling for arm-linux,
 398         dnl we need to have SPEEX_LIBS defined
 399         dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 400         dnl since top-level configure --help will not print them.
 401         PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 402 fi
 403
 404 dnl conditionnal build of video support
 405 AC_ARG_ENABLE(video,
 406       [AS_HELP_STRING([--enable-video], [Turn on video support compiling])],
 407       [case "${enableval}" in
 408         yes) video=true ;;
 409         no)  video=false ;;
 410         *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 411       esac],[video=true])
 412
 413 AC_ARG_WITH( ffmpeg,
 414       [AS_HELP_STRING([--with-ffmpeg], [Sets the installation prefix of ffmpeg, needed for video support. (default=/usr)])],
 415       [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 416
 417 if test "$video" = "true"; then
 418
 419         if test "$enable_x11" = "true"; then
 420                 AC_CHECK_HEADERS(X11/Xlib.h)
 421                 if test "$build_macos" = "yes"; then
 422                         X11_LIBS="-L/usr/X11/lib -lX11"
 423                 else
 424                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 425                 fi
 426                 AC_SUBST(X11_LIBS)
 427         fi
 428         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 429 fi
 430
 431 AC_ARG_ENABLE(alsa,
 432       [AS_HELP_STRING([--enable-alsa], [Turn on alsa native support compiling])],
 433       [case "${enableval}" in
 434         yes) alsa=true ;;
 435         no)  alsa=false ;;
 436         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 437       esac],[alsa=true])
 438
 439 AC_ARG_ENABLE(zrtp,
 440       [AS_HELP_STRING([--enable-zrtp], [Turn on zrtp support])],
 441       [case "${enableval}" in
 442         yes) zrtp=true ;;
 443         no)  zrtp=false ;;
 444         *) AC_MSG_ERROR(bad value ${enableval} for --enable-zrtp) ;;
 445       esac],[zrtp=false])
 446
 447
 448 AC_ARG_ENABLE(portaudio,
 449       [AS_HELP_STRING([--enable-portaudio], [Turn on portaudio native support compiling])],
 450       [case "${enableval}" in
 451         yes) portaudio=true ;;
 452         no)  portaudio=false ;;
 453         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 454       esac],[portaudio=false])
 455
 456 dnl build console if required
 457 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 458
 459 dnl special things for arm-linux cross compilation toolchain
 460 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 461
 462 dnl compilation of gtk user interface
 463 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 464 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 465 AM_CONDITIONAL(BUILD_ZRTP, test x$zrtp = xtrue)
 466
 467 dnl check getenv
 468 AH_TEMPLATE([HAVE_GETENV])
 469 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 470
 471 dnl
 472 AC_MSG_CHECKING([for sighandler_t])
 473 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 474 has_sighandler_t=yes,has_sighandler_t=no)
 475 AC_MSG_RESULT($has_sighandler_t)
 476 if test "$has_sighandler_t" = "yes" ; then
 477     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 478 fi
 479
 480 AC_ARG_ENABLE(assistant,
 481       [AS_HELP_STRING([--enable-assistant], [Turn on assistant compiling])],
 482       [case "${enableval}" in
 483         yes) build_wizard=true ;;
 484         no)  build_wizard=false ;;
 485         *) AC_MSG_ERROR(bad value ${enableval} for --enable-assistant) ;;
 486       esac],[build_wizard=check])
 487
 488 dnl check libsoup (needed for wizard)
 489 if test "$build_wizard" != "false" ; then
 490         PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26],[],
 491         [
 492                 if test "$build_wizard" = "true" ; then
 493                         AC_MSG_ERROR([Could not found libsoup, assistant cannot be compiled.])
 494                 else
 495                         build_wizard=false
 496                 fi
 497         ])
 498 fi
 499 if test "$build_wizard" != "false" ; then
 500         PKG_CHECK_MODULES(LIBGTKWIZARD, [gtk+-2.0 >= 2.22.0],[],
 501         [
 502                 if test "$build_wizard" = "true" ; then
 503                         AC_MSG_ERROR([gtk+-2.0 < 2.22.0, assistant cannot be compiled.])
 504                 else
 505                         build_wizard=false
 506                 fi
 507         ])
 508 fi
 509 AC_SUBST(LIBSOUP_CFLAGS)
 510 AC_SUBST(LIBSOUP_LIBS)
 511 AM_CONDITIONAL(BUILD_WIZARD, test x$build_wizard != xfalse)
 512 if test "$build_wizard" != "false" ; then
 513    build_wizard=true
 514    AC_DEFINE(BUILD_WIZARD, 1, [Define if wizard enabled] )
 515 fi
 516
 517 AC_CHECK_HEADERS(libudev.h)
 518 AC_CHECK_LIB(udev,udev_new)
 519
 520 ##################################################
 521 # Stricter build options (after external packages)
 522 ##################################################
 523
 524
 525 AC_ARG_ENABLE(strict,
 526         AC_HELP_STRING([--enable-strict],
 527                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 528         strictness="${enableval}"],[strictness=yes]
 529 )
 530
 531 STRICT_OPTIONS="-Wall "
 532
 533 if test "$strictness" = "yes" ; then
 534         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 535         CFLAGS="$CFLAGS -fno-strict-aliasing"
 536 fi
 537
 538 AC_SUBST(STRICT_OPTIONS)
 539
 540 top_srcdir=`dirname $0`
 541
 542 AC_ARG_ENABLE([external-mediastreamer],
 543       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 544       [enable_external_mediastreamer=no])
 545
 546 AS_CASE($enable_external_mediastreamer,
 547                 [yes],[
 548                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 549                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 550                         ],
 551                 [no],[
 552                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 553                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 554                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 555                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer_base.la \$(top_builddir)/mediastreamer2/src/libmediastreamer_voip.la"
 556 dnl need to temporary change quotes to allow square brackets
 557                         changequote(<<, >>)
 558                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 559                         changequote([, ])
 560                         MS2_DIR=mediastreamer2
 561                         ],
 562         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 563
 564 AC_SUBST(MEDIASTREAMER_CFLAGS)
 565 AC_SUBST(MEDIASTREAMER_LIBS)
 566 AC_SUBST([MS2_VERSION])
 567 AC_SUBST([MS2_DIR])
 568
 569
 570
 571 AC_ARG_ENABLE(tunnel,
 572       [AS_HELP_STRING([--enable-tunnel=[yes/no]], [Turn on compilation of tunnel support (default=no)])],
 573       [case "${enableval}" in
 574         yes) enable_tunnel=true ;;
 575         no)  enable_tunnel=false ;;
 576         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tunnel) ;;
 577       esac],[enable_tunnel=false])
 578 AM_CONDITIONAL(BUILD_TUNNEL, test x$enable_tunnel = xtrue)
 579 if test x$enable_tunnel = xtrue; then
 580      PKG_CHECK_MODULES(TUNNEL, tunnel >= 0.3.3)
 581      TUNNEL_CFLAGS+="-DTUNNEL_ENABLED"
 582      AC_SUBST(TUNNEL_CFLAGS)
 583      AC_SUBST(TUNNEL_LIBS)
 584 fi
 585
 586
 587
 588
 589
 590
 591
 592
 593
 594
 595 dnl check for db2html (docbook) to generate html user manual
 596 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 597 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 598
 599 dnl for external use of linphone libs
 600 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 601 LINPHONE_LIBS="-L${libdir} -llinphone"
 602
 603 if test x$mingw_found = xyes ; then
 604         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 605 fi
 606 AC_SUBST(LINPHONE_CFLAGS)
 607 AC_SUBST(LINPHONE_LIBS)
 608
 609 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 610
 611 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 612 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 613 AC_SUBST(LINPHONE_PLUGINS_DIR)
 614
 615 AC_ARG_ENABLE(external-ortp,
 616       [AS_HELP_STRING([--enable-external-ortp], [Use external oRTP library])],
 617       [case "${enableval}" in
 618         yes) external_ortp=true ;;
 619         no)  external_ortp=false ;;
 620         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 621       esac],[external_ortp=false])
 622
 623 if test "$external_ortp" = 'true'; then
 624         PKG_CHECK_MODULES([ORTP], [ortp])
 625         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 626 else
 627         AC_CONFIG_SUBDIRS( oRTP )
 628         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 629         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 630         if test x$ac_cv_c_bigendian = xyes ; then
 631                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 632         fi
 633         if test x$ntptimestamp = xtrue ; then
 634                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_TIMESTAMP"
 635         fi
 636         ORTP_DIR=oRTP
 637         changequote(<<, >>)
 638         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 639         changequote([, ])
 640 fi
 641 AC_SUBST(ORTP_CFLAGS)
 642 AC_SUBST(ORTP_LIBS)
 643 AC_SUBST([ORTP_VERSION])
 644 AC_SUBST([ORTP_DIR])
 645
 646 AC_ARG_ENABLE(tests_enabled,
 647       [AS_HELP_STRING([--disable-tests], [Disable compilation of tests])],
 648       [case "${enableval}" in
 649         yes) tests_enabled=true ;;
 650         no)  tests_enabled=false ;;
 651         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 652       esac],[tests_enabled=false])
 653 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 654
 655
 656
 657 dnl ##################################################
 658 dnl # Check for doxygen
 659 dnl ##################################################
 660
 661 AC_PATH_PROG(DOXYGEN,doxygen,false)
 662 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 663
 664
 665 AC_CONFIG_FILES([
 666 Makefile
 667 build/Makefile
 668 build/macos/Makefile
 669 build/macos/Info-linphone.plist
 670 m4/Makefile
 671 po/Makefile.in
 672 pixmaps/Makefile
 673 coreapi/Makefile
 674 coreapi/help/Makefile
 675 coreapi/help/Doxyfile
 676 gtk/Makefile
 677 console/Makefile
 678 share/Makefile
 679 share/C/Makefile
 680 share/fr/Makefile
 681 share/it/Makefile
 682 share/ja/Makefile
 683 share/cs/Makefile
 684 share/xml/Makefile
 685 share/linphone.pc
 686 share/linphone.desktop
 687 scripts/Makefile
 688 tools/Makefile
 689 linphone.spec
 690 linphone.iss
 691 ])
 692
 693 AC_OUTPUT
 694
 695 echo "Linphone build configuration ended."
 696 echo "Summary of build options:"
 697 printf "* Video support\t\t\t%s\n" $video
 698 printf "* GTK interface\t\t\t%s\n" $gtk_ui
 699 printf "* Account assistant\t\t%s\n" $build_wizard
 700 printf "* Console interface\t\t%s\n" $console_ui
 701 printf "* Tools\t\t\t\t%s\n" $build_tools
 702 printf "* zRTP encryption (GPLv3)\t%s\n" $zrtp
 703
 704 if test "$enable_tunnel" = "true" ; then
 705         printf "* Tunnel support\t\ttrue\n"
 706 fi
 707
 708 echo "Now type 'make' to compile, and then 'make install' as root to install it."