sjero.net Git - wget/blob - m4/fseeko.m4

   1 # fseeko.m4 serial 4
   2 dnl Copyright (C) 2007, 2008, 2009 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_FSEEKO],
   8 [
   9   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  10   AC_REQUIRE([AC_PROG_CC])
  11   AC_REQUIRE([gl_STDIN_LARGE_OFFSET])
  12
  13   dnl Persuade glibc <stdio.h> to declare fseeko().
  14   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  15
  16   AC_CACHE_CHECK([for fseeko], [gl_cv_func_fseeko],
  17     [
  18       AC_TRY_LINK([#include <stdio.h>], [fseeko (stdin, 0, 0);],
  19         [gl_cv_func_fseeko=yes], [gl_cv_func_fseeko=no])
  20     ])
  21   if test $gl_cv_func_fseeko = no; then
  22     HAVE_FSEEKO=0
  23     gl_REPLACE_FSEEKO
  24   elif test $gl_cv_var_stdin_large_offset = no; then
  25     gl_REPLACE_FSEEKO
  26   fi
  27 ])
  28
  29 AC_DEFUN([gl_REPLACE_FSEEKO],
  30 [
  31   AC_LIBOBJ([fseeko])
  32   AC_REQUIRE([gl_STDIO_H_DEFAULTS])
  33   REPLACE_FSEEKO=1
  34 ])