sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for basic compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_C_VOLATILE
 157 AC_C_BIGENDIAN
 158
 159 dnl
 160 dnl Checks for headers
 161 dnl
 162 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 164 AC_CHECK_HEADERS(inttypes.h signal.h setjmp.h pwd.h)
 165 AC_HEADER_TIME
 166
 167 dnl
 168 dnl Check integral type sizes.
 169 dnl
 170 AC_CHECK_SIZEOF(short)
 171 AC_CHECK_SIZEOF(int)
 172 AC_CHECK_SIZEOF(long)
 173 AC_CHECK_SIZEOF(long long)
 174
 175 dnl
 176 dnl Checks for non-universal or system-specific types.
 177 dnl
 178 AC_TYPE_SIZE_T
 179 AC_TYPE_PID_T
 180 AC_CHECK_TYPES(uint32_t)
 181 AC_TYPE_SIGNAL
 182 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 183 #include <stdio.h>
 184 #include <sys/types.h>
 185 #if HAVE_INTTYPES_H
 186 # include <inttypes.h>
 187 #endif
 188 #ifdef HAVE_SIGNAL_H
 189 # include <signal.h>
 190 #endif
 191 ])
 192
 193 dnl
 194 dnl Checks for library functions.
 195 dnl
 196 AC_FUNC_ALLOCA
 197 AC_FUNC_MMAP
 198 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 199 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 200 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 201
 202 dnl
 203 dnl Call Wget's local macros defined in aclocal.
 204 dnl
 205 WGET_STRUCT_UTIMBUF
 206 WGET_SOCKLEN_T
 207 WGET_FNMATCH
 208 WGET_NANOSLEEP
 209 WGET_NSL_SOCKET
 210
 211 dnl
 212 dnl Check if we need to compile in getopt.c.
 213 dnl
 214 AC_CHECK_FUNC(getopt_long, [], [
 215   GETOPT_OBJ='getopt$o'
 216 ])
 217 AC_SUBST(GETOPT_OBJ)
 218
 219 dnl
 220 dnl Checks for libraries.
 221 dnl
 222
 223 dnl #### This appears to be deficient with later versions of SOCKS.
 224 if test "x${with_socks}" = xyes
 225 then
 226   AC_CHECK_LIB(resolv, main)
 227   AC_CHECK_LIB(socks, Rconnect)
 228 fi
 229
 230 dnl $with_ssl can be one of:
 231 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 232 dnl  - "yes", meaning link with SSL or bail out.
 233 dnl  - "no", meaning don't link with SSL.
 234 dnl  - anything else, meaning use that as the SSL root, and bail out
 235 dnl    if it fails.
 236
 237 if test x"$with_ssl" = x; then
 238   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 239   dnl implements the "auto-detect by default" feature.  If you want to
 240   dnl change this to "ignore SSL by default", change "auto" to "no".
 241   with_ssl=auto
 242 fi
 243
 244 dnl Detection of OpenSSL is much hairier than the detection of other
 245 dnl libraries because OpenSSL can be compiled as a third-party
 246 dnl library, which means it will not be found without additional
 247 dnl linker magic.  It would be really nice to rework this check into
 248 dnl an AC_DEFUN so that we can reuse it for other third-party
 249 dnl libraries.
 250
 251 if test x"$with_ssl" != x"no"; then
 252
 253   wget_force_ssl=no
 254   if test x"$with_ssl" = x"yes"; then
 255     wget_force_ssl=yes
 256   fi
 257
 258   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 259     dnl OpenSSL's root was not specified, so we have to guess.  First
 260     dnl try the system default location, then "/usr/local/ssl" (where
 261     dnl OpenSSL installs by default), then "/usr/local" (traditional
 262     dnl choice for installation root), then "/opt".
 263     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 264   else
 265     dnl Root has been specified by the user.
 266     ssl_all_roots=$with_ssl
 267     wget_force_ssl=yes
 268   fi
 269
 270   wget_save_CC=$CC
 271   wget_save_LIBS=$LIBS
 272   wget_save_LDFLAGS=$LDFLAGS
 273   wget_save_CPPFLAGS=$CPPFLAGS
 274
 275   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 276   dnl without having to know how the linker handles it.
 277   CC="$SHELL ./libtool $CC"
 278
 279   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 280   dnl shared library doesn't record its dependency on libdl, so we
 281   dnl need to check for it ourselves so we won't fail to link due to a
 282   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 283   dnl shl_load().
 284   AC_CHECK_LIB(dl,dlopen)
 285   AC_CHECK_LIB(dl,shl_load)
 286
 287   ssl_success=no
 288
 289   dnl Now try to find SSL libraries in each of the likely SSL roots.
 290   for ssl_root in $ssl_all_roots
 291   do
 292     if test x"$ssl_root" = x"system-default"; then
 293       dnl Try the default include and library locations.
 294       SSL_INCLUDES=
 295     else
 296       dnl Try this specific root.
 297       SSL_INCLUDES=-I$ssl_root/include
 298       dnl It's OK to use -R directly because libtool will
 299       dnl interpret it for us.
 300       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 301     fi
 302
 303     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 304
 305     dnl Check whether the compiler can find the include files.  On
 306     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 307     dnl to find the includes in /usr/local/include.
 308
 309     ssl_found_includes=no
 310     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 311
 312     AC_MSG_CHECKING([for includes])
 313
 314     AC_TRY_CPP([#include <openssl/ssl.h>
 315 #include <openssl/rsa.h>
 316 ],
 317       AC_MSG_RESULT(found); ssl_found_includes=yes,
 318       AC_MSG_RESULT([not found])
 319     )
 320
 321     if test x"$ssl_found_includes" = xno; then
 322       continue
 323     fi
 324
 325     ssl_link_failure=no
 326
 327     dnl Make sure that the checks don't run afoul of the cache.  It
 328     dnl would be nicer to temporarily turn off the cache, but
 329     dnl apparently Autoconf doesn't allow that.
 330
 331     unset ac_cv_lib_crypto_RSA_new
 332     unset ac_cv_lib_ssl_SSL_new
 333
 334     dnl These checks need to be in this order, or you'll get a link
 335     dnl failure if you use a static libcrypto.a and libssl.a rather
 336     dnl than shared libraries.
 337
 338     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 339     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 340
 341     if test x"$ssl_link_failure" = xyes; then
 342       dnl One or both libs failed to link.
 343       continue
 344     fi
 345
 346     dnl The libraries link.  But we still need to check if the program
 347     dnl linked with those libraries under these settings with run.  On
 348     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 349     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 350     dnl executables that link, but fail to run.
 351
 352     dnl If we are cross-compiling, just assume that working linkage
 353     dnl implies working executable.
 354
 355     ssl_run_failure=no
 356
 357     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 358     AC_TRY_RUN([
 359 int RSA_new();
 360 int SSL_new();
 361 main(){return 0;}
 362 ],
 363       AC_MSG_RESULT(yes),
 364       AC_MSG_RESULT(no); ssl_run_failure=yes,
 365       AC_MSG_RESULT(cross)
 366     )
 367
 368     if test x"$ssl_run_failure" = xno; then
 369       ssl_success=yes
 370       break
 371     fi
 372   done
 373
 374   if test x"$ssl_success" = xyes; then
 375     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 376     dnl to use instead.
 377     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 378     AC_DEFINE(HAVE_SSL)
 379     AC_SUBST(SSL_INCLUDES)
 380     SSL_OBJ='gen_sslfunc$o'
 381     AC_SUBST(SSL_OBJ)
 382   else
 383     LDFLAGS=$wget_save_LDFLAGS
 384     LIBS=$wget_save_LIBS
 385
 386     dnl If linking with SSL was forced rather than auto-detected, then
 387     dnl bail out if SSL failed.
 388     if test x"$wget_force_ssl" = x"yes"; then
 389       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 390     fi
 391   fi
 392
 393   dnl Restore the compiler setting.
 394   CC=$wget_save_CC
 395
 396   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 397   dnl with SSL succeeded -- SSL includes will be handled using
 398   dnl @SSL_INCLUDES@.
 399   CPPFLAGS=$wget_save_CPPFLAGS
 400 fi
 401
 402 dnl
 403 dnl Find an md5 implementation.
 404 dnl
 405
 406 if test x"$wget_need_md5" = xyes
 407 then
 408   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 409   dnl manipulate MD5_OBJ from the defun.
 410
 411   MD5_OBJ='gen-md5$o'
 412   found_md5=no
 413
 414   dnl Check for the system MD5 library on Solaris.  We don't check for
 415   dnl something simple like "MD5Update" because there are a number of
 416   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 417   dnl specific to the Solaris MD5 library.
 418   if test x"$found_md5" = xno; then
 419     AC_CHECK_LIB(md5, md5_calc, [
 420       dnl Some installations have bogus <md5.h> in the compiler's
 421       dnl include path, making the system md5 library useless.
 422       AC_MSG_CHECKING([whether md5.h can be included])
 423       AC_COMPILE_IFELSE([#include <md5.h>
 424                         ], [
 425         AC_MSG_RESULT(yes)
 426         AC_DEFINE(HAVE_SOLARIS_MD5)
 427         LIBS="-lmd5 $LIBS"
 428         found_md5=yes
 429         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 430       ], [AC_MSG_RESULT(no)])
 431     ])
 432   fi
 433
 434   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 435   dnl implementation.
 436   if test x"$found_md5" = xno; then
 437     if test x"$ssl_success" = xyes; then
 438       AC_DEFINE(HAVE_OPENSSL_MD5)
 439       found_md5=yes
 440       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 441     fi
 442   fi
 443
 444   dnl If none of the above worked, use the one we ship with Wget.
 445   if test x"$found_md5" = xno; then
 446     AC_DEFINE(HAVE_BUILTIN_MD5)
 447     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 448     found_md5=yes
 449     AC_MSG_NOTICE([using the GNU MD5 implementation])
 450   fi
 451 fi
 452 AC_DEFINE(HAVE_MD5)
 453 AC_SUBST(MD5_OBJ)
 454
 455 dnl **********************************************************************
 456 dnl Checks for IPv6
 457 dnl **********************************************************************
 458
 459 dnl
 460 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 461 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 462 dnl don't use IPv6 or getaddrinfo.
 463 dnl
 464
 465 ipv6=
 466 check_for_ipv6=no
 467 AC_ARG_ENABLE(ipv6,
 468   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 469   [case "${enable_ipv6}" in
 470   no)
 471     AC_MSG_NOTICE([Disabling IPv6 at user request])
 472     ipv6=no
 473     ;;
 474   *)
 475     ipv6=yes
 476     ;;
 477   esac],
 478   dnl If unspecified, check for IPv6 and use it where available.
 479   [check_for_ipv6=yes]
 480 )
 481
 482 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 483   AC_CHECK_FUNCS(getaddrinfo,[
 484     GETADDRINFO_AI_ADDRCONFIG(
 485       AC_DEFINE(
 486         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 487         [Define if the system headers support the AI_ADDRCONFIG flag.]
 488       )
 489     )
 490     GETADDRINFO_AI_V4MAPPED(
 491       AC_DEFINE(
 492         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 493         [Define if the system headers support the AI_V4MAPPED flag.]
 494       )
 495     )
 496     GETADDRINFO_AI_ALL(
 497       AC_DEFINE(
 498         [HAVE_GETADDRINFO_AI_ALL], 1,
 499         [Define if the system headers support the AI_ALL flag.]
 500       )
 501     )
 502   ],[
 503     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 504     ipv6=no
 505   ])
 506 fi
 507
 508 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 509   PROTO_INET6(,[
 510     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 511     ipv6=no
 512   ])
 513 fi
 514
 515 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 516   TYPE_STRUCT_SOCKADDR_IN6([
 517     ipv6=yes
 518   ],[
 519     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 520     ipv6=no
 521   ])
 522   if test "X$ipv6" = "Xyes"; then
 523     MEMBER_SIN6_SCOPE_ID
 524   fi
 525 fi
 526
 527 if test "X$ipv6" = "Xyes"; then
 528   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 529 fi
 530
 531
 532 dnl
 533 dnl Set of available languages.
 534 dnl
 535 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 536
 537 dnl Originally this used to be static, looking like this:
 538 dnl     ALL_LINGUAS="cs de hr it ..."
 539 dnl The downside was that configure needed to be rebuilt whenever a
 540 dnl new language was added.
 541
 542 dnl internationalization macros
 543 WGET_WITH_NLS
 544
 545 dnl
 546 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 547 dnl Emacs cannot be found, look for XEmacs.
 548 dnl
 549
 550 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 551
 552 case "${MAKEINFO}" in
 553    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 554    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 555    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 556 esac
 557
 558 dnl
 559 dnl Find perl and pod2man
 560 dnl
 561
 562 AC_PATH_PROGS(PERL, perl5 perl, no)
 563 AC_PATH_PROG(POD2MAN, pod2man, no)
 564
 565 if test "x${POD2MAN}" = xno; then
 566   COMMENT_IF_NO_POD2MAN="# "
 567 else
 568   COMMENT_IF_NO_POD2MAN=
 569 fi
 570 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 571
 572 dnl
 573 dnl Create output
 574 dnl
 575 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 576            windows/Makefile],
 577 [WGET_PROCESS_PO
 578 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])