sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.99.2],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target_os in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63         *darwin*)
  64                 dnl use macport installation
  65                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  66                 build_macos=yes
  67         ;;
  68 esac
  69
  70 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  71 AC_SUBST(CONSOLE_FLAGS)
  72 AC_SUBST(GUI_FLAGS)
  73
  74 dnl localization tools
  75 IT_PROG_INTLTOOL([0.40], [no-xml])
  76
  77 dnl Initialize libtool
  78 LT_INIT([win32-dll shared disable-static])
  79
  80 AC_CONFIG_COMMANDS([libtool-hacking],[
  81 if test "$mingw_found" = "yes" ; then
  82         echo "Hacking libtool to work with mingw..."
  83         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  84         cp -f ./libtool.tmp ./libtool
  85         rm -f ./libtool.tmp
  86 fi
  87 ],[mingw_found=$mingw_found])
  88
  89 dnl Add the languages which your application supports here.
  90 PKG_PROG_PKG_CONFIG
  91 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  92 AC_SUBST(ALL_LINGUAS)
  93 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  94
  95 if test "$mingw_found" != "yes" ; then
  96 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  97 AM_GNU_GETTEXT([external])
  98 LIBS="$LIBS $LIBINTL"
  99 else
 100         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 101         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 102         LIBS="$LIBS -lintl"
 103 fi
 104
 105 GETTEXT_PACKAGE=linphone
 106 AC_SUBST(GETTEXT_PACKAGE)
 107 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 108 dnl AC_CHECK_LIB(intl,libintl_gettext)
 109
 110 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 111
 112 AC_ARG_ENABLE(x11,
 113                           [  --disable-x11    Disable X11 support],
 114                           [case "${enableval}" in
 115                           yes) enable_x11=true ;;
 116                           no)  enable_x11=false ;;
 117                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 118                           esac],[enable_x11=true])
 119
 120 dnl conditionnal build of console interface.
 121 AC_ARG_ENABLE(console_ui,
 122       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 123       [case "${enableval}" in
 124         yes) console_ui=true ;;
 125         no)  console_ui=false ;;
 126         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 127       esac],[console_ui=true])
 128
 129 dnl conditionnal build of gtk interface.
 130 AC_ARG_ENABLE(gtk_ui,
 131       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 132       [case "${enableval}" in
 133         yes) gtk_ui=true ;;
 134         no)  gtk_ui=false ;;
 135         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 136       esac],[gtk_ui=true])
 137
 138 if test "$gtk_ui" = "true" ; then
 139         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 140         if test "$enable_x11" = "false" ; then
 141                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 142                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 143         fi
 144 else
 145         echo "GTK interface compilation is disabled."
 146 fi
 147
 148 AC_ARG_ENABLE(notify,
 149                 [  --enable-notify=[yes/no]    Enable libnotify support [default=yes]],
 150                 [case "${enableval}" in
 151                   yes) notify=true ;;
 152                   no)  notify=false ;;
 153                   *) AC_MSG_ERROR(bad value ${enableval} for --enable-notify) ;;
 154                 esac],[notify=true])
 155
 156 dnl conditionnal build of the notify library
 157 if test "$gtk_ui" = "true" ; then
 158         if test "$notify" = "true"; then
 159                 PKG_CHECK_MODULES([NOTIFY], [libnotify >= 0.7.0 ], [found_notify=yes], foo=bar)
 160                 case "$found_notify" in
 161                   yes)
 162                                 AC_SUBST(NOTIFY_CFLAGS)
 163                                 AC_SUBST(NOTIFY_LIBS)
 164                                 AC_DEFINE([HAVE_NOTIFY],[1],[NOTIFY support])
 165                 esac
 166         else
 167                 echo "Libnotify support is disabled."
 168         fi
 169 fi
 170
 171 dnl os-specific problems not handled by existing macros.
 172 case "$host_os" in
 173         *freebsd*)
 174                 LDFLAGS="$LDFLAGS -pthread"
 175                 ;;
 176 esac
 177
 178 case "$host_cpu" in
 179         *arm*)
 180                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 181                 use_arm_toolchain=yes
 182                 ;;
 183 esac
 184
 185 AC_ARG_WITH( configdir,
 186       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 187       [ configdir=${withval}],[ configdir="Linphone" ])
 188
 189 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 190
 191 AC_ARG_ENABLE(relativeprefix,
 192       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 193       [case "${enableval}" in
 194         yes) relativeprefix=yes ;;
 195         no)  relativeprefix=no ;;
 196         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 197       esac],[relativeprefix=guess])
 198
 199 AC_ARG_ENABLE(date,
 200       [  --enable-date    Use build date in internal version number],
 201       [case "${enableval}" in
 202         yes) use_date=yes ;;
 203         no)  use_date=no ;;
 204         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 205       esac],[use_date=no])
 206
 207 if test x$use_date =  xyes ; then
 208         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 209 fi
 210
 211
 212 dnl enable ipv6 support
 213 AC_ARG_ENABLE(ipv6,
 214       [  --enable-ipv6    Turn on ipv6 support],
 215       [case "${enableval}" in
 216         yes)  ipv6=true;;
 217         no)   ipv6=false;;
 218         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 219       esac],[ipv6=true])
 220 IPV6_CFLAGS=
 221 if test x$ipv6 = xtrue ; then
 222         IPV6_CFLAGS=-DINET6
 223 fi
 224 AC_SUBST(IPV6_CFLAGS)
 225
 226 dnl enable truespeech codec support
 227 AC_ARG_ENABLE(truespeech,
 228       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 229       [case "${enableval}" in
 230         yes)  truespeech=true;;
 231         no)   truespeech=false;;
 232         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 233       esac],[truespeech=false])
 234 TRUESPEECH_CFLAGS=
 235 if test x$truespeech = xtrue ; then
 236         TRUESPEECH_CFLAGS=-DTRUESPEECH
 237 fi
 238 AC_SUBST(TRUESPEECH_CFLAGS)
 239 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 240
 241 AC_ARG_ENABLE(nonstandard-gsm,
 242       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 243       [case "${enableval}" in
 244         yes) exotic_gsm=yes
 245         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 246          ;;
 247         no)  exotic_gsm=no ;;
 248         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 249       esac],[exotic_gsm=no])
 250
 251
 252 dnl support for RSVP (by Vincent Maury)
 253 AC_ARG_ENABLE(rsvp,
 254 [  --enable-rsvp           enable support for QoS reservations.],
 255 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 256 should be compiled.]) )
 257
 258 if test "x${prefix}" = "xNONE"; then
 259         package_prefix=${ac_default_prefix}
 260 else
 261         package_prefix=${prefix}
 262 fi
 263
 264 if test "$relativeprefix" = "guess" ; then
 265         if test "$mingw_found" = "yes" ; then
 266                 relativeprefix="yes"
 267         fi
 268 fi
 269
 270 if test "$relativeprefix" = "yes" ; then
 271         dnl allow binaries to install everywhere
 272         package_prefix="."
 273 fi
 274
 275 dnl Set PACKAGE_LOCALE_DIR in config.h.
 276 DATADIRNAME=share
 277 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 278
 279 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 280
 281 dnl Set PACKAGE_SOUND_DIR in config.h.
 282 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 283
 284
 285 dnl check if we have the getifaddrs() sytem call
 286 AC_CHECK_FUNCS(getifaddrs)
 287
 288 dnl check for osip2
 289 LP_CHECK_OSIP2
 290
 291 dnl conditionnal build for ssl
 292 AC_ARG_ENABLE(ssl,
 293                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 294                 [case "${enableval}" in
 295                 yes) build_ssl=true ;;
 296                 no)  build_ssl=false ;;
 297                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 298                 esac],[build_ssl=false])
 299
 300 if test "$build_ssl" = "true"; then
 301         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 302 fi
 303 dnl setup flags for exosip library
 304 LP_SETUP_EXOSIP
 305
 306 if test "$console_ui" = "true" ; then
 307 dnl check gnu readline
 308 LP_CHECK_READLINE
 309 else
 310 echo "Console interface compilation is disabled."
 311 fi
 312
 313 AC_WORDS_BIGENDIAN
 314
 315 dnl normaly this should only by done by mediastreamer2/configure.ac
 316 dnl but to workaround bugs when cross-compiling for arm-linux,
 317 dnl we need to have SPEEX_LIBS defined
 318 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 319 dnl since top-level configure --help will not print them.
 320
 321 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 322
 323 dnl conditionnal build of video support
 324 AC_ARG_ENABLE(video,
 325                 [  --enable-video    Turn on video support compiling],
 326                 [case "${enableval}" in
 327                 yes) video=true ;;
 328                 no)  video=false ;;
 329                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 330                 esac],[video=true])
 331
 332 AC_ARG_WITH( ffmpeg,
 333                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 334                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 335
 336 if test "$video" = "true"; then
 337
 338         if test "$enable_x11" = "true"; then
 339                 AC_CHECK_HEADERS(X11/Xlib.h)
 340                 if test "$build_macos" = "yes"; then
 341                         X11_LIBS="-L/usr/X11/lib -lX11"
 342                 else
 343                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 344                 fi
 345                 AC_SUBST(X11_LIBS)
 346         fi
 347         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 348 fi
 349
 350 AC_ARG_ENABLE(alsa,
 351       [  --enable-alsa    Turn on alsa native support compiling],
 352       [case "${enableval}" in
 353         yes) alsa=true ;;
 354         no)  alsa=false ;;
 355         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 356       esac],[alsa=true])
 357
 358 AC_ARG_ENABLE(artsc,
 359       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 360       [case "${enableval}" in
 361         yes) artsc=true ;;
 362         no)  artsc=false ;;
 363         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 364       esac],[artsc=false])
 365
 366 AC_ARG_ENABLE(portaudio,
 367       [  --enable-portaudio    Turn on portaudio native support compiling],
 368       [case "${enableval}" in
 369         yes) portaudio=true ;;
 370         no)  portaudio=false ;;
 371         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 372       esac],[portaudio=false])
 373
 374 dnl build console if required
 375 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 376 dnl special things for arm-linux cross compilation toolchain
 377 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 378 dnl compilation of gtk user interface
 379 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 380 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 381
 382 dnl check getenv
 383 AH_TEMPLATE([HAVE_GETENV])
 384 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 385
 386 dnl
 387 AC_MSG_CHECKING([for sighandler_t])
 388 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 389 has_sighandler_t=yes,has_sighandler_t=no)
 390 AC_MSG_RESULT($has_sighandler_t)
 391 if test "$has_sighandler_t" = "yes" ; then
 392     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 393 fi
 394
 395 ##################################################
 396 # Stricter build options (after external packages)
 397 ##################################################
 398
 399
 400 AC_ARG_ENABLE(strict,
 401         AC_HELP_STRING([--enable-strict],
 402                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 403         strictness="${enableval}"],[strictness=yes]
 404 )
 405
 406 STRICT_OPTIONS="-Wall "
 407
 408 if test "$GCC$strictness" = "yesyes" ; then
 409         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 410         CFLAGS="$CFLAGS -fno-strict-aliasing"
 411 fi
 412
 413 AC_SUBST(STRICT_OPTIONS)
 414
 415 top_srcdir=`dirname $0`
 416
 417 AC_ARG_ENABLE([external-mediastreamer],
 418       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 419       [enable_external_mediastreamer=no])
 420
 421 AS_CASE($enable_external_mediastreamer,
 422                 [yes],[
 423                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 424                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 425                         ],
 426                 [no],[
 427                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 428                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 429                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 430                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 431 dnl need to temporary change quotes to allow square brackets
 432                         changequote(<<, >>)
 433                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 434                         changequote([, ])
 435                         MS2_DIR=mediastreamer2
 436                         ],
 437         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 438
 439 AC_SUBST(MEDIASTREAMER_CFLAGS)
 440 AC_SUBST(MEDIASTREAMER_LIBS)
 441 AC_SUBST([MS2_VERSION])
 442 AC_SUBST([MS2_DIR])
 443
 444 dnl check for db2html (docbook) to generate html user manual
 445 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 446 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 447
 448 dnl for external use of linphone libs
 449 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 450 LINPHONE_LIBS="-L${libdir} -llinphone"
 451
 452 if test x$mingw_found = xyes ; then
 453         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 454 fi
 455 AC_SUBST(LINPHONE_CFLAGS)
 456 AC_SUBST(LINPHONE_LIBS)
 457
 458 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 459
 460 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 461 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 462 AC_SUBST(LINPHONE_PLUGINS_DIR)
 463
 464 AC_ARG_ENABLE(external-ortp,
 465       [  --enable-external-ortp    Use external oRTP library],
 466       [case "${enableval}" in
 467         yes) external_ortp=true ;;
 468         no)  external_ortp=false ;;
 469         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 470       esac],[external_ortp=false])
 471
 472 if test "$external_ortp" = 'true'; then
 473         PKG_CHECK_MODULES([ORTP], [ortp])
 474         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 475 else
 476         AC_CONFIG_SUBDIRS( oRTP )
 477         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 478         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 479         if test x$ac_cv_c_bigendian = xyes ; then
 480                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 481         fi
 482         ORTP_DIR=oRTP
 483         changequote(<<, >>)
 484         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 485         changequote([, ])
 486 fi
 487 AC_SUBST(ORTP_CFLAGS)
 488 AC_SUBST(ORTP_LIBS)
 489 AC_SUBST([ORTP_VERSION])
 490 AC_SUBST([ORTP_DIR])
 491
 492 AC_ARG_ENABLE(tests_enabled,
 493       [  --disable-tests    Disable compilation of tests],
 494       [case "${enableval}" in
 495         yes) tests_enabled=true ;;
 496         no)  tests_enabled=false ;;
 497         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 498       esac],[tests_enabled=false])
 499 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 500
 501 dnl ##################################################
 502 dnl # Check for doxygen
 503 dnl ##################################################
 504
 505 AC_PATH_PROG(DOXYGEN,doxygen,false)
 506 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 507
 508
 509 AC_CONFIG_FILES([
 510 Makefile
 511 build/Makefile
 512 build/macos/Makefile
 513 build/macos/Info-linphone.plist
 514 m4/Makefile
 515 po/Makefile.in
 516 pixmaps/Makefile
 517 coreapi/Makefile
 518 coreapi/help/Makefile
 519 coreapi/help/Doxyfile
 520 gtk/Makefile
 521 console/Makefile
 522 share/Makefile
 523 share/C/Makefile
 524 share/fr/Makefile
 525 share/it/Makefile
 526 share/ja/Makefile
 527 share/cs/Makefile
 528 share/linphone.pc
 529 share/linphone.desktop
 530 scripts/Makefile
 531 linphone.spec
 532 linphone.iss
 533 ])
 534
 535 AC_OUTPUT
 536
 537 echo "Linphone build configuration ended."
 538
 539 if test x$gtk_ui = xtrue ; then
 540         echo "* GTK interface will be compiled."
 541 fi
 542 if test x$console_ui = xtrue ; then
 543         echo "* Console interface will be compiled."
 544 fi
 545
 546 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 547