sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.5.99.0],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=5 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_SUBST([docdir], [${datadir}/doc])
  36 AC_CONFIG_HEADERS(config.h)
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_C_INLINE
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target in
  48         *mingw32ce)
  49                 CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51                 LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54         ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63         armv6-apple-darwin|armv7-apple-darwin|i386-apple-darwin|armv7s-apple-darwin)
  64                 CFLAGS="$CFLAGS -DTARGET_OS_IPHONE "
  65                 build_tests=no
  66                 ios_found=yes
  67         ;;
  68         x86_64-apple-darwin*|i686-apple-darwin*)
  69                 MSPLUGINS_CFLAGS=""
  70                 dnl use macport installation
  71                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  72                 build_macos=yes
  73         ;;
  74
  75 esac
  76
  77 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  78 AC_SUBST(CONSOLE_FLAGS)
  79 AC_SUBST(GUI_FLAGS)
  80
  81 dnl localization tools
  82 IT_PROG_INTLTOOL([0.40], [no-xml])
  83
  84 AM_CONDITIONAL(BUILD_TESTS,test x$build_tests != xno)
  85
  86 dnl Initialize libtool
  87 LT_INIT([win32-dll shared disable-static])
  88
  89 dnl Enable library dependencies linking
  90 AC_ARG_ENABLE(deplibs-link,
  91         [AS_HELP_STRING([--disable-deplibs-link ], [Disable library dependencies linking (might break builds)])],
  92         [enable_deplibs_linking="$enableval"],
  93         [enable_deplibs_linking="yes"]
  94 )
  95 AC_MSG_NOTICE([Enable library dependencies linking: $enable_interlib_deps])
  96 if test "${enable_deplibs_linking}" == "yes"; then
  97         link_all_deplibs=yes
  98         link_all_deplibs_CXX=yes
  99 else
 100         link_all_deplibs=no
 101         link_all_deplibs_CXX=no
 102 fi
 103
 104 AC_CONFIG_COMMANDS([libtool-hacking],
 105         [if test "$mingw_found" = "yes" ; then
 106                 echo "Hacking libtool to work with mingw..."
 107                 sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
 108                 cp -f ./libtool.tmp ./libtool
 109                 rm -f ./libtool.tmp
 110         fi],
 111         [mingw_found=$mingw_found]
 112 )
 113
 114 dnl Add the languages which your application supports here.
 115 PKG_PROG_PKG_CONFIG
 116 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW he"
 117 AC_SUBST(ALL_LINGUAS)
 118 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
 119
 120 if test "$mingw_found" != "yes" ; then
 121         dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 122
 123         dnl AM_GNU_GETTEXT pollutes CPPFLAGS: workaround this.
 124         CPPFLAGS_save=$CPPFLAGS
 125         AM_GNU_GETTEXT([external])
 126         AC_SUBST(INTLLIBS)
 127         CPPFLAGS=$CPPFLAGS_save
 128         LIBS="$LIBS $LIBINTL"
 129 else
 130         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 131         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 132         LIBS="$LIBS -lintl"
 133 fi
 134
 135 GETTEXT_PACKAGE=linphone
 136 AC_SUBST(GETTEXT_PACKAGE)
 137 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext package name])
 138 dnl AC_CHECK_LIB(intl,libintl_gettext)
 139
 140 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 141
 142 AC_ARG_ENABLE(x11,
 143         [AS_HELP_STRING([--disable-x11], [Disable X11 support (default=no)])],
 144         [case "${enableval}" in
 145                 yes)    enable_x11=true ;;
 146                 no)     enable_x11=false ;;
 147                 *)      AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 148         esac],
 149         [enable_x11=true]
 150 )
 151
 152 dnl conditionnal build of console interface.
 153 AC_ARG_ENABLE(console_ui,
 154         [AS_HELP_STRING([--enable-console_ui=[yes/no]], [Turn on or off compilation of console interface (default=yes)])],
 155         [case "${enableval}" in
 156                 yes)    console_ui=true ;;
 157                 no)     console_ui=false ;;
 158                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 159         esac],
 160         [console_ui=true]
 161 )
 162
 163 dnl conditionnal build of tools.
 164 AC_ARG_ENABLE(tools,
 165         [AS_HELP_STRING([--enable-tools=[yes/no]], [Turn on or off compilation of console interface (default=yes)])],
 166         [case "${enableval}" in
 167                 yes)    build_tools=true ;;
 168                 no)     build_tools=false ;;
 169                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-tools) ;;
 170         esac],
 171         [build_tools=check]
 172 )
 173
 174 dnl check for installed version of libupnp
 175 AC_ARG_ENABLE(upnp,
 176         [AS_HELP_STRING([--disable-upnp], [Disable uPnP support])],
 177         [case "${enableval}" in
 178                 yes)    build_upnp=true ;;
 179                 no)     build_upnp=false ;;
 180                 *)      AC_MSG_ERROR(bad value ${enableval} for --disable-upnp) ;;
 181         esac],
 182         [build_upnp=auto]
 183 )
 184
 185 if test "$build_upnp" != "false" ; then
 186         PKG_CHECK_MODULES([LIBUPNP], [libupnp], [build_upnp=true],
 187                 [if test "$build_upnp" == "true" ; then
 188                         AC_MSG_ERROR([libupnp not found.])
 189                 else
 190                         build_upnp=false
 191                 fi]
 192         )
 193
 194 fi
 195
 196 AM_CONDITIONAL(BUILD_UPNP, test x$build_upnp != xfalse)
 197 if test "$build_upnp" != "false" ; then
 198         AC_DEFINE(BUILD_UPNP, 1, [Define if upnp enabled])
 199 fi
 200
 201 dnl check libxml2 (needed for tools)
 202 if test "$build_tools" != "false" ; then
 203         PKG_CHECK_MODULES(LIBXML2, [libxml-2.0],[],
 204                 [if test "$build_tools" = "true" ; then
 205                         AC_MSG_ERROR([Could not found libxml2, tools cannot be compiled.])
 206                 else
 207                         build_tools=false
 208                 fi]
 209         )
 210 fi
 211
 212 AM_CONDITIONAL(BUILD_TOOLS, test x$build_tools != xfalse)
 213 if test "$build_tools" != "false" ; then
 214         build_tools=true
 215         AC_DEFINE(BUILD_TOOLS, 1, [Define if tools enabled] )
 216 fi
 217
 218 dnl conditionnal build of gtk interface.
 219 AC_ARG_ENABLE(gtk_ui,
 220         [AS_HELP_STRING([--enable-gtk_ui=[yes/no]], [Turn on or off compilation of gtk interface (default=yes)])],
 221         [case "${enableval}" in
 222                 yes)    gtk_ui=true ;;
 223                 no)     gtk_ui=false ;;
 224                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 225         esac],
 226         [gtk_ui=true]
 227 )
 228
 229 if test "$gtk_ui" = "true" ; then
 230         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.18.0 gthread-2.0)
 231         if test "$enable_x11" = "false" ; then
 232                 PKG_CHECK_MODULES(LIBGTKMAC,[gtk-mac-integration >= 2.0.1])
 233                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 234         fi
 235 else
 236         echo "GTK interface compilation is disabled."
 237 fi
 238
 239 AC_ARG_ENABLE(notify,
 240         [AS_HELP_STRING([--enable-notify=[yes/no]], [Enable libnotify support (default=yes)])],
 241         [case "${enableval}" in
 242                 yes)    notify=true ;;
 243                 no)     notify=false ;;
 244                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-notify) ;;
 245         esac],
 246         [notify=true]
 247 )
 248
 249 dnl conditionnal build of the notify library
 250 if test "$gtk_ui" = "true" ; then
 251         if test "$notify" = "true"; then
 252                 PKG_CHECK_MODULES([NOTIFY4], [libnotify >= 0.7.0 ], [found_notify4=yes], foo=bar)
 253                 case "$found_notify4" in
 254                         yes)
 255                                 AC_SUBST(NOTIFY4_CFLAGS)
 256                                 AC_SUBST(NOTIFY4_LIBS)
 257                                 AC_DEFINE([HAVE_NOTIFY4],[1],[NOTIFY4 support])
 258                 esac
 259
 260                 PKG_CHECK_MODULES([NOTIFY1], [libnotify < 0.7.0], [found_notify1=yes], foo=bar)
 261                 case "$found_notify1" in
 262                         yes)
 263                                 AC_SUBST(NOTIFY1_CFLAGS)
 264                                 AC_SUBST(NOTIFY1_LIBS)
 265                                 AC_DEFINE([HAVE_NOTIFY1],[1],[NOTIFY1 support])
 266                 esac
 267         else
 268                 NotifyNotification *n;
 269                 echo "Libnotify support is disabled."
 270         fi
 271 fi
 272
 273 dnl os-specific problems not handled by existing macros.
 274 case "$host_os" in
 275         *freebsd*)
 276                 LDFLAGS="$LDFLAGS -pthread"
 277         ;;
 278 esac
 279
 280 case "$host_cpu" in
 281         *arm*)
 282                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 283                 use_arm_toolchain=yes
 284         ;;
 285 esac
 286
 287 AC_ARG_WITH(configdir,
 288         [AS_HELP_STRING([--with-configdir], [Set a APPDATA subdir where linphone is supposed to find its config (windows only)])],
 289         [ configdir=${withval}],[ configdir="Linphone" ])
 290
 291 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 292
 293 AC_ARG_ENABLE(relativeprefix,
 294         [AS_HELP_STRING([--enable-relativeprefix], [Build a linphone that finds its resources relatively to the directory where it is installed])],
 295         [case "${enableval}" in
 296                 yes)    relativeprefix=yes ;;
 297                 no)     relativeprefix=no ;;
 298                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 299         esac],
 300         [relativeprefix=guess]
 301 )
 302
 303 AC_ARG_ENABLE(date,
 304         [AS_HELP_STRING([--enable-date], [Use build date in internal version number])],
 305         [case "${enableval}" in
 306                 yes)    use_date=yes ;;
 307                 no)     use_date=no ;;
 308                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 309         esac],
 310         [use_date=no]
 311 )
 312
 313 if test x$use_date =  xyes ; then
 314         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 315 fi
 316
 317
 318 dnl enable ipv6 support
 319 AC_ARG_ENABLE(ipv6,
 320         [AS_HELP_STRING([--enable-ipv6], [Turn on ipv6 support])],
 321         [case "${enableval}" in
 322                 yes)    ipv6=true;;
 323                 no)     ipv6=false;;
 324                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 325         esac],
 326         [ipv6=true]
 327 )
 328 IPV6_CFLAGS=
 329 if test x$ipv6 = xtrue ; then
 330         IPV6_CFLAGS=-DINET6
 331 fi
 332 AC_SUBST(IPV6_CFLAGS)
 333
 334 dnl enable timestamp support
 335 AC_ARG_ENABLE(ntp-timestamp,
 336         [AS_HELP_STRING([--enable-ntp-timestamp], [Turn on NTP timestamping on received packet])],
 337         [case "${enableval}" in
 338                 yes)    ntptimestamp=true;;
 339                 no)     ntptimestamp=false;;
 340                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-ntp-timestamp) ;;
 341         esac],
 342         [ntptimestamp=false]
 343 )
 344
 345 AC_ARG_ENABLE(debug,
 346         [AS_HELP_STRING([--enable-debug=[yes/no]], [Enables the display of traces showing the execution of the library. (default=yes)])],
 347         [case "${enableval}" in
 348                 yes)    debug_enabled=yes;;
 349                 no)     debug_enabled=no;;
 350                 *)      AC_MSG_ERROR("Bad value for --enable-debug");;
 351         esac],
 352         [debug_enabled=no]
 353 )
 354
 355 dnl enable truespeech codec support
 356 AC_ARG_ENABLE(truespeech,
 357         [AS_HELP_STRING([--enable-truespeech], [Turn on TrueSpeech support (x86 only)])],
 358         [case "${enableval}" in
 359                 yes)    truespeech=true;;
 360                 no)     truespeech=false;;
 361                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 362         esac],
 363         [truespeech=false]
 364 )
 365 TRUESPEECH_CFLAGS=
 366 if test x$truespeech = xtrue ; then
 367         TRUESPEECH_CFLAGS=-DTRUESPEECH
 368 fi
 369 AC_SUBST(TRUESPEECH_CFLAGS)
 370 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 371
 372 AC_ARG_ENABLE(nonstandard-gsm,
 373         [AS_HELP_STRING([--enable-nonstandard-gsm], [Enable GSM codec at nonstandard rates (11025hz, 16000hz)])],
 374         [case "${enableval}" in
 375                 yes)
 376                         exotic_gsm=yes
 377                         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 378                 ;;
 379                 no)     exotic_gsm=no ;;
 380                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 381         esac],
 382         [exotic_gsm=no]
 383 )
 384
 385
 386 dnl support for RSVP (by Vincent Maury)
 387 AC_ARG_ENABLE(rsvp,
 388         [AS_HELP_STRING([--enable-rsvp], [Enable support for QoS reservations.])],
 389         AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support should be compiled.])
 390 )
 391
 392 if test "x${prefix}" = "xNONE"; then
 393         package_prefix=${ac_default_prefix}
 394 else
 395         package_prefix=${prefix}
 396 fi
 397
 398 if test "$relativeprefix" = "guess" ; then
 399         if test "$mingw_found" = "yes" ; then
 400                 relativeprefix="yes"
 401         fi
 402 fi
 403
 404 if test "$relativeprefix" = "yes" ; then
 405         dnl allow binaries to install everywhere
 406         package_prefix="."
 407 fi
 408
 409 dnl Set PACKAGE_LOCALE_DIR in config.h.
 410 DATADIRNAME=share
 411 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 412
 413 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 414
 415 dnl Set PACKAGE_SOUND_DIR in config.h.
 416 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 417
 418
 419 dnl check if we have the getifaddrs() sytem call
 420 AC_CHECK_FUNCS(getifaddrs)
 421
 422 dnl check for osip2
 423 LP_CHECK_OSIP2
 424
 425 dnl conditionnal build for ssl
 426 AC_ARG_ENABLE(ssl,
 427         [AS_HELP_STRING([--enable-ssl], [Turn on ssl support compiling. Required for sip tls. (default=false)])],
 428         [case "${enableval}" in
 429                 yes)    build_ssl=true ;;
 430                 no)     build_ssl=false ;;
 431                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 432         esac],
 433         [build_ssl=false]
 434 )
 435
 436 if test "$build_ssl" = "true"; then
 437         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 438 fi
 439 dnl setup flags for exosip library
 440 LP_SETUP_EXOSIP
 441
 442 dnl check exosip support of DSCP in exosip
 443 AC_MSG_CHECKING([for DSCP support in exosip])
 444 AC_TRY_COMPILE([#include <eXosip2/eXosip.h>],
 445         [int dscp=0;eXosip_set_option(EXOSIP_OPT_SET_DSCP,&dscp);],
 446         has_exosip_dscp=yes,
 447         has_exosip_dscp=no
 448 )
 449 AC_MSG_RESULT($has_exosip_dscp)
 450 if test "$has_exosip_dscp" = "yes" ; then
 451         AC_DEFINE( HAVE_EXOSIP_DSCP, 1, [Define if exosip dscp available] )
 452 fi
 453
 454
 455 if test "$console_ui" = "true" ; then
 456         dnl check gnu readline
 457         LP_CHECK_READLINE
 458 else
 459         echo "Console interface compilation is disabled."
 460 fi
 461
 462 AC_WORDS_BIGENDIAN
 463
 464 AC_ARG_ENABLE([speex],
 465         AS_HELP_STRING([--disable-speex], [Disable speex support]),
 466         [],
 467         [enable_speex=yes]
 468 )
 469 if test "x$enable_speex" = "xyes"; then
 470         dnl normaly this should only by done by mediastreamer2/configure.ac
 471         dnl but to workaround bugs when cross-compiling for arm-linux,
 472         dnl we need to have SPEEX_LIBS defined
 473         dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 474         dnl since top-level configure --help will not print them.
 475         PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 476 fi
 477
 478 dnl conditionnal build of video support
 479 AC_ARG_ENABLE(video,
 480         [AS_HELP_STRING([--enable-video], [Turn on video support compiling])],
 481         [case "${enableval}" in
 482                 yes)    video=true ;;
 483                 no)     video=false ;;
 484                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 485         esac],
 486         [video=true]
 487 )
 488
 489 AC_ARG_WITH(ffmpeg,
 490         [AS_HELP_STRING([--with-ffmpeg], [Sets the installation prefix of ffmpeg, needed for video support. (default=/usr)])],
 491         [ ffmpegdir=${withval}],
 492         [ ffmpegdir=/usr ]
 493 )
 494
 495 if test "$video" = "true"; then
 496
 497         if test "$enable_x11" = "true"; then
 498                 AC_CHECK_HEADERS(X11/Xlib.h)
 499                 if test "$build_macos" = "yes"; then
 500                         X11_LIBS="-L/usr/X11/lib -lX11"
 501                 else
 502                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 503                 fi
 504                 AC_SUBST(X11_LIBS)
 505         fi
 506         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 507 fi
 508
 509 AC_ARG_ENABLE(alsa,
 510         [AS_HELP_STRING([--enable-alsa], [Turn on alsa native support compiling])],
 511         [case "${enableval}" in
 512                 yes)    alsa=true ;;
 513                 no)     alsa=false ;;
 514                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 515         esac],
 516         [alsa=true]
 517 )
 518
 519 AC_ARG_ENABLE(zrtp,
 520         [AS_HELP_STRING([--enable-zrtp], [Turn on zrtp support])],
 521         [case "${enableval}" in
 522                 yes)    zrtp=true ;;
 523                 no)     zrtp=false ;;
 524                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-zrtp) ;;
 525         esac],
 526         [zrtp=false]
 527 )
 528
 529
 530 AC_ARG_ENABLE(portaudio,
 531         [AS_HELP_STRING([--enable-portaudio], [Turn on portaudio native support compiling])],
 532         [case "${enableval}" in
 533                 yes)    portaudio=true ;;
 534                 no)     portaudio=false ;;
 535                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 536         esac],
 537         [portaudio=false]
 538 )
 539
 540 dnl build console if required
 541 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 542
 543 dnl special things for arm-linux cross compilation toolchain
 544 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 545
 546 dnl compilation of gtk user interface
 547 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 548 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 549 AM_CONDITIONAL(BUILD_ZRTP, test x$zrtp = xtrue)
 550
 551 dnl check getenv
 552 AH_TEMPLATE([HAVE_GETENV])
 553 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 554
 555 dnl
 556 AC_MSG_CHECKING([for sighandler_t])
 557 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 558 has_sighandler_t=yes,has_sighandler_t=no)
 559 AC_MSG_RESULT($has_sighandler_t)
 560 if test "$has_sighandler_t" = "yes" ; then
 561         AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 562 fi
 563
 564 AC_ARG_ENABLE(assistant,
 565         [AS_HELP_STRING([--enable-assistant], [Turn on assistant compiling])],
 566         [case "${enableval}" in
 567                 yes)    build_wizard=true ;;
 568                 no)     build_wizard=false ;;
 569                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-assistant) ;;
 570         esac],
 571         [build_wizard=check]
 572 )
 573
 574 dnl check libsoup (needed for wizard)
 575 if test "$build_wizard" != "false" ; then
 576         PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26],[],
 577                 [if test "$build_wizard" = "true" ; then
 578                         AC_MSG_ERROR([Could not found libsoup, assistant cannot be compiled.])
 579                 else
 580                         build_wizard=false
 581                 fi]
 582         )
 583 fi
 584 if test "$build_wizard" != "false" ; then
 585         PKG_CHECK_MODULES(LIBGTKWIZARD, [gtk+-2.0 >= 2.22.0],[],
 586                 [if test "$build_wizard" = "true" ; then
 587                         AC_MSG_ERROR([gtk+-2.0 < 2.22.0, assistant cannot be compiled.])
 588                 else
 589                         build_wizard=false
 590                 fi]
 591         )
 592 fi
 593 AC_SUBST(LIBSOUP_CFLAGS)
 594 AC_SUBST(LIBSOUP_LIBS)
 595 AM_CONDITIONAL(BUILD_WIZARD, test x$build_wizard != xfalse)
 596 if test "$build_wizard" != "false" ; then
 597         build_wizard=true
 598          AC_DEFINE(BUILD_WIZARD, 1, [Define if wizard enabled] )
 599 fi
 600
 601 AC_CHECK_HEADERS(libudev.h)
 602 AC_CHECK_LIB(udev,udev_new)
 603
 604 ##################################################
 605 # Stricter build options (after external packages)
 606 ##################################################
 607
 608
 609 AC_ARG_ENABLE(strict,
 610         AC_HELP_STRING([--enable-strict], [Build with stricter options (gcc only) @<:@yes@:>@]),
 611         [strictness="${enableval}"],
 612         [strictness=yes]
 613 )
 614
 615 STRICT_OPTIONS="-Wall "
 616
 617 if test "$strictness" = "yes" ; then
 618         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 619         CFLAGS="$CFLAGS -fno-strict-aliasing"
 620 fi
 621
 622 AC_SUBST(STRICT_OPTIONS)
 623
 624 top_srcdir=`dirname $0`
 625
 626 AC_ARG_ENABLE([external-mediastreamer],
 627         [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 628         [enable_external_mediastreamer=no]
 629 )
 630
 631 AS_CASE($enable_external_mediastreamer,
 632         [yes],
 633         [PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 634         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`],
 635         [no],
 636         [AC_CONFIG_SUBDIRS( mediastreamer2 )
 637         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 638         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 639         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer_base.la \$(top_builddir)/mediastreamer2/src/libmediastreamer_voip.la"
 640 dnl need to temporary change quotes to allow square brackets
 641         changequote(<<, >>)
 642         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 643         changequote([, ])
 644         MS2_DIR=mediastreamer2],
 645         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])]
 646 )
 647
 648 AC_SUBST(MEDIASTREAMER_CFLAGS)
 649 AC_SUBST(MEDIASTREAMER_LIBS)
 650 AC_SUBST([MS2_VERSION])
 651 AC_SUBST([MS2_DIR])
 652
 653
 654
 655 AC_ARG_ENABLE(tunnel,
 656         [AS_HELP_STRING([--enable-tunnel=[yes/no]], [Turn on compilation of tunnel support (default=no)])],
 657         [case "${enableval}" in
 658                 yes)    enable_tunnel=true ;;
 659                 no)     enable_tunnel=false ;;
 660                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-tunnel) ;;
 661         esac],
 662         [enable_tunnel=false]
 663 )
 664 AM_CONDITIONAL(BUILD_TUNNEL, test x$enable_tunnel = xtrue)
 665 if test x$enable_tunnel = xtrue; then
 666         PKG_CHECK_MODULES(TUNNEL, tunnel >= 0.3.3)
 667         TUNNEL_CFLAGS+="-DTUNNEL_ENABLED"
 668         AC_SUBST(TUNNEL_CFLAGS)
 669         AC_SUBST(TUNNEL_LIBS)
 670 fi
 671
 672 AC_ARG_ENABLE(msg-storage,
 673         [AS_HELP_STRING([--enable-msg-storage=[yes/no]], [Turn on compilation of message storage (default=yes)])],
 674         [case "${enableval}" in
 675                 yes)    enable_msg_storage=true ;;
 676                 no)     enable_msg_storage=false ;;
 677                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-msg-storage) ;;
 678         esac],
 679         [enable_msg_storage=true]
 680 )
 681 AM_CONDITIONAL(BUILD_MSG_STORAGE, test x$enable_msg_storage = xtrue)
 682 if test x$enable_msg_storage = xtrue; then
 683         PKG_CHECK_MODULES(SQLITE3,[ sqlite3 >= 3.7.0],[],[
 684                 AC_MSG_ERROR([sqlite3 required for message storage not found.])] )
 685         SQLITE3_CFLAGS+="-DMSG_STORAGE_ENABLED"
 686         AC_SUBST(SQLITE3_CFLAGS)
 687         AC_SUBST(SQLITE3_LIBS)
 688 fi
 689
 690
 691 dnl check for db2html (docbook) to generate html user manual
 692 AC_CHECK_PROG(have_sgmltools, sgmltools, yes, no)
 693 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 694
 695 dnl for external use of linphone libs
 696 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 697 LINPHONE_LIBS="-L${libdir} -llinphone"
 698
 699 if test x$mingw_found = xyes ; then
 700         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 701 fi
 702 AC_SUBST(LINPHONE_CFLAGS)
 703 AC_SUBST(LINPHONE_LIBS)
 704
 705 AC_DEFINE_UNQUOTED(LINPHONE_VERSION, "$PACKAGE_VERSION", [Linphone\'s version number])
 706
 707 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 708 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 709 AC_SUBST(LINPHONE_PLUGINS_DIR)
 710
 711 AC_ARG_ENABLE(external-ortp,
 712         [AS_HELP_STRING([--enable-external-ortp], [Use external oRTP library])],
 713         [case "${enableval}" in
 714                 yes)    external_ortp=true ;;
 715                 no)     external_ortp=false ;;
 716                 *)      AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 717         esac],
 718         [external_ortp=false]
 719 )
 720
 721 if test "$external_ortp" = 'true'; then
 722         PKG_CHECK_MODULES([ORTP], [ortp])
 723         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 724 else
 725         AC_CONFIG_SUBDIRS( oRTP )
 726         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 727         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 728         if test x$ac_cv_c_bigendian = xyes ; then
 729                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 730         fi
 731         if test x$ntptimestamp = xtrue ; then
 732                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_TIMESTAMP"
 733         fi
 734         ORTP_DIR=oRTP
 735         changequote(<<, >>)
 736         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 737         changequote([, ])
 738 fi
 739 AC_SUBST(ORTP_CFLAGS)
 740 AC_SUBST(ORTP_LIBS)
 741 AC_SUBST([ORTP_VERSION])
 742 AC_SUBST([ORTP_DIR])
 743
 744 AC_ARG_ENABLE(tests_enabled,
 745         [AS_HELP_STRING([--disable-tests], [Disable compilation of tests])],
 746         [case "${enableval}" in
 747                 yes)    tests_enabled=true ;;
 748                 no)     tests_enabled=false ;;
 749                 *)      AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 750         esac],
 751         [tests_enabled=false]
 752 )
 753 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 754
 755
 756
 757 dnl ##################################################
 758 dnl # Check for doxygen
 759 dnl ##################################################
 760
 761 AC_PATH_PROG(DOXYGEN,doxygen,false)
 762 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 763
 764
 765 AC_CONFIG_FILES([
 766         Makefile
 767         build/Makefile
 768         build/macos/Makefile
 769         build/macos/Info-linphone.plist
 770         m4/Makefile
 771         po/Makefile.in
 772         pixmaps/Makefile
 773         coreapi/Makefile
 774         coreapi/help/Makefile
 775         coreapi/help/Doxyfile
 776         gtk/Makefile
 777         console/Makefile
 778         share/Makefile
 779         share/C/Makefile
 780         share/fr/Makefile
 781         share/it/Makefile
 782         share/ja/Makefile
 783         share/cs/Makefile
 784         share/xml/Makefile
 785         share/linphone.pc
 786         share/linphone.desktop
 787         scripts/Makefile
 788         tools/Makefile
 789         linphone.spec
 790         linphone.iss
 791 ])
 792
 793 AC_OUTPUT
 794
 795 echo "Linphone build configuration ended."
 796 echo "Summary of build options:"
 797 printf "* %-30s %s\n" "Video support"           $video
 798 printf "* %-30s %s\n" "GTK interface"           $gtk_ui
 799 printf "* %-30s %s\n" "Account assistant"       $build_wizard
 800 printf "* %-30s %s\n" "Console interface"       $console_ui
 801 printf "* %-30s %s\n" "Tools"                   $build_tools
 802 printf "* %-30s %s\n" "Message storage"         $enable_msg_storage
 803 printf "* %-30s %s\n" "zRTP encryption (GPLv3)" $zrtp
 804 printf "* %-30s %s\n" "uPnP support"            $build_upnp
 805
 806 if test "$enable_tunnel" = "true" ; then
 807         printf "* Tunnel support\t\ttrue\n"
 808 fi
 809
 810 echo "Now type 'make' to compile, and then 'make install' as root to install it."