sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.3],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44
  45 case $target in
  46         *mingw32ce)
  47         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  48         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  49         LIBS="$LIBS -lws2 -liphlpapi"
  50                 mingw_found=yes
  51                 mingwce_found=yes
  52                 ;;
  53         *mingw*)
  54                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  55                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  56                 LIBS="$LIBS -lws2_32"
  57                 GUI_FLAGS="-mwindows"
  58                 CONSOLE_FLAGS="-mconsole"
  59                 mingw_found=yes
  60         ;;
  61        armv6-apple-darwin|armv7-apple-darwin|i386-apple-darwin)
  62                 CFLAGS="$CFLAGS -DTARGET_OS_IPHONE "
  63                 build_tests=no
  64                 ios_found=yes
  65         ;;
  66         x86_64-apple-darwin*|i686-apple-darwin*)
  67                 MSPLUGINS_CFLAGS=""
  68                 dnl use macport installation
  69                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  70                 build_macos=yes
  71         ;;
  72
  73 esac
  74
  75 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  76 AC_SUBST(CONSOLE_FLAGS)
  77 AC_SUBST(GUI_FLAGS)
  78
  79 dnl localization tools
  80 IT_PROG_INTLTOOL([0.40], [no-xml])
  81
  82 AM_CONDITIONAL(BUILD_TESTS,test x$build_tests != xno)
  83 dnl Initialize libtool
  84 LT_INIT([win32-dll shared disable-static])
  85
  86 AC_CONFIG_COMMANDS([libtool-hacking],[
  87 if test "$mingw_found" = "yes" ; then
  88         echo "Hacking libtool to work with mingw..."
  89         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  90         cp -f ./libtool.tmp ./libtool
  91         rm -f ./libtool.tmp
  92 fi
  93 ],[mingw_found=$mingw_found])
  94
  95 dnl Add the languages which your application supports here.
  96 PKG_PROG_PKG_CONFIG
  97 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  98 AC_SUBST(ALL_LINGUAS)
  99 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
 100
 101 if test "$mingw_found" != "yes" ; then
 102 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 103 AM_GNU_GETTEXT([external])
 104 LIBS="$LIBS $LIBINTL"
 105 else
 106         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 107         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 108         LIBS="$LIBS -lintl"
 109 fi
 110
 111 GETTEXT_PACKAGE=linphone
 112 AC_SUBST(GETTEXT_PACKAGE)
 113 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 114 dnl AC_CHECK_LIB(intl,libintl_gettext)
 115
 116 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 117
 118 AC_ARG_ENABLE(x11,
 119                           [  --disable-x11    Disable X11 support],
 120                           [case "${enableval}" in
 121                           yes) enable_x11=true ;;
 122                           no)  enable_x11=false ;;
 123                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 124                           esac],[enable_x11=true])
 125
 126 dnl conditionnal build of console interface.
 127 AC_ARG_ENABLE(console_ui,
 128       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 129       [case "${enableval}" in
 130         yes) console_ui=true ;;
 131         no)  console_ui=false ;;
 132         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 133       esac],[console_ui=true])
 134
 135 dnl conditionnal build of gtk interface.
 136 AC_ARG_ENABLE(gtk_ui,
 137       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 138       [case "${enableval}" in
 139         yes) gtk_ui=true ;;
 140         no)  gtk_ui=false ;;
 141         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 142       esac],[gtk_ui=true])
 143
 144 if test "$gtk_ui" = "true" ; then
 145         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 146         if test "$enable_x11" = "false" ; then
 147                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 148                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 149         fi
 150 else
 151         echo "GTK interface compilation is disabled."
 152 fi
 153
 154
 155 dnl os-specific problems not handled by existing macros.
 156 case "$host_os" in
 157         *freebsd*)
 158                 LDFLAGS="$LDFLAGS -pthread"
 159                 ;;
 160 esac
 161
 162 case "$host_cpu" in
 163         *arm*)
 164                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 165                 use_arm_toolchain=yes
 166                 ;;
 167 esac
 168
 169 AC_ARG_WITH( configdir,
 170       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 171       [ configdir=${withval}],[ configdir="Linphone" ])
 172
 173 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 174
 175 AC_ARG_ENABLE(relativeprefix,
 176       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 177       [case "${enableval}" in
 178         yes) relativeprefix=yes ;;
 179         no)  relativeprefix=no ;;
 180         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 181       esac],[relativeprefix=auto])
 182
 183 AC_ARG_ENABLE(date,
 184       [  --enable-date    Use build date in internal version number],
 185       [case "${enableval}" in
 186         yes) use_date=yes ;;
 187         no)  use_date=no ;;
 188         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 189       esac],[use_date=no])
 190
 191 if test x$use_date =  xyes ; then
 192         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 193 fi
 194
 195
 196 dnl enable ipv6 support
 197 AC_ARG_ENABLE(ipv6,
 198       [  --enable-ipv6    Turn on ipv6 support],
 199       [case "${enableval}" in
 200         yes)  ipv6=true;;
 201         no)   ipv6=false;;
 202         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 203       esac],[ipv6=true])
 204 IPV6_CFLAGS=
 205 if test x$ipv6 = xtrue ; then
 206         IPV6_CFLAGS=-DINET6
 207 fi
 208 AC_SUBST(IPV6_CFLAGS)
 209
 210 dnl enable truespeech codec support
 211 AC_ARG_ENABLE(truespeech,
 212       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 213       [case "${enableval}" in
 214         yes)  truespeech=true;;
 215         no)   truespeech=false;;
 216         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 217       esac],[truespeech=false])
 218 TRUESPEECH_CFLAGS=
 219 if test x$truespeech = xtrue ; then
 220         TRUESPEECH_CFLAGS=-DTRUESPEECH
 221 fi
 222 AC_SUBST(TRUESPEECH_CFLAGS)
 223 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 224
 225 AC_ARG_ENABLE(nonstandard-gsm,
 226       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 227       [case "${enableval}" in
 228         yes) exotic_gsm=yes
 229         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 230          ;;
 231         no)  exotic_gsm=no ;;
 232         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 233       esac],[exotic_gsm=no])
 234
 235
 236 dnl support for RSVP (by Vincent Maury)
 237 AC_ARG_ENABLE(rsvp,
 238 [  --enable-rsvp           enable support for QoS reservations.],
 239 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 240 should be compiled.]) )
 241
 242 if test "x${prefix}" = "xNONE"; then
 243         package_prefix=${ac_default_prefix}
 244 else
 245         package_prefix=${prefix}
 246 fi
 247
 248 if test "$relativeprefix" = "auto" ; then
 249         case $target_os in
 250                 *darwin*)
 251                 if test "$enable_x11" = "false" ; then
 252                         relativeprefix=yes
 253                 fi
 254                 ;;
 255                 *mingw*)
 256                 relativeprefix=yes
 257                 ;;
 258         esac
 259 fi
 260
 261 if test "$relativeprefix" = "yes" ; then
 262         dnl allow binaries to install everywhere
 263         package_prefix="."
 264 fi
 265
 266 dnl Set PACKAGE_LOCALE_DIR in config.h.
 267 DATADIRNAME=share
 268 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 269
 270 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 271
 272 dnl Set PACKAGE_SOUND_DIR in config.h.
 273 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 274
 275
 276 dnl check if we have the getifaddrs() sytem call
 277 AC_CHECK_FUNCS(getifaddrs)
 278
 279 dnl check for osip2
 280 LP_CHECK_OSIP2
 281
 282 dnl conditionnal build for ssl
 283 AC_ARG_ENABLE(ssl,
 284                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 285                 [case "${enableval}" in
 286                 yes) build_ssl=true ;;
 287                 no)  build_ssl=false ;;
 288                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 289                 esac],[build_ssl=false])
 290
 291 if test "$build_ssl" = "true"; then
 292         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 293 fi
 294 dnl setup flags for exosip library
 295 LP_SETUP_EXOSIP
 296
 297 if test "$console_ui" = "true" ; then
 298 dnl check gnu readline
 299 LP_CHECK_READLINE
 300 else
 301 echo "Console interface compilation is disabled."
 302 fi
 303
 304 AC_WORDS_BIGENDIAN
 305
 306 dnl normaly this should only by done by mediastreamer2/configure.ac
 307 dnl but to workaround bugs when cross-compiling for arm-linux,
 308 dnl we need to have SPEEX_LIBS defined
 309 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 310 dnl since top-level configure --help will not print them.
 311
 312 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 313
 314 dnl conditionnal build of video support
 315 AC_ARG_ENABLE(video,
 316                 [  --enable-video    Turn on video support compiling],
 317                 [case "${enableval}" in
 318                 yes) video=true ;;
 319                 no)  video=false ;;
 320                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 321                 esac],[video=true])
 322
 323 AC_ARG_WITH( ffmpeg,
 324                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 325                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 326
 327 if test "$video" = "true"; then
 328
 329         if test "$enable_x11" = "true"; then
 330                 AC_CHECK_HEADERS(X11/Xlib.h)
 331                 if test "$build_macos" = "yes"; then
 332                         X11_LIBS="-L/usr/X11/lib -lX11"
 333                 else
 334                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 335                 fi
 336                 AC_SUBST(X11_LIBS)
 337         fi
 338         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 339 fi
 340
 341 AC_ARG_ENABLE(alsa,
 342       [  --enable-alsa    Turn on alsa native support compiling],
 343       [case "${enableval}" in
 344         yes) alsa=true ;;
 345         no)  alsa=false ;;
 346         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 347       esac],[alsa=true])
 348
 349 AC_ARG_ENABLE(artsc,
 350       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 351       [case "${enableval}" in
 352         yes) artsc=true ;;
 353         no)  artsc=false ;;
 354         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 355       esac],[artsc=false])
 356
 357 AC_ARG_ENABLE(portaudio,
 358       [  --enable-portaudio    Turn on portaudio native support compiling],
 359       [case "${enableval}" in
 360         yes) portaudio=true ;;
 361         no)  portaudio=false ;;
 362         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 363       esac],[portaudio=false])
 364
 365 dnl build console if required
 366 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 367 dnl special things for arm-linux cross compilation toolchain
 368 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 369 dnl compilation of gtk user interface
 370 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 371 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 372
 373 dnl check getenv
 374 AH_TEMPLATE([HAVE_GETENV])
 375 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 376
 377 dnl
 378 AC_MSG_CHECKING([for sighandler_t])
 379 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 380 has_sighandler_t=yes,has_sighandler_t=no)
 381 AC_MSG_RESULT($has_sighandler_t)
 382 if test "$has_sighandler_t" = "yes" ; then
 383     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 384 fi
 385
 386 ##################################################
 387 # Stricter build options (after external packages)
 388 ##################################################
 389
 390
 391 AC_ARG_ENABLE(strict,
 392         AC_HELP_STRING([--enable-strict],
 393                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 394         strictness="${enableval}"],[strictness=yes]
 395 )
 396
 397 STRICT_OPTIONS="-Wall "
 398
 399 if test "$GCC$strictness" = "yesyes" ; then
 400         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 401         CFLAGS="$CFLAGS -fno-strict-aliasing"
 402 fi
 403
 404 AC_SUBST(STRICT_OPTIONS)
 405
 406 top_srcdir=`dirname $0`
 407
 408 AC_ARG_ENABLE([external-mediastreamer],
 409       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 410       [enable_external_mediastreamer=no])
 411
 412 AS_CASE($enable_external_mediastreamer,
 413                 [yes],[
 414                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 415                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 416                         ],
 417                 [no],[
 418                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 419                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 420                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 421                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 422 dnl need to temporary change quotes to allow square brackets
 423                         changequote(<<, >>)
 424                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 425                         changequote([, ])
 426                         MS2_DIR=mediastreamer2
 427                         ],
 428         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 429
 430 AC_SUBST(MEDIASTREAMER_CFLAGS)
 431 AC_SUBST(MEDIASTREAMER_LIBS)
 432 AC_SUBST([MS2_VERSION])
 433 AC_SUBST([MS2_DIR])
 434
 435 dnl check for db2html (docbook) to generate html user manual
 436 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 437 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 438
 439 dnl for external use of linphone libs
 440 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 441 LINPHONE_LIBS="-L${libdir} -llinphone"
 442
 443 if test x$mingw_found = xyes ; then
 444         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 445 fi
 446 AC_SUBST(LINPHONE_CFLAGS)
 447 AC_SUBST(LINPHONE_LIBS)
 448
 449 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 450
 451 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 452 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 453 AC_SUBST(LINPHONE_PLUGINS_DIR)
 454
 455 AC_ARG_ENABLE(external-ortp,
 456       [  --enable-external-ortp    Use external oRTP library],
 457       [case "${enableval}" in
 458         yes) external_ortp=true ;;
 459         no)  external_ortp=false ;;
 460         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 461       esac],[external_ortp=false])
 462
 463 if test "$external_ortp" = 'true'; then
 464         PKG_CHECK_MODULES([ORTP], [ortp])
 465         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 466 else
 467         AC_CONFIG_SUBDIRS( oRTP )
 468         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 469         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 470         if test x$ac_cv_c_bigendian = xyes ; then
 471                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 472         fi
 473         ORTP_DIR=oRTP
 474         changequote(<<, >>)
 475         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 476         changequote([, ])
 477 fi
 478 AC_SUBST(ORTP_CFLAGS)
 479 AC_SUBST(ORTP_LIBS)
 480 AC_SUBST([ORTP_VERSION])
 481 AC_SUBST([ORTP_DIR])
 482
 483 dnl ##################################################
 484 dnl # Check for doxygen
 485 dnl ##################################################
 486
 487 AC_PATH_PROG(DOXYGEN,doxygen,false)
 488 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 489
 490
 491 AC_CONFIG_FILES([
 492 Makefile
 493 build/Makefile
 494 build/macos/Makefile
 495 build/macos/Info-linphone.plist
 496 m4/Makefile
 497 po/Makefile.in
 498 pixmaps/Makefile
 499 coreapi/Makefile
 500 coreapi/help/Makefile
 501 coreapi/help/Doxyfile
 502 gtk/Makefile
 503 console/Makefile
 504 share/Makefile
 505 share/C/Makefile
 506 share/fr/Makefile
 507 share/it/Makefile
 508 share/ja/Makefile
 509 share/cs/Makefile
 510 share/linphone.pc
 511 share/linphone.desktop
 512 scripts/Makefile
 513 linphone.spec
 514 linphone.iss
 515 ])
 516
 517 AC_OUTPUT
 518
 519 echo "Linphone build configuration ended."
 520
 521 if test x$gtk_ui = xtrue ; then
 522         echo "* GTK interface will be compiled."
 523 fi
 524 if test x$console_ui = xtrue ; then
 525         echo "* Console interface will be compiled."
 526 fi
 527
 528 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 529