sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.99.4],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  45 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  46
  47 case $target_os in
  48         *mingw32ce)
  49         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  50         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         LIBS="$LIBS -lws2 -liphlpapi"
  52                 mingw_found=yes
  53                 mingwce_found=yes
  54                 ;;
  55         *mingw*)
  56                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  57                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  58                 LIBS="$LIBS -lws2_32"
  59                 GUI_FLAGS="-mwindows"
  60                 CONSOLE_FLAGS="-mconsole"
  61                 mingw_found=yes
  62         ;;
  63         *darwin*)
  64                 dnl use macport installation
  65                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  66                 build_macos=yes
  67         ;;
  68 esac
  69
  70 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  71 AC_SUBST(CONSOLE_FLAGS)
  72 AC_SUBST(GUI_FLAGS)
  73
  74 dnl localization tools
  75 IT_PROG_INTLTOOL([0.40], [no-xml])
  76
  77 dnl Initialize libtool
  78 LT_INIT([win32-dll shared disable-static])
  79
  80 AC_CONFIG_COMMANDS([libtool-hacking],[
  81 if test "$mingw_found" = "yes" ; then
  82         echo "Hacking libtool to work with mingw..."
  83         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  84         cp -f ./libtool.tmp ./libtool
  85         rm -f ./libtool.tmp
  86 fi
  87 ],[mingw_found=$mingw_found])
  88
  89 dnl Add the languages which your application supports here.
  90 PKG_PROG_PKG_CONFIG
  91 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
  92 AC_SUBST(ALL_LINGUAS)
  93 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  94
  95 if test "$mingw_found" != "yes" ; then
  96 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  97 AM_GNU_GETTEXT([external])
  98 LIBS="$LIBS $LIBINTL"
  99 else
 100         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 101         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 102         LIBS="$LIBS -lintl"
 103 fi
 104
 105 GETTEXT_PACKAGE=linphone
 106 AC_SUBST(GETTEXT_PACKAGE)
 107 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 108 dnl AC_CHECK_LIB(intl,libintl_gettext)
 109
 110 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 111
 112 AC_ARG_ENABLE(x11,
 113                           [  --disable-x11    Disable X11 support],
 114                           [case "${enableval}" in
 115                           yes) enable_x11=true ;;
 116                           no)  enable_x11=false ;;
 117                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 118                           esac],[enable_x11=true])
 119
 120 dnl conditionnal build of console interface.
 121 AC_ARG_ENABLE(console_ui,
 122       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 123       [case "${enableval}" in
 124         yes) console_ui=true ;;
 125         no)  console_ui=false ;;
 126         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 127       esac],[console_ui=true])
 128
 129 dnl conditionnal build of gtk interface.
 130 AC_ARG_ENABLE(gtk_ui,
 131       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 132       [case "${enableval}" in
 133         yes) gtk_ui=true ;;
 134         no)  gtk_ui=false ;;
 135         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 136       esac],[gtk_ui=true])
 137
 138 if test "$gtk_ui" = "true" ; then
 139         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 140         if test "$enable_x11" = "false" ; then
 141                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 142                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 143         fi
 144 else
 145         echo "GTK interface compilation is disabled."
 146 fi
 147
 148 AC_ARG_ENABLE(notify,
 149                 [  --enable-notify=[yes/no]    Enable libnotify support [default=yes]],
 150                 [case "${enableval}" in
 151                   yes) notify=true ;;
 152                   no)  notify=false ;;
 153                   *) AC_MSG_ERROR(bad value ${enableval} for --enable-notify) ;;
 154                 esac],[notify=true])
 155
 156 dnl conditionnal build of the notify library
 157 if test "$gtk_ui" = "true" ; then
 158         if test "$notify" = "true"; then
 159                 PKG_CHECK_MODULES([NOTIFY4], [libnotify >= 0.7.0 ], [found_notify4=yes], foo=bar)
 160                 case "$found_notify4" in
 161                   yes)
 162                                 AC_SUBST(NOTIFY4_CFLAGS)
 163                                 AC_SUBST(NOTIFY4_LIBS)
 164                                 AC_DEFINE([HAVE_NOTIFY4],[1],[NOTIFY4 support])
 165                 esac
 166
 167                 PKG_CHECK_MODULES([NOTIFY1], [libnotify < 0.7.0], [found_notify1=yes], foo=bar)
 168                 case "$found_notify1" in
 169                   yes)
 170                                 AC_SUBST(NOTIFY1_CFLAGS)
 171                                 AC_SUBST(NOTIFY1_LIBS)
 172                                 AC_DEFINE([HAVE_NOTIFY1],[1],[NOTIFY1 support])
 173                 esac
 174         else
 175                                 NotifyNotification *n;
 176                 echo "Libnotify support is disabled."
 177         fi
 178 fi
 179
 180 dnl os-specific problems not handled by existing macros.
 181 case "$host_os" in
 182         *freebsd*)
 183                 LDFLAGS="$LDFLAGS -pthread"
 184                 ;;
 185 esac
 186
 187 case "$host_cpu" in
 188         *arm*)
 189                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 190                 use_arm_toolchain=yes
 191                 ;;
 192 esac
 193
 194 AC_ARG_WITH( configdir,
 195       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 196       [ configdir=${withval}],[ configdir="Linphone" ])
 197
 198 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 199
 200 AC_ARG_ENABLE(relativeprefix,
 201       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 202       [case "${enableval}" in
 203         yes) relativeprefix=yes ;;
 204         no)  relativeprefix=no ;;
 205         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 206       esac],[relativeprefix=guess])
 207
 208 AC_ARG_ENABLE(date,
 209       [  --enable-date    Use build date in internal version number],
 210       [case "${enableval}" in
 211         yes) use_date=yes ;;
 212         no)  use_date=no ;;
 213         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 214       esac],[use_date=no])
 215
 216 if test x$use_date =  xyes ; then
 217         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 218 fi
 219
 220
 221 dnl enable ipv6 support
 222 AC_ARG_ENABLE(ipv6,
 223       [  --enable-ipv6    Turn on ipv6 support],
 224       [case "${enableval}" in
 225         yes)  ipv6=true;;
 226         no)   ipv6=false;;
 227         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 228       esac],[ipv6=true])
 229 IPV6_CFLAGS=
 230 if test x$ipv6 = xtrue ; then
 231         IPV6_CFLAGS=-DINET6
 232 fi
 233 AC_SUBST(IPV6_CFLAGS)
 234
 235 dnl enable truespeech codec support
 236 AC_ARG_ENABLE(truespeech,
 237       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 238       [case "${enableval}" in
 239         yes)  truespeech=true;;
 240         no)   truespeech=false;;
 241         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 242       esac],[truespeech=false])
 243 TRUESPEECH_CFLAGS=
 244 if test x$truespeech = xtrue ; then
 245         TRUESPEECH_CFLAGS=-DTRUESPEECH
 246 fi
 247 AC_SUBST(TRUESPEECH_CFLAGS)
 248 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 249
 250 AC_ARG_ENABLE(nonstandard-gsm,
 251       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 252       [case "${enableval}" in
 253         yes) exotic_gsm=yes
 254         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 255          ;;
 256         no)  exotic_gsm=no ;;
 257         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 258       esac],[exotic_gsm=no])
 259
 260
 261 dnl support for RSVP (by Vincent Maury)
 262 AC_ARG_ENABLE(rsvp,
 263 [  --enable-rsvp           enable support for QoS reservations.],
 264 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 265 should be compiled.]) )
 266
 267 if test "x${prefix}" = "xNONE"; then
 268         package_prefix=${ac_default_prefix}
 269 else
 270         package_prefix=${prefix}
 271 fi
 272
 273 if test "$relativeprefix" = "guess" ; then
 274         if test "$mingw_found" = "yes" ; then
 275                 relativeprefix="yes"
 276         fi
 277 fi
 278
 279 if test "$relativeprefix" = "yes" ; then
 280         dnl allow binaries to install everywhere
 281         package_prefix="."
 282 fi
 283
 284 dnl Set PACKAGE_LOCALE_DIR in config.h.
 285 DATADIRNAME=share
 286 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 287
 288 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 289
 290 dnl Set PACKAGE_SOUND_DIR in config.h.
 291 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 292
 293
 294 dnl check if we have the getifaddrs() sytem call
 295 AC_CHECK_FUNCS(getifaddrs)
 296
 297 dnl check for osip2
 298 LP_CHECK_OSIP2
 299
 300 dnl conditionnal build for ssl
 301 AC_ARG_ENABLE(ssl,
 302                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 303                 [case "${enableval}" in
 304                 yes) build_ssl=true ;;
 305                 no)  build_ssl=false ;;
 306                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 307                 esac],[build_ssl=false])
 308
 309 if test "$build_ssl" = "true"; then
 310         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 311 fi
 312 dnl setup flags for exosip library
 313 LP_SETUP_EXOSIP
 314
 315 if test "$console_ui" = "true" ; then
 316 dnl check gnu readline
 317 LP_CHECK_READLINE
 318 else
 319 echo "Console interface compilation is disabled."
 320 fi
 321
 322 AC_WORDS_BIGENDIAN
 323
 324 dnl normaly this should only by done by mediastreamer2/configure.ac
 325 dnl but to workaround bugs when cross-compiling for arm-linux,
 326 dnl we need to have SPEEX_LIBS defined
 327 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 328 dnl since top-level configure --help will not print them.
 329
 330 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 331
 332 dnl conditionnal build of video support
 333 AC_ARG_ENABLE(video,
 334                 [  --enable-video    Turn on video support compiling],
 335                 [case "${enableval}" in
 336                 yes) video=true ;;
 337                 no)  video=false ;;
 338                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 339                 esac],[video=true])
 340
 341 AC_ARG_WITH( ffmpeg,
 342                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 343                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 344
 345 if test "$video" = "true"; then
 346
 347         if test "$enable_x11" = "true"; then
 348                 AC_CHECK_HEADERS(X11/Xlib.h)
 349                 if test "$build_macos" = "yes"; then
 350                         X11_LIBS="-L/usr/X11/lib -lX11"
 351                 else
 352                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 353                 fi
 354                 AC_SUBST(X11_LIBS)
 355         fi
 356         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 357 fi
 358
 359 AC_ARG_ENABLE(alsa,
 360       [  --enable-alsa    Turn on alsa native support compiling],
 361       [case "${enableval}" in
 362         yes) alsa=true ;;
 363         no)  alsa=false ;;
 364         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 365       esac],[alsa=true])
 366
 367 AC_ARG_ENABLE(artsc,
 368       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 369       [case "${enableval}" in
 370         yes) artsc=true ;;
 371         no)  artsc=false ;;
 372         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 373       esac],[artsc=false])
 374
 375 AC_ARG_ENABLE(portaudio,
 376       [  --enable-portaudio    Turn on portaudio native support compiling],
 377       [case "${enableval}" in
 378         yes) portaudio=true ;;
 379         no)  portaudio=false ;;
 380         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 381       esac],[portaudio=false])
 382
 383 dnl build console if required
 384 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 385 dnl special things for arm-linux cross compilation toolchain
 386 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 387 dnl compilation of gtk user interface
 388 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 389 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 390
 391 dnl check getenv
 392 AH_TEMPLATE([HAVE_GETENV])
 393 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 394
 395 dnl
 396 AC_MSG_CHECKING([for sighandler_t])
 397 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 398 has_sighandler_t=yes,has_sighandler_t=no)
 399 AC_MSG_RESULT($has_sighandler_t)
 400 if test "$has_sighandler_t" = "yes" ; then
 401     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 402 fi
 403
 404 ##################################################
 405 # Stricter build options (after external packages)
 406 ##################################################
 407
 408
 409 AC_ARG_ENABLE(strict,
 410         AC_HELP_STRING([--enable-strict],
 411                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 412         strictness="${enableval}"],[strictness=yes]
 413 )
 414
 415 STRICT_OPTIONS="-Wall "
 416
 417 if test "$GCC$strictness" = "yesyes" ; then
 418         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 419         CFLAGS="$CFLAGS -fno-strict-aliasing"
 420 fi
 421
 422 AC_SUBST(STRICT_OPTIONS)
 423
 424 top_srcdir=`dirname $0`
 425
 426 AC_ARG_ENABLE([external-mediastreamer],
 427       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 428       [enable_external_mediastreamer=no])
 429
 430 AS_CASE($enable_external_mediastreamer,
 431                 [yes],[
 432                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 433                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 434                         ],
 435                 [no],[
 436                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 437                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 438                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 439                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 440 dnl need to temporary change quotes to allow square brackets
 441                         changequote(<<, >>)
 442                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 443                         changequote([, ])
 444                         MS2_DIR=mediastreamer2
 445                         ],
 446         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 447
 448 AC_SUBST(MEDIASTREAMER_CFLAGS)
 449 AC_SUBST(MEDIASTREAMER_LIBS)
 450 AC_SUBST([MS2_VERSION])
 451 AC_SUBST([MS2_DIR])
 452
 453 dnl check for db2html (docbook) to generate html user manual
 454 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 455 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 456
 457 dnl for external use of linphone libs
 458 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 459 LINPHONE_LIBS="-L${libdir} -llinphone"
 460
 461 if test x$mingw_found = xyes ; then
 462         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 463 fi
 464 AC_SUBST(LINPHONE_CFLAGS)
 465 AC_SUBST(LINPHONE_LIBS)
 466
 467 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 468
 469 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 470 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 471 AC_SUBST(LINPHONE_PLUGINS_DIR)
 472
 473 AC_ARG_ENABLE(external-ortp,
 474       [  --enable-external-ortp    Use external oRTP library],
 475       [case "${enableval}" in
 476         yes) external_ortp=true ;;
 477         no)  external_ortp=false ;;
 478         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 479       esac],[external_ortp=false])
 480
 481 if test "$external_ortp" = 'true'; then
 482         PKG_CHECK_MODULES([ORTP], [ortp])
 483         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 484 else
 485         AC_CONFIG_SUBDIRS( oRTP )
 486         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 487         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 488         if test x$ac_cv_c_bigendian = xyes ; then
 489                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 490         fi
 491         ORTP_DIR=oRTP
 492         changequote(<<, >>)
 493         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 494         changequote([, ])
 495 fi
 496 AC_SUBST(ORTP_CFLAGS)
 497 AC_SUBST(ORTP_LIBS)
 498 AC_SUBST([ORTP_VERSION])
 499 AC_SUBST([ORTP_DIR])
 500
 501 AC_ARG_ENABLE(tests_enabled,
 502       [  --disable-tests    Disable compilation of tests],
 503       [case "${enableval}" in
 504         yes) tests_enabled=true ;;
 505         no)  tests_enabled=false ;;
 506         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 507       esac],[tests_enabled=false])
 508 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 509
 510 dnl ##################################################
 511 dnl # Check for doxygen
 512 dnl ##################################################
 513
 514 AC_PATH_PROG(DOXYGEN,doxygen,false)
 515 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 516
 517
 518 AC_CONFIG_FILES([
 519 Makefile
 520 build/Makefile
 521 build/macos/Makefile
 522 build/macos/Info-linphone.plist
 523 m4/Makefile
 524 po/Makefile.in
 525 pixmaps/Makefile
 526 coreapi/Makefile
 527 coreapi/help/Makefile
 528 coreapi/help/Doxyfile
 529 gtk/Makefile
 530 console/Makefile
 531 share/Makefile
 532 share/C/Makefile
 533 share/fr/Makefile
 534 share/it/Makefile
 535 share/ja/Makefile
 536 share/cs/Makefile
 537 share/linphone.pc
 538 share/linphone.desktop
 539 scripts/Makefile
 540 linphone.spec
 541 linphone.iss
 542 ])
 543
 544 AC_OUTPUT
 545
 546 echo "Linphone build configuration ended."
 547
 548 if test x$gtk_ui = xtrue ; then
 549         echo "* GTK interface will be compiled."
 550 fi
 551 if test x$console_ui = xtrue ; then
 552         echo "* Console interface will be compiled."
 553 fi
 554
 555 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 556