sjero.net Git - linphone/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([linphone],[3.4.2],[linphone-developers@nongnu.org])
   4 AC_CANONICAL_SYSTEM
   5 AC_CONFIG_SRCDIR([coreapi/linphonecore.c])
   6
   7 dnl Source packaging numbers
   8
   9 LINPHONE_MAJOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f1)
  10 LINPHONE_MINOR_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f2)
  11 LINPHONE_MICRO_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f3)
  12 LINPHONE_EXTRA_VERSION=$(echo $PACKAGE_VERSION | cut -d. -f4)
  13
  14 dnl program extension
  15 LINPHONE_VERSION=$LINPHONE_MAJOR_VERSION.$LINPHONE_MINOR_VERSION.${LINPHONE_MICRO_VERSION}
  16 if test "$LINPHONE_EXTRA_VERSION" != "" ;then
  17         LINPHONE_VERSION=$LINPHONE_VERSION.${LINPHONE_EXTRA_VERSION}
  18 fi
  19
  20 LIBLINPHONE_SO_CURRENT=4 dnl increment this number when you add/change/remove an interface
  21 LIBLINPHONE_SO_REVISION=0 dnl increment this number when you change source code, without changing interfaces; set to 0 when incrementing CURRENT
  22 LIBLINPHONE_SO_AGE=0 dnl increment this number when you add an interface, set to 0 if you remove an interface
  23
  24 LIBLINPHONE_SO_VERSION=$LIBLINPHONE_SO_CURRENT:$LIBLINPHONE_SO_REVISION:$LIBLINPHONE_SO_AGE
  25
  26 AC_SUBST(LIBLINPHONE_SO_VERSION, $LIBLINPHONE_SO_VERSION)
  27 AC_SUBST(LINPHONE_VERSION)
  28
  29 AC_MSG_NOTICE([$PACKAGE_NAME-$PACKAGE_VERSION           A full featured audio/video sip phone.])
  30 AC_MSG_NOTICE([licensed under the terms of the General Public License (GPL)])
  31
  32 AM_INIT_AUTOMAKE
  33 AC_SUBST([LIBTOOL_DEPS])
  34 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],)
  35 AC_CONFIG_HEADER(config.h)
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_SUBST([mkdir_p])
  38 AC_ISC_POSIX
  39 AC_PROG_CC
  40 AC_C_INLINE
  41 AM_PROG_CC_STDC
  42 AC_HEADER_STDC
  43 AM_PROG_CC_C_O
  44
  45 case $target_os in
  46         *mingw32ce)
  47         CFLAGS="$CFLAGS -D_WIN32_WCE -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  48         CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  49         LIBS="$LIBS -lws2 -liphlpapi"
  50                 mingw_found=yes
  51                 mingwce_found=yes
  52                 ;;
  53         *mingw*)
  54                 CFLAGS="$CFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501 "
  55                 CXXFLAGS="$CXXFLAGS -DORTP_STATIC -D_WIN32_WINNT=0x0501"
  56                 LIBS="$LIBS -lws2_32"
  57                 GUI_FLAGS="-mwindows"
  58                 CONSOLE_FLAGS="-mconsole"
  59                 mingw_found=yes
  60         ;;
  61         *darwin*)
  62                 dnl use macport installation
  63                 ACLOCAL_MACOS_FLAGS="-I /opt/local/share/aclocal"
  64         ;;
  65 esac
  66
  67 AC_SUBST(ACLOCAL_MACOS_FLAGS)
  68 AC_SUBST(CONSOLE_FLAGS)
  69 AC_SUBST(GUI_FLAGS)
  70
  71 dnl localization tools
  72 IT_PROG_INTLTOOL([0.40], [no-xml])
  73
  74 dnl Initialize libtool
  75 AC_LIBTOOL_WIN32_DLL
  76 AC_PROG_LIBTOOL
  77 AM_PROG_LIBTOOL
  78 AC_ENABLE_SHARED(yes)
  79 AC_ENABLE_STATIC(no)
  80
  81
  82 AC_CONFIG_COMMANDS([libtool-hacking],[
  83 if test "$mingw_found" = "yes" ; then
  84         echo "Hacking libtool to work with mingw..."
  85         sed -e 's/\*\" \$a_deplib \"\*/\*/' < ./libtool > libtool.tmp
  86         cp -f ./libtool.tmp ./libtool
  87         rm -f ./libtool.tmp
  88 fi
  89 ],[mingw_found=$mingw_found])
  90
  91 dnl Add the languages which your application supports here.
  92 PKG_PROG_PKG_CONFIG
  93 ALL_LINGUAS="fr it de ja es pl cs nl sv pt_BR hu ru zh_CN"
  94 AC_SUBST(ALL_LINGUAS)
  95 AC_DEFINE_UNQUOTED(LINPHONE_ALL_LANGS, "$ALL_LINGUAS", [All supported languages])
  96
  97 if test "$mingw_found" != "yes" ; then
  98 dnl gettext macro does not work properly under mingw. And we want to use the one provided by GTK.
  99 AM_GNU_GETTEXT([external])
 100 LIBS="$LIBS $LIBINTL"
 101 else
 102         AC_DEFINE(ENABLE_NLS,1,[Tells whether localisation is possible])
 103         AC_DEFINE(HAVE_GETTEXT,1,[Tells wheter localisation is possible])
 104         LIBS="$LIBS -lintl"
 105 fi
 106
 107 GETTEXT_PACKAGE=linphone
 108 AC_SUBST(GETTEXT_PACKAGE)
 109 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[The name of the gettext package name])
 110 dnl AC_CHECK_LIB(intl,libintl_gettext)
 111
 112 AC_CHECK_FUNCS([get_current_dir_name strndup stpcpy] )
 113
 114 dnl conditionnal build of console interface.
 115 AC_ARG_ENABLE(console_ui,
 116       [  --enable-console_ui=[yes/no]    Turn on or off compilation of console interface [default=yes]],
 117       [case "${enableval}" in
 118         yes) console_ui=true ;;
 119         no)  console_ui=false ;;
 120         *) AC_MSG_ERROR(bad value ${enableval} for --enable-console_ui) ;;
 121       esac],[console_ui=true])
 122
 123 dnl conditionnal build of gtk interface.
 124 AC_ARG_ENABLE(gtk_ui,
 125       [  --enable-gtk_ui=[yes/no]    Turn on or off compilation of gtk interface [default=yes]],
 126       [case "${enableval}" in
 127         yes) gtk_ui=true ;;
 128         no)  gtk_ui=false ;;
 129         *) AC_MSG_ERROR(bad value ${enableval} for --enable-gtk_ui) ;;
 130       esac],[gtk_ui=true])
 131
 132
 133 if test "$gtk_ui" = "true" ; then
 134         PKG_CHECK_MODULES(LIBGTK, gtk+-2.0 >= 2.4.0 gthread-2.0)
 135         AC_SUBST(LIBGTK_CFLAGS)
 136         AC_SUBST(LIBGTK_LIBS)
 137 else
 138         echo "GTK interface compilation is disabled."
 139 fi
 140
 141
 142 dnl os-specific problems not handled by existing macros.
 143 case "$host_os" in
 144         *freebsd*)
 145                 LDFLAGS="$LDFLAGS -pthread"
 146                 ;;
 147 esac
 148
 149 case "$host_cpu" in
 150         *arm*)
 151                 AC_DEFINE(__ARM__,1,[Defined if we are compiling for arm processor])
 152                 use_arm_toolchain=yes
 153                 ;;
 154 esac
 155
 156 AC_ARG_WITH( configdir,
 157       [  --with-configdir      Set a APPDATA subdir where linphone is supposed to find its config (windows only) ],
 158       [ configdir=${withval}],[ configdir="Linphone" ])
 159
 160 AC_DEFINE_UNQUOTED(LINPHONE_CONFIG_DIR,"$configdir",[Windows appdata subdir where linphonerc can be found])
 161
 162 AC_ARG_ENABLE(manual,
 163       [  --disable-manual    Do not attempt to build html linphone's user documentation],
 164       [case "${enableval}" in
 165         yes) build_manual=yes ;;
 166         no)  build_manual=false ;;
 167         *) AC_MSG_ERROR(bad value ${enableval} for --enable-manual) ;;
 168       esac],[build_manual=yes])
 169
 170 AC_ARG_ENABLE(date,
 171       [  --enable-date    Use build date in internal version number],
 172       [case "${enableval}" in
 173         yes) use_date=yes ;;
 174         no)  use_date=no ;;
 175         *) AC_MSG_ERROR(bad value ${enableval} for --enable-date) ;;
 176       esac],[use_date=no])
 177
 178 if test x$use_date =  xyes ; then
 179         AC_DEFINE(USE_BUILDDATE_VERSION,1,[Tell whether date_version.h must be used])
 180 fi
 181
 182
 183 dnl enable ipv6 support
 184 AC_ARG_ENABLE(ipv6,
 185       [  --enable-ipv6    Turn on ipv6 support],
 186       [case "${enableval}" in
 187         yes)  ipv6=true;;
 188         no)   ipv6=false;;
 189         *) AC_MSG_ERROR(bad value ${enableval} for --enable-ipv6) ;;
 190       esac],[ipv6=true])
 191 IPV6_CFLAGS=
 192 if test x$ipv6 = xtrue ; then
 193         IPV6_CFLAGS=-DINET6
 194 fi
 195 AC_SUBST(IPV6_CFLAGS)
 196
 197 dnl enable truespeech codec support
 198 AC_ARG_ENABLE(truespeech,
 199       [  --enable-truespeech    Turn on TrueSpeech support (x86 only)],
 200       [case "${enableval}" in
 201         yes)  truespeech=true;;
 202         no)   truespeech=false;;
 203         *) AC_MSG_ERROR(bad value ${enableval} for --enable-truespeech) ;;
 204       esac],[truespeech=false])
 205 TRUESPEECH_CFLAGS=
 206 if test x$truespeech = xtrue ; then
 207         TRUESPEECH_CFLAGS=-DTRUESPEECH
 208 fi
 209 AC_SUBST(TRUESPEECH_CFLAGS)
 210 AM_CONDITIONAL([BUILD_TRUESPEECH], [test x$truespeech = xtrue])
 211
 212 AC_ARG_ENABLE(nonstandard-gsm,
 213       [  --enable-nonstandard-gsm    Enable GSM codec at nonstandard rates (11025hz, 16000hz)],
 214       [case "${enableval}" in
 215         yes) exotic_gsm=yes
 216         AC_DEFINE(ENABLE_NONSTANDARD_GSM,1,[Defined when using gsm at nonstandard rates])
 217          ;;
 218         no)  exotic_gsm=no ;;
 219         *) AC_MSG_ERROR(bad value ${enableval} for --enable-nonstandard-gsm) ;;
 220       esac],[exotic_gsm=no])
 221
 222
 223 dnl support for RSVP (by Vincent Maury)
 224 AC_ARG_ENABLE(rsvp,
 225 [  --enable-rsvp           enable support for QoS reservations.],
 226 AC_DEFINE(VINCENT_MAURY_RSVP,1,[Tell whether RSVP support
 227 should be compiled.]) )
 228
 229 if test "x${prefix}" = "xNONE"; then
 230         package_prefix=${ac_default_prefix}
 231 else
 232         package_prefix=${prefix}
 233 fi
 234
 235 if test x$mingw_found = xyes ; then
 236 dnl allow binaries to install everywhere
 237 package_prefix="."
 238 fi
 239
 240 dnl Set PACKAGE_LOCALE_DIR in config.h.
 241 DATADIRNAME=share
 242 AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${package_prefix}/${DATADIRNAME}/locale",[Defines the place where locales can be found])
 243
 244 AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${package_prefix}/${DATADIRNAME}",[Defines the place where data are found])
 245
 246 dnl Set PACKAGE_SOUND_DIR in config.h.
 247 AC_DEFINE_UNQUOTED(PACKAGE_SOUND_DIR, "${package_prefix}/${DATADIRNAME}/sounds/linphone",[Defines the place where linphone sounds are found])
 248
 249
 250 dnl check if we have the getifaddrs() sytem call
 251 AC_CHECK_FUNCS(getifaddrs)
 252
 253 dnl check for osip2
 254 LP_CHECK_OSIP2
 255
 256 dnl conditionnal build for ssl
 257 AC_ARG_ENABLE(ssl,
 258                 [  --enable-ssl    Turn on ssl support compiling. Required for sip tls. default = false],
 259                 [case "${enableval}" in
 260                 yes) build_ssl=true ;;
 261                 no)  build_ssl=false ;;
 262                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-ssl) ;;
 263                 esac],[build_ssl=false])
 264
 265 if test "$build_ssl" = "true"; then
 266         PKG_CHECK_MODULES(OPENSSL, libssl >= 0.9.8)
 267 fi
 268 dnl setup flags for exosip library
 269 LP_SETUP_EXOSIP
 270
 271 if test "$console_ui" = "true" ; then
 272 dnl check gnu readline
 273 LP_CHECK_READLINE
 274 else
 275 echo "Console interface compilation is disabled."
 276 fi
 277
 278 AC_WORDS_BIGENDIAN
 279
 280 dnl normaly this should only by done by mediastreamer2/configure.ac
 281 dnl but to workaround bugs when cross-compiling for arm-linux,
 282 dnl we need to have SPEEX_LIBS defined
 283 dnl Furthermore it is good to repeat here all mediastreamer2 toggles
 284 dnl since top-level configure --help will not print them.
 285
 286 PKG_CHECK_MODULES(SPEEX, speex >= 1.1.6, build_speex=yes)
 287
 288 dnl conditionnal build of video support
 289 AC_ARG_ENABLE(video,
 290                 [  --enable-video    Turn on video support compiling],
 291                 [case "${enableval}" in
 292                 yes) video=true ;;
 293                 no)  video=false ;;
 294                 *) AC_MSG_ERROR(bad value ${enableval} for --enable-video) ;;
 295                 esac],[video=true])
 296
 297 AC_ARG_WITH( ffmpeg,
 298                 [  --with-ffmpeg                Sets the installation prefix of ffmpeg, needed for video support. [default=/usr] ],
 299                 [ ffmpegdir=${withval}],[ ffmpegdir=/usr ])
 300
 301 AC_ARG_ENABLE(x11,
 302                           [  --disable-x11    Disable X11 support],
 303                           [case "${enableval}" in
 304                           yes) enable_x11=true ;;
 305                           no)  enable_x11=false ;;
 306                           *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 307                           esac],[enable_x11=true])
 308
 309 if test "$video" = "true"; then
 310
 311         if test "$enable_x11" = "true"; then
 312                 AC_CHECK_HEADERS(X11/Xlib.h)
 313                 AC_CHECK_LIB(X11,XUnmapWindow, X11_LIBS="-lX11")
 314                 AC_SUBST(X11_LIBS)
 315         fi
 316         AC_DEFINE(VIDEO_ENABLED,1,[defined if video support is available])
 317 fi
 318
 319 AC_ARG_ENABLE(alsa,
 320       [  --enable-alsa    Turn on alsa native support compiling],
 321       [case "${enableval}" in
 322         yes) alsa=true ;;
 323         no)  alsa=false ;;
 324         *) AC_MSG_ERROR(bad value ${enableval} for --enable-alsa) ;;
 325       esac],[alsa=true])
 326
 327 AC_ARG_ENABLE(artsc,
 328       [  --enable-artsc    Turn on artsc (kde) sound input/output (auto) ],
 329       [case "${enableval}" in
 330         yes) artsc=true ;;
 331         no)  artsc=false ;;
 332         *) AC_MSG_ERROR(bad value ${enableval} for --enable-artsc) ;;
 333       esac],[artsc=false])
 334
 335 AC_ARG_ENABLE(portaudio,
 336       [  --enable-portaudio    Turn on portaudio native support compiling],
 337       [case "${enableval}" in
 338         yes) portaudio=true ;;
 339         no)  portaudio=false ;;
 340         *) AC_MSG_ERROR(bad value ${enableval} for --enable-portaudio) ;;
 341       esac],[portaudio=false])
 342
 343 dnl build console if required
 344 AM_CONDITIONAL(BUILD_CONSOLE, test x$console_ui = xtrue)
 345 dnl special things for arm-linux cross compilation toolchain
 346 AM_CONDITIONAL(ARMBUILD, test x$use_arm_toolchain = xyes)
 347 dnl compilation of gtk user interface
 348 AM_CONDITIONAL(BUILD_GTK_UI, [test x$gtk_ui = xtrue ] )
 349 AM_CONDITIONAL(BUILD_WIN32, test x$mingw_found = xyes )
 350
 351 dnl check getenv
 352 AH_TEMPLATE([HAVE_GETENV])
 353 AC_CHECK_FUNC([getenv], AC_DEFINE([HAVE_GETENV], [1], [If present, the getenv function allows fim to read environment variables.]))
 354
 355 dnl
 356 AC_MSG_CHECKING([for sighandler_t])
 357 AC_TRY_COMPILE([#include <signal.h>],[sighandler_t *f;],
 358 has_sighandler_t=yes,has_sighandler_t=no)
 359 AC_MSG_RESULT($has_sighandler_t)
 360 if test "$has_sighandler_t" = "yes" ; then
 361     AC_DEFINE( HAVE_SIGHANDLER_T, 1, [Define if sighandler_t available] )
 362 fi
 363
 364 ##################################################
 365 # Stricter build options (after external packages)
 366 ##################################################
 367
 368
 369 AC_ARG_ENABLE(strict,
 370         AC_HELP_STRING([--enable-strict],
 371                        [Build with stricter options (gcc only) @<:@yes@:>@]),[
 372         strictness="${enableval}"],[strictness=yes]
 373 )
 374
 375 if test "$GCC$strictness" = "yesyes" ; then
 376         STRICT_OPTIONS="-Wall "
 377         STRICT_OPTIONS="$STRICT_OPTIONS -Werror"
 378         CFLAGS="$CFLAGS -fno-strict-aliasing"
 379 fi
 380
 381 AC_SUBST(STRICT_OPTIONS)
 382
 383 top_srcdir=`dirname $0`
 384
 385 AC_ARG_ENABLE([external-mediastreamer],
 386       [AS_HELP_STRING([--enable-external-mediastreamer],[Use external mediastreamer library])],,
 387       [enable_external_mediastreamer=no])
 388
 389 AS_CASE($enable_external_mediastreamer,
 390                 [yes],[
 391                         PKG_CHECK_MODULES([MEDIASTREAMER], [mediastreamer])
 392                         MS2_VERSION=`$PKG_CONFIG --modversion mediastreamer`
 393                         AM_CONDITIONAL(EXTERNAL_MEDIASTREAMER, [true])],
 394                 [no],[
 395                         AC_CONFIG_SUBDIRS( mediastreamer2 )
 396                         MEDIASTREAMER_DIR=${top_srcdir}/mediastreamer2
 397                         MEDIASTREAMER_CFLAGS="-I\$(top_srcdir)/mediastreamer2/include"
 398                         MEDIASTREAMER_LIBS="\$(top_builddir)/mediastreamer2/src/libmediastreamer.la"
 399 dnl need to temporary change quotes to allow square brackets
 400                         changequote(<<, >>)
 401                         MS2_VERSION=`grep -e '^.C_INIT(' $MEDIASTREAMER_DIR/configure.ac | sed -e 's:\([^(]\+\)(\[mediastreamer\],\[\(.*\)\]):\2:g'`
 402                         changequote([, ])
 403                         AM_CONDITIONAL(EXTERNAL_MEDIASTREAMER, [false])],
 404         [AC_MSG_ERROR([bad value '${enable_external_mediastreamer}' for --enable-external-mediastreamer])])
 405
 406 AC_SUBST(MEDIASTREAMER_CFLAGS)
 407 AC_SUBST(MEDIASTREAMER_LIBS)
 408 AC_SUBST([MS2_VERSION])
 409
 410 dnl check for db2html (docbook) to generate html user manual
 411 AC_CHECK_PROG(have_sgmltools,sgmltools, yes, no)
 412 AM_CONDITIONAL(ENABLE_MANUAL, test x$have_sgmltools$build_manual = xyesyes )
 413
 414 dnl for external use of linphone libs
 415 LINPHONE_CFLAGS="-I${includedir} -I${includedir}/linphone"
 416 LINPHONE_LIBS="-L${libdir} -llinphone"
 417
 418 if test x$mingw_found = xyes ; then
 419         LINPHONE_LIBS="$LINPHONE_LIBS $OSIP_LIBS"
 420 fi
 421 AC_SUBST(LINPHONE_CFLAGS)
 422 AC_SUBST(LINPHONE_LIBS)
 423
 424 AC_DEFINE_UNQUOTED(LINPHONE_VERSION,"$PACKAGE_VERSION",[Linphone's version number])
 425
 426 AC_DEFINE_UNQUOTED(LINPHONE_PLUGINS_DIR, "${package_prefix}/lib/liblinphone/plugins" ,[path of liblinphone plugins, not mediastreamer2 plugins])
 427 LINPHONE_PLUGINS_DIR="${package_prefix}/lib/liblinphone/plugins"
 428 AC_SUBST(LINPHONE_PLUGINS_DIR)
 429
 430 AC_ARG_ENABLE(external-ortp,
 431       [  --enable-external-ortp    Use external oRTP library],
 432       [case "${enableval}" in
 433         yes) external_ortp=true ;;
 434         no)  external_ortp=false ;;
 435         *) AC_MSG_ERROR(bad value ${enableval} for --enable-external-ortp) ;;
 436       esac],[external_ortp=false])
 437
 438 if test "$external_ortp" = 'true'; then
 439         PKG_CHECK_MODULES([ORTP], [ortp])
 440         ORTP_VERSION=`$PKG_CONFIG --modversion ortp`
 441 else
 442         AC_CONFIG_SUBDIRS( oRTP )
 443         ORTP_CFLAGS="-I\$(top_srcdir)/oRTP/include"
 444         ORTP_LIBS="\$(top_builddir)/oRTP/src/libortp.la"
 445         if test x$ac_cv_c_bigendian = xyes ; then
 446                 ORTP_CFLAGS="$ORTP_CFLAGS -DORTP_BIGENDIAN"
 447         fi
 448         changequote(<<, >>)
 449         ORTP_VERSION=`grep -E ^[AC]+_INIT ${top_srcdir}/oRTP/configure.ac | sed -e 's:^.*_INIT(.*,\[\(.*\)\]):\1:g'`
 450         changequote([, ])
 451 fi
 452 AC_SUBST(ORTP_CFLAGS)
 453 AC_SUBST(ORTP_LIBS)
 454 AC_SUBST([ORTP_VERSION])
 455
 456 AM_CONDITIONAL(EXTERNAL_ORTP, [test "$external_ortp" = 'true'])
 457
 458 dnl ##################################################
 459 dnl # Check for doxygen
 460 dnl ##################################################
 461
 462 AC_PATH_PROG(DOXYGEN,doxygen,false)
 463 AM_CONDITIONAL(HAVE_DOXYGEN, test $DOXYGEN != false)
 464
 465
 466 AC_OUTPUT([
 467 Makefile
 468 m4/Makefile
 469 po/Makefile.in
 470 pixmaps/Makefile
 471 coreapi/Makefile
 472 coreapi/help/Makefile
 473 coreapi/help/Doxyfile
 474 gtk/Makefile
 475 console/Makefile
 476 share/Makefile
 477 share/C/Makefile
 478 share/fr/Makefile
 479 share/it/Makefile
 480 share/ja/Makefile
 481 share/cs/Makefile
 482 share/linphone.pc
 483 share/linphone.desktop
 484 scripts/Makefile
 485 linphone.spec
 486 linphone.iss
 487 ])
 488
 489 echo "Linphone build configuration ended."
 490
 491 if test x$gtk_ui = xtrue ; then
 492         echo "* GTK interface will be compiled."
 493 fi
 494 if test x$console_ui = xtrue ; then
 495         echo "* Console interface will be compiled."
 496 fi
 497
 498 echo "Now type 'make' to compile, and then 'make install' as root to install it."