sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl Include the M4 macros we use.
  36 builtin(include, [m4/wget.m4])dnl
  37 builtin(include, [m4/lib-ld.m4])dnl
  38 builtin(include, [m4/lib-link.m4])dnl
  39 builtin(include, [m4/lib-prefix.m4])dnl
  40
  41 dnl
  42 dnl What version of Wget are we building?
  43 dnl
  44 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  45 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  46 AC_SUBST(VERSION)
  47 PACKAGE=wget
  48 AC_SUBST(PACKAGE)
  49
  50 dnl
  51 dnl Get cannonical host
  52 dnl
  53 AC_CANONICAL_HOST
  54 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  55                    [Define to be the name of the operating system.])
  56
  57 dnl
  58 dnl Process features.
  59 dnl
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  67 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  73 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(ntlm,
  77 [  --disable-ntlm          disable support for NTLM authorization],
  78 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  79
  80 AC_ARG_ENABLE(debug,
  81 [  --disable-debug         disable support for debugging output],
  82 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  83 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  84    [Define if you want the debug output support compiled in.])
  85
  86 wget_need_md5=no
  87
  88 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  89 *yes*)
  90         wget_need_md5=yes
  91 esac
  92 if test x"$ENABLE_OPIE" = xyes; then
  93   OPIE_OBJ='ftp-opie.o'
  94 fi
  95 AC_SUBST(OPIE_OBJ)
  96
  97 dnl
  98 dnl Whether make sets $(MAKE)...
  99 dnl
 100 AC_PROG_MAKE_SET
 101
 102 dnl
 103 dnl Find a good install
 104 dnl
 105 AC_PROG_INSTALL
 106
 107 dnl
 108 dnl Find the compiler
 109 dnl
 110
 111 dnl We want these before the checks, so the checks can modify their values.
 112 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 113 test -z "$CC" && cc_specified=yes
 114
 115 AC_PROG_CC
 116 AC_AIX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 139 dnl Might also be erelevant for DJGPP.
 140 dnl
 141 case "$host_os" in
 142   *win32) exeext='.exe';;
 143   *) exeext='';;
 144 esac
 145 AC_SUBST(exeext)
 146
 147 dnl
 148 dnl Checks for basic compiler characteristics.
 149 dnl
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_VOLATILE
 153 dnl Needed for GNU md5 code.
 154 AC_C_BIGENDIAN
 155
 156 dnl
 157 dnl Checks for header files that might be missing.
 158 dnl
 159
 160 dnl Check for basic headers, even though we expect their presence to
 161 dnl compile.  This is because test programs used by Autoconf macros
 162 dnl check for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before including
 163 dnl them.  Without these checks they will fail to be included in test
 164 dnl programs, which will subsequently fail.
 165 AC_HEADER_STDC
 166
 167 dnl Now the real checks:
 168 AC_HEADER_STDBOOL
 169 AC_CHECK_HEADERS(unistd.h sys/time.h)
 170 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 171 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 172
 173 dnl
 174 dnl Check sizes of signed integer types.  These are used to find n-bit
 175 dnl integral types on older systems that fail to provide intN_t and
 176 dnl uintN_t typedefs.
 177 dnl
 178 AC_CHECK_SIZEOF(short)
 179 AC_CHECK_SIZEOF(int)
 180 AC_CHECK_SIZEOF(long)
 181 AC_CHECK_SIZEOF(long long)
 182
 183 dnl
 184 dnl Check for large file support.  This check needs to come fairly
 185 dnl early because it could (in principle) affect whether functions and
 186 dnl headers are available, whether they work, etc.
 187 dnl
 188 AC_SYS_LARGEFILE
 189 AC_CHECK_SIZEOF(off_t)
 190
 191 dnl
 192 dnl Checks for non-universal or system-specific types.
 193 dnl
 194 AC_TYPE_SIZE_T
 195 AC_TYPE_PID_T
 196 AC_CHECK_TYPES(uint32_t)
 197 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 198 #include <stdio.h>
 199 #include <sys/types.h>
 200 #if HAVE_INTTYPES_H
 201 # include <inttypes.h>
 202 #endif
 203 #include <signal.h>
 204 ])
 205
 206 dnl
 207 dnl Checks for library functions.
 208 dnl
 209 AC_FUNC_ALLOCA
 210 AC_FUNC_MMAP
 211 AC_FUNC_FSEEKO
 212 AC_CHECK_FUNCS(strptime snprintf vsnprintf)
 213 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp symlink)
 214
 215 dnl We expect to have these functions on Unix-like systems configure
 216 dnl runs on.  The defines are provided to get them in config.h.in so
 217 dnl Wget can still be ported to non-Unix systems (such as Windows)
 218 dnl that lack some of these functions.
 219 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 220 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 221 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 222 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 223 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 224
 225 dnl
 226 dnl Call Wget-specific macros defined in aclocal.
 227 dnl
 228 WGET_STRUCT_UTIMBUF
 229 WGET_SOCKLEN_T
 230 WGET_FNMATCH
 231 WGET_NANOSLEEP
 232 WGET_POSIX_CLOCK
 233 WGET_NSL_SOCKET
 234
 235 dnl
 236 dnl Check if we need to compile in getopt.c.
 237 dnl
 238 AC_CHECK_FUNC(getopt_long, [], [
 239   GETOPT_OBJ='getopt.o'
 240 ])
 241 AC_SUBST(GETOPT_OBJ)
 242
 243 dnl
 244 dnl Checks for libraries.
 245 dnl
 246
 247 dnl Check for OpenSSL
 248 if test x"$with_ssl" != x"no"
 249 then
 250   dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 251   dnl doesn't record its dependency on libdl, so we need to make sure
 252   dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 253   dnl dlopen(), but HP-UX uses dnl shl_load().
 254   AC_CHECK_LIB(dl, dlopen, [], [
 255     AC_CHECK_LIB(dl, shl_load)
 256   ])
 257
 258   dnl Now actually check for -lssl
 259   AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 260 #include <openssl/ssl.h>
 261 #include <openssl/x509.h>
 262 #include <openssl/err.h>
 263 #include <openssl/rand.h>
 264 #include <openssl/des.h>
 265 #include <openssl/md4.h>
 266 #include <openssl/md5.h>
 267   ], [SSL_library_init ()])
 268   if test x"$LIBSSL" != x
 269   then
 270     AC_MSG_NOTICE([compiling in support for SSL])
 271     AC_DEFINE([HAVE_SSL], 1,
 272               [Define if SSL support should be compiled in.])
 273     SSL_OBJ='openssl.o'
 274   fi
 275 fi
 276 AC_SUBST(SSL_OBJ)
 277
 278 dnl Enable NTLM if requested and if SSL is available.
 279 NTLM_OBJ=''
 280 if test x"$LIBSSL" != x
 281 then
 282   if test x"$ENABLE_NTLM" != xno
 283   then
 284     AC_DEFINE([ENABLE_NTLM], 1,
 285      [Define if you want the NTLM authorization support compiled in.])
 286     NTLM_OBJ='http-ntlm.o'
 287   fi
 288 else
 289   dnl If SSL is unavailable and the user explicitly requested NTLM,
 290   dnl abort.
 291   if test x"$ENABLE_NTLM" = xyes
 292   then
 293     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 294   fi
 295 fi
 296 AC_SUBST(NTLM_OBJ)
 297
 298 dnl
 299 dnl Find an md5 implementation.
 300 dnl
 301
 302 if test x"$wget_need_md5" = xyes
 303 then
 304   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 305   dnl manipulate MD5_OBJ from the defun.
 306
 307   MD5_OBJ='gen-md5.o'
 308   found_md5=no
 309
 310   dnl Check for the system MD5 library on Solaris.  We don't check for
 311   dnl something simple like "MD5Update" because there are a number of
 312   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 313   dnl specific to the Solaris MD5 library.
 314   if test x"$found_md5" = xno; then
 315     AC_CHECK_LIB(md5, md5_calc, [
 316       dnl Some installations have bogus <md5.h> in the compiler's
 317       dnl include path, making the system md5 library useless.
 318       AC_MSG_CHECKING([for working md5.h])
 319       AC_COMPILE_IFELSE([#include <md5.h>
 320                         ], [
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 323         LIBS="-lmd5 $LIBS"
 324         found_md5=yes
 325         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 326       ], [AC_MSG_RESULT(no)])
 327     ])
 328   fi
 329
 330   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 331   dnl implementation.
 332   if test x"$found_md5" = xno; then
 333     if test x"$ssl_success" = xyes; then
 334       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 335       found_md5=yes
 336       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 337     fi
 338   fi
 339
 340   dnl If none of the above worked, use the one we ship with Wget.
 341   if test x"$found_md5" = xno; then
 342     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 343     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 344     found_md5=yes
 345     AC_MSG_NOTICE([using the GNU MD5 implementation])
 346   fi
 347 fi
 348 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 349 AC_SUBST(MD5_OBJ)
 350
 351 dnl **********************************************************************
 352 dnl Checks for IPv6
 353 dnl **********************************************************************
 354
 355 dnl
 356 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 357 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 358 dnl don't use IPv6 or getaddrinfo.  Otherwise we detect IPv6 and use
 359 dnl it where available.
 360 dnl
 361
 362 AC_ARG_ENABLE(ipv6,
 363   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 364   [case "${enable_ipv6}" in
 365     no)
 366       AC_MSG_NOTICE([disabling IPv6 at user request])
 367       dnl Disable IPv6 checking
 368       ipv6=no
 369       ;;
 370     yes)
 371       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 372       ipv6=yes
 373       force_ipv6=yes
 374       ;;
 375     auto)
 376       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 377       ipv6=yes
 378       ;;
 379     *)
 380       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 381       ;;
 382     esac
 383   ], [
 384     dnl If nothing is specified, assume auto-detection.
 385     ipv6=yes
 386   ]
 387 )
 388
 389 if test "X$ipv6" = "Xyes"; then
 390   AC_CHECK_FUNCS(getaddrinfo, [], [
 391     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 392     ipv6=no
 393   ])
 394 fi
 395
 396 if test "X$ipv6" = "Xyes"; then
 397   PROTO_INET6([], [
 398     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 399     ipv6=no
 400   ])
 401 fi
 402
 403 if test "X$ipv6" = "Xyes"; then
 404   TYPE_STRUCT_SOCKADDR_IN6([],[
 405     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 406     ipv6=no
 407   ])
 408   if test "X$ipv6" = "Xyes"; then
 409     WGET_STRUCT_SOCKADDR_STORAGE
 410     MEMBER_SIN6_SCOPE_ID
 411   fi
 412 fi
 413
 414 if test "X$ipv6" = "Xyes"; then
 415   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 416   AC_MSG_NOTICE([Enabling support for IPv6.])
 417 elif test "x$force_ipv6" = "xyes"; then
 418   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 419 fi
 420
 421
 422 dnl
 423 dnl Set of available languages.
 424 dnl
 425 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 426
 427 dnl Originally this used to be static, looking like this:
 428 dnl     ALL_LINGUAS="cs de hr it ..."
 429 dnl The downside was that configure needed to be rebuilt whenever a
 430 dnl new language was added.
 431
 432 dnl internationalization macros
 433 WGET_WITH_NLS
 434
 435 dnl
 436 dnl Find makeinfo.  We used to provide support for Emacs processing
 437 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 438 dnl unavailable, but that broke with the addition of makeinfo-specific
 439 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 440 dnl build the Info documentation.
 441 dnl
 442
 443 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 444
 445 dnl
 446 dnl Find perl and pod2man
 447 dnl
 448
 449 AC_PATH_PROGS(PERL, [perl5 perl], no)
 450 AC_PATH_PROG(POD2MAN, pod2man, no)
 451
 452 if test "x${POD2MAN}" = xno; then
 453   COMMENT_IF_NO_POD2MAN="# "
 454 else
 455   COMMENT_IF_NO_POD2MAN=
 456 fi
 457 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 458
 459 dnl
 460 dnl Create output
 461 dnl
 462 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 463                  po/Makefile.in windows/Makefile])
 464 AC_CONFIG_HEADERS([src/config.h])
 465 AH_BOTTOM([
 466 #include "config-post.h"
 467 ])
 468 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 469 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 470 AC_OUTPUT