sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.5.99.0],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=5 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_SUBST([docdir], [${datadir}/doc])
  36 AC_CONFIG_HEADERS(config.h)
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_C_INLINE
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63        armv6-apple-darwin|armv7-apple-darwin|i386-apple-darwin|armv7s-apple-darwin)
  64                 CFLAGS="$CFLAGS -DTARGET_OS_IPHONE "
  65                 build_tests=no
  66                 ios_found=yes
  67         ;;
  68         x86_64-apple-darwin*|i686-apple-darwin*)
  69         MSPLUGINS_CFLAGS=""
  70                 dnl use macport installation
  71                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  72                 build_macos=yes
  73         ;;
  74
  75 esac
  76
  77 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  78 AC_SUBST(CONSOLE_FLAGS)
  79 AC_SUBST(GUI_FLAGS)
  80
  81 dnl localization tools
  82 IT_PROG_INTLTOOL([0.40], [no-xml])
  83
  84 AM_CONDITIONAL(BUILD_TESTS,test x$build_tests != xno)
  85 dnl Initialize libtool
  86 LT_INIT([win32-dll shared disable-static])
  87 dnl Enable library dependencies linking
  88 AC_ARG_ENABLE(deplibs-link,
  89       [AS_HELP_STRING([--disable-deplibs-link ], [Disable library dependencies linking (might break builds)])],
  90       [enable_deplibs_linking="$enableval"],
  91       [enable_deplibs_linking="yes"])
  92 AC_MSG_NOTICE([Enable library dependencies linking: $enable_interlib_deps])
  93 if test "${enable_deplibs_linking}" == "yes"; then
  94       link_all_deplibs=yes
  95       link_all_deplibs_CXX=yes
  96 else
  97       link_all_deplibs=no
  98       link_all_deplibs_CXX=no
  99 fi
 100
 101 AC_CONFIG_COMMANDS([libtool-hacking],[
 102 if test "$mingw_found" = "yes" ; then
 103         echo "Hacking libtool to work with mingw..."
 104         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
 105         cp -f ./libtool.tmp ./libtool
 106         rm -f ./libtool.tmp
 107 fi
 108 ],[mingw_found=$mingw_found])
 109
 110 dnl Add the languages which your application supports here.
 111 PKG_PROG_PKG_CONFIG
 112 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW he"
 113 AC_SUBST(ALL_LINGUAS)
 114 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
 115
 116 if test "$mingw_found" != "yes" ; then
 117         dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 118
 119         dnl AM_GNU_GETTEXT pollutes CPPFLAGS: workaround this.
 120         CPPFLAGS_save=$CPPFLAGS
 121         AM_GNU_GETTEXT([external])
 122         AC_SUBST(INTLLIBS)
 123         CPPFLAGS=$CPPFLAGS_save
 124         LIBS="$LIBS $LIBINTL"
 125 else
 126         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 127         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 128         LIBS="$LIBS -lintl"
 129 fi
 130
 131 GETTEXT_PACKAGE=linphone
 132 AC_SUBST(GETTEXT_PACKAGE)
 133 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext package name])
 134 dnl AC_CHECK_LIB(intl,libintl_gettext)
 135
 136 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 137
 138 AC_ARG_ENABLE(x11,
 139       [AS_HELP_STRING([--disable-x11], [Disable X11 support (default=no)])],
 140       [case "${enableval}" in
 141         yes) enable_x11=true ;;
 142         no)  enable_x11=false ;;
 143         *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 144       esac],[enable_x11=true])
 145
 146 dnl conditionnal build of console interface.
 147 AC_ARG_ENABLE(console_ui,
 148       [AS_HELP_STRING([--enable-console_ui=[yes/no]], [Turn on or off compilation of console interface (default=yes)])],
 149       [case "${enableval}" in
 150         yes) console_ui=true ;;
 151         no)  console_ui=false ;;
 152         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 153       esac],[console_ui=true])
 154
 155 dnl conditionnal build of tools.
 156 AC_ARG_ENABLE(tools,
 157       [AS_HELP_STRING([--enable-tools=[yes/no]], [Turn on or off compilation of console interface (default=yes)])],
 158       [case "${enableval}" in
 159         yes) build_tools=true ;;
 160         no)  build_tools=false ;;
 161         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tools) ;;
 162       esac],[build_tools=check])
 163
 164 dnl check for installed version of libupnp
 165 AC_ARG_ENABLE(upnp,
 166       [AS_HELP_STRING([--disable-upnp], [Disable uPnP support])],
 167       [case "${enableval}" in
 168         yes) build_upnp=true ;;
 169         no)  build_upnp=false ;;
 170         *) AC_MSG_ERROR(bad value ${enableval} for --disable-upnp) ;;
 171       esac],[build_upnp=auto])
 172
 173 if test "$build_upnp" != "false" ; then
 174 PKG_CHECK_MODULES([LIBUPNP], [libupnp], [build_upnp=true],
 175         [
 176                 if test "$build_upnp" == "true" ; then
 177                         AC_MSG_ERROR([libupnp not found.])
 178                 else
 179                         build_upnp=false
 180                 fi
 181         ])
 182
 183 fi
 184
 185 AM_CONDITIONAL(BUILD_UPNP, test x$build_upnp != xfalse)
 186 if test "$build_upnp" != "false" ; then
 187         AC_DEFINE(BUILD_UPNP, 1, [Define if upnp enabled])
 188 fi
 189
 190 dnl check libxml2 (needed for tools)
 191 if test "$build_tools" != "false" ; then
 192         PKG_CHECK_MODULES(LIBXML2, [libxml-2.0],[],
 193         [
 194                 if test "$build_tools" = "true" ; then
 195                         AC_MSG_ERROR([Could not found libxml2, tools cannot be compiled.])
 196                 else
 197                         build_tools=false
 198                 fi
 199         ])
 200 fi
 201
 202 AM_CONDITIONAL(BUILD_TOOLS, test x$build_tools != xfalse)
 203 if test "$build_tools" != "false" ; then
 204    build_tools=true
 205    AC_DEFINE(BUILD_TOOLS, 1, [Define if tools enabled] )
 206 fi
 207
 208 dnl conditionnal build of gtk interface.
 209 AC_ARG_ENABLE(gtk_ui,
 210       [AS_HELP_STRING([--enable-gtk_ui=[yes/no]], [Turn on or off compilation of gtk interface (default=yes)])],
 211       [case "${enableval}" in
 212         yes) gtk_ui=true ;;
 213         no)  gtk_ui=false ;;
 214         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 215       esac],[gtk_ui=true])
 216
 217 if test "$gtk_ui" = "true" ; then
 218         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.18.0 gthread-2.0)
 219         if test "$enable_x11" = "false" ; then
 220                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 221                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 222         fi
 223 else
 224         echo "GTK interface compilation is disabled."
 225 fi
 226
 227 AC_ARG_ENABLE(notify,
 228       [AS_HELP_STRING([--enable-notify=[yes/no]], [Enable libnotify support (default=yes)])],
 229       [case "${enableval}" in
 230         yes) notify=true ;;
 231         no)  notify=false ;;
 232         *) AC_MSG_ERROR(bad value ${enableval} for --enable-notify) ;;
 233       esac],[notify=true])
 234
 235 dnl conditionnal build of the notify library
 236 if test "$gtk_ui" = "true" ; then
 237         if test "$notify" = "true"; then
 238                 PKG_CHECK_MODULES([NOTIFY4], [libnotify >= 0.7.0 ], [found_notify4=yes], foo=bar)
 239                 case "$found_notify4" in
 240                   yes)
 241                                 AC_SUBST(NOTIFY4_CFLAGS)
 242                                 AC_SUBST(NOTIFY4_LIBS)
 243                                 AC_DEFINE([HAVE_NOTIFY4],[1],[NOTIFY4 support])
 244                 esac
 245
 246                 PKG_CHECK_MODULES([NOTIFY1], [libnotify < 0.7.0], [found_notify1=yes], foo=bar)
 247                 case "$found_notify1" in
 248                   yes)
 249                                 AC_SUBST(NOTIFY1_CFLAGS)
 250                                 AC_SUBST(NOTIFY1_LIBS)
 251                                 AC_DEFINE([HAVE_NOTIFY1],[1],[NOTIFY1 support])
 252                 esac
 253         else
 254                                 NotifyNotification *n;
 255                 echo "Libnotify support is disabled."
 256         fi
 257 fi
 258
 259 dnl os-specific problems not handled by existing macros.
 260 case "$host_os" in
 261         *freebsd*)
 262                 LDFLAGS="$LDFLAGS -pthread"
 263                 ;;
 264 esac
 265
 266 case "$host_cpu" in
 267         *arm*)
 268                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 269                 use_arm_toolchain=yes
 270                 ;;
 271 esac
 272
 273 AC_ARG_WITH(configdir,
 274       [AS_HELP_STRING([--with-configdir], [Set a APPDATA subdir where linphone is supposed to find its config (windows only)])],
 275       [ configdir=${withval}],[ configdir="Linphone" ])
 276
 277 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 278
 279 AC_ARG_ENABLE(relativeprefix,
 280       [AS_HELP_STRING([--enable-relativeprefix], [Build a linphone that finds its resources relatively to the directory where it is installed])],
 281       [case "${enableval}" in
 282         yes) relativeprefix=yes ;;
 283         no)  relativeprefix=no ;;
 284         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 285       esac],[relativeprefix=guess])
 286
 287 AC_ARG_ENABLE(date,
 288       [AS_HELP_STRING([--enable-date], [Use build date in internal version number])],
 289       [case "${enableval}" in
 290         yes) use_date=yes ;;
 291         no)  use_date=no ;;
 292         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 293       esac],[use_date=no])
 294
 295 if test x$use_date =  xyes ; then
 296         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 297 fi
 298
 299
 300 dnl enable ipv6 support
 301 AC_ARG_ENABLE(ipv6,
 302       [AS_HELP_STRING([--enable-ipv6], [Turn on ipv6 support])],
 303       [case "${enableval}" in
 304         yes)  ipv6=true;;
 305         no)   ipv6=false;;
 306         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 307       esac],[ipv6=true])
 308 IPV6_CFLAGS=
 309 if test x$ipv6 = xtrue ; then
 310         IPV6_CFLAGS=-DINET6
 311 fi
 312 AC_SUBST(IPV6_CFLAGS)
 313
 314 dnl enable timestamp support
 315 AC_ARG_ENABLE(ntp-timestamp,
 316       [AS_HELP_STRING([--enable-ntp-timestamp], [Turn on NTP timestamping on received packet])],
 317       [case "${enableval}" in
 318         yes)  ntptimestamp=true;;
 319         no)   ntptimestamp=false;;
 320         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ntp-timestamp) ;;
 321       esac],[ntptimestamp=false])
 322
 323 AC_ARG_ENABLE(debug,
 324       [AS_HELP_STRING([--enable-debug=[yes/no]], [Enables the display of traces showing the execution of the library. (default=yes)])],
 325       [case "${enableval}" in
 326         yes) debug_enabled=yes;;
 327         no) debug_enabled=no;;
 328         *) AC_MSG_ERROR("Bad value for --enable-debug");;
 329       esac],[debug_enabled=no])
 330
 331 dnl enable truespeech codec support
 332 AC_ARG_ENABLE(truespeech,
 333       [AS_HELP_STRING([--enable-truespeech], [Turn on TrueSpeech support (x86 only)])],
 334       [case "${enableval}" in
 335         yes)  truespeech=true;;
 336         no)   truespeech=false;;
 337         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 338       esac],[truespeech=false])
 339 TRUESPEECH_CFLAGS=
 340 if test x$truespeech = xtrue ; then
 341         TRUESPEECH_CFLAGS=-DTRUESPEECH
 342 fi
 343 AC_SUBST(TRUESPEECH_CFLAGS)
 344 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 345
 346 AC_ARG_ENABLE(nonstandard-gsm,
 347       [AS_HELP_STRING([--enable-nonstandard-gsm], [Enable GSM codec at nonstandard rates (11025hz, 16000hz)])],
 348       [case "${enableval}" in
 349         yes) exotic_gsm=yes
 350          AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 351          ;;
 352         no)  exotic_gsm=no ;;
 353         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 354       esac],[exotic_gsm=no])
 355
 356
 357 dnl support for RSVP (by Vincent Maury)
 358 AC_ARG_ENABLE(rsvp,
 359 [AS_HELP_STRING([--enable-rsvp], [Enable support for QoS reservations.])],
 360 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 361 should be compiled.]) )
 362
 363 if test "x${prefix}" = "xNONE"; then
 364         package_prefix=${ac_default_prefix}
 365 else
 366         package_prefix=${prefix}
 367 fi
 368
 369 if test "$relativeprefix" = "guess" ; then
 370         if test "$mingw_found" = "yes" ; then
 371                 relativeprefix="yes"
 372         fi
 373 fi
 374
 375 if test "$relativeprefix" = "yes" ; then
 376         dnl allow binaries to install everywhere
 377         package_prefix="."
 378 fi
 379
 380 dnl Set PACKAGE_LOCALE_DIR in config.h.
 381 DATADIRNAME=share
 382 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 383
 384 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 385
 386 dnl Set PACKAGE_SOUND_DIR in config.h.
 387 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 388
 389
 390 dnl check if we have the getifaddrs() sytem call
 391 AC_CHECK_FUNCS(getifaddrs)
 392
 393 dnl check for osip2
 394 LP_CHECK_OSIP2
 395
 396 dnl conditionnal build for ssl
 397 AC_ARG_ENABLE(ssl,
 398       [AS_HELP_STRING([--enable-ssl], [Turn on ssl support compiling. Required for sip tls. (default=false)])],
 399       [case "${enableval}" in
 400         yes) build_ssl=true ;;
 401         no)  build_ssl=false ;;
 402         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 403       esac],[build_ssl=false])
 404
 405 if test "$build_ssl" = "true"; then
 406         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 407 fi
 408 dnl setup flags for exosip library
 409 LP_SETUP_EXOSIP
 410
 411 dnl check exosip support of DSCP in exosip
 412 AC_MSG_CHECKING([for DSCP support in exosip])
 413 AC_TRY_COMPILE([#include <eXosip2/eXosip.h>],
 414 [int dscp=0;eXosip_set_option(EXOSIP_OPT_SET_DSCP,&dscp);],
 415 has_exosip_dscp=yes,has_exosip_dscp=no)
 416 AC_MSG_RESULT($has_exosip_dscp)
 417 if test "$has_exosip_dscp" = "yes" ; then
 418     AC_DEFINE( HAVE_EXOSIP_DSCP, 1, [Define if exosip dscp available] )
 419 fi
 420
 421
 422 if test "$console_ui" = "true" ; then
 423 dnl check gnu readline
 424 LP_CHECK_READLINE
 425 else
 426 echo "Console interface compilation is disabled."
 427 fi
 428
 429 AC_WORDS_BIGENDIAN
 430
 431 AC_ARG_ENABLE([speex],
 432               AS_HELP_STRING([--disable-speex], [Disable speex support]),
 433               [], [enable_speex=yes])
 434 if test "x$enable_speex" = "xyes"; then
 435         dnl normaly this should only by done by mediastreamer2/configure.ac
 436         dnl but to workaround bugs when cross-compiling for arm-linux,
 437         dnl we need to have SPEEX_LIBS defined
 438         dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 439         dnl since top-level configure --help will not print them.
 440         PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 441 fi
 442
 443 dnl conditionnal build of video support
 444 AC_ARG_ENABLE(video,
 445       [AS_HELP_STRING([--enable-video], [Turn on video support compiling])],
 446       [case "${enableval}" in
 447         yes) video=true ;;
 448         no)  video=false ;;
 449         *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 450       esac],[video=true])
 451
 452 AC_ARG_WITH( ffmpeg,
 453       [AS_HELP_STRING([--with-ffmpeg], [Sets the installation prefix of ffmpeg, needed for video support. (default=/usr)])],
 454       [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 455
 456 if test "$video" = "true"; then
 457
 458         if test "$enable_x11" = "true"; then
 459                 AC_CHECK_HEADERS(X11/Xlib.h)
 460                 if test "$build_macos" = "yes"; then
 461                         X11_LIBS="-L/usr/X11/lib -lX11"
 462                 else
 463                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 464                 fi
 465                 AC_SUBST(X11_LIBS)
 466         fi
 467         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 468 fi
 469
 470 AC_ARG_ENABLE(alsa,
 471       [AS_HELP_STRING([--enable-alsa], [Turn on alsa native support compiling])],
 472       [case "${enableval}" in
 473         yes) alsa=true ;;
 474         no)  alsa=false ;;
 475         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 476       esac],[alsa=true])
 477
 478 AC_ARG_ENABLE(zrtp,
 479       [AS_HELP_STRING([--enable-zrtp], [Turn on zrtp support])],
 480       [case "${enableval}" in
 481         yes) zrtp=true ;;
 482         no)  zrtp=false ;;
 483         *) AC_MSG_ERROR(bad value ${enableval} for --enable-zrtp) ;;
 484       esac],[zrtp=false])
 485
 486
 487 AC_ARG_ENABLE(portaudio,
 488       [AS_HELP_STRING([--enable-portaudio], [Turn on portaudio native support compiling])],
 489       [case "${enableval}" in
 490         yes) portaudio=true ;;
 491         no)  portaudio=false ;;
 492         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 493       esac],[portaudio=false])
 494
 495 dnl build console if required
 496 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 497
 498 dnl special things for arm-linux cross compilation toolchain
 499 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 500
 501 dnl compilation of gtk user interface
 502 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 503 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 504 AM_CONDITIONAL(BUILD_ZRTP, test x$zrtp = xtrue)
 505
 506 dnl check getenv
 507 AH_TEMPLATE([HAVE_GETENV])
 508 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 509
 510 dnl
 511 AC_MSG_CHECKING([for sighandler_t])
 512 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 513 has_sighandler_t=yes,has_sighandler_t=no)
 514 AC_MSG_RESULT($has_sighandler_t)
 515 if test "$has_sighandler_t" = "yes" ; then
 516     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 517 fi
 518
 519 AC_ARG_ENABLE(assistant,
 520       [AS_HELP_STRING([--enable-assistant], [Turn on assistant compiling])],
 521       [case "${enableval}" in
 522         yes) build_wizard=true ;;
 523         no)  build_wizard=false ;;
 524         *) AC_MSG_ERROR(bad value ${enableval} for --enable-assistant) ;;
 525       esac],[build_wizard=check])
 526
 527 dnl check libsoup (needed for wizard)
 528 if test "$build_wizard" != "false" ; then
 529         PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26],[],
 530         [
 531                 if test "$build_wizard" = "true" ; then
 532                         AC_MSG_ERROR([Could not found libsoup, assistant cannot be compiled.])
 533                 else
 534                         build_wizard=false
 535                 fi
 536         ])
 537 fi
 538 if test "$build_wizard" != "false" ; then
 539         PKG_CHECK_MODULES(LIBGTKWIZARD, [gtk+-2.0 >= 2.22.0],[],
 540         [
 541                 if test "$build_wizard" = "true" ; then
 542                         AC_MSG_ERROR([gtk+-2.0 < 2.22.0, assistant cannot be compiled.])
 543                 else
 544                         build_wizard=false
 545                 fi
 546         ])
 547 fi
 548 AC_SUBST(LIBSOUP_CFLAGS)
 549 AC_SUBST(LIBSOUP_LIBS)
 550 AM_CONDITIONAL(BUILD_WIZARD, test x$build_wizard != xfalse)
 551 if test "$build_wizard" != "false" ; then
 552    build_wizard=true
 553    AC_DEFINE(BUILD_WIZARD, 1, [Define if wizard enabled] )
 554 fi
 555
 556 AC_CHECK_HEADERS(libudev.h)
 557 AC_CHECK_LIB(udev,udev_new)
 558
 559 ##################################################
 560 # Stricter build options (after external packages)
 561 ##################################################
 562
 563
 564 AC_ARG_ENABLE(strict,
 565         AC_HELP_STRING([--enable-strict],
 566                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 567         strictness="${enableval}"],[strictness=yes]
 568 )
 569
 570 STRICT_OPTIONS="-Wall "
 571
 572 if test "$strictness" = "yes" ; then
 573         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 574         CFLAGS="$CFLAGS -fno-strict-aliasing"
 575 fi
 576
 577 AC_SUBST(STRICT_OPTIONS)
 578
 579 top_srcdir=`dirname $0`
 580
 581 AC_ARG_ENABLE([external-mediastreamer],
 582       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 583       [enable_external_mediastreamer=no])
 584
 585 AS_CASE($enable_external_mediastreamer,
 586                 [yes],[
 587                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 588                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 589                         ],
 590                 [no],[
 591                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 592                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 593                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 594                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer_base.la \$(top_builddir)/mediastreamer2/src/libmediastreamer_voip.la"
 595 dnl need to temporary change quotes to allow square brackets
 596                         changequote(<<, >>)
 597                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 598                         changequote([, ])
 599                         MS2_DIR=mediastreamer2
 600                         ],
 601         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 602
 603 AC_SUBST(MEDIASTREAMER_CFLAGS)
 604 AC_SUBST(MEDIASTREAMER_LIBS)
 605 AC_SUBST([MS2_VERSION])
 606 AC_SUBST([MS2_DIR])
 607
 608
 609
 610 AC_ARG_ENABLE(tunnel,
 611       [AS_HELP_STRING([--enable-tunnel=[yes/no]], [Turn on compilation of tunnel support (default=no)])],
 612       [case "${enableval}" in
 613         yes) enable_tunnel=true ;;
 614         no)  enable_tunnel=false ;;
 615         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tunnel) ;;
 616       esac],[enable_tunnel=false])
 617 AM_CONDITIONAL(BUILD_TUNNEL, test x$enable_tunnel = xtrue)
 618 if test x$enable_tunnel = xtrue; then
 619      PKG_CHECK_MODULES(TUNNEL, tunnel >= 0.3.3)
 620      TUNNEL_CFLAGS+="-DTUNNEL_ENABLED"
 621      AC_SUBST(TUNNEL_CFLAGS)
 622      AC_SUBST(TUNNEL_LIBS)
 623 fi
 624
 625
 626
 627
 628
 629
 630
 631
 632
 633
 634 dnl check for db2html (docbook) to generate html user manual
 635 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 636 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 637
 638 dnl for external use of linphone libs
 639 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 640 LINPHONE_LIBS="-L${libdir} -llinphone"
 641
 642 if test x$mingw_found = xyes ; then
 643         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 644 fi
 645 AC_SUBST(LINPHONE_CFLAGS)
 646 AC_SUBST(LINPHONE_LIBS)
 647
 648 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 649
 650 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 651 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 652 AC_SUBST(LINPHONE_PLUGINS_DIR)
 653
 654 AC_ARG_ENABLE(external-ortp,
 655       [AS_HELP_STRING([--enable-external-ortp], [Use external oRTP library])],
 656       [case "${enableval}" in
 657         yes) external_ortp=true ;;
 658         no)  external_ortp=false ;;
 659         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 660       esac],[external_ortp=false])
 661
 662 if test "$external_ortp" = 'true'; then
 663         PKG_CHECK_MODULES([ORTP], [ortp])
 664         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 665 else
 666         AC_CONFIG_SUBDIRS( oRTP )
 667         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 668         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 669         if test x$ac_cv_c_bigendian = xyes ; then
 670                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 671         fi
 672         if test x$ntptimestamp = xtrue ; then
 673                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_TIMESTAMP"
 674         fi
 675         ORTP_DIR=oRTP
 676         changequote(<<, >>)
 677         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 678         changequote([, ])
 679 fi
 680 AC_SUBST(ORTP_CFLAGS)
 681 AC_SUBST(ORTP_LIBS)
 682 AC_SUBST([ORTP_VERSION])
 683 AC_SUBST([ORTP_DIR])
 684
 685 AC_ARG_ENABLE(tests_enabled,
 686       [AS_HELP_STRING([--disable-tests], [Disable compilation of tests])],
 687       [case "${enableval}" in
 688         yes) tests_enabled=true ;;
 689         no)  tests_enabled=false ;;
 690         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 691       esac],[tests_enabled=false])
 692 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 693
 694
 695
 696 dnl ##################################################
 697 dnl # Check for doxygen
 698 dnl ##################################################
 699
 700 AC_PATH_PROG(DOXYGEN,doxygen,false)
 701 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 702
 703
 704 AC_CONFIG_FILES([
 705 Makefile
 706 build/Makefile
 707 build/macos/Makefile
 708 build/macos/Info-linphone.plist
 709 m4/Makefile
 710 po/Makefile.in
 711 pixmaps/Makefile
 712 coreapi/Makefile
 713 coreapi/help/Makefile
 714 coreapi/help/Doxyfile
 715 gtk/Makefile
 716 console/Makefile
 717 share/Makefile
 718 share/C/Makefile
 719 share/fr/Makefile
 720 share/it/Makefile
 721 share/ja/Makefile
 722 share/cs/Makefile
 723 share/xml/Makefile
 724 share/linphone.pc
 725 share/linphone.desktop
 726 scripts/Makefile
 727 tools/Makefile
 728 linphone.spec
 729 linphone.iss
 730 ])
 731
 732 AC_OUTPUT
 733
 734 echo "Linphone build configuration ended."
 735 echo "Summary of build options:"
 736 printf "* Video support\t\t\t%s\n" $video
 737 printf "* GTK interface\t\t\t%s\n" $gtk_ui
 738 printf "* Account assistant\t\t%s\n" $build_wizard
 739 printf "* Console interface\t\t%s\n" $console_ui
 740 printf "* Tools\t\t\t\t%s\n" $build_tools
 741 printf "* zRTP encryption (GPLv3)\t%s\n" $zrtp
 742
 743 if test "$enable_tunnel" = "true" ; then
 744         printf "* Tunnel support\t\ttrue\n"
 745 fi
 746
 747 echo "Now type 'make' to compile, and then 'make install' as root to install it."