sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 echo "configuring for GNU Wget $VERSION"
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 DEBUG=$enableval, DEBUG=yes)
  75 test x"${DEBUG}" = xyes && AC_DEFINE(DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for typedefs, structures, and compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_PID_T
 158 AC_C_BIGENDIAN
 159
 160 # Check size of long.
 161 AC_CHECK_SIZEOF(long)
 162 AC_CHECK_SIZEOF(long long)
 163
 164 dnl
 165 dnl Checks for headers
 166 dnl
 167 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 168 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 169 AC_CHECK_HEADERS(signal.h setjmp.h)
 170 AC_HEADER_TIME
 171
 172 dnl
 173 dnl Return type of signal-handlers
 174 dnl
 175 AC_TYPE_SIGNAL
 176
 177 dnl
 178 dnl Check for struct utimbuf
 179 WGET_STRUCT_UTIMBUF
 180
 181 dnl
 182 dnl Checks for library functions.
 183 dnl
 184 AC_FUNC_ALLOCA
 185 AC_FUNC_MMAP
 186 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 187 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 188 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 189 AC_CHECK_FUNCS(uname gethostname usleep)
 190
 191 dnl
 192 dnl Check if we need to compile in getopt.c.
 193 dnl
 194 AC_CHECK_FUNC(getopt_long, [], [
 195   GETOPT_OBJ='getopt$o'
 196 ])
 197 AC_SUBST(GETOPT_OBJ)
 198
 199 dnl
 200 dnl Checks for libraries.
 201 dnl
 202
 203 dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
 204 dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
 205 dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
 206 dnl look for such known offenders and if one of them is not found, we
 207 dnl check if -lnsl is needed.
 208
 209 wget_check_in_nsl=NONE
 210 AC_CHECK_FUNCS(gethostbyname, [], [
 211   wget_check_in_nsl=gethostbyname
 212 ])
 213 AC_CHECK_FUNCS(inet_ntoa, [], [
 214   wget_check_in_nsl=inet_ntoa
 215 ])
 216 if test $wget_check_in_nsl != NONE; then
 217   AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 218 fi
 219
 220 AC_CHECK_LIB(socket, socket)
 221
 222 dnl #### This appears to be deficient with later versions of SOCKS.
 223 if test "x${with_socks}" = xyes
 224 then
 225   AC_CHECK_LIB(resolv, main)
 226   AC_CHECK_LIB(socks, Rconnect)
 227 fi
 228
 229 dnl $with_ssl can be one of:
 230 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 231 dnl  - "yes", meaning link with SSL or bail out.
 232 dnl  - "no", meaning don't link with SSL.
 233 dnl  - anything else, meaning use that as the SSL root, and bail out
 234 dnl    if it fails.
 235
 236 if test x"$with_ssl" = x; then
 237   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 238   dnl implements the "auto-detect by default" feature.  If you want to
 239   dnl change this to "ignore SSL by default", change "auto" to "no".
 240   with_ssl=auto
 241 fi
 242
 243 dnl Detection of OpenSSL is much hairier than the detection of other
 244 dnl libraries because OpenSSL can be compiled as a third-party
 245 dnl library, which means it will not be found without additional
 246 dnl linker magic.  It would be really nice to rework this check into
 247 dnl an AC_DEFUN so that we can reuse it for other third-party
 248 dnl libraries.
 249
 250 if test x"$with_ssl" != x"no"; then
 251
 252   wget_force_ssl=no
 253   if test x"$with_ssl" = x"yes"; then
 254     wget_force_ssl=yes
 255   fi
 256
 257   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 258     dnl OpenSSL's root was not specified, so we have to guess.  First
 259     dnl try the system default location, then "/usr/local/ssl" (where
 260     dnl OpenSSL installs by default), then "/usr/local" (traditional
 261     dnl choice for installation root), then "/opt".
 262     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 263   else
 264     dnl Root has been specified by the user.
 265     ssl_all_roots=$with_ssl
 266     wget_force_ssl=yes
 267   fi
 268
 269   wget_save_CC=$CC
 270   wget_save_LIBS=$LIBS
 271   wget_save_LDFLAGS=$LDFLAGS
 272   wget_save_CPPFLAGS=$CPPFLAGS
 273
 274   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 275   dnl without having to know how the linker handles it.
 276   CC="$SHELL ./libtool $CC"
 277
 278   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 279   dnl shared library doesn't record its dependency on libdl, so we
 280   dnl need to check for it ourselves so we won't fail to link due to a
 281   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 282   dnl shl_load().
 283   AC_CHECK_LIB(dl,dlopen)
 284   AC_CHECK_LIB(dl,shl_load)
 285
 286   ssl_success=no
 287
 288   dnl Now try to find SSL libraries in each of the likely SSL roots.
 289   for ssl_root in $ssl_all_roots
 290   do
 291     if test x"$ssl_root" = x"system-default"; then
 292       dnl Try the default include and library locations.
 293       SSL_INCLUDES=
 294     else
 295       dnl Try this specific root.
 296       SSL_INCLUDES=-I$ssl_root/include
 297       dnl It's OK to use -R directly because libtool will
 298       dnl interpret it for us.
 299       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 300     fi
 301
 302     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 303
 304     dnl Check whether the compiler can find the include files.  On
 305     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 306     dnl to find the includes in /usr/local/include.
 307
 308     ssl_found_includes=no
 309     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 310
 311     AC_MSG_CHECKING([for includes])
 312
 313     AC_TRY_CPP([#include <openssl/ssl.h>
 314 #include <openssl/rsa.h>
 315 ],
 316       AC_MSG_RESULT(found); ssl_found_includes=yes,
 317       AC_MSG_RESULT([not found])
 318     )
 319
 320     if test x"$ssl_found_includes" = xno; then
 321       continue
 322     fi
 323
 324     ssl_link_failure=no
 325
 326     dnl Make sure that the checks don't run afoul of the cache.  It
 327     dnl would be nicer to temporarily turn off the cache, but
 328     dnl apparently Autoconf doesn't allow that.
 329
 330     unset ac_cv_lib_crypto_RSA_new
 331     unset ac_cv_lib_ssl_SSL_new
 332
 333     dnl These checks need to be in this order, or you'll get a link
 334     dnl failure if you use a static libcrypto.a and libssl.a rather
 335     dnl than shared libraries.
 336
 337     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 338     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 339
 340     if test x"$ssl_link_failure" = xyes; then
 341       dnl One or both libs failed to link.
 342       continue
 343     fi
 344
 345     dnl The libraries link.  But we still need to check if the program
 346     dnl linked with those libraries under these settings with run.  On
 347     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 348     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 349     dnl executables that link, but fail to run.
 350
 351     dnl If we are cross-compiling, just assume that working linkage
 352     dnl implies working executable.
 353
 354     ssl_run_failure=no
 355
 356     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 357     AC_TRY_RUN([
 358 int RSA_new();
 359 int SSL_new();
 360 main(){return 0;}
 361 ],
 362       AC_MSG_RESULT(yes),
 363       AC_MSG_RESULT(no); ssl_run_failure=yes,
 364       AC_MSG_RESULT(cross)
 365     )
 366
 367     if test x"$ssl_run_failure" = xno; then
 368       ssl_success=yes
 369       break
 370     fi
 371   done
 372
 373   if test x"$ssl_success" = xyes; then
 374     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 375     dnl to use instead.
 376     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 377     AC_DEFINE(HAVE_SSL)
 378     AC_SUBST(SSL_INCLUDES)
 379     SSL_OBJ='gen_sslfunc$o'
 380     AC_SUBST(SSL_OBJ)
 381   else
 382     LDFLAGS=$wget_save_LDFLAGS
 383     LIBS=$wget_save_LIBS
 384
 385     dnl If linking with SSL was forced rather than auto-detected, then
 386     dnl bail out if SSL failed.
 387     if test x"$wget_force_ssl" = x"yes"; then
 388       exec >&2
 389       echo "ERROR: Failed to find OpenSSL libraries."
 390       exit 2
 391     fi
 392   fi
 393
 394   dnl Restore the compiler setting.
 395   CC=$wget_save_CC
 396
 397   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 398   dnl with SSL succeeded -- SSL includes will be handled using
 399   dnl @SSL_INCLUDES@.
 400   CPPFLAGS=$wget_save_CPPFLAGS
 401 fi
 402
 403 dnl
 404 dnl Find an md5 implementation.
 405 dnl
 406
 407 if test x"$wget_need_md5" = xyes
 408 then
 409   MD5_OBJ='gen-md5$o'
 410
 411   found_md5=no
 412
 413   dnl Check for the system MD5 library on Solaris.  We don't check for
 414   dnl something simple like "MD5Update" because there are a number of
 415   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 416   dnl specific to the Solaris MD5 library.
 417   if test x"$found_md5" = xno; then
 418     AC_CHECK_LIB(md5, md5_calc, [
 419       AC_DEFINE(HAVE_SOLARIS_MD5)
 420       LIBS="-lmd5 $LIBS"
 421       found_md5=yes
 422     ])
 423   fi
 424
 425   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 426   dnl implementation.
 427   if test x"$found_md5" = xno; then
 428     if test x"$ssl_success" = xyes; then
 429       AC_DEFINE(HAVE_OPENSSL_MD5)
 430       found_md5=yes
 431     fi
 432   fi
 433
 434   dnl If none of the above worked, use the one we ship with Wget.
 435   if test x"$found_md5" = xno; then
 436     AC_DEFINE(HAVE_BUILTIN_MD5)
 437     found_md5=yes
 438     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 439   fi
 440 fi
 441 AC_DEFINE(HAVE_MD5)
 442 AC_SUBST(MD5_OBJ)
 443
 444 dnl **********************************************************************
 445 dnl Checks for IPv6
 446 dnl **********************************************************************
 447
 448 dnl
 449 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 450 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 451 dnl don't use IPv6 or getaddrinfo.  If neither are specified, we test
 452 dnl whether it's possible to create an AF_INET6 socket and if yes, use
 453 dnl IPv6.
 454 dnl
 455
 456 ipv6=
 457 check_for_ipv6=no
 458 AC_ARG_ENABLE(ipv6,
 459   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 460   [case "${enable_ipv6}" in
 461   no)
 462     AC_MSG_NOTICE([Disabling IPv6 at user request])
 463     ipv6=no
 464     ;;
 465   *)
 466     ipv6=yes
 467     ;;
 468   esac],
 469   [check_for_ipv6=yes]
 470 )
 471
 472 if test "X$ipv6" = "Xyes" -o "X$check_for_ipv6" = "Xyes"; then
 473   AC_CHECK_FUNC(getaddrinfo,[
 474     AC_DEFINE([HAVE_GETADDRINFO], 1)
 475     GETADDRINFO_AI_ADDRCONFIG(
 476       AC_DEFINE(
 477         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 478         [Define if the system headers support the AI_ADDRCONFIG flag.]
 479       )
 480     )
 481     GETADDRINFO_AI_V4MAPPED(
 482       AC_DEFINE(
 483         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 484         [Define if the system headers support the AI_V4MAPPED flag.]
 485       )
 486     )
 487     GETADDRINFO_AI_ALL(
 488       AC_DEFINE(
 489         [HAVE_GETADDRINFO_AI_ALL], 1,
 490         [Define if the system headers support the AI_ALL flag.]
 491       )
 492     )
 493   ],[
 494     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 495     ipv6=no
 496   ])
 497 fi
 498
 499 if test "X$ipv6" = "Xyes" -o "X$check_for_ipv6" = "Xyes"; then
 500   PROTO_INET6(,[
 501     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 502     ipv6=no
 503   ])
 504 fi
 505
 506 if test "X$ipv6" = "Xyes" -o "X$check_for_ipv6" = "Xyes"; then
 507   TYPE_STRUCT_SOCKADDR_IN6([
 508     ipv6=yes
 509   ],[
 510     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 511     ipv6=no
 512   ])
 513   if test "X$ipv6" = "Xyes"; then
 514     MEMBER_SIN6_SCOPE_ID
 515   fi
 516 fi
 517
 518 if test "X$ipv6" = "Xyes"; then
 519   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 520 fi
 521
 522
 523 dnl
 524 dnl Set of available languages.
 525 dnl
 526 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 527
 528 dnl Originally this used to be static, looking like this:
 529 dnl     ALL_LINGUAS="cs de hr it ..."
 530 dnl The downside was that configure needed to be rebuilt whenever a
 531 dnl new language was added.
 532
 533 dnl internationalization macros
 534 WGET_WITH_NLS
 535
 536 dnl
 537 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 538 dnl Emacs cannot be found, look for XEmacs.
 539 dnl
 540
 541 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 542
 543 case "${MAKEINFO}" in
 544    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 545    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 546    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 547 esac
 548
 549 dnl
 550 dnl Find perl and pod2man
 551 dnl
 552
 553 AC_PATH_PROGS(PERL, perl5 perl, no)
 554 AC_PATH_PROG(POD2MAN, pod2man, no)
 555
 556 if test "x${POD2MAN}" = xno; then
 557   COMMENT_IF_NO_POD2MAN="# "
 558 else
 559   COMMENT_IF_NO_POD2MAN=
 560 fi
 561 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 562
 563 dnl
 564 dnl Create output
 565 dnl
 566 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 567            windows/Makefile],
 568 [WGET_PROCESS_PO
 569 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])