sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.5.1],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_C_INLINE
  42 AM_PROG_CC_STDC
  43 AC_HEADER_STDC
  44 AM_PROG_CC_C_O
  45 AC_CHECK_PROGS(MD5SUM,[md5sum md5])
  46 AM_CONDITIONAL(HAVE_MD5SUM,test -n $MD5SUM)
  47
  48 case $target in
  49         *mingw32ce)
  50         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  51         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  52         LIBS="$LIBS -lws2 -liphlpapi"
  53                 mingw_found=yes
  54                 mingwce_found=yes
  55                 ;;
  56         *mingw*)
  57                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  58                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  59                 LIBS="$LIBS -lws2_32"
  60                 GUI_FLAGS="-mwindows"
  61                 CONSOLE_FLAGS="-mconsole"
  62                 mingw_found=yes
  63         ;;
  64        armv6-apple-darwin|armv7-apple-darwin|i386-apple-darwin)
  65                 CFLAGS="$CFLAGS -DTARGET_OS_IPHONE "
  66                 build_tests=no
  67                 ios_found=yes
  68         ;;
  69         x86_64-apple-darwin*|i686-apple-darwin*)
  70                 MSPLUGINS_CFLAGS=""
  71                 dnl use macport installation
  72                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  73                 build_macos=yes
  74         ;;
  75
  76 esac
  77
  78 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  79 AC_SUBST(CONSOLE_FLAGS)
  80 AC_SUBST(GUI_FLAGS)
  81
  82 dnl localization tools
  83 IT_PROG_INTLTOOL([0.40], [no-xml])
  84
  85 AM_CONDITIONAL(BUILD_TESTS,test x$build_tests != xno)
  86 dnl Initialize libtool
  87 LT_INIT([win32-dll shared disable-static])
  88
  89 AC_CONFIG_COMMANDS([libtool-hacking],[
  90 if test "$mingw_found" = "yes" ; then
  91         echo "Hacking libtool to work with mingw..."
  92         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  93         cp -f ./libtool.tmp ./libtool
  94         rm -f ./libtool.tmp
  95 fi
  96 ],[mingw_found=$mingw_found])
  97
  98 dnl Add the languages which your application supports here.
  99 PKG_PROG_PKG_CONFIG
 100 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN nb_NO zh_TW"
 101 AC_SUBST(ALL_LINGUAS)
 102 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
 103
 104 if test "$mingw_found" != "yes" ; then
 105 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
 106 AM_GNU_GETTEXT([external])
 107 LIBS="$LIBS $LIBINTL"
 108 else
 109         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 110         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 111         LIBS="$LIBS -lintl"
 112 fi
 113
 114 GETTEXT_PACKAGE=linphone
 115 AC_SUBST(GETTEXT_PACKAGE)
 116 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 117 dnl AC_CHECK_LIB(intl,libintl_gettext)
 118
 119 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 120
 121 AC_ARG_ENABLE(x11,
 122                           [  --disable-x11    Disable X11 support],
 123                           [case "${enableval}" in
 124                           yes) enable_x11=true ;;
 125                           no)  enable_x11=false ;;
 126                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 127                           esac],[enable_x11=true])
 128
 129 dnl conditionnal build of console interface.
 130 AC_ARG_ENABLE(console_ui,
 131       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 132       [case "${enableval}" in
 133         yes) console_ui=true ;;
 134         no)  console_ui=false ;;
 135         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 136       esac],[console_ui=true])
 137
 138 dnl conditionnal build of gtk interface.
 139 AC_ARG_ENABLE(gtk_ui,
 140       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 141       [case "${enableval}" in
 142         yes) gtk_ui=true ;;
 143         no)  gtk_ui=false ;;
 144         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 145       esac],[gtk_ui=true])
 146
 147 if test "$gtk_ui" = "true" ; then
 148         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.18.0 gthread-2.0)
 149         if test "$enable_x11" = "false" ; then
 150                 PKG_CHECK_MODULES(LIBGTKMAC,[ige-mac-integration >= 0.9.7 ])
 151                 AC_DEFINE([HAVE_GTK_OSX],[1],[Defined when gtk osx is used])
 152         fi
 153 else
 154         echo "GTK interface compilation is disabled."
 155 fi
 156
 157 AC_ARG_ENABLE(notify,
 158                 [  --enable-notify=[yes/no]    Enable libnotify support [default=yes]],
 159                 [case "${enableval}" in
 160                   yes) notify=true ;;
 161                   no)  notify=false ;;
 162                   *) AC_MSG_ERROR(bad value ${enableval} for --enable-notify) ;;
 163                 esac],[notify=true])
 164
 165 dnl conditionnal build of the notify library
 166 if test "$gtk_ui" = "true" ; then
 167         if test "$notify" = "true"; then
 168                 PKG_CHECK_MODULES([NOTIFY4], [libnotify >= 0.7.0 ], [found_notify4=yes], foo=bar)
 169                 case "$found_notify4" in
 170                   yes)
 171                                 AC_SUBST(NOTIFY4_CFLAGS)
 172                                 AC_SUBST(NOTIFY4_LIBS)
 173                                 AC_DEFINE([HAVE_NOTIFY4],[1],[NOTIFY4 support])
 174                 esac
 175
 176                 PKG_CHECK_MODULES([NOTIFY1], [libnotify < 0.7.0], [found_notify1=yes], foo=bar)
 177                 case "$found_notify1" in
 178                   yes)
 179                                 AC_SUBST(NOTIFY1_CFLAGS)
 180                                 AC_SUBST(NOTIFY1_LIBS)
 181                                 AC_DEFINE([HAVE_NOTIFY1],[1],[NOTIFY1 support])
 182                 esac
 183         else
 184                                 NotifyNotification *n;
 185                 echo "Libnotify support is disabled."
 186         fi
 187 fi
 188
 189 dnl os-specific problems not handled by existing macros.
 190 case "$host_os" in
 191         *freebsd*)
 192                 LDFLAGS="$LDFLAGS -pthread"
 193                 ;;
 194 esac
 195
 196 case "$host_cpu" in
 197         *arm*)
 198                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 199                 use_arm_toolchain=yes
 200                 ;;
 201 esac
 202
 203 AC_ARG_WITH( configdir,
 204       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 205       [ configdir=${withval}],[ configdir="Linphone" ])
 206
 207 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 208
 209 AC_ARG_ENABLE(relativeprefix,
 210       [  --enable-relativeprefix    Build a linphone that finds its resources relatively to the directory where it is installed],
 211       [case "${enableval}" in
 212         yes) relativeprefix=yes ;;
 213         no)  relativeprefix=no ;;
 214         *) AC_MSG_ERROR(bad value ${enableval} for --enable-relativeprefix) ;;
 215       esac],[relativeprefix=guess])
 216
 217 AC_ARG_ENABLE(date,
 218       [  --enable-date    Use build date in internal version number],
 219       [case "${enableval}" in
 220         yes) use_date=yes ;;
 221         no)  use_date=no ;;
 222         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 223       esac],[use_date=no])
 224
 225 if test x$use_date =  xyes ; then
 226         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 227 fi
 228
 229
 230 dnl enable ipv6 support
 231 AC_ARG_ENABLE(ipv6,
 232       [  --enable-ipv6    Turn on ipv6 support],
 233       [case "${enableval}" in
 234         yes)  ipv6=true;;
 235         no)   ipv6=false;;
 236         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 237       esac],[ipv6=true])
 238 IPV6_CFLAGS=
 239 if test x$ipv6 = xtrue ; then
 240         IPV6_CFLAGS=-DINET6
 241 fi
 242 AC_SUBST(IPV6_CFLAGS)
 243
 244 dnl enable truespeech codec support
 245 AC_ARG_ENABLE(truespeech,
 246       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 247       [case "${enableval}" in
 248         yes)  truespeech=true;;
 249         no)   truespeech=false;;
 250         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 251       esac],[truespeech=false])
 252 TRUESPEECH_CFLAGS=
 253 if test x$truespeech = xtrue ; then
 254         TRUESPEECH_CFLAGS=-DTRUESPEECH
 255 fi
 256 AC_SUBST(TRUESPEECH_CFLAGS)
 257 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 258
 259 AC_ARG_ENABLE(nonstandard-gsm,
 260       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 261       [case "${enableval}" in
 262         yes) exotic_gsm=yes
 263         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 264          ;;
 265         no)  exotic_gsm=no ;;
 266         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 267       esac],[exotic_gsm=no])
 268
 269
 270 dnl support for RSVP (by Vincent Maury)
 271 AC_ARG_ENABLE(rsvp,
 272 [  --enable-rsvp           enable support for QoS reservations.],
 273 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 274 should be compiled.]) )
 275
 276 if test "x${prefix}" = "xNONE"; then
 277         package_prefix=${ac_default_prefix}
 278 else
 279         package_prefix=${prefix}
 280 fi
 281
 282 if test "$relativeprefix" = "guess" ; then
 283         if test "$mingw_found" = "yes" ; then
 284                 relativeprefix="yes"
 285         fi
 286 fi
 287
 288 if test "$relativeprefix" = "yes" ; then
 289         dnl allow binaries to install everywhere
 290         package_prefix="."
 291 fi
 292
 293 dnl Set PACKAGE_LOCALE_DIR in config.h.
 294 DATADIRNAME=share
 295 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 296
 297 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 298
 299 dnl Set PACKAGE_SOUND_DIR in config.h.
 300 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 301
 302
 303 dnl check if we have the getifaddrs() sytem call
 304 AC_CHECK_FUNCS(getifaddrs)
 305
 306 dnl check for osip2
 307 LP_CHECK_OSIP2
 308
 309 dnl conditionnal build for ssl
 310 AC_ARG_ENABLE(ssl,
 311                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 312                 [case "${enableval}" in
 313                 yes) build_ssl=true ;;
 314                 no)  build_ssl=false ;;
 315                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 316                 esac],[build_ssl=false])
 317
 318 if test "$build_ssl" = "true"; then
 319         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 320 fi
 321 dnl setup flags for exosip library
 322 LP_SETUP_EXOSIP
 323
 324 if test "$console_ui" = "true" ; then
 325 dnl check gnu readline
 326 LP_CHECK_READLINE
 327 else
 328 echo "Console interface compilation is disabled."
 329 fi
 330
 331 AC_WORDS_BIGENDIAN
 332
 333 AC_ARG_ENABLE([speex],
 334               AS_HELP_STRING([--disable-speex], [Disable speex support]),
 335               [], [enable_speex=yes])
 336 if test "x$enable_speex" = "xyes"; then
 337         dnl normaly this should only by done by mediastreamer2/configure.ac
 338         dnl but to workaround bugs when cross-compiling for arm-linux,
 339         dnl we need to have SPEEX_LIBS defined
 340         dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 341         dnl since top-level configure --help will not print them.
 342         PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 343 fi
 344
 345 dnl conditionnal build of video support
 346 AC_ARG_ENABLE(video,
 347                 [  --enable-video    Turn on video support compiling],
 348                 [case "${enableval}" in
 349                 yes) video=true ;;
 350                 no)  video=false ;;
 351                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 352                 esac],[video=true])
 353
 354 AC_ARG_WITH( ffmpeg,
 355                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 356                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 357
 358 if test "$video" = "true"; then
 359
 360         if test "$enable_x11" = "true"; then
 361                 AC_CHECK_HEADERS(X11/Xlib.h)
 362                 if test "$build_macos" = "yes"; then
 363                         X11_LIBS="-L/usr/X11/lib -lX11"
 364                 else
 365                         AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 366                 fi
 367                 AC_SUBST(X11_LIBS)
 368         fi
 369         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 370 fi
 371
 372 AC_ARG_ENABLE(alsa,
 373       [  --enable-alsa    Turn on alsa native support compiling],
 374       [case "${enableval}" in
 375         yes) alsa=true ;;
 376         no)  alsa=false ;;
 377         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 378       esac],[alsa=true])
 379
 380 AC_ARG_ENABLE(zrtp,
 381       [  --enable-zrtp    Turn on zrtp support ],
 382       [case "${enableval}" in
 383         yes) zrtp=true ;;
 384         no)  zrtp=false ;;
 385         *) AC_MSG_ERROR(bad value ${enableval} for --enable-zrtp) ;;
 386       esac],[zrtp=false])
 387
 388
 389 AC_ARG_ENABLE(portaudio,
 390       [  --enable-portaudio    Turn on portaudio native support compiling],
 391       [case "${enableval}" in
 392         yes) portaudio=true ;;
 393         no)  portaudio=false ;;
 394         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 395       esac],[portaudio=false])
 396
 397 dnl build console if required
 398 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 399 dnl special things for arm-linux cross compilation toolchain
 400 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 401 dnl compilation of gtk user interface
 402 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 403 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 404 AM_CONDITIONAL(BUILD_ZRTP, test x$zrtp = xtrue)
 405
 406 dnl check getenv
 407 AH_TEMPLATE([HAVE_GETENV])
 408 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 409
 410 dnl
 411 AC_MSG_CHECKING([for sighandler_t])
 412 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 413 has_sighandler_t=yes,has_sighandler_t=no)
 414 AC_MSG_RESULT($has_sighandler_t)
 415 if test "$has_sighandler_t" = "yes" ; then
 416     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 417 fi
 418
 419 dnl check libsoup (needed for wizard)
 420 PKG_CHECK_MODULES(LIBSOUP, [libsoup-2.4 >= 2.26],[build_wizard=true],foo=bar)
 421 AC_SUBST(LIBSOUP_CFLAGS)
 422 AC_SUBST(LIBSOUP_LIBS)
 423 AM_CONDITIONAL(BUILD_WIZARD, test x$build_wizard = xtrue)
 424 if test "$build_wizard" = "true" ; then
 425    AC_DEFINE( BUILD_WIZARD, 1, [Define if wizard enabled] )
 426 fi
 427
 428 ##################################################
 429 # Stricter build options (after external packages)
 430 ##################################################
 431
 432
 433 AC_ARG_ENABLE(strict,
 434         AC_HELP_STRING([--enable-strict],
 435                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 436         strictness="${enableval}"],[strictness=yes]
 437 )
 438
 439 STRICT_OPTIONS="-Wall "
 440
 441 if test "$GCC$strictness" = "yesyes" ; then
 442         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 443         CFLAGS="$CFLAGS -fno-strict-aliasing"
 444 fi
 445
 446 AC_SUBST(STRICT_OPTIONS)
 447
 448 top_srcdir=`dirname $0`
 449
 450 AC_ARG_ENABLE([external-mediastreamer],
 451       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 452       [enable_external_mediastreamer=no])
 453
 454 AS_CASE($enable_external_mediastreamer,
 455                 [yes],[
 456                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 457                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 458                         ],
 459                 [no],[
 460                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 461                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 462                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 463                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 464 dnl need to temporary change quotes to allow square brackets
 465                         changequote(<<, >>)
 466                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 467                         changequote([, ])
 468                         MS2_DIR=mediastreamer2
 469                         ],
 470         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 471
 472 AC_SUBST(MEDIASTREAMER_CFLAGS)
 473 AC_SUBST(MEDIASTREAMER_LIBS)
 474 AC_SUBST([MS2_VERSION])
 475 AC_SUBST([MS2_DIR])
 476
 477
 478
 479 AC_ARG_ENABLE(tunnel,
 480       [  --enable-tunnel=[yes/no]    Turn on compilation of tunnel support [default=no]],
 481       [case "${enableval}" in
 482         yes) enable_tunnel=true ;;
 483         no)  enable_tunnel=false ;;
 484         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tunnel) ;;
 485       esac],[enable_tunnel=false])
 486 AM_CONDITIONAL(BUILD_TUNNEL, test x$enable_tunnel = xtrue)
 487 if test x$enable_tunnel = xtrue; then
 488      PKG_CHECK_MODULES(TUNNEL, tunnel >= 0.3.3)
 489      TUNNEL_CFLAGS+="-DTUNNEL_ENABLED"
 490      AC_SUBST(TUNNEL_CFLAGS)
 491      AC_SUBST(TUNNEL_LIBS)
 492 fi
 493
 494
 495
 496
 497
 498
 499
 500
 501
 502
 503 dnl check for db2html (docbook) to generate html user manual
 504 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 505 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 506
 507 dnl for external use of linphone libs
 508 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 509 LINPHONE_LIBS="-L${libdir} -llinphone"
 510
 511 if test x$mingw_found = xyes ; then
 512         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 513 fi
 514 AC_SUBST(LINPHONE_CFLAGS)
 515 AC_SUBST(LINPHONE_LIBS)
 516
 517 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 518
 519 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 520 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 521 AC_SUBST(LINPHONE_PLUGINS_DIR)
 522
 523 AC_ARG_ENABLE(external-ortp,
 524       [  --enable-external-ortp    Use external oRTP library],
 525       [case "${enableval}" in
 526         yes) external_ortp=true ;;
 527         no)  external_ortp=false ;;
 528         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 529       esac],[external_ortp=false])
 530
 531 if test "$external_ortp" = 'true'; then
 532         PKG_CHECK_MODULES([ORTP], [ortp])
 533         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 534 else
 535         AC_CONFIG_SUBDIRS( oRTP )
 536         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 537         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 538         if test x$ac_cv_c_bigendian = xyes ; then
 539                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 540         fi
 541         ORTP_DIR=oRTP
 542         changequote(<<, >>)
 543         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 544         changequote([, ])
 545 fi
 546 AC_SUBST(ORTP_CFLAGS)
 547 AC_SUBST(ORTP_LIBS)
 548 AC_SUBST([ORTP_VERSION])
 549 AC_SUBST([ORTP_DIR])
 550
 551 AC_ARG_ENABLE(tests_enabled,
 552       [  --disable-tests    Disable compilation of tests],
 553       [case "${enableval}" in
 554         yes) tests_enabled=true ;;
 555         no)  tests_enabled=false ;;
 556         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
 557       esac],[tests_enabled=false])
 558 AM_CONDITIONAL(ENABLE_TESTS, test x$tests_enabled = xyes)
 559
 560
 561
 562 dnl ##################################################
 563 dnl # Check for doxygen
 564 dnl ##################################################
 565
 566 AC_PATH_PROG(DOXYGEN,doxygen,false)
 567 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 568
 569
 570 AC_CONFIG_FILES([
 571 Makefile
 572 build/Makefile
 573 build/macos/Makefile
 574 build/macos/Info-linphone.plist
 575 m4/Makefile
 576 po/Makefile.in
 577 pixmaps/Makefile
 578 coreapi/Makefile
 579 coreapi/help/Makefile
 580 coreapi/help/Doxyfile
 581 gtk/Makefile
 582 console/Makefile
 583 share/Makefile
 584 share/C/Makefile
 585 share/fr/Makefile
 586 share/it/Makefile
 587 share/ja/Makefile
 588 share/cs/Makefile
 589 share/linphone.pc
 590 share/linphone.desktop
 591 scripts/Makefile
 592 linphone.spec
 593 linphone.iss
 594 ])
 595
 596 AC_OUTPUT
 597
 598 echo "Linphone build configuration ended."
 599
 600 if test x$gtk_ui = xtrue ; then
 601         echo "* GTK interface will be compiled."
 602 fi
 603 if test x$console_ui = xtrue ; then
 604         echo "* Console interface will be compiled."
 605 fi
 606
 607 echo "Now type 'make' to compile, and then 'make install' as root to install it."
 608