sjero.net Git - wget/blob - md5/m4/stdint.m4

   1 # stdint.m4 serial 34
   2 dnl Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   3 dnl 2010 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Paul Eggert and Bruno Haible.
   9 dnl Test whether <stdint.h> is supported or must be substituted.
  10
  11 AC_DEFUN([gl_STDINT_H],
  12 [
  13   AC_PREREQ([2.59])dnl
  14
  15   dnl Check for long long int and unsigned long long int.
  16   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  17   if test $ac_cv_type_long_long_int = yes; then
  18     HAVE_LONG_LONG_INT=1
  19   else
  20     HAVE_LONG_LONG_INT=0
  21   fi
  22   AC_SUBST([HAVE_LONG_LONG_INT])
  23   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  24   if test $ac_cv_type_unsigned_long_long_int = yes; then
  25     HAVE_UNSIGNED_LONG_LONG_INT=1
  26   else
  27     HAVE_UNSIGNED_LONG_LONG_INT=0
  28   fi
  29   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  30
  31   dnl Check for <inttypes.h>.
  32   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  33   if test $ac_cv_header_inttypes_h = yes; then
  34     HAVE_INTTYPES_H=1
  35   else
  36     HAVE_INTTYPES_H=0
  37   fi
  38   AC_SUBST([HAVE_INTTYPES_H])
  39
  40   dnl Check for <sys/types.h>.
  41   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  42   if test $ac_cv_header_sys_types_h = yes; then
  43     HAVE_SYS_TYPES_H=1
  44   else
  45     HAVE_SYS_TYPES_H=0
  46   fi
  47   AC_SUBST([HAVE_SYS_TYPES_H])
  48
  49   gl_CHECK_NEXT_HEADERS([stdint.h])
  50   if test $ac_cv_header_stdint_h = yes; then
  51     HAVE_STDINT_H=1
  52   else
  53     HAVE_STDINT_H=0
  54   fi
  55   AC_SUBST([HAVE_STDINT_H])
  56
  57   dnl Now see whether we need a substitute <stdint.h>.
  58   if test $ac_cv_header_stdint_h = yes; then
  59     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  60       [gl_cv_header_working_stdint_h],
  61       [gl_cv_header_working_stdint_h=no
  62        AC_COMPILE_IFELSE([
  63          AC_LANG_PROGRAM([[
  64 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  65 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  66 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
  67 #include <stdint.h>
  68 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
  69 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
  70 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
  71 #endif
  72 ]
  73 gl_STDINT_INCLUDES
  74 [
  75 #ifdef INT8_MAX
  76 int8_t a1 = INT8_MAX;
  77 int8_t a1min = INT8_MIN;
  78 #endif
  79 #ifdef INT16_MAX
  80 int16_t a2 = INT16_MAX;
  81 int16_t a2min = INT16_MIN;
  82 #endif
  83 #ifdef INT32_MAX
  84 int32_t a3 = INT32_MAX;
  85 int32_t a3min = INT32_MIN;
  86 #endif
  87 #ifdef INT64_MAX
  88 int64_t a4 = INT64_MAX;
  89 int64_t a4min = INT64_MIN;
  90 #endif
  91 #ifdef UINT8_MAX
  92 uint8_t b1 = UINT8_MAX;
  93 #else
  94 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
  95 #endif
  96 #ifdef UINT16_MAX
  97 uint16_t b2 = UINT16_MAX;
  98 #endif
  99 #ifdef UINT32_MAX
 100 uint32_t b3 = UINT32_MAX;
 101 #endif
 102 #ifdef UINT64_MAX
 103 uint64_t b4 = UINT64_MAX;
 104 #endif
 105 int_least8_t c1 = INT8_C (0x7f);
 106 int_least8_t c1max = INT_LEAST8_MAX;
 107 int_least8_t c1min = INT_LEAST8_MIN;
 108 int_least16_t c2 = INT16_C (0x7fff);
 109 int_least16_t c2max = INT_LEAST16_MAX;
 110 int_least16_t c2min = INT_LEAST16_MIN;
 111 int_least32_t c3 = INT32_C (0x7fffffff);
 112 int_least32_t c3max = INT_LEAST32_MAX;
 113 int_least32_t c3min = INT_LEAST32_MIN;
 114 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 115 int_least64_t c4max = INT_LEAST64_MAX;
 116 int_least64_t c4min = INT_LEAST64_MIN;
 117 uint_least8_t d1 = UINT8_C (0xff);
 118 uint_least8_t d1max = UINT_LEAST8_MAX;
 119 uint_least16_t d2 = UINT16_C (0xffff);
 120 uint_least16_t d2max = UINT_LEAST16_MAX;
 121 uint_least32_t d3 = UINT32_C (0xffffffff);
 122 uint_least32_t d3max = UINT_LEAST32_MAX;
 123 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 124 uint_least64_t d4max = UINT_LEAST64_MAX;
 125 int_fast8_t e1 = INT_FAST8_MAX;
 126 int_fast8_t e1min = INT_FAST8_MIN;
 127 int_fast16_t e2 = INT_FAST16_MAX;
 128 int_fast16_t e2min = INT_FAST16_MIN;
 129 int_fast32_t e3 = INT_FAST32_MAX;
 130 int_fast32_t e3min = INT_FAST32_MIN;
 131 int_fast64_t e4 = INT_FAST64_MAX;
 132 int_fast64_t e4min = INT_FAST64_MIN;
 133 uint_fast8_t f1 = UINT_FAST8_MAX;
 134 uint_fast16_t f2 = UINT_FAST16_MAX;
 135 uint_fast32_t f3 = UINT_FAST32_MAX;
 136 uint_fast64_t f4 = UINT_FAST64_MAX;
 137 #ifdef INTPTR_MAX
 138 intptr_t g = INTPTR_MAX;
 139 intptr_t gmin = INTPTR_MIN;
 140 #endif
 141 #ifdef UINTPTR_MAX
 142 uintptr_t h = UINTPTR_MAX;
 143 #endif
 144 intmax_t i = INTMAX_MAX;
 145 uintmax_t j = UINTMAX_MAX;
 146
 147 #include <limits.h> /* for CHAR_BIT */
 148 #define TYPE_MINIMUM(t) \
 149   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ (t) 0 << (sizeof (t) * CHAR_BIT - 1)))
 150 #define TYPE_MAXIMUM(t) \
 151   ((t) ((t) 0 < (t) -1 ? (t) -1 : ~ (~ (t) 0 << (sizeof (t) * CHAR_BIT - 1))))
 152 struct s {
 153   int check_PTRDIFF:
 154       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 155       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 156       ? 1 : -1;
 157   /* Detect bug in FreeBSD 6.0 / ia64.  */
 158   int check_SIG_ATOMIC:
 159       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 160       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 161       ? 1 : -1;
 162   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 163   int check_WCHAR:
 164       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 165       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 166       ? 1 : -1;
 167   /* Detect bug in mingw.  */
 168   int check_WINT:
 169       WINT_MIN == TYPE_MINIMUM (wint_t)
 170       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 171       ? 1 : -1;
 172
 173   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 174   int check_UINT8_C:
 175         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 176   int check_UINT16_C:
 177         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 178
 179   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 180 #ifdef UINT8_MAX
 181   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 182 #endif
 183 #ifdef UINT16_MAX
 184   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 185 #endif
 186 #ifdef UINT32_MAX
 187   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 188 #endif
 189 #ifdef UINT64_MAX
 190   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 191 #endif
 192   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 193   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 194   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 195   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 196   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 197   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 198   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 199   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 200   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 201   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 202   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 203 };
 204          ]])],
 205          [dnl Determine whether the various *_MIN, *_MAX macros are usable
 206           dnl in preprocessor expression. We could do it by compiling a test
 207           dnl program for each of these macros. It is faster to run a program
 208           dnl that inspects the macro expansion.
 209           dnl This detects a bug on HP-UX 11.23/ia64.
 210           AC_RUN_IFELSE([
 211             AC_LANG_PROGRAM([[
 212 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
 213 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
 214 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 215 #include <stdint.h>
 216 ]
 217 gl_STDINT_INCLUDES
 218 [
 219 #include <stdio.h>
 220 #include <string.h>
 221 #define MVAL(macro) MVAL1(macro)
 222 #define MVAL1(expression) #expression
 223 static const char *macro_values[] =
 224   {
 225 #ifdef INT8_MAX
 226     MVAL (INT8_MAX),
 227 #endif
 228 #ifdef INT16_MAX
 229     MVAL (INT16_MAX),
 230 #endif
 231 #ifdef INT32_MAX
 232     MVAL (INT32_MAX),
 233 #endif
 234 #ifdef INT64_MAX
 235     MVAL (INT64_MAX),
 236 #endif
 237 #ifdef UINT8_MAX
 238     MVAL (UINT8_MAX),
 239 #endif
 240 #ifdef UINT16_MAX
 241     MVAL (UINT16_MAX),
 242 #endif
 243 #ifdef UINT32_MAX
 244     MVAL (UINT32_MAX),
 245 #endif
 246 #ifdef UINT64_MAX
 247     MVAL (UINT64_MAX),
 248 #endif
 249     NULL
 250   };
 251 ]], [[
 252   const char **mv;
 253   for (mv = macro_values; *mv != NULL; mv++)
 254     {
 255       const char *value = *mv;
 256       /* Test whether it looks like a cast expression.  */
 257       if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0
 258           || strncmp (value, "((unsigned short)"/*)*/, 17) == 0
 259           || strncmp (value, "((unsigned char)"/*)*/, 16) == 0
 260           || strncmp (value, "((int)"/*)*/, 6) == 0
 261           || strncmp (value, "((signed short)"/*)*/, 15) == 0
 262           || strncmp (value, "((signed char)"/*)*/, 14) == 0)
 263         return 1;
 264     }
 265   return 0;
 266 ]])],
 267               [gl_cv_header_working_stdint_h=yes],
 268               [],
 269               [dnl When cross-compiling, assume it works.
 270                gl_cv_header_working_stdint_h=yes
 271               ])
 272          ])
 273       ])
 274   fi
 275   if test "$gl_cv_header_working_stdint_h" = yes; then
 276     STDINT_H=
 277   else
 278     dnl Check for <sys/inttypes.h>, and for
 279     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 280     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 281     if test $ac_cv_header_sys_inttypes_h = yes; then
 282       HAVE_SYS_INTTYPES_H=1
 283     else
 284       HAVE_SYS_INTTYPES_H=0
 285     fi
 286     AC_SUBST([HAVE_SYS_INTTYPES_H])
 287     if test $ac_cv_header_sys_bitypes_h = yes; then
 288       HAVE_SYS_BITYPES_H=1
 289     else
 290       HAVE_SYS_BITYPES_H=0
 291     fi
 292     AC_SUBST([HAVE_SYS_BITYPES_H])
 293
 294     dnl Check for <wchar.h> (missing in Linux uClibc when built without wide
 295     dnl character support).
 296     AC_CHECK_HEADERS_ONCE([wchar.h])
 297
 298     gl_STDINT_TYPE_PROPERTIES
 299     STDINT_H=stdint.h
 300   fi
 301   AC_SUBST([STDINT_H])
 302 ])
 303
 304 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 305 dnl Determine the size of each of the given types in bits.
 306 AC_DEFUN([gl_STDINT_BITSIZEOF],
 307 [
 308   dnl Use a shell loop, to avoid bloating configure, and
 309   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 310   dnl   config.h.in,
 311   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 312   m4_foreach_w([gltype], [$1],
 313     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 314        [Define to the number of bits in type ']gltype['.])])
 315   for gltype in $1 ; do
 316     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 317       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 318          [$2
 319 #include <limits.h>], [result=unknown])
 320        eval gl_cv_bitsizeof_${gltype}=\$result
 321       ])
 322     eval result=\$gl_cv_bitsizeof_${gltype}
 323     if test $result = unknown; then
 324       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 325       dnl do a syntax check even on unused #if conditions and give an error
 326       dnl on valid C code like this:
 327       dnl   #if 0
 328       dnl   # if  > 32
 329       dnl   # endif
 330       dnl   #endif
 331       result=0
 332     fi
 333     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 334     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 335     eval BITSIZEOF_${GLTYPE}=\$result
 336   done
 337   m4_foreach_w([gltype], [$1],
 338     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 339 ])
 340
 341 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 342 dnl Determine the signedness of each of the given types.
 343 dnl Define HAVE_SIGNED_TYPE if type is signed.
 344 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 345 [
 346   dnl Use a shell loop, to avoid bloating configure, and
 347   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 348   dnl   config.h.in,
 349   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 350   m4_foreach_w([gltype], [$1],
 351     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 352        [Define to 1 if ']gltype[' is a signed integer type.])])
 353   for gltype in $1 ; do
 354     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 355       [AC_COMPILE_IFELSE(
 356          [AC_LANG_PROGRAM([$2[
 357             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 358          result=yes, result=no)
 359        eval gl_cv_type_${gltype}_signed=\$result
 360       ])
 361     eval result=\$gl_cv_type_${gltype}_signed
 362     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 363     if test "$result" = yes; then
 364       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1])
 365       eval HAVE_SIGNED_${GLTYPE}=1
 366     else
 367       eval HAVE_SIGNED_${GLTYPE}=0
 368     fi
 369   done
 370   m4_foreach_w([gltype], [$1],
 371     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 372 ])
 373
 374 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 375 dnl Determine the suffix to use for integer constants of the given types.
 376 dnl Define t_SUFFIX for each such type.
 377 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 378 [
 379   dnl Use a shell loop, to avoid bloating configure, and
 380   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 381   dnl   config.h.in,
 382   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 383   m4_foreach_w([gltype], [$1],
 384     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 385        [Define to l, ll, u, ul, ull, etc., as suitable for
 386         constants of type ']gltype['.])])
 387   for gltype in $1 ; do
 388     AC_CACHE_CHECK([for $gltype integer literal suffix],
 389       [gl_cv_type_${gltype}_suffix],
 390       [eval gl_cv_type_${gltype}_suffix=no
 391        eval result=\$gl_cv_type_${gltype}_signed
 392        if test "$result" = yes; then
 393          glsufu=
 394        else
 395          glsufu=u
 396        fi
 397        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 398          case $glsuf in
 399            '')  gltype1='int';;
 400            l)   gltype1='long int';;
 401            ll)  gltype1='long long int';;
 402            i64) gltype1='__int64';;
 403            u)   gltype1='unsigned int';;
 404            ul)  gltype1='unsigned long int';;
 405            ull) gltype1='unsigned long long int';;
 406            ui64)gltype1='unsigned __int64';;
 407          esac
 408          AC_COMPILE_IFELSE(
 409            [AC_LANG_PROGRAM([$2[
 410               extern $gltype foo;
 411               extern $gltype1 foo;]])],
 412            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 413          eval result=\$gl_cv_type_${gltype}_suffix
 414          test "$result" != no && break
 415        done])
 416     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 417     eval result=\$gl_cv_type_${gltype}_suffix
 418     test "$result" = no && result=
 419     eval ${GLTYPE}_SUFFIX=\$result
 420     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result])
 421   done
 422   m4_foreach_w([gltype], [$1],
 423     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 424 ])
 425
 426 dnl gl_STDINT_INCLUDES
 427 AC_DEFUN([gl_STDINT_INCLUDES],
 428 [[
 429   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 430      included before <wchar.h>.  */
 431   #include <stddef.h>
 432   #include <signal.h>
 433   #if HAVE_WCHAR_H
 434   # include <stdio.h>
 435   # include <time.h>
 436   # include <wchar.h>
 437   #endif
 438 ]])
 439
 440 dnl gl_STDINT_TYPE_PROPERTIES
 441 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 442 dnl of interest to stdint.in.h.
 443 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 444 [
 445   AC_REQUIRE([gl_MULTIARCH])
 446   if test $APPLE_UNIVERSAL_BUILD = 0; then
 447     gl_STDINT_BITSIZEOF([ptrdiff_t size_t],
 448       [gl_STDINT_INCLUDES])
 449   fi
 450   gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t],
 451     [gl_STDINT_INCLUDES])
 452   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 453     [gl_STDINT_INCLUDES])
 454   gl_cv_type_ptrdiff_t_signed=yes
 455   gl_cv_type_size_t_signed=no
 456   if test $APPLE_UNIVERSAL_BUILD = 0; then
 457     gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t],
 458       [gl_STDINT_INCLUDES])
 459   fi
 460   gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t],
 461     [gl_STDINT_INCLUDES])
 462 ])
 463
 464 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 465 dnl Remove this when we can assume autoconf >= 2.61.
 466 m4_ifdef([AC_COMPUTE_INT], [], [
 467   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 468 ])
 469
 470 # Hey Emacs!
 471 # Local Variables:
 472 # indent-tabs-mode: nil
 473 # End: