sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl
  19 dnl Process this file with autoconf to produce a configure script.
  20 dnl
  21
  22 AC_INIT(src/version.c)
  23 AC_PREREQ(2.12)
  24 AC_CONFIG_HEADER(src/config.h)
  25
  26 dnl
  27 dnl What version of Wget are we building?
  28 dnl
  29 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  30 echo "configuring for GNU Wget $VERSION"
  31 AC_SUBST(VERSION)
  32 PACKAGE=wget
  33 AC_SUBST(PACKAGE)
  34
  35 dnl
  36 dnl Get cannonical host
  37 dnl
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  40
  41 dnl
  42 dnl Process features.
  43 dnl
  44 AC_ARG_WITH(socks,
  45 [  --with-socks            use the socks library],
  46 [AC_DEFINE(HAVE_SOCKS)])
  47
  48 AC_ARG_WITH(ssl,
  49 [  --with-ssl[=SSL_ROOT]   link with libssl [in SSL_ROOT/lib] for https: support])
  50
  51 AC_ARG_ENABLE(opie,
  52 [  --disable-opie          disable support for opie or s/key FTP login],
  53 USE_OPIE=$enableval, USE_OPIE=yes)
  54 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  55
  56 AC_ARG_ENABLE(digest,
  57 [  --disable-digest        disable support for HTTP digest authorization],
  58 USE_DIGEST=$enableval, USE_DIGEST=yes)
  59 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  60
  61 AC_ARG_ENABLE(debug,
  62 [  --disable-debug         disable support for debugging output],
  63 DEBUG=$enableval, DEBUG=yes)
  64 test x"${DEBUG}" = xyes && AC_DEFINE(DEBUG)
  65
  66 case "${USE_OPIE}${USE_DIGEST}" in
  67 *yes*)
  68         MD5_OBJ='md5$o'
  69 esac
  70 if test x"$USE_OPIE" = xyes; then
  71   OPIE_OBJ='ftp-opie$o'
  72 fi
  73 AC_SUBST(MD5_OBJ)
  74 AC_SUBST(OPIE_OBJ)
  75
  76 dnl
  77 dnl Whether make sets $(MAKE)...
  78 dnl
  79 AC_PROG_MAKE_SET
  80
  81 dnl
  82 dnl Find a good install
  83 dnl
  84 AC_PROG_INSTALL
  85
  86 dnl
  87 dnl Configure our included libtool and make sure it's regenerated when needed
  88 dnl
  89 AM_PROG_LIBTOOL
  90 AC_SUBST(LIBTOOL_DEPS)
  91
  92 dnl
  93 dnl Find the compiler
  94 dnl
  95
  96 dnl We want these before the checks, so the checks can modify their values.
  97 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
  98 test -z "$CC" && cc_specified=yes
  99
 100 AC_PROG_CC
 101
 102 dnl
 103 dnl if the user hasn't specified CFLAGS, then
 104 dnl   if compiler is gcc, then use -O2 and some warning flags
 105 dnl   else use os-specific flags or -O
 106 dnl
 107 if test -n "$auto_cflags"; then
 108   if test -n "$GCC"; then
 109     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 110   else
 111     case "$host_os" in
 112       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 113       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 114       *)       CFLAGS="$CFLAGS -O" ;;
 115     esac
 116   fi
 117 fi
 118
 119 dnl
 120 dnl Handle AIX
 121 dnl
 122 AC_AIX
 123
 124 dnl
 125 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 126 dnl Might also be erelevant for DJGPP.
 127 dnl
 128 case "$host_os" in
 129   *win32) exeext='.exe';;
 130   *) exeext='';;
 131 esac
 132 AC_SUBST(exeext)
 133
 134 dnl
 135 dnl Check if we can handle prototypes.
 136 dnl
 137 AM_C_PROTOTYPES
 138
 139 dnl
 140 dnl Checks for typedefs, structures, and compiler characteristics.
 141 dnl
 142 AC_C_CONST
 143 AC_C_INLINE
 144 AC_TYPE_SIZE_T
 145 AC_TYPE_PID_T
 146 dnl #### This generates a warning.  What do I do to shut it up?
 147 AC_C_BIGENDIAN
 148
 149 # Check size of long.
 150 AC_CHECK_SIZEOF(long)
 151 AC_CHECK_SIZEOF(long long)
 152
 153 dnl
 154 dnl Checks for headers
 155 dnl
 156 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h)
 157 AC_CHECK_HEADERS(sys/select.h sys/utsname.h pwd.h signal.h)
 158 AC_HEADER_TIME
 159
 160 dnl
 161 dnl Return type of signal-handlers
 162 dnl
 163 AC_TYPE_SIGNAL
 164
 165 dnl
 166 dnl Check for struct utimbuf
 167 WGET_STRUCT_UTIMBUF
 168
 169 dnl
 170 dnl Checks for library functions.
 171 dnl
 172 AC_FUNC_ALLOCA
 173 AC_FUNC_MMAP
 174 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp)
 175 AC_CHECK_FUNCS(gettimeofday mktime strptime)
 176 AC_CHECK_FUNCS(strerror snprintf vsnprintf select signal symlink access isatty)
 177 AC_CHECK_FUNCS(uname gethostname)
 178
 179 AC_CHECK_FUNCS(gethostbyname, [], [
 180   AC_CHECK_LIB(nsl, gethostbyname)
 181 ])
 182
 183 dnl
 184 dnl Checks for libraries.
 185 dnl
 186
 187 AC_CHECK_LIB(socket, socket)
 188
 189 dnl #### This appears to be deficient with later versions of SOCKS.
 190 if test "x${with_socks}" = xyes
 191 then
 192   AC_CHECK_LIB(resolv, main)
 193   AC_CHECK_LIB(socks, Rconnect)
 194 fi
 195
 196 dnl If --with-ssl was specified, make sure we can link with the
 197 dnl OpenSSL libs.  We should probably auto-detect this by default.
 198
 199 if test x"$with_ssl" != x -a x"$with_ssl" != x"no"; then
 200   if test x"$with_ssl" = x"yes"; then
 201     dnl OpenSSL's default install location is "/usr/local/ssl".  We also
 202     dnl allow /usr/local for regular-style install, and /usr for Linux
 203     dnl stuff.
 204     ssl_all_roots="default /usr/local/ssl /usr/local /opt"
 205   else
 206     dnl Root has been kindly provided by the user.
 207     ssl_all_roots=$with_ssl
 208   fi
 209
 210   wget_save_LIBS=$LIBS
 211   wget_save_LDFLAGS=$LDFLAGS
 212   wget_save_CC=$CC
 213
 214   dnl Use libtool for OpenSSL tests to handle the "-R<rpath>" option.
 215   CC="$SHELL ./libtool $CC"
 216
 217   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 218   dnl shared library doesn't record its dependency on libdl, so we
 219   dnl need to check for it ourselves so we won't fail to link due to a
 220   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 221   dnl shl_load().
 222   AC_CHECK_LIB(dl,dlopen)
 223   AC_CHECK_LIB(dl,shl_load)
 224
 225   ssl_linked=no
 226
 227   dnl Now try to find SSL libraries in each of the likely SSL roots.
 228   for ssl_root in $ssl_all_roots
 229   do
 230     if test x"$ssl_root" = xdefault; then
 231       dnl Try the default library locations.
 232       SSL_INCLUDES=
 233     else
 234       dnl Try this specific root.
 235       SSL_INCLUDES=-I$ssl_root/include
 236       dnl It's OK to use -R directly because libtool will
 237       dnl interpret it for us.
 238       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 239     fi
 240
 241     ssl_link_failure=no
 242
 243     AC_MSG_RESULT(["Looking for SSL libraries in $ssl_root"])
 244
 245     dnl Make sure that the checks don't run afoul of the cache.  It
 246     dnl would be nicer to temporarily turn off the cache, but
 247     dnl apparently Autoconf doesn't allow that.
 248
 249     unset ac_cv_lib_crypto_RSA_new
 250     unset ac_cv_lib_ssl_SSL_new
 251
 252     dnl These checks need to be in this order, or you'll get a link
 253     dnl failure if you use a static libcrypto.a and libssl.a rather
 254     dnl than shared libraries.
 255
 256     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 257     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 258
 259     dnl If ssl_link_failure is still no, the libraries link.  But we
 260     dnl still need to check if the program linked with those libraries
 261     dnl under these settings with run.  On some systems (Solaris), Gcc
 262     dnl adds -L/usr/local/lib to the linking line, but fails to add
 263     dnl -R/usr/local/lib, thus creating executables that link, but
 264     dnl fail to run.
 265
 266     dnl If we are cross-compiling, just assume that working linkage
 267     dnl implies working executable.
 268
 269     if test x"$ssl_link_failure" = xno; then
 270       dnl Now try to run the thing.
 271       AC_MSG_CHECKING("whether SSL libs are resolved at runtime")
 272       AC_TRY_RUN([
 273 int RSA_new();
 274 int SSL_new();
 275 main(){return 0;}
 276 ],
 277         AC_MSG_RESULT("yes"),
 278         AC_MSG_RESULT("no"); ssl_link_failure=yes,
 279         AC_MSG_RESULT("cross"))
 280     fi
 281
 282     if test x"$ssl_link_failure" = xno; then
 283       dnl This echo doesn't look right, but I'm not sure what to use
 284       dnl instead.
 285       AC_MSG_RESULT("Compiling in support for SSL in $ssl_root")
 286       AC_DEFINE(HAVE_SSL)
 287       AC_SUBST(SSL_INCLUDES)
 288       SSL_OBJ='gen_sslfunc$o'
 289       AC_SUBST(SSL_OBJ)
 290       ssl_linked=yes
 291       break
 292     fi
 293   done
 294
 295   if test x"$ssl_linked" = xno; then
 296     LD_FLAGS=$wget_save_LDFLAGS
 297     LIBS=$wget_save_LIBS
 298
 299     dnl Perhaps we should abort here.  Dan argues that configure
 300     dnl scripts shouldn't abort out of principle, but on the other
 301     dnl hand remember that the user explicitly requested linking with
 302     dnl SSL.
 303
 304     dnl IMHO there should be a way to specify whether SSL should be
 305     dnl avoided, auto-detected, or required, defaulting to
 306     dnl `autodetect'.  Only in the `require' mode the script would
 307     dnl abort if SSL is not found.
 308     echo
 309     echo "WARNING: Failed to link with OpenSSL libraries in $ssl_root/lib."
 310     echo "         Wget will be built without support for https://... URLs."
 311     echo
 312   fi
 313
 314   CC=$wget_save_CC
 315 fi
 316
 317 dnl
 318 dnl Set of available languages.
 319 dnl
 320 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//')`
 321
 322 dnl Originally this used to be static, looking like this:
 323 dnl     ALL_LINGUAS="cs de hr it ..."
 324 dnl The downside was that configure needed to be rebuilt whenever a
 325 dnl new language was added.
 326
 327 dnl internationalization macros
 328 WGET_WITH_NLS
 329
 330 dnl
 331 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 332 dnl Emacs cannot be found, look for XEmacs.
 333 dnl
 334
 335 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 336
 337 case "${MAKEINFO}" in
 338    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 339    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 340    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 341 esac
 342
 343 dnl
 344 dnl Find perl and pod2man
 345 dnl
 346
 347 AC_PATH_PROGS(PERL, perl5 perl, no)
 348 AC_PATH_PROG(POD2MAN, pod2man, no)
 349
 350 if test "x${POD2MAN}" = xno; then
 351   COMMENT_IF_NO_POD2MAN="# "
 352 else
 353   COMMENT_IF_NO_POD2MAN=
 354 fi
 355 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 356
 357 dnl
 358 dnl Create output
 359 dnl
 360 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 361            windows/Makefile],
 362 [WGET_PROCESS_PO
 363 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])