sjero.net Git - wget/blob - doc/texi2pod.pl

   1 #! /usr/bin/env perl
   2
   3 #   Copyright (C) 1999, 2000, 2001, 2003 Free Software Foundation, Inc.
   4
   5 # This file is part of GCC.
   6
   7 # GCC is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3, or (at your option)
  10 # any later version.
  11
  12 # GCC is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with GCC.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # This does trivial (and I mean _trivial_) conversion of Texinfo
  21 # markup to Perl POD format.  It's intended to be used to extract
  22 # something suitable for a manpage from a Texinfo document.
  23
  24 use warnings;
  25
  26 $output = 0;
  27 $skipping = 0;
  28 %sects = ();
  29 $section = "";
  30 @icstack = ();
  31 @endwstack = ();
  32 @skstack = ();
  33 @instack = ();
  34 $shift = "";
  35 %defs = ();
  36 $fnno = 1;
  37 $inf = "";
  38 $ibase = "";
  39
  40 while ($_ = shift) {
  41     if (/^-D(.*)$/) {
  42         if ($1 ne "") {
  43             $flag = $1;
  44         } else {
  45             $flag = shift;
  46         }
  47         $value = "";
  48         ($flag, $value) = ($flag =~ /^([^=]+)(?:=(.+))?/);
  49         die "no flag specified for -D\n"
  50             unless $flag ne "";
  51         die "flags may only contain letters, digits, hyphens, dashes and underscores\n"
  52             unless $flag =~ /^[a-zA-Z0-9_-]+$/;
  53         $defs{$flag} = $value;
  54     } elsif (/^-/) {
  55         usage();
  56     } else {
  57         $in = $_, next unless defined $in;
  58         $out = $_, next unless defined $out;
  59         usage();
  60     }
  61 }
  62
  63 if (defined $in) {
  64     $inf = gensym();
  65     open($inf, "<$in") or die "opening \"$in\": $!\n";
  66     $ibase = $1 if $in =~ m|^(.+)/[^/]+$|;
  67 } else {
  68     $inf = \*STDIN;
  69 }
  70
  71 if (defined $out) {
  72     open(STDOUT, ">$out") or die "opening \"$out\": $!\n";
  73 }
  74
  75 while(defined $inf) {
  76 while(<$inf>) {
  77     # Certain commands are discarded without further processing.
  78     /^\@(?:
  79          [a-z]+index            # @*index: useful only in complete manual
  80          |need                  # @need: useful only in printed manual
  81          |(?:end\s+)?group      # @group .. @end group: ditto
  82          |page                  # @page: ditto
  83          |node                  # @node: useful only in .info file
  84          |(?:end\s+)?ifnottex   # @ifnottex .. @end ifnottex: use contents
  85         )\b/x and next;
  86
  87     chomp;
  88
  89     # Look for filename and title markers.
  90     /^\@setfilename\s+([^.]+)/ and $fn = $1, next;
  91     /^\@settitle\s+([^.]+)/ and $tl = postprocess($1), next;
  92
  93     # Identify a man title but keep only the one we are interested in.
  94     /^\@c\s+man\s+title\s+([A-Za-z0-9-]+)\s+(.+)/ and do {
  95         if (exists $defs{$1}) {
  96             $fn = $1;
  97             $tl = postprocess($2);
  98         }
  99         next;
 100     };
 101
 102     # Look for blocks surrounded by @c man begin SECTION ... @c man end.
 103     # This really oughta be @ifman ... @end ifman and the like, but such
 104     # would require rev'ing all other Texinfo translators.
 105     /^\@c\s+man\s+begin\s+([A-Z]+)\s+([A-Za-z0-9-]+)/ and do {
 106         $output = 1 if exists $defs{$2};
 107         $sect = $1;
 108         next;
 109     };
 110     /^\@c\s+man\s+begin\s+([A-Z]+)/ and $sect = $1, $output = 1, next;
 111     /^\@c\s+man\s+end/ and do {
 112         $sects{$sect} = "" unless exists $sects{$sect};
 113         $sects{$sect} .= postprocess($section);
 114         $section = "";
 115         $output = 0;
 116         next;
 117     };
 118
 119     # handle variables
 120     /^\@set\s+([a-zA-Z0-9_-]+)\s*(.*)$/ and do {
 121         $defs{$1} = $2;
 122         next;
 123     };
 124     /^\@clear\s+([a-zA-Z0-9_-]+)/ and do {
 125         delete $defs{$1};
 126         next;
 127     };
 128
 129     next unless $output;
 130
 131     # Discard comments.  (Can't do it above, because then we'd never see
 132     # @c man lines.)
 133     /^\@c\b/ and next;
 134
 135     # End-block handler goes up here because it needs to operate even
 136     # if we are skipping.
 137     /^\@end\s+([a-z]+)/ and do {
 138         # Ignore @end foo, where foo is not an operation which may
 139         # cause us to skip, if we are presently skipping.
 140         my $ended = $1;
 141         next if $skipping && $ended !~ /^(?:ifset|ifclear|ignore|menu|iftex|copying)$/;
 142
 143         die "\@end $ended without \@$ended at line $.\n" unless defined $endw;
 144         die "\@$endw ended by \@end $ended at line $.\n" unless $ended eq $endw;
 145
 146         $endw = pop @endwstack;
 147
 148         if ($ended =~ /^(?:ifset|ifclear|ignore|menu|iftex)$/) {
 149             $skipping = pop @skstack;
 150             next;
 151         } elsif ($ended =~ /^(?:example|smallexample|display)$/) {
 152             $shift = "";
 153             $_ = "";    # need a paragraph break
 154         } elsif ($ended =~ /^(?:itemize|enumerate|[fv]?table)$/) {
 155             $_ = "\n=back\n";
 156             $ic = pop @icstack;
 157         } else {
 158             die "unknown command \@end $ended at line $.\n";
 159         }
 160     };
 161
 162     # We must handle commands which can cause skipping even while we
 163     # are skipping, otherwise we will not process nested conditionals
 164     # correctly.
 165     /^\@ifset\s+([a-zA-Z0-9_-]+)/ and do {
 166         push @endwstack, $endw;
 167         push @skstack, $skipping;
 168         $endw = "ifset";
 169         $skipping = 1 unless exists $defs{$1};
 170         next;
 171     };
 172
 173     /^\@ifclear\s+([a-zA-Z0-9_-]+)/ and do {
 174         push @endwstack, $endw;
 175         push @skstack, $skipping;
 176         $endw = "ifclear";
 177         $skipping = 1 if exists $defs{$1};
 178         next;
 179     };
 180
 181     /^\@(ignore|menu|iftex|copying)\b/ and do {
 182         push @endwstack, $endw;
 183         push @skstack, $skipping;
 184         $endw = $1;
 185         $skipping = 1;
 186         next;
 187     };
 188
 189     next if $skipping;
 190
 191     # Character entities.  First the ones that can be replaced by raw text
 192     # or discarded outright:
 193     s/\@copyright\{\}/(c)/g;
 194     s/\@dots\{\}/.../g;
 195     s/\@enddots\{\}/..../g;
 196     s/\@([.!? ])/$1/g;
 197     s/\@[:-]//g;
 198     s/\@bullet(?:\{\})?/*/g;
 199     s/\@TeX\{\}/TeX/g;
 200     s/\@pounds\{\}/\#/g;
 201     s/\@minus(?:\{\})?/-/g;
 202     s/\\,/,/g;
 203
 204     # Now the ones that have to be replaced by special escapes
 205     # (which will be turned back into text by unmunge())
 206     s/&/&amp;/g;
 207     s/\@\@/&at;/g;
 208     s/\@\{/&lbrace;/g;
 209     s/\@\}/&rbrace;/g;
 210
 211     # Inside a verbatim block, handle @var specially.
 212     if ($shift ne "") {
 213         s/\@var\{([^\}]*)\}/<$1>/g;
 214     }
 215
 216     # POD doesn't interpret E<> inside a verbatim block.
 217     if ($shift eq "") {
 218         s/</&lt;/g;
 219         s/>/&gt;/g;
 220     } else {
 221         s/</&LT;/g;
 222         s/>/&GT;/g;
 223     }
 224
 225     # Single line command handlers.
 226
 227     /^\@include\s+(.+)$/ and do {
 228         push @instack, $inf;
 229         $inf = gensym();
 230
 231         # Try cwd and $ibase.
 232         open($inf, "<" . $1)
 233             or open($inf, "<" . $ibase . "/" . $1)
 234                 or die "cannot open $1 or $ibase/$1: $!\n";
 235         next;
 236     };
 237
 238     /^\@(?:section|unnumbered|unnumberedsec|center)\s+(.+)$/
 239         and $_ = "\n=head2 $1\n";
 240     /^\@subsection\s+(.+)$/
 241         and $_ = "\n=head3 $1\n";
 242
 243     # Block command handlers:
 244     /^\@itemize(?:\s+(\@[a-z]+|\*|-))?/ and do {
 245         push @endwstack, $endw;
 246         push @icstack, $ic;
 247         if (defined $1) {
 248             $ic = $1;
 249         } else {
 250             $ic = '@bullet';
 251         }
 252         $_ = "\n=over 4\n";
 253         $endw = "itemize";
 254     };
 255
 256     /^\@enumerate(?:\s+([a-zA-Z0-9]+))?/ and do {
 257         push @endwstack, $endw;
 258         push @icstack, $ic;
 259         if (defined $1) {
 260             $ic = $1 . ".";
 261         } else {
 262             $ic = "1.";
 263         }
 264         $_ = "\n=over 4\n";
 265         $endw = "enumerate";
 266     };
 267
 268     /^\@([fv]?table)\s+(\@[a-z]+)/ and do {
 269         push @endwstack, $endw;
 270         push @icstack, $ic;
 271         $endw = $1;
 272         $ic = $2;
 273         $ic =~ s/\@(?:samp|strong|key|gcctabopt|env)/B/;
 274         $ic =~ s/\@(?:code|kbd)/C/;
 275         $ic =~ s/\@(?:dfn|var|emph|cite|i)/I/;
 276         $ic =~ s/\@(?:file)/F/;
 277         $ic =~ s/\@(?:asis)/S/; # punt
 278         $_ = "\n=over 4\n";
 279     };
 280
 281     /^\@((?:small)?example|display)/ and do {
 282         push @endwstack, $endw;
 283         $endw = $1;
 284         $shift = "\t";
 285         $_ = "";        # need a paragraph break
 286     };
 287
 288     /^\@itemx?\s*(.+)?$/ and do {
 289         if (defined $1) {
 290             # Entity escapes prevent munging by the <> processing below.
 291             $_ = "\n=item $ic\&LT;$1\&GT;\n";
 292         } else {
 293             $_ = "\n=item $ic\n";
 294             $ic =~ y/A-Ya-y/B-Zb-z/;
 295             $ic =~ s/(\d+)/$1 + 1/eg;
 296         }
 297     };
 298
 299     $section .= $shift.$_."\n";
 300 }
 301 # End of current file.
 302 close($inf);
 303 $inf = pop @instack;
 304 }
 305
 306 die "No filename or title\n" unless defined $fn && defined $tl;
 307
 308 $sects{NAME} = "$fn \- $tl\n";
 309 $sects{FOOTNOTES} .= "=back\n" if exists $sects{FOOTNOTES};
 310
 311 for $sect (qw(NAME SYNOPSIS DESCRIPTION OPTIONS ENVIRONMENT EXAMPLES FILES
 312               BUGS NOTES FOOTNOTES SEEALSO AUTHOR COPYRIGHT)) {
 313     if(exists $sects{$sect}) {
 314         $head = $sect;
 315         $head =~ s/SEEALSO/SEE ALSO/;
 316         print "=head1 $head\n\n";
 317         print scalar unmunge ($sects{$sect});
 318         print "\n";
 319     }
 320 }
 321
 322 sub usage
 323 {
 324     die "usage: $0 [-D toggle...] [infile [outfile]]\n";
 325 }
 326
 327 sub postprocess
 328 {
 329     local $_ = $_[0];
 330
 331     # @value{foo} is replaced by whatever 'foo' is defined as.
 332     while (m/(\@value\{([a-zA-Z0-9_-]+)\})/g) {
 333         if (! exists $defs{$2}) {
 334             print STDERR "Option $2 not defined\n";
 335             s/\Q$1\E//;
 336         } else {
 337             $value = $defs{$2};
 338             s/\Q$1\E/$value/;
 339         }
 340     }
 341
 342     # Formatting commands.
 343     # Temporary escape for @r.
 344     s/\@r\{([^\}]*)\}/R<$1>/g;
 345     s/\@(?:dfn|var|emph|cite|i)\{([^\}]*)\}/I<$1>/g;
 346     s/\@(?:code|kbd)\{([^\}]*)\}/C<$1>/g;
 347     s/\@(?:gccoptlist|samp|strong|key|option|env|command|b)\{([^\}]*)\}/B<$1>/g;
 348     s/\@sc\{([^\}]*)\}/\U$1/g;
 349     s/\@file\{([^\}]*)\}/F<$1>/g;
 350     s/\@w\{([^\}]*)\}/S<$1>/g;
 351     s/\@(?:dmn|math)\{([^\}]*)\}/$1/g;
 352
 353     # Cross references are thrown away, as are @noindent and @refill.
 354     # (@noindent is impossible in .pod, and @refill is unnecessary.)
 355     # @* is also impossible in .pod; we discard it and any newline that
 356     # follows it.  Similarly, our macro @gol must be discarded.
 357
 358     s/\(?\@xref\{(?:[^\}]*)\}(?:[^.<]|(?:<[^<>]*>))*\.\)?//g;
 359     s/\s+\(\@pxref\{(?:[^\}]*)\}\)//g;
 360     s/;\s+\@pxref\{(?:[^\}]*)\}//g;
 361     s/\@noindent\s*//g;
 362     s/\@refill//g;
 363     s/\@gol//g;
 364     s/\@\*\s*\n?//g;
 365
 366     # @uref can take one, two, or three arguments, with different
 367     # semantics each time.  @url and @email are just like @uref with
 368     # one argument, for our purposes.
 369     s/\@(?:uref|url|email)\{([^\},]*)\}/&lt;B<$1>&gt;/g;
 370     s/\@uref\{([^\},]*),([^\},]*)\}/$2 (C<$1>)/g;
 371     s/\@uref\{([^\},]*),([^\},]*),([^\},]*)\}/$3/g;
 372
 373     # Un-escape <> at this point.
 374     s/&LT;/</g;
 375     s/&GT;/>/g;
 376
 377     # Now un-nest all B<>, I<>, R<>.  Theoretically we could have
 378     # indefinitely deep nesting; in practice, one level suffices.
 379     1 while s/([BIR])<([^<>]*)([BIR])<([^<>]*)>/$1<$2>$3<$4>$1</g;
 380
 381     # Replace R<...> with bare ...; eliminate empty markup, B<>;
 382     # shift white space at the ends of [BI]<...> expressions outside
 383     # the expression.
 384     s/R<([^<>]*)>/$1/g;
 385     s/[BI]<>//g;
 386     s/([BI])<(\s+)([^>]+)>/$2$1<$3>/g;
 387     s/([BI])<([^>]+?)(\s+)>/$1<$2>$3/g;
 388
 389     # Extract footnotes.  This has to be done after all other
 390     # processing because otherwise the regexp will choke on formatting
 391     # inside @footnote.
 392     while (/\@footnote/g) {
 393         s/\@footnote\{([^\}]+)\}/[$fnno]/;
 394         add_footnote($1, $fnno);
 395         $fnno++;
 396     }
 397
 398     return $_;
 399 }
 400
 401 sub unmunge
 402 {
 403     # Replace escaped symbols with their equivalents.
 404     local $_ = $_[0];
 405
 406     s/&lt;/E<lt>/g;
 407     s/&gt;/E<gt>/g;
 408     s/&lbrace;/\{/g;
 409     s/&rbrace;/\}/g;
 410     s/&at;/\@/g;
 411     s/&amp;/&/g;
 412     return $_;
 413 }
 414
 415 sub add_footnote
 416 {
 417     unless (exists $sects{FOOTNOTES}) {
 418         $sects{FOOTNOTES} = "\n=over 4\n\n";
 419     }
 420
 421     $sects{FOOTNOTES} .= "=item $fnno.\n\n"; $fnno++;
 422     $sects{FOOTNOTES} .= $_[0];
 423     $sects{FOOTNOTES} .= "\n\n";
 424 }
 425
 426 # stolen from Symbol.pm
 427 {
 428     my $genseq = 0;
 429     sub gensym
 430     {
 431         my $name = "GEN" . $genseq++;
 432         my $ref = \*{$name};
 433         delete $::{$name};
 434         return $ref;
 435     }
 436 }