sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55   [  --with-socks            use the socks library],
  56   [AC_DEFINE([HAVE_SOCKS], 1,
  57              [Define if you wish to compile with socks support.])]
  58 )
  59
  60 AC_ARG_WITH(ssl,
  61 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  62   --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 USE_OPIE=$enableval, USE_OPIE=yes)
  67 test x"${USE_OPIE}" = xyes && AC_DEFINE([USE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 USE_DIGEST=$enableval, USE_DIGEST=yes)
  73 test x"${USE_DIGEST}" = xyes && AC_DEFINE([USE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(debug,
  77 [  --disable-debug         disable support for debugging output],
  78 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  79 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  80    [Define if you want the debug output support compiled in.])
  81
  82 wget_need_md5=no
  83
  84 case "${USE_OPIE}${USE_DIGEST}" in
  85 *yes*)
  86         wget_need_md5=yes
  87 esac
  88 if test x"$USE_OPIE" = xyes; then
  89   OPIE_OBJ='ftp-opie$o'
  90 fi
  91 AC_SUBST(OPIE_OBJ)
  92
  93 dnl
  94 dnl Whether make sets $(MAKE)...
  95 dnl
  96 AC_PROG_MAKE_SET
  97
  98 dnl
  99 dnl Find a good install
 100 dnl
 101 AC_PROG_INSTALL
 102
 103 dnl
 104 dnl Find the compiler
 105 dnl
 106
 107 dnl We want these before the checks, so the checks can modify their values.
 108 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 109 test -z "$CC" && cc_specified=yes
 110
 111 AC_PROG_CC
 112
 113 dnl
 114 dnl if the user hasn't specified CFLAGS, then
 115 dnl   if compiler is gcc, then use -O2 and some warning flags
 116 dnl   else use os-specific flags or -O
 117 dnl
 118 if test -n "$auto_cflags"; then
 119   if test -n "$GCC"; then
 120     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 121   else
 122     case "$host_os" in
 123       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 124       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 125       *)       CFLAGS="$CFLAGS -O" ;;
 126     esac
 127   fi
 128 fi
 129
 130 dnl
 131 dnl Handle AIX
 132 dnl
 133 AC_AIX
 134
 135 dnl
 136 dnl Configure our included libtool and make sure it's regenerated when needed
 137 dnl
 138 AC_PROG_LIBTOOL
 139 AC_SUBST(LIBTOOL_DEPS)
 140
 141 dnl
 142 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 143 dnl Might also be erelevant for DJGPP.
 144 dnl
 145 case "$host_os" in
 146   *win32) exeext='.exe';;
 147   *) exeext='';;
 148 esac
 149 AC_SUBST(exeext)
 150
 151 dnl
 152 dnl Check if we can handle prototypes.
 153 dnl
 154 AM_C_PROTOTYPES
 155
 156 dnl
 157 dnl Checks for basic compiler characteristics.
 158 dnl
 159 AC_C_CONST
 160 AC_C_INLINE
 161 AC_C_VOLATILE
 162 AC_C_BIGENDIAN
 163
 164 dnl
 165 dnl Checks for headers
 166 dnl
 167
 168 dnl Check for these even though we assume their presence.  This is
 169 dnl because Autoconf built-in macros expect their HAVE_* constants to
 170 dnl be available.
 171 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 172
 173 AC_CHECK_HEADERS(string.h strings.h stdarg.h unistd.h sys/time.h)
 174 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 175 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 176 AC_HEADER_TIME
 177
 178 dnl
 179 dnl Check integral type sizes.
 180 dnl
 181 AC_CHECK_SIZEOF(short)
 182 AC_CHECK_SIZEOF(int)
 183 AC_CHECK_SIZEOF(long)
 184 AC_CHECK_SIZEOF(long long)
 185
 186 dnl
 187 dnl Checks for non-universal or system-specific types.
 188 dnl
 189 AC_TYPE_SIZE_T
 190 AC_TYPE_PID_T
 191 AC_CHECK_TYPES(uint32_t)
 192 AC_TYPE_SIGNAL
 193 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 194 #include <stdio.h>
 195 #include <sys/types.h>
 196 #if HAVE_INTTYPES_H
 197 # include <inttypes.h>
 198 #endif
 199 #ifdef HAVE_SIGNAL_H
 200 # include <signal.h>
 201 #endif
 202 ])
 203
 204 dnl
 205 dnl Checks for library functions.
 206 dnl
 207 AC_FUNC_ALLOCA
 208 AC_FUNC_MMAP
 209 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 210 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 211 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 212
 213 dnl
 214 dnl Call Wget's local macros defined in aclocal.
 215 dnl
 216 WGET_STRUCT_UTIMBUF
 217 WGET_SOCKLEN_T
 218 WGET_FNMATCH
 219 WGET_NANOSLEEP
 220 WGET_NSL_SOCKET
 221
 222 dnl
 223 dnl Check if we need to compile in getopt.c.
 224 dnl
 225 AC_CHECK_FUNC(getopt_long, [], [
 226   GETOPT_OBJ='getopt$o'
 227 ])
 228 AC_SUBST(GETOPT_OBJ)
 229
 230 dnl
 231 dnl Checks for libraries.
 232 dnl
 233
 234 dnl #### This appears to be deficient with later versions of SOCKS.
 235 if test "x${with_socks}" = xyes
 236 then
 237   AC_CHECK_LIB(resolv, main)
 238   AC_CHECK_LIB(socks, Rconnect)
 239 fi
 240
 241 dnl $with_ssl can be one of:
 242 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 243 dnl  - "yes", meaning link with SSL or bail out.
 244 dnl  - "no", meaning don't link with SSL.
 245 dnl  - anything else, meaning use that as the SSL root, and bail out
 246 dnl    if it fails.
 247
 248 if test x"$with_ssl" = x; then
 249   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 250   dnl implements the "auto-detect by default" feature.  If you want to
 251   dnl change this to "ignore SSL by default", change "auto" to "no".
 252   with_ssl=auto
 253 fi
 254
 255 dnl Detection of OpenSSL is much hairier than the detection of other
 256 dnl libraries because OpenSSL can be compiled as a third-party
 257 dnl library, which means it will not be found without additional
 258 dnl linker magic.  It would be really nice to rework this check into
 259 dnl an AC_DEFUN so that we can reuse it for other third-party
 260 dnl libraries.
 261
 262 if test x"$with_ssl" != x"no"; then
 263
 264   wget_force_ssl=no
 265   if test x"$with_ssl" = x"yes"; then
 266     wget_force_ssl=yes
 267   fi
 268
 269   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 270     dnl OpenSSL's root was not specified, so we have to guess.  First
 271     dnl try the system default location, then "/usr/local/ssl" (where
 272     dnl OpenSSL installs by default), then "/usr/local" (traditional
 273     dnl choice for installation root), then "/opt".
 274     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 275   else
 276     dnl Root has been specified by the user.
 277     ssl_all_roots=$with_ssl
 278     wget_force_ssl=yes
 279   fi
 280
 281   wget_save_CC=$CC
 282   wget_save_LIBS=$LIBS
 283   wget_save_LDFLAGS=$LDFLAGS
 284   wget_save_CPPFLAGS=$CPPFLAGS
 285
 286   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 287   dnl without having to know how the linker handles it.
 288   CC="$SHELL ./libtool $CC"
 289
 290   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 291   dnl shared library doesn't record its dependency on libdl, so we
 292   dnl need to check for it ourselves so we won't fail to link due to a
 293   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 294   dnl shl_load().
 295   AC_CHECK_LIB(dl,dlopen)
 296   AC_CHECK_LIB(dl,shl_load)
 297
 298   ssl_success=no
 299
 300   dnl Now try to find SSL libraries in each of the likely SSL roots.
 301   for ssl_root in $ssl_all_roots
 302   do
 303     if test x"$ssl_root" = x"system-default"; then
 304       dnl Try the default include and library locations.
 305       SSL_INCLUDES=
 306     else
 307       dnl Try this specific root.
 308       SSL_INCLUDES=-I$ssl_root/include
 309       dnl It's OK to use -R directly because libtool will
 310       dnl interpret it for us.
 311       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 312     fi
 313
 314     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 315
 316     dnl Check whether the compiler can find the include files.  On
 317     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 318     dnl to find the includes in /usr/local/include.
 319
 320     ssl_found_includes=no
 321     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 322
 323     AC_MSG_CHECKING([for includes])
 324
 325     AC_TRY_CPP([#include <openssl/ssl.h>
 326 #include <openssl/rsa.h>
 327 ],
 328       AC_MSG_RESULT(found); ssl_found_includes=yes,
 329       AC_MSG_RESULT([not found])
 330     )
 331
 332     if test x"$ssl_found_includes" = xno; then
 333       continue
 334     fi
 335
 336     ssl_link_failure=no
 337
 338     dnl Make sure that the checks don't run afoul of the cache.  It
 339     dnl would be nicer to temporarily turn off the cache, but
 340     dnl apparently Autoconf doesn't allow that.
 341
 342     unset ac_cv_lib_crypto_RSA_new
 343     unset ac_cv_lib_ssl_SSL_new
 344
 345     dnl These checks need to be in this order, or you'll get a link
 346     dnl failure if you use a static libcrypto.a and libssl.a rather
 347     dnl than shared libraries.
 348
 349     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 350     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 351
 352     if test x"$ssl_link_failure" = xyes; then
 353       dnl One or both libs failed to link.
 354       continue
 355     fi
 356
 357     dnl The libraries link.  But we still need to check if the program
 358     dnl linked with those libraries under these settings with run.  On
 359     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 360     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 361     dnl executables that link, but fail to run.
 362
 363     dnl If we are cross-compiling, just assume that working linkage
 364     dnl implies working executable.
 365
 366     ssl_run_failure=no
 367
 368     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 369     AC_TRY_RUN([
 370 int RSA_new();
 371 int SSL_new();
 372 main(){return 0;}
 373 ],
 374       AC_MSG_RESULT(yes),
 375       AC_MSG_RESULT(no); ssl_run_failure=yes,
 376       AC_MSG_RESULT(cross)
 377     )
 378
 379     if test x"$ssl_run_failure" = xno; then
 380       ssl_success=yes
 381       break
 382     fi
 383   done
 384
 385   if test x"$ssl_success" = xyes; then
 386     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 387     AC_DEFINE([HAVE_SSL], 1,
 388               [Define if SSL support should be compiled in.])
 389     AC_SUBST(SSL_INCLUDES)
 390     SSL_OBJ='gen_sslfunc$o'
 391     AC_SUBST(SSL_OBJ)
 392   else
 393     LDFLAGS=$wget_save_LDFLAGS
 394     LIBS=$wget_save_LIBS
 395
 396     dnl If linking with SSL was forced rather than auto-detected, then
 397     dnl bail out if SSL failed.
 398     if test x"$wget_force_ssl" = x"yes"; then
 399       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 400     fi
 401   fi
 402
 403   dnl Restore the compiler setting.
 404   CC=$wget_save_CC
 405
 406   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 407   dnl with SSL succeeded -- SSL includes will be handled using
 408   dnl @SSL_INCLUDES@.
 409   CPPFLAGS=$wget_save_CPPFLAGS
 410 fi
 411
 412 dnl
 413 dnl Find an md5 implementation.
 414 dnl
 415
 416 if test x"$wget_need_md5" = xyes
 417 then
 418   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 419   dnl manipulate MD5_OBJ from the defun.
 420
 421   MD5_OBJ='gen-md5$o'
 422   found_md5=no
 423
 424   dnl Check for the system MD5 library on Solaris.  We don't check for
 425   dnl something simple like "MD5Update" because there are a number of
 426   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 427   dnl specific to the Solaris MD5 library.
 428   if test x"$found_md5" = xno; then
 429     AC_CHECK_LIB(md5, md5_calc, [
 430       dnl Some installations have bogus <md5.h> in the compiler's
 431       dnl include path, making the system md5 library useless.
 432       AC_MSG_CHECKING([whether md5.h can be included])
 433       AC_COMPILE_IFELSE([#include <md5.h>
 434                         ], [
 435         AC_MSG_RESULT(yes)
 436         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 437         LIBS="-lmd5 $LIBS"
 438         found_md5=yes
 439         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 440       ], [AC_MSG_RESULT(no)])
 441     ])
 442   fi
 443
 444   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 445   dnl implementation.
 446   if test x"$found_md5" = xno; then
 447     if test x"$ssl_success" = xyes; then
 448       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 449       found_md5=yes
 450       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 451     fi
 452   fi
 453
 454   dnl If none of the above worked, use the one we ship with Wget.
 455   if test x"$found_md5" = xno; then
 456     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 457     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 458     found_md5=yes
 459     AC_MSG_NOTICE([using the GNU MD5 implementation])
 460   fi
 461 fi
 462 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 463 AC_SUBST(MD5_OBJ)
 464
 465 dnl **********************************************************************
 466 dnl Checks for IPv6
 467 dnl **********************************************************************
 468
 469 dnl
 470 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 471 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 472 dnl don't use IPv6 or getaddrinfo.
 473 dnl
 474
 475 ipv6=
 476 check_for_ipv6=no
 477 AC_ARG_ENABLE(ipv6,
 478   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 479   [case "${enable_ipv6}" in
 480   no)
 481     AC_MSG_NOTICE([disabling IPv6 at user request])
 482     ipv6=no
 483     ;;
 484   *)
 485     ipv6=yes
 486     ;;
 487   esac],
 488   dnl If unspecified, check for IPv6 and use it where available.
 489   [check_for_ipv6=yes]
 490 )
 491
 492 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 493   AC_CHECK_FUNCS(getaddrinfo,[
 494     GETADDRINFO_AI_ADDRCONFIG(
 495       AC_DEFINE(
 496         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 497         [Define if the system headers support the AI_ADDRCONFIG flag.]
 498       )
 499     )
 500     GETADDRINFO_AI_V4MAPPED(
 501       AC_DEFINE(
 502         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 503         [Define if the system headers support the AI_V4MAPPED flag.]
 504       )
 505     )
 506     GETADDRINFO_AI_ALL(
 507       AC_DEFINE(
 508         [HAVE_GETADDRINFO_AI_ALL], 1,
 509         [Define if the system headers support the AI_ALL flag.]
 510       )
 511     )
 512   ],[
 513     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 514     ipv6=no
 515   ])
 516 fi
 517
 518 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 519   PROTO_INET6(,[
 520     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 521     ipv6=no
 522   ])
 523 fi
 524
 525 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 526   TYPE_STRUCT_SOCKADDR_IN6([
 527     ipv6=yes
 528   ],[
 529     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 530     ipv6=no
 531   ])
 532   if test "X$ipv6" = "Xyes"; then
 533     MEMBER_SIN6_SCOPE_ID
 534   fi
 535 fi
 536
 537 if test "X$ipv6" = "Xyes"; then
 538   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 539 fi
 540
 541
 542 dnl
 543 dnl Set of available languages.
 544 dnl
 545 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 546
 547 dnl Originally this used to be static, looking like this:
 548 dnl     ALL_LINGUAS="cs de hr it ..."
 549 dnl The downside was that configure needed to be rebuilt whenever a
 550 dnl new language was added.
 551
 552 dnl internationalization macros
 553 WGET_WITH_NLS
 554
 555 dnl
 556 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 557 dnl Emacs cannot be found, look for XEmacs.
 558 dnl
 559
 560 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 561
 562 case "${MAKEINFO}" in
 563    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 564    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 565    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 566 esac
 567
 568 dnl
 569 dnl Find perl and pod2man
 570 dnl
 571
 572 AC_PATH_PROGS(PERL, perl5 perl, no)
 573 AC_PATH_PROG(POD2MAN, pod2man, no)
 574
 575 if test "x${POD2MAN}" = xno; then
 576   COMMENT_IF_NO_POD2MAN="# "
 577 else
 578   COMMENT_IF_NO_POD2MAN=
 579 fi
 580 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 581
 582 dnl
 583 dnl Create output
 584 dnl
 585 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 586                  po/Makefile.in windows/Makefile])
 587 AC_CONFIG_HEADERS([src/config.h])
 588 AH_BOTTOM([
 589 #include "config-post.h"
 590 ])
 591 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 592 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 593 AC_OUTPUT