sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.99.1],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target_os in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63         *darwin*)
  64                 dnl use macport installation
  65                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  66                 build_macos=yes
  67         ;;
  68 esac
  69
  70 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  71 AC_SUBST(CONSOLE_FLAGS)
  72 AC_SUBST(GUI_FLAGS)
  73
  74 dnl localization tools
  75 IT_PROG_INTLTOOL([0.40], [no-xml])
  76
  77 dnl Initialize libtool
  78 LT_INIT([win32-dll shared disable-static])
  79
  80 AC_CONFIG_COMMANDS([libtool-hacking],[
  81 if test "$mingw_found" = "yes" ; then
  82         echo "Hacking libtool to work with mingw..."
  83         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  84         cp -f ./libtool.tmp ./libtool
  85         rm -f ./libtool.tmp
  86 fi
  87 ],[mingw_found=$mingw_found])
  88
  89 dnl Add the languages which your application supports here.
  90 PKG_PROG_PKG_CONFIG
  91 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  92 AC_SUBST(ALL_LINGUAS)
  93 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  94
  95 if test "$mingw_found" != "yes" ; then
  96 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  97 AM_GNU_GETTEXT([external])
  98 LIBS="$LIBS $LIBINTL"
  99 else
 100         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 101         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 102         LIBS="$LIBS -lintl"
 103 fi
 104
 105 GETTEXT_PACKAGE=linphone
 106 AC_SUBST(GETTEXT_PACKAGE)
 107 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 108 dnl AC_CHECK_LIB(intl,libintl_gettext)
 109
 110 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 111
 112 AC_ARG_ENABLE(x11,
 113                           [  --disable-x11    Disable X11 support],
 114                           [case "${enableval}" in
 115                           yes) enable_x11=true ;;
 116                           no)  enable_x11=false ;;
 117                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 118                           esac],[enable_x11=true])
 119
 120 dnl conditionnal build of console interface.
 121 AC_ARG_ENABLE(console_ui,
 122       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 123       [case "${enableval}" in
 124         yes) console_ui=true ;;
 125         no)  console_ui=false ;;
 126         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 127       esac],[console_ui=true])
 128
 129 dnl conditionnal build of gtk interface.
 130 AC_ARG_ENABLE(gtk_ui,
 131       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 132       [case "${enableval}" in
 133         yes) gtk_ui=true ;;
 134         no)  gtk_ui=false ;;
 135         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 136       esac],[gtk_ui=true])
 137
 138 if test "$gtk_ui" = "true" ; then
 139         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 140         if test "$enable_x11" = "false" ; then
 141                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 142                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 143         fi
 144 else
 145         echo "GTK interface compilation is disabled."
 146 fi
 147
 148
 149 dnl os-specific problems not handled by existing macros.
 150 case "$host_os" in
 151         *freebsd*)
 152                 LDFLAGS="$LDFLAGS -pthread"
 153                 ;;
 154 esac
 155
 156 case "$host_cpu" in
 157         *arm*)
 158                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 159                 use_arm_toolchain=yes
 160                 ;;
 161 esac
 162
 163 AC_ARG_WITH( configdir,
 164       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 165       [ configdir=${withval}],[ configdir="Linphone" ])
 166
 167 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 168
 169 AC_ARG_ENABLE(relativeprefix,
 170       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 171       [case "${enableval}" in
 172         yes) relativeprefix=yes ;;
 173         no)  relativeprefix=no ;;
 174         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 175       esac],[relativeprefix=auto])
 176
 177 AC_ARG_ENABLE(date,
 178       [  --enable-date    Use build date in internal version number],
 179       [case "${enableval}" in
 180         yes) use_date=yes ;;
 181         no)  use_date=no ;;
 182         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 183       esac],[use_date=no])
 184
 185 if test x$use_date =  xyes ; then
 186         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 187 fi
 188
 189
 190 dnl enable ipv6 support
 191 AC_ARG_ENABLE(ipv6,
 192       [  --enable-ipv6    Turn on ipv6 support],
 193       [case "${enableval}" in
 194         yes)  ipv6=true;;
 195         no)   ipv6=false;;
 196         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 197       esac],[ipv6=true])
 198 IPV6_CFLAGS=
 199 if test x$ipv6 = xtrue ; then
 200         IPV6_CFLAGS=-DINET6
 201 fi
 202 AC_SUBST(IPV6_CFLAGS)
 203
 204 dnl enable truespeech codec support
 205 AC_ARG_ENABLE(truespeech,
 206       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 207       [case "${enableval}" in
 208         yes)  truespeech=true;;
 209         no)   truespeech=false;;
 210         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 211       esac],[truespeech=false])
 212 TRUESPEECH_CFLAGS=
 213 if test x$truespeech = xtrue ; then
 214         TRUESPEECH_CFLAGS=-DTRUESPEECH
 215 fi
 216 AC_SUBST(TRUESPEECH_CFLAGS)
 217 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 218
 219 AC_ARG_ENABLE(nonstandard-gsm,
 220       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 221       [case "${enableval}" in
 222         yes) exotic_gsm=yes
 223         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 224          ;;
 225         no)  exotic_gsm=no ;;
 226         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 227       esac],[exotic_gsm=no])
 228
 229
 230 dnl support for RSVP (by Vincent Maury)
 231 AC_ARG_ENABLE(rsvp,
 232 [  --enable-rsvp           enable support for QoS reservations.],
 233 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 234 should be compiled.]) )
 235
 236 if test "x${prefix}" = "xNONE"; then
 237         package_prefix=${ac_default_prefix}
 238 else
 239         package_prefix=${prefix}
 240 fi
 241
 242 if test "$relativeprefix" = "auto" ; then
 243         case $target_os in
 244                 *darwin*)
 245                 if test "$enable_x11" = "false" ; then
 246                         relativeprefix=yes
 247                 fi
 248                 ;;
 249                 *mingw*)
 250                 relativeprefix=yes
 251                 ;;
 252         esac
 253 fi
 254
 255 if test "$relativeprefix" = "yes" ; then
 256         dnl allow binaries to install everywhere
 257         package_prefix="."
 258 fi
 259
 260 dnl Set PACKAGE_LOCALE_DIR in config.h.
 261 DATADIRNAME=share
 262 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 263
 264 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 265
 266 dnl Set PACKAGE_SOUND_DIR in config.h.
 267 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 268
 269
 270 dnl check if we have the getifaddrs() sytem call
 271 AC_CHECK_FUNCS(getifaddrs)
 272
 273 dnl check for osip2
 274 LP_CHECK_OSIP2
 275
 276 dnl conditionnal build for ssl
 277 AC_ARG_ENABLE(ssl,
 278                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 279                 [case "${enableval}" in
 280                 yes) build_ssl=true ;;
 281                 no)  build_ssl=false ;;
 282                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 283                 esac],[build_ssl=false])
 284
 285 if test "$build_ssl" = "true"; then
 286         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 287 fi
 288 dnl setup flags for exosip library
 289 LP_SETUP_EXOSIP
 290
 291 if test "$console_ui" = "true" ; then
 292 dnl check gnu readline
 293 LP_CHECK_READLINE
 294 else
 295 echo "Console interface compilation is disabled."
 296 fi
 297
 298 AC_WORDS_BIGENDIAN
 299
 300 dnl normaly this should only by done by mediastreamer2/configure.ac
 301 dnl but to workaround bugs when cross-compiling for arm-linux,
 302 dnl we need to have SPEEX_LIBS defined
 303 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 304 dnl since top-level configure --help will not print them.
 305
 306 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 307
 308 dnl conditionnal build of video support
 309 AC_ARG_ENABLE(video,
 310                 [  --enable-video    Turn on video support compiling],
 311                 [case "${enableval}" in
 312                 yes) video=true ;;
 313                 no)  video=false ;;
 314                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 315                 esac],[video=true])
 316
 317 AC_ARG_WITH( ffmpeg,
 318                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 319                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 320
 321 if test "$video" = "true"; then
 322
 323         if test "$enable_x11" = "true"; then
 324                 AC_CHECK_HEADERS(X11/Xlib.h)
 325                 if test "$build_macos" = "yes"; then
 326                         X11_LIBS="-L/usr/X11/lib -lX11"
 327                 else
 328                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 329                 fi
 330                 AC_SUBST(X11_LIBS)
 331         fi
 332         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 333 fi
 334
 335 AC_ARG_ENABLE(alsa,
 336       [  --enable-alsa    Turn on alsa native support compiling],
 337       [case "${enableval}" in
 338         yes) alsa=true ;;
 339         no)  alsa=false ;;
 340         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 341       esac],[alsa=true])
 342
 343 AC_ARG_ENABLE(artsc,
 344       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 345       [case "${enableval}" in
 346         yes) artsc=true ;;
 347         no)  artsc=false ;;
 348         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 349       esac],[artsc=false])
 350
 351 AC_ARG_ENABLE(portaudio,
 352       [  --enable-portaudio    Turn on portaudio native support compiling],
 353       [case "${enableval}" in
 354         yes) portaudio=true ;;
 355         no)  portaudio=false ;;
 356         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 357       esac],[portaudio=false])
 358
 359 dnl build console if required
 360 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 361 dnl special things for arm-linux cross compilation toolchain
 362 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 363 dnl compilation of gtk user interface
 364 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 365 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 366
 367 dnl check getenv
 368 AH_TEMPLATE([HAVE_GETENV])
 369 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 370
 371 dnl
 372 AC_MSG_CHECKING([for sighandler_t])
 373 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 374 has_sighandler_t=yes,has_sighandler_t=no)
 375 AC_MSG_RESULT($has_sighandler_t)
 376 if test "$has_sighandler_t" = "yes" ; then
 377     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 378 fi
 379
 380 ##################################################
 381 # Stricter build options (after external packages)
 382 ##################################################
 383
 384
 385 AC_ARG_ENABLE(strict,
 386         AC_HELP_STRING([--enable-strict],
 387                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 388         strictness="${enableval}"],[strictness=yes]
 389 )
 390
 391 STRICT_OPTIONS="-Wall "
 392
 393 if test "$GCC$strictness" = "yesyes" ; then
 394         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 395         CFLAGS="$CFLAGS -fno-strict-aliasing"
 396 fi
 397
 398 AC_SUBST(STRICT_OPTIONS)
 399
 400 top_srcdir=`dirname $0`
 401
 402 AC_ARG_ENABLE([external-mediastreamer],
 403       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 404       [enable_external_mediastreamer=no])
 405
 406 AS_CASE($enable_external_mediastreamer,
 407                 [yes],[
 408                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 409                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 410                         ],
 411                 [no],[
 412                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 413                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 414                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 415                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 416 dnl need to temporary change quotes to allow square brackets
 417                         changequote(<<, >>)
 418                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 419                         changequote([, ])
 420                         MS2_DIR=mediastreamer2
 421                         ],
 422         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 423
 424 AC_SUBST(MEDIASTREAMER_CFLAGS)
 425 AC_SUBST(MEDIASTREAMER_LIBS)
 426 AC_SUBST([MS2_VERSION])
 427 AC_SUBST([MS2_DIR])
 428
 429 dnl check for db2html (docbook) to generate html user manual
 430 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 431 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 432
 433 dnl for external use of linphone libs
 434 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 435 LINPHONE_LIBS="-L${libdir} -llinphone"
 436
 437 if test x$mingw_found = xyes ; then
 438         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 439 fi
 440 AC_SUBST(LINPHONE_CFLAGS)
 441 AC_SUBST(LINPHONE_LIBS)
 442
 443 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 444
 445 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 446 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 447 AC_SUBST(LINPHONE_PLUGINS_DIR)
 448
 449 AC_ARG_ENABLE(external-ortp,
 450       [  --enable-external-ortp    Use external oRTP library],
 451       [case "${enableval}" in
 452         yes) external_ortp=true ;;
 453         no)  external_ortp=false ;;
 454         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 455       esac],[external_ortp=false])
 456
 457 if test "$external_ortp" = 'true'; then
 458         PKG_CHECK_MODULES([ORTP], [ortp])
 459         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 460 else
 461         AC_CONFIG_SUBDIRS( oRTP )
 462         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 463         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 464         if test x$ac_cv_c_bigendian = xyes ; then
 465                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 466         fi
 467         ORTP_DIR=oRTP
 468         changequote(<<, >>)
 469         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 470         changequote([, ])
 471 fi
 472 AC_SUBST(ORTP_CFLAGS)
 473 AC_SUBST(ORTP_LIBS)
 474 AC_SUBST([ORTP_VERSION])
 475 AC_SUBST([ORTP_DIR])
 476
 477 dnl ##################################################
 478 dnl # Check for doxygen
 479 dnl ##################################################
 480
 481 AC_PATH_PROG(DOXYGEN,doxygen,false)
 482 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 483
 484
 485 AC_CONFIG_FILES([
 486 Makefile
 487 build/Makefile
 488 build/macos/Makefile
 489 build/macos/Info-linphone.plist
 490 m4/Makefile
 491 po/Makefile.in
 492 pixmaps/Makefile
 493 coreapi/Makefile
 494 coreapi/help/Makefile
 495 coreapi/help/Doxyfile
 496 gtk/Makefile
 497 console/Makefile
 498 share/Makefile
 499 share/C/Makefile
 500 share/fr/Makefile
 501 share/it/Makefile
 502 share/ja/Makefile
 503 share/cs/Makefile
 504 share/linphone.pc
 505 share/linphone.desktop
 506 scripts/Makefile
 507 linphone.spec
 508 linphone.iss
 509 ])
 510
 511 AC_OUTPUT
 512
 513 echo "Linphone build configuration ended."
 514
 515 if test x$gtk_ui = xtrue ; then
 516         echo "* GTK interface will be compiled."
 517 fi
 518 if test x$console_ui = xtrue ; then
 519         echo "* Console interface will be compiled."
 520 fi
 521
 522 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 523