sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for typedefs, structures, and compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_PID_T
 158 AC_C_BIGENDIAN
 159
 160 dnl
 161 dnl Check integral type sizes.
 162 dnl
 163 AC_CHECK_SIZEOF(short)
 164 AC_CHECK_SIZEOF(int)
 165 AC_CHECK_SIZEOF(long)
 166 AC_CHECK_SIZEOF(long long)
 167 AC_CHECK_HEADERS(inttypes.h)
 168 AC_CHECK_TYPES(uint32_t)
 169
 170 dnl
 171 dnl Checks for headers
 172 dnl
 173 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 174 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 175 AC_CHECK_HEADERS(signal.h setjmp.h)
 176 AC_HEADER_TIME
 177
 178 dnl
 179 dnl Return type of signal-handlers
 180 dnl
 181 AC_TYPE_SIGNAL
 182
 183 dnl
 184 dnl Call several of Wget's macros.
 185 dnl
 186 WGET_STRUCT_UTIMBUF
 187 WGET_SOCKLEN_T
 188
 189 dnl
 190 dnl Checks for library functions.
 191 dnl
 192 AC_FUNC_ALLOCA
 193 AC_FUNC_MMAP
 194 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 195 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 196 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 197 AC_CHECK_FUNCS(uname gethostname usleep)
 198
 199 dnl
 200 dnl Check if we need to compile in getopt.c.
 201 dnl
 202 AC_CHECK_FUNC(getopt_long, [], [
 203   GETOPT_OBJ='getopt$o'
 204 ])
 205 AC_SUBST(GETOPT_OBJ)
 206
 207 dnl
 208 dnl Checks for libraries.
 209 dnl
 210
 211 dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
 212 dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
 213 dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
 214 dnl look for such known offenders and if one of them is not found, we
 215 dnl check if -lnsl is needed.
 216
 217 wget_check_in_nsl=NONE
 218 AC_CHECK_FUNCS(gethostbyname, [], [
 219   wget_check_in_nsl=gethostbyname
 220 ])
 221 AC_CHECK_FUNCS(inet_ntoa, [], [
 222   wget_check_in_nsl=inet_ntoa
 223 ])
 224 if test $wget_check_in_nsl != NONE; then
 225   AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 226 fi
 227
 228 AC_CHECK_LIB(socket, socket)
 229
 230 dnl nanosleep on Solaris requires -lrt (more recently) or -lposix4
 231 dnl (older versions).
 232
 233 AC_CHECK_FUNCS(nanosleep, [], [
 234   AC_CHECK_LIB(rt, nanosleep, [
 235     AC_DEFINE(HAVE_NANOSLEEP)
 236     LIBS="-lrt $LIBS"
 237   ], [
 238     AC_CHECK_LIB(posix4, nanosleep, [
 239       AC_DEFINE(HAVE_NANOSLEEP)
 240       LIBS="-lposix4 $LIBS"
 241     ])
 242   ])])
 243
 244 dnl #### This appears to be deficient with later versions of SOCKS.
 245 if test "x${with_socks}" = xyes
 246 then
 247   AC_CHECK_LIB(resolv, main)
 248   AC_CHECK_LIB(socks, Rconnect)
 249 fi
 250
 251 dnl $with_ssl can be one of:
 252 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 253 dnl  - "yes", meaning link with SSL or bail out.
 254 dnl  - "no", meaning don't link with SSL.
 255 dnl  - anything else, meaning use that as the SSL root, and bail out
 256 dnl    if it fails.
 257
 258 if test x"$with_ssl" = x; then
 259   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 260   dnl implements the "auto-detect by default" feature.  If you want to
 261   dnl change this to "ignore SSL by default", change "auto" to "no".
 262   with_ssl=auto
 263 fi
 264
 265 dnl Detection of OpenSSL is much hairier than the detection of other
 266 dnl libraries because OpenSSL can be compiled as a third-party
 267 dnl library, which means it will not be found without additional
 268 dnl linker magic.  It would be really nice to rework this check into
 269 dnl an AC_DEFUN so that we can reuse it for other third-party
 270 dnl libraries.
 271
 272 if test x"$with_ssl" != x"no"; then
 273
 274   wget_force_ssl=no
 275   if test x"$with_ssl" = x"yes"; then
 276     wget_force_ssl=yes
 277   fi
 278
 279   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 280     dnl OpenSSL's root was not specified, so we have to guess.  First
 281     dnl try the system default location, then "/usr/local/ssl" (where
 282     dnl OpenSSL installs by default), then "/usr/local" (traditional
 283     dnl choice for installation root), then "/opt".
 284     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 285   else
 286     dnl Root has been specified by the user.
 287     ssl_all_roots=$with_ssl
 288     wget_force_ssl=yes
 289   fi
 290
 291   wget_save_CC=$CC
 292   wget_save_LIBS=$LIBS
 293   wget_save_LDFLAGS=$LDFLAGS
 294   wget_save_CPPFLAGS=$CPPFLAGS
 295
 296   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 297   dnl without having to know how the linker handles it.
 298   CC="$SHELL ./libtool $CC"
 299
 300   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 301   dnl shared library doesn't record its dependency on libdl, so we
 302   dnl need to check for it ourselves so we won't fail to link due to a
 303   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 304   dnl shl_load().
 305   AC_CHECK_LIB(dl,dlopen)
 306   AC_CHECK_LIB(dl,shl_load)
 307
 308   ssl_success=no
 309
 310   dnl Now try to find SSL libraries in each of the likely SSL roots.
 311   for ssl_root in $ssl_all_roots
 312   do
 313     if test x"$ssl_root" = x"system-default"; then
 314       dnl Try the default include and library locations.
 315       SSL_INCLUDES=
 316     else
 317       dnl Try this specific root.
 318       SSL_INCLUDES=-I$ssl_root/include
 319       dnl It's OK to use -R directly because libtool will
 320       dnl interpret it for us.
 321       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 322     fi
 323
 324     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 325
 326     dnl Check whether the compiler can find the include files.  On
 327     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 328     dnl to find the includes in /usr/local/include.
 329
 330     ssl_found_includes=no
 331     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 332
 333     AC_MSG_CHECKING([for includes])
 334
 335     AC_TRY_CPP([#include <openssl/ssl.h>
 336 #include <openssl/rsa.h>
 337 ],
 338       AC_MSG_RESULT(found); ssl_found_includes=yes,
 339       AC_MSG_RESULT([not found])
 340     )
 341
 342     if test x"$ssl_found_includes" = xno; then
 343       continue
 344     fi
 345
 346     ssl_link_failure=no
 347
 348     dnl Make sure that the checks don't run afoul of the cache.  It
 349     dnl would be nicer to temporarily turn off the cache, but
 350     dnl apparently Autoconf doesn't allow that.
 351
 352     unset ac_cv_lib_crypto_RSA_new
 353     unset ac_cv_lib_ssl_SSL_new
 354
 355     dnl These checks need to be in this order, or you'll get a link
 356     dnl failure if you use a static libcrypto.a and libssl.a rather
 357     dnl than shared libraries.
 358
 359     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 360     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 361
 362     if test x"$ssl_link_failure" = xyes; then
 363       dnl One or both libs failed to link.
 364       continue
 365     fi
 366
 367     dnl The libraries link.  But we still need to check if the program
 368     dnl linked with those libraries under these settings with run.  On
 369     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 370     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 371     dnl executables that link, but fail to run.
 372
 373     dnl If we are cross-compiling, just assume that working linkage
 374     dnl implies working executable.
 375
 376     ssl_run_failure=no
 377
 378     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 379     AC_TRY_RUN([
 380 int RSA_new();
 381 int SSL_new();
 382 main(){return 0;}
 383 ],
 384       AC_MSG_RESULT(yes),
 385       AC_MSG_RESULT(no); ssl_run_failure=yes,
 386       AC_MSG_RESULT(cross)
 387     )
 388
 389     if test x"$ssl_run_failure" = xno; then
 390       ssl_success=yes
 391       break
 392     fi
 393   done
 394
 395   if test x"$ssl_success" = xyes; then
 396     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 397     dnl to use instead.
 398     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 399     AC_DEFINE(HAVE_SSL)
 400     AC_SUBST(SSL_INCLUDES)
 401     SSL_OBJ='gen_sslfunc$o'
 402     AC_SUBST(SSL_OBJ)
 403   else
 404     LDFLAGS=$wget_save_LDFLAGS
 405     LIBS=$wget_save_LIBS
 406
 407     dnl If linking with SSL was forced rather than auto-detected, then
 408     dnl bail out if SSL failed.
 409     if test x"$wget_force_ssl" = x"yes"; then
 410       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 411     fi
 412   fi
 413
 414   dnl Restore the compiler setting.
 415   CC=$wget_save_CC
 416
 417   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 418   dnl with SSL succeeded -- SSL includes will be handled using
 419   dnl @SSL_INCLUDES@.
 420   CPPFLAGS=$wget_save_CPPFLAGS
 421 fi
 422
 423 dnl
 424 dnl Find an md5 implementation.
 425 dnl
 426
 427 if test x"$wget_need_md5" = xyes
 428 then
 429   MD5_OBJ='gen-md5$o'
 430
 431   found_md5=no
 432
 433   dnl Check for the system MD5 library on Solaris.  We don't check for
 434   dnl something simple like "MD5Update" because there are a number of
 435   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 436   dnl specific to the Solaris MD5 library.
 437   if test x"$found_md5" = xno; then
 438     AC_CHECK_LIB(md5, md5_calc, [
 439       dnl There are programs that insert bogus <md5.h> in the include
 440       dnl path.  That makes the system md5 library is useless to us.
 441       AC_CHECK_HEADERS([md5.h], [
 442         AC_DEFINE(HAVE_SOLARIS_MD5)
 443         LIBS="-lmd5 $LIBS"
 444         found_md5=yes
 445         AC_MSG_NOTICE([using Solaris MD5 implementation])
 446       ])
 447     ])
 448   fi
 449
 450   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 451   dnl implementation.
 452   if test x"$found_md5" = xno; then
 453     if test x"$ssl_success" = xyes; then
 454       AC_DEFINE(HAVE_OPENSSL_MD5)
 455       found_md5=yes
 456       AC_MSG_NOTICE([using OpenSSL MD5 implementation])
 457     fi
 458   fi
 459
 460   dnl If none of the above worked, use the one we ship with Wget.
 461   if test x"$found_md5" = xno; then
 462     AC_DEFINE(HAVE_BUILTIN_MD5)
 463     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 464     found_md5=yes
 465     AC_MSG_NOTICE([using GNU MD5 implementation])
 466   fi
 467 fi
 468 AC_DEFINE(HAVE_MD5)
 469 AC_SUBST(MD5_OBJ)
 470
 471 dnl **********************************************************************
 472 dnl Checks for IPv6
 473 dnl **********************************************************************
 474
 475 dnl
 476 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 477 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 478 dnl don't use IPv6 or getaddrinfo.
 479 dnl
 480
 481 ipv6=
 482 check_for_ipv6=no
 483 AC_ARG_ENABLE(ipv6,
 484   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 485   [case "${enable_ipv6}" in
 486   no)
 487     AC_MSG_NOTICE([Disabling IPv6 at user request])
 488     ipv6=no
 489     ;;
 490   *)
 491     ipv6=yes
 492     ;;
 493   esac],
 494   dnl If unspecified, check for IPv6 and use it where available.
 495   [check_for_ipv6=yes]
 496 )
 497
 498 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 499   AC_CHECK_FUNCS(getaddrinfo,[
 500     GETADDRINFO_AI_ADDRCONFIG(
 501       AC_DEFINE(
 502         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 503         [Define if the system headers support the AI_ADDRCONFIG flag.]
 504       )
 505     )
 506     GETADDRINFO_AI_V4MAPPED(
 507       AC_DEFINE(
 508         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 509         [Define if the system headers support the AI_V4MAPPED flag.]
 510       )
 511     )
 512     GETADDRINFO_AI_ALL(
 513       AC_DEFINE(
 514         [HAVE_GETADDRINFO_AI_ALL], 1,
 515         [Define if the system headers support the AI_ALL flag.]
 516       )
 517     )
 518   ],[
 519     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 520     ipv6=no
 521   ])
 522 fi
 523
 524 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 525   PROTO_INET6(,[
 526     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 527     ipv6=no
 528   ])
 529 fi
 530
 531 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 532   TYPE_STRUCT_SOCKADDR_IN6([
 533     ipv6=yes
 534   ],[
 535     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 536     ipv6=no
 537   ])
 538   if test "X$ipv6" = "Xyes"; then
 539     MEMBER_SIN6_SCOPE_ID
 540   fi
 541 fi
 542
 543 if test "X$ipv6" = "Xyes"; then
 544   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 545 fi
 546
 547
 548 dnl
 549 dnl Set of available languages.
 550 dnl
 551 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 552
 553 dnl Originally this used to be static, looking like this:
 554 dnl     ALL_LINGUAS="cs de hr it ..."
 555 dnl The downside was that configure needed to be rebuilt whenever a
 556 dnl new language was added.
 557
 558 dnl internationalization macros
 559 WGET_WITH_NLS
 560
 561 dnl
 562 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 563 dnl Emacs cannot be found, look for XEmacs.
 564 dnl
 565
 566 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 567
 568 case "${MAKEINFO}" in
 569    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 570    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 571    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 572 esac
 573
 574 dnl
 575 dnl Find perl and pod2man
 576 dnl
 577
 578 AC_PATH_PROGS(PERL, perl5 perl, no)
 579 AC_PATH_PROG(POD2MAN, pod2man, no)
 580
 581 if test "x${POD2MAN}" = xno; then
 582   COMMENT_IF_NO_POD2MAN="# "
 583 else
 584   COMMENT_IF_NO_POD2MAN=
 585 fi
 586 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 587
 588 dnl
 589 dnl Create output
 590 dnl
 591 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 592            windows/Makefile],
 593 [WGET_PROCESS_PO
 594 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])