sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  50                    [Define to be the name of the operating system.])
  51
  52 dnl
  53 dnl Process features.
  54 dnl
  55 AC_ARG_WITH(socks,
  56   [  --with-socks            use the socks library],
  57   [AC_DEFINE([HAVE_SOCKS], [],
  58              [Define if you wish to compile with socks support.])]
  59 )
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  63   --without-ssl           disable SSL autodetection]])
  64
  65 AC_ARG_ENABLE(opie,
  66 [  --disable-opie          disable support for opie or s/key FTP login],
  67 USE_OPIE=$enableval, USE_OPIE=yes)
  68 test x"${USE_OPIE}" = xyes && AC_DEFINE([USE_OPIE], [],
  69    [Define if you want the Opie support for FTP compiled in.])
  70
  71 AC_ARG_ENABLE(digest,
  72 [  --disable-digest        disable support for HTTP digest authorization],
  73 USE_DIGEST=$enableval, USE_DIGEST=yes)
  74 test x"${USE_DIGEST}" = xyes && AC_DEFINE([USE_DIGEST], [],
  75    [Define if you want the HTTP Digest Authorization compiled in.])
  76
  77 AC_ARG_ENABLE(debug,
  78 [  --disable-debug         disable support for debugging output],
  79 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  80 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], [],
  81    [Define if you want the debug output support compiled in.])
  82
  83 wget_need_md5=no
  84
  85 case "${USE_OPIE}${USE_DIGEST}" in
  86 *yes*)
  87         wget_need_md5=yes
  88 esac
  89 if test x"$USE_OPIE" = xyes; then
  90   OPIE_OBJ='ftp-opie$o'
  91 fi
  92 AC_SUBST(OPIE_OBJ)
  93
  94 dnl
  95 dnl Whether make sets $(MAKE)...
  96 dnl
  97 AC_PROG_MAKE_SET
  98
  99 dnl
 100 dnl Find a good install
 101 dnl
 102 AC_PROG_INSTALL
 103
 104 dnl
 105 dnl Find the compiler
 106 dnl
 107
 108 dnl We want these before the checks, so the checks can modify their values.
 109 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 110 test -z "$CC" && cc_specified=yes
 111
 112 AC_PROG_CC
 113
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then use -O2 and some warning flags
 117 dnl   else use os-specific flags or -O
 118 dnl
 119 if test -n "$auto_cflags"; then
 120   if test -n "$GCC"; then
 121     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 122   else
 123     case "$host_os" in
 124       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 125       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 126       *)       CFLAGS="$CFLAGS -O" ;;
 127     esac
 128   fi
 129 fi
 130
 131 dnl
 132 dnl Handle AIX
 133 dnl
 134 AC_AIX
 135
 136 dnl
 137 dnl Configure our included libtool and make sure it's regenerated when needed
 138 dnl
 139 AC_PROG_LIBTOOL
 140 AC_SUBST(LIBTOOL_DEPS)
 141
 142 dnl
 143 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 144 dnl Might also be erelevant for DJGPP.
 145 dnl
 146 case "$host_os" in
 147   *win32) exeext='.exe';;
 148   *) exeext='';;
 149 esac
 150 AC_SUBST(exeext)
 151
 152 dnl
 153 dnl Check if we can handle prototypes.
 154 dnl
 155 AM_C_PROTOTYPES
 156
 157 dnl
 158 dnl Checks for basic compiler characteristics.
 159 dnl
 160 AC_C_CONST
 161 AC_C_INLINE
 162 AC_C_VOLATILE
 163 AC_C_BIGENDIAN
 164
 165 dnl
 166 dnl Checks for headers
 167 dnl
 168 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h)
 169 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 170 AC_CHECK_HEADERS(inttypes.h signal.h setjmp.h pwd.h)
 171 AC_HEADER_TIME
 172
 173 dnl
 174 dnl Check integral type sizes.
 175 dnl
 176 AC_CHECK_SIZEOF(short)
 177 AC_CHECK_SIZEOF(int)
 178 AC_CHECK_SIZEOF(long)
 179 AC_CHECK_SIZEOF(long long)
 180
 181 dnl
 182 dnl Checks for non-universal or system-specific types.
 183 dnl
 184 AC_TYPE_SIZE_T
 185 AC_TYPE_PID_T
 186 AC_CHECK_TYPES(uint32_t)
 187 AC_TYPE_SIGNAL
 188 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 189 #include <stdio.h>
 190 #include <sys/types.h>
 191 #if HAVE_INTTYPES_H
 192 # include <inttypes.h>
 193 #endif
 194 #ifdef HAVE_SIGNAL_H
 195 # include <signal.h>
 196 #endif
 197 ])
 198
 199 dnl
 200 dnl Checks for library functions.
 201 dnl
 202 AC_FUNC_ALLOCA
 203 AC_FUNC_MMAP
 204 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 205 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 206 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 207
 208 dnl
 209 dnl Call Wget's local macros defined in aclocal.
 210 dnl
 211 WGET_STRUCT_UTIMBUF
 212 WGET_SOCKLEN_T
 213 WGET_FNMATCH
 214 WGET_NANOSLEEP
 215 WGET_NSL_SOCKET
 216
 217 dnl
 218 dnl Check if we need to compile in getopt.c.
 219 dnl
 220 AC_CHECK_FUNC(getopt_long, [], [
 221   GETOPT_OBJ='getopt$o'
 222 ])
 223 AC_SUBST(GETOPT_OBJ)
 224
 225 dnl
 226 dnl Checks for libraries.
 227 dnl
 228
 229 dnl #### This appears to be deficient with later versions of SOCKS.
 230 if test "x${with_socks}" = xyes
 231 then
 232   AC_CHECK_LIB(resolv, main)
 233   AC_CHECK_LIB(socks, Rconnect)
 234 fi
 235
 236 dnl $with_ssl can be one of:
 237 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 238 dnl  - "yes", meaning link with SSL or bail out.
 239 dnl  - "no", meaning don't link with SSL.
 240 dnl  - anything else, meaning use that as the SSL root, and bail out
 241 dnl    if it fails.
 242
 243 if test x"$with_ssl" = x; then
 244   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 245   dnl implements the "auto-detect by default" feature.  If you want to
 246   dnl change this to "ignore SSL by default", change "auto" to "no".
 247   with_ssl=auto
 248 fi
 249
 250 dnl Detection of OpenSSL is much hairier than the detection of other
 251 dnl libraries because OpenSSL can be compiled as a third-party
 252 dnl library, which means it will not be found without additional
 253 dnl linker magic.  It would be really nice to rework this check into
 254 dnl an AC_DEFUN so that we can reuse it for other third-party
 255 dnl libraries.
 256
 257 if test x"$with_ssl" != x"no"; then
 258
 259   wget_force_ssl=no
 260   if test x"$with_ssl" = x"yes"; then
 261     wget_force_ssl=yes
 262   fi
 263
 264   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 265     dnl OpenSSL's root was not specified, so we have to guess.  First
 266     dnl try the system default location, then "/usr/local/ssl" (where
 267     dnl OpenSSL installs by default), then "/usr/local" (traditional
 268     dnl choice for installation root), then "/opt".
 269     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 270   else
 271     dnl Root has been specified by the user.
 272     ssl_all_roots=$with_ssl
 273     wget_force_ssl=yes
 274   fi
 275
 276   wget_save_CC=$CC
 277   wget_save_LIBS=$LIBS
 278   wget_save_LDFLAGS=$LDFLAGS
 279   wget_save_CPPFLAGS=$CPPFLAGS
 280
 281   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 282   dnl without having to know how the linker handles it.
 283   CC="$SHELL ./libtool $CC"
 284
 285   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 286   dnl shared library doesn't record its dependency on libdl, so we
 287   dnl need to check for it ourselves so we won't fail to link due to a
 288   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 289   dnl shl_load().
 290   AC_CHECK_LIB(dl,dlopen)
 291   AC_CHECK_LIB(dl,shl_load)
 292
 293   ssl_success=no
 294
 295   dnl Now try to find SSL libraries in each of the likely SSL roots.
 296   for ssl_root in $ssl_all_roots
 297   do
 298     if test x"$ssl_root" = x"system-default"; then
 299       dnl Try the default include and library locations.
 300       SSL_INCLUDES=
 301     else
 302       dnl Try this specific root.
 303       SSL_INCLUDES=-I$ssl_root/include
 304       dnl It's OK to use -R directly because libtool will
 305       dnl interpret it for us.
 306       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 307     fi
 308
 309     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 310
 311     dnl Check whether the compiler can find the include files.  On
 312     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 313     dnl to find the includes in /usr/local/include.
 314
 315     ssl_found_includes=no
 316     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 317
 318     AC_MSG_CHECKING([for includes])
 319
 320     AC_TRY_CPP([#include <openssl/ssl.h>
 321 #include <openssl/rsa.h>
 322 ],
 323       AC_MSG_RESULT(found); ssl_found_includes=yes,
 324       AC_MSG_RESULT([not found])
 325     )
 326
 327     if test x"$ssl_found_includes" = xno; then
 328       continue
 329     fi
 330
 331     ssl_link_failure=no
 332
 333     dnl Make sure that the checks don't run afoul of the cache.  It
 334     dnl would be nicer to temporarily turn off the cache, but
 335     dnl apparently Autoconf doesn't allow that.
 336
 337     unset ac_cv_lib_crypto_RSA_new
 338     unset ac_cv_lib_ssl_SSL_new
 339
 340     dnl These checks need to be in this order, or you'll get a link
 341     dnl failure if you use a static libcrypto.a and libssl.a rather
 342     dnl than shared libraries.
 343
 344     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 345     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 346
 347     if test x"$ssl_link_failure" = xyes; then
 348       dnl One or both libs failed to link.
 349       continue
 350     fi
 351
 352     dnl The libraries link.  But we still need to check if the program
 353     dnl linked with those libraries under these settings with run.  On
 354     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 355     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 356     dnl executables that link, but fail to run.
 357
 358     dnl If we are cross-compiling, just assume that working linkage
 359     dnl implies working executable.
 360
 361     ssl_run_failure=no
 362
 363     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 364     AC_TRY_RUN([
 365 int RSA_new();
 366 int SSL_new();
 367 main(){return 0;}
 368 ],
 369       AC_MSG_RESULT(yes),
 370       AC_MSG_RESULT(no); ssl_run_failure=yes,
 371       AC_MSG_RESULT(cross)
 372     )
 373
 374     if test x"$ssl_run_failure" = xno; then
 375       ssl_success=yes
 376       break
 377     fi
 378   done
 379
 380   if test x"$ssl_success" = xyes; then
 381     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 382     AC_DEFINE([HAVE_SSL], [],
 383               [Define if SSL support should be compiled in.])
 384     AC_SUBST(SSL_INCLUDES)
 385     SSL_OBJ='gen_sslfunc$o'
 386     AC_SUBST(SSL_OBJ)
 387   else
 388     LDFLAGS=$wget_save_LDFLAGS
 389     LIBS=$wget_save_LIBS
 390
 391     dnl If linking with SSL was forced rather than auto-detected, then
 392     dnl bail out if SSL failed.
 393     if test x"$wget_force_ssl" = x"yes"; then
 394       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 395     fi
 396   fi
 397
 398   dnl Restore the compiler setting.
 399   CC=$wget_save_CC
 400
 401   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 402   dnl with SSL succeeded -- SSL includes will be handled using
 403   dnl @SSL_INCLUDES@.
 404   CPPFLAGS=$wget_save_CPPFLAGS
 405 fi
 406
 407 dnl
 408 dnl Find an md5 implementation.
 409 dnl
 410
 411 if test x"$wget_need_md5" = xyes
 412 then
 413   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 414   dnl manipulate MD5_OBJ from the defun.
 415
 416   MD5_OBJ='gen-md5$o'
 417   found_md5=no
 418
 419   dnl Check for the system MD5 library on Solaris.  We don't check for
 420   dnl something simple like "MD5Update" because there are a number of
 421   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 422   dnl specific to the Solaris MD5 library.
 423   if test x"$found_md5" = xno; then
 424     AC_CHECK_LIB(md5, md5_calc, [
 425       dnl Some installations have bogus <md5.h> in the compiler's
 426       dnl include path, making the system md5 library useless.
 427       AC_MSG_CHECKING([whether md5.h can be included])
 428       AC_COMPILE_IFELSE([#include <md5.h>
 429                         ], [
 430         AC_MSG_RESULT(yes)
 431         AC_DEFINE([HAVE_SOLARIS_MD5], [], [Define to use Solaris MD5.])
 432         LIBS="-lmd5 $LIBS"
 433         found_md5=yes
 434         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 435       ], [AC_MSG_RESULT(no)])
 436     ])
 437   fi
 438
 439   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 440   dnl implementation.
 441   if test x"$found_md5" = xno; then
 442     if test x"$ssl_success" = xyes; then
 443       AC_DEFINE([HAVE_OPENSSL_MD5], [], [Define to use OpenSSL MD5.])
 444       found_md5=yes
 445       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 446     fi
 447   fi
 448
 449   dnl If none of the above worked, use the one we ship with Wget.
 450   if test x"$found_md5" = xno; then
 451     AC_DEFINE([HAVE_BUILTIN_MD5], [], [Define to use built-in MD5.])
 452     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 453     found_md5=yes
 454     AC_MSG_NOTICE([using the GNU MD5 implementation])
 455   fi
 456 fi
 457 AC_DEFINE([HAVE_MD5], [], [Define if we're compiling support for MD5.])
 458 AC_SUBST(MD5_OBJ)
 459
 460 dnl **********************************************************************
 461 dnl Checks for IPv6
 462 dnl **********************************************************************
 463
 464 dnl
 465 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 466 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 467 dnl don't use IPv6 or getaddrinfo.
 468 dnl
 469
 470 ipv6=
 471 check_for_ipv6=no
 472 AC_ARG_ENABLE(ipv6,
 473   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 474   [case "${enable_ipv6}" in
 475   no)
 476     AC_MSG_NOTICE([disabling IPv6 at user request])
 477     ipv6=no
 478     ;;
 479   *)
 480     ipv6=yes
 481     ;;
 482   esac],
 483   dnl If unspecified, check for IPv6 and use it where available.
 484   [check_for_ipv6=yes]
 485 )
 486
 487 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 488   AC_CHECK_FUNCS(getaddrinfo,[
 489     GETADDRINFO_AI_ADDRCONFIG(
 490       AC_DEFINE(
 491         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 492         [Define if the system headers support the AI_ADDRCONFIG flag.]
 493       )
 494     )
 495     GETADDRINFO_AI_V4MAPPED(
 496       AC_DEFINE(
 497         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 498         [Define if the system headers support the AI_V4MAPPED flag.]
 499       )
 500     )
 501     GETADDRINFO_AI_ALL(
 502       AC_DEFINE(
 503         [HAVE_GETADDRINFO_AI_ALL], 1,
 504         [Define if the system headers support the AI_ALL flag.]
 505       )
 506     )
 507   ],[
 508     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 509     ipv6=no
 510   ])
 511 fi
 512
 513 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 514   PROTO_INET6(,[
 515     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 516     ipv6=no
 517   ])
 518 fi
 519
 520 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 521   TYPE_STRUCT_SOCKADDR_IN6([
 522     ipv6=yes
 523   ],[
 524     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 525     ipv6=no
 526   ])
 527   if test "X$ipv6" = "Xyes"; then
 528     MEMBER_SIN6_SCOPE_ID
 529   fi
 530 fi
 531
 532 if test "X$ipv6" = "Xyes"; then
 533   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 534 fi
 535
 536
 537 dnl
 538 dnl Set of available languages.
 539 dnl
 540 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 541
 542 dnl Originally this used to be static, looking like this:
 543 dnl     ALL_LINGUAS="cs de hr it ..."
 544 dnl The downside was that configure needed to be rebuilt whenever a
 545 dnl new language was added.
 546
 547 dnl internationalization macros
 548 WGET_WITH_NLS
 549
 550 dnl
 551 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 552 dnl Emacs cannot be found, look for XEmacs.
 553 dnl
 554
 555 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 556
 557 case "${MAKEINFO}" in
 558    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 559    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 560    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 561 esac
 562
 563 dnl
 564 dnl Find perl and pod2man
 565 dnl
 566
 567 AC_PATH_PROGS(PERL, perl5 perl, no)
 568 AC_PATH_PROG(POD2MAN, pod2man, no)
 569
 570 if test "x${POD2MAN}" = xno; then
 571   COMMENT_IF_NO_POD2MAN="# "
 572 else
 573   COMMENT_IF_NO_POD2MAN=
 574 fi
 575 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 576
 577 dnl
 578 dnl Create output
 579 dnl
 580 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 581            windows/Makefile],
 582 [WGET_PROCESS_PO
 583 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])