sjero.net Git - wget/blob - m4/progtest.m4

   1 # progtest.m4 serial 4 (gettext-0.14.2)
   2 dnl Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2005,
   3 dnl 2009 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7 dnl
   8 dnl This file can can be used in projects which are not available under
   9 dnl the GNU General Public License or the GNU Library General Public
  10 dnl License but which still want to provide support for the GNU gettext
  11 dnl functionality.
  12 dnl Please note that the actual code of the GNU gettext library is covered
  13 dnl by the GNU Library General Public License, and the rest of the GNU
  14 dnl gettext package package is covered by the GNU General Public License.
  15 dnl They are *not* in the public domain.
  16
  17 dnl Authors:
  18 dnl   Ulrich Drepper <drepper@cygnus.com>, 1996.
  19
  20 AC_PREREQ(2.50)
  21
  22 # Search path for a program which passes the given test.
  23
  24 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
  25 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
  26 AC_DEFUN([AM_PATH_PROG_WITH_TEST],
  27 [
  28 # Prepare PATH_SEPARATOR.
  29 # The user is always right.
  30 if test "${PATH_SEPARATOR+set}" != set; then
  31   echo "#! /bin/sh" >conf$$.sh
  32   echo  "exit 0"   >>conf$$.sh
  33   chmod +x conf$$.sh
  34   if (PATH="/nonexistent;."; conf$$.sh) >/dev/null 2>&1; then
  35     PATH_SEPARATOR=';'
  36   else
  37     PATH_SEPARATOR=:
  38   fi
  39   rm -f conf$$.sh
  40 fi
  41
  42 # Find out how to test for executable files. Don't use a zero-byte file,
  43 # as systems may use methods other than mode bits to determine executability.
  44 cat >conf$$.file <<_ASEOF
  45 #! /bin/sh
  46 exit 0
  47 _ASEOF
  48 chmod +x conf$$.file
  49 if test -x conf$$.file >/dev/null 2>&1; then
  50   ac_executable_p="test -x"
  51 else
  52   ac_executable_p="test -f"
  53 fi
  54 rm -f conf$$.file
  55
  56 # Extract the first word of "$2", so it can be a program name with args.
  57 set dummy $2; ac_word=[$]2
  58 AC_MSG_CHECKING([for $ac_word])
  59 AC_CACHE_VAL(ac_cv_path_$1,
  60 [case "[$]$1" in
  61   [[\\/]]* | ?:[[\\/]]*)
  62     ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
  63     ;;
  64   *)
  65     ac_save_IFS="$IFS"; IFS=$PATH_SEPARATOR
  66     for ac_dir in ifelse([$5], , $PATH, [$5]); do
  67       IFS="$ac_save_IFS"
  68       test -z "$ac_dir" && ac_dir=.
  69       for ac_exec_ext in '' $ac_executable_extensions; do
  70         if $ac_executable_p "$ac_dir/$ac_word$ac_exec_ext"; then
  71           echo "$as_me: trying $ac_dir/$ac_word..." >&AS_MESSAGE_LOG_FD
  72           if [$3]; then
  73             ac_cv_path_$1="$ac_dir/$ac_word$ac_exec_ext"
  74             break 2
  75           fi
  76         fi
  77       done
  78     done
  79     IFS="$ac_save_IFS"
  80 dnl If no 4th arg is given, leave the cache variable unset,
  81 dnl so AC_PATH_PROGS will keep looking.
  82 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
  83 ])dnl
  84     ;;
  85 esac])dnl
  86 $1="$ac_cv_path_$1"
  87 if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then
  88   AC_MSG_RESULT([$]$1)
  89 else
  90   AC_MSG_RESULT(no)
  91 fi
  92 AC_SUBST($1)dnl
  93 ])