sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55   [  --with-socks            use the socks library],
  56   [AC_DEFINE([HAVE_SOCKS], 1,
  57              [Define if you wish to compile with socks support.])]
  58 )
  59
  60 AC_ARG_WITH(ssl,
  61 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  62   --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 USE_OPIE=$enableval, USE_OPIE=yes)
  67 test x"${USE_OPIE}" = xyes && AC_DEFINE([USE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 USE_DIGEST=$enableval, USE_DIGEST=yes)
  73 test x"${USE_DIGEST}" = xyes && AC_DEFINE([USE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(debug,
  77 [  --disable-debug         disable support for debugging output],
  78 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  79 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  80    [Define if you want the debug output support compiled in.])
  81
  82 wget_need_md5=no
  83
  84 case "${USE_OPIE}${USE_DIGEST}" in
  85 *yes*)
  86         wget_need_md5=yes
  87 esac
  88 if test x"$USE_OPIE" = xyes; then
  89   OPIE_OBJ='ftp-opie$o'
  90 fi
  91 AC_SUBST(OPIE_OBJ)
  92
  93 dnl
  94 dnl Whether make sets $(MAKE)...
  95 dnl
  96 AC_PROG_MAKE_SET
  97
  98 dnl
  99 dnl Find a good install
 100 dnl
 101 AC_PROG_INSTALL
 102
 103 dnl
 104 dnl Find the compiler
 105 dnl
 106
 107 dnl We want these before the checks, so the checks can modify their values.
 108 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 109 test -z "$CC" && cc_specified=yes
 110
 111 AC_PROG_CC
 112 AC_AIX
 113 AM_PROG_CC_STDC
 114
 115 dnl Turn on optimization by default.  Specifically:
 116 dnl
 117 dnl if the user hasn't specified CFLAGS, then
 118 dnl   if compiler is gcc, then
 119 dnl     use -O2 and some warning flags
 120 dnl   else
 121 dnl     use os-specific flags or -O
 122 if test -n "$auto_cflags"; then
 123   if test -n "$GCC"; then
 124     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 125   else
 126     case "$host_os" in
 127       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 128       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 129       *)       CFLAGS="$CFLAGS -O" ;;
 130     esac
 131   fi
 132 fi
 133
 134 dnl
 135 dnl Configure our included libtool and make sure it's regenerated when needed
 136 dnl
 137 AC_PROG_LIBTOOL
 138 AC_SUBST(LIBTOOL_DEPS)
 139
 140 dnl
 141 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 142 dnl Might also be erelevant for DJGPP.
 143 dnl
 144 case "$host_os" in
 145   *win32) exeext='.exe';;
 146   *) exeext='';;
 147 esac
 148 AC_SUBST(exeext)
 149
 150 dnl
 151 dnl Checks for basic compiler characteristics.
 152 dnl
 153 AC_C_CONST
 154 AC_C_INLINE
 155 AC_C_VOLATILE
 156 AC_C_BIGENDIAN
 157 AC_C_PROTOTYPES
 158
 159 if test x"$am_cv_prog_cc_stdc" != xno; then
 160   true
 161   AC_SUBST(U, [])
 162   AC_SUBST(ANSI2KNR, [])
 163 else
 164   AC_SUBST(U, [_])
 165   AC_SUBST(ANSI2KNR, [./ansi2knr])
 166 fi
 167
 168 dnl
 169 dnl Checks for header files that might be missing.
 170 dnl
 171
 172 dnl Check for basic headers, even those we assume the presence of.
 173 dnl This is because Autoconf default includes check for STDC_HEADERS,
 174 dnl HAVE_SYS_TYPES_H, etc. before including them.
 175 AC_HEADER_STDC
 176 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 177 dnl Now check for the others.
 178 AC_CHECK_HEADERS(string.h strings.h stdarg.h unistd.h sys/time.h)
 179 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 180 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 181 AC_HEADER_TIME
 182
 183 dnl
 184 dnl Check integral type sizes.
 185 dnl
 186 AC_CHECK_SIZEOF(short)
 187 AC_CHECK_SIZEOF(int)
 188 AC_CHECK_SIZEOF(long)
 189 AC_CHECK_SIZEOF(long long)
 190
 191 dnl
 192 dnl Checks for non-universal or system-specific types.
 193 dnl
 194 AC_TYPE_SIZE_T
 195 AC_TYPE_PID_T
 196 AC_CHECK_TYPES(uint32_t)
 197 AC_TYPE_SIGNAL
 198 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 199 #include <stdio.h>
 200 #include <sys/types.h>
 201 #if HAVE_INTTYPES_H
 202 # include <inttypes.h>
 203 #endif
 204 #ifdef HAVE_SIGNAL_H
 205 # include <signal.h>
 206 #endif
 207 ])
 208
 209 dnl
 210 dnl Checks for library functions.
 211 dnl
 212 AC_FUNC_ALLOCA
 213 AC_FUNC_MMAP
 214 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 215 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 216 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 217
 218 dnl
 219 dnl Call Wget's local macros defined in aclocal.
 220 dnl
 221 WGET_STRUCT_UTIMBUF
 222 WGET_SOCKLEN_T
 223 WGET_FNMATCH
 224 WGET_NANOSLEEP
 225 WGET_NSL_SOCKET
 226
 227 dnl
 228 dnl Check if we need to compile in getopt.c.
 229 dnl
 230 AC_CHECK_FUNC(getopt_long, [], [
 231   GETOPT_OBJ='getopt$o'
 232 ])
 233 AC_SUBST(GETOPT_OBJ)
 234
 235 dnl
 236 dnl Checks for libraries.
 237 dnl
 238
 239 dnl #### This appears to be deficient with later versions of SOCKS.
 240 if test "x${with_socks}" = xyes
 241 then
 242   AC_CHECK_LIB(resolv, main)
 243   AC_CHECK_LIB(socks, Rconnect)
 244 fi
 245
 246 dnl $with_ssl can be one of:
 247 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 248 dnl  - "yes", meaning link with SSL or bail out.
 249 dnl  - "no", meaning don't link with SSL.
 250 dnl  - anything else, meaning use that as the SSL root, and bail out
 251 dnl    if it fails.
 252
 253 if test x"$with_ssl" = x; then
 254   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 255   dnl implements the "auto-detect by default" feature.  If you want to
 256   dnl change this to "ignore SSL by default", change "auto" to "no".
 257   with_ssl=auto
 258 fi
 259
 260 dnl Detection of OpenSSL is much hairier than the detection of other
 261 dnl libraries because OpenSSL can be compiled as a third-party
 262 dnl library, which means it will not be found without additional
 263 dnl linker magic.  It would be really nice to rework this check into
 264 dnl an AC_DEFUN so that we can reuse it for other third-party
 265 dnl libraries.
 266
 267 if test x"$with_ssl" != x"no"; then
 268
 269   wget_force_ssl=no
 270   if test x"$with_ssl" = x"yes"; then
 271     wget_force_ssl=yes
 272   fi
 273
 274   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 275     dnl OpenSSL's root was not specified, so we have to guess.  First
 276     dnl try the system default location, then "/usr/local/ssl" (where
 277     dnl OpenSSL installs by default), then "/usr/local" (traditional
 278     dnl choice for installation root), then "/opt".
 279     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 280   else
 281     dnl Root has been specified by the user.
 282     ssl_all_roots=$with_ssl
 283     wget_force_ssl=yes
 284   fi
 285
 286   wget_save_CC=$CC
 287   wget_save_LIBS=$LIBS
 288   wget_save_LDFLAGS=$LDFLAGS
 289   wget_save_CPPFLAGS=$CPPFLAGS
 290
 291   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 292   dnl without having to know how the linker handles it.
 293   CC="$SHELL ./libtool $CC"
 294
 295   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 296   dnl shared library doesn't record its dependency on libdl, so we
 297   dnl need to check for it ourselves so we won't fail to link due to a
 298   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 299   dnl shl_load().
 300   AC_CHECK_LIB(dl,dlopen)
 301   AC_CHECK_LIB(dl,shl_load)
 302
 303   ssl_success=no
 304
 305   dnl Now try to find SSL libraries in each of the likely SSL roots.
 306   for ssl_root in $ssl_all_roots
 307   do
 308     if test x"$ssl_root" = x"system-default"; then
 309       dnl Try the default include and library locations.
 310       SSL_INCLUDES=
 311     else
 312       dnl Try this specific root.
 313       SSL_INCLUDES=-I$ssl_root/include
 314       dnl It's OK to use -R directly because libtool will
 315       dnl interpret it for us.
 316       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 317     fi
 318
 319     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 320
 321     dnl Check whether the compiler can find the include files.  On
 322     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 323     dnl to find the includes in /usr/local/include.
 324
 325     ssl_found_includes=no
 326     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 327
 328     AC_MSG_CHECKING([for includes])
 329
 330     AC_TRY_CPP([#include <openssl/ssl.h>
 331 #include <openssl/rsa.h>
 332 ],
 333       AC_MSG_RESULT(found); ssl_found_includes=yes,
 334       AC_MSG_RESULT([not found])
 335     )
 336
 337     if test x"$ssl_found_includes" = xno; then
 338       continue
 339     fi
 340
 341     ssl_link_failure=no
 342
 343     dnl Make sure that the checks don't run afoul of the cache.  It
 344     dnl would be nicer to temporarily turn off the cache, but
 345     dnl apparently Autoconf doesn't allow that.
 346
 347     unset ac_cv_lib_crypto_RSA_new
 348     unset ac_cv_lib_ssl_SSL_new
 349
 350     dnl These checks need to be in this order, or you'll get a link
 351     dnl failure if you use a static libcrypto.a and libssl.a rather
 352     dnl than shared libraries.
 353
 354     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 355     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 356
 357     if test x"$ssl_link_failure" = xyes; then
 358       dnl One or both libs failed to link.
 359       continue
 360     fi
 361
 362     dnl The libraries link.  But we still need to check if the program
 363     dnl linked with those libraries under these settings with run.  On
 364     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 365     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 366     dnl executables that link, but fail to run.
 367
 368     dnl If we are cross-compiling, just assume that working linkage
 369     dnl implies working executable.
 370
 371     ssl_run_failure=no
 372
 373     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 374     AC_TRY_RUN([
 375 int RSA_new();
 376 int SSL_new();
 377 main(){return 0;}
 378 ],
 379       AC_MSG_RESULT(yes),
 380       AC_MSG_RESULT(no); ssl_run_failure=yes,
 381       AC_MSG_RESULT(cross)
 382     )
 383
 384     if test x"$ssl_run_failure" = xno; then
 385       ssl_success=yes
 386       break
 387     fi
 388   done
 389
 390   if test x"$ssl_success" = xyes; then
 391     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 392     AC_DEFINE([HAVE_SSL], 1,
 393               [Define if SSL support should be compiled in.])
 394     AC_SUBST(SSL_INCLUDES)
 395     SSL_OBJ='gen_sslfunc$o'
 396     AC_SUBST(SSL_OBJ)
 397   else
 398     LDFLAGS=$wget_save_LDFLAGS
 399     LIBS=$wget_save_LIBS
 400
 401     dnl If linking with SSL was forced rather than auto-detected, then
 402     dnl bail out if SSL failed.
 403     if test x"$wget_force_ssl" = x"yes"; then
 404       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 405     fi
 406   fi
 407
 408   dnl Restore the compiler setting.
 409   CC=$wget_save_CC
 410
 411   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 412   dnl with SSL succeeded -- SSL includes will be handled using
 413   dnl @SSL_INCLUDES@.
 414   CPPFLAGS=$wget_save_CPPFLAGS
 415 fi
 416
 417 dnl
 418 dnl Find an md5 implementation.
 419 dnl
 420
 421 if test x"$wget_need_md5" = xyes
 422 then
 423   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 424   dnl manipulate MD5_OBJ from the defun.
 425
 426   MD5_OBJ='gen-md5$o'
 427   found_md5=no
 428
 429   dnl Check for the system MD5 library on Solaris.  We don't check for
 430   dnl something simple like "MD5Update" because there are a number of
 431   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 432   dnl specific to the Solaris MD5 library.
 433   if test x"$found_md5" = xno; then
 434     AC_CHECK_LIB(md5, md5_calc, [
 435       dnl Some installations have bogus <md5.h> in the compiler's
 436       dnl include path, making the system md5 library useless.
 437       AC_MSG_CHECKING([whether md5.h can be included])
 438       AC_COMPILE_IFELSE([#include <md5.h>
 439                         ], [
 440         AC_MSG_RESULT(yes)
 441         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 442         LIBS="-lmd5 $LIBS"
 443         found_md5=yes
 444         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 445       ], [AC_MSG_RESULT(no)])
 446     ])
 447   fi
 448
 449   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 450   dnl implementation.
 451   if test x"$found_md5" = xno; then
 452     if test x"$ssl_success" = xyes; then
 453       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 454       found_md5=yes
 455       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 456     fi
 457   fi
 458
 459   dnl If none of the above worked, use the one we ship with Wget.
 460   if test x"$found_md5" = xno; then
 461     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 462     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 463     found_md5=yes
 464     AC_MSG_NOTICE([using the GNU MD5 implementation])
 465   fi
 466 fi
 467 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 468 AC_SUBST(MD5_OBJ)
 469
 470 dnl **********************************************************************
 471 dnl Checks for IPv6
 472 dnl **********************************************************************
 473
 474 dnl
 475 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 476 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 477 dnl don't use IPv6 or getaddrinfo.
 478 dnl
 479
 480 ipv6=
 481 check_for_ipv6=no
 482 AC_ARG_ENABLE(ipv6,
 483   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 484   [case "${enable_ipv6}" in
 485   no)
 486     AC_MSG_NOTICE([disabling IPv6 at user request])
 487     ipv6=no
 488     ;;
 489   *)
 490     ipv6=yes
 491     ;;
 492   esac],
 493   dnl If unspecified, check for IPv6 and use it where available.
 494   [check_for_ipv6=yes]
 495 )
 496
 497 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 498   AC_CHECK_FUNCS(getaddrinfo,[
 499     GETADDRINFO_AI_ADDRCONFIG(
 500       AC_DEFINE(
 501         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 502         [Define if the system headers support the AI_ADDRCONFIG flag.]
 503       )
 504     )
 505     GETADDRINFO_AI_V4MAPPED(
 506       AC_DEFINE(
 507         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 508         [Define if the system headers support the AI_V4MAPPED flag.]
 509       )
 510     )
 511     GETADDRINFO_AI_ALL(
 512       AC_DEFINE(
 513         [HAVE_GETADDRINFO_AI_ALL], 1,
 514         [Define if the system headers support the AI_ALL flag.]
 515       )
 516     )
 517   ],[
 518     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 519     ipv6=no
 520   ])
 521 fi
 522
 523 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 524   PROTO_INET6(,[
 525     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 526     ipv6=no
 527   ])
 528 fi
 529
 530 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 531   TYPE_STRUCT_SOCKADDR_IN6([
 532     ipv6=yes
 533   ],[
 534     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 535     ipv6=no
 536   ])
 537   if test "X$ipv6" = "Xyes"; then
 538     MEMBER_SIN6_SCOPE_ID
 539   fi
 540 fi
 541
 542 if test "X$ipv6" = "Xyes"; then
 543   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 544 fi
 545
 546
 547 dnl
 548 dnl Set of available languages.
 549 dnl
 550 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 551
 552 dnl Originally this used to be static, looking like this:
 553 dnl     ALL_LINGUAS="cs de hr it ..."
 554 dnl The downside was that configure needed to be rebuilt whenever a
 555 dnl new language was added.
 556
 557 dnl internationalization macros
 558 WGET_WITH_NLS
 559
 560 dnl
 561 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 562 dnl Emacs cannot be found, look for XEmacs.
 563 dnl
 564
 565 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 566
 567 case "${MAKEINFO}" in
 568    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 569    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 570    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 571 esac
 572
 573 dnl
 574 dnl Find perl and pod2man
 575 dnl
 576
 577 AC_PATH_PROGS(PERL, perl5 perl, no)
 578 AC_PATH_PROG(POD2MAN, pod2man, no)
 579
 580 if test "x${POD2MAN}" = xno; then
 581   COMMENT_IF_NO_POD2MAN="# "
 582 else
 583   COMMENT_IF_NO_POD2MAN=
 584 fi
 585 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 586
 587 dnl
 588 dnl Create output
 589 dnl
 590 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 591                  po/Makefile.in windows/Makefile])
 592 AC_CONFIG_HEADERS([src/config.h])
 593 AH_BOTTOM([
 594 #include "config-post.h"
 595 ])
 596 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 597 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 598 AC_OUTPUT