sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for typedefs, structures, and compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_PID_T
 158 AC_C_BIGENDIAN
 159
 160 dnl
 161 dnl Check integral type sizes.
 162 dnl
 163 AC_CHECK_SIZEOF(short)
 164 AC_CHECK_SIZEOF(int)
 165 AC_CHECK_SIZEOF(long)
 166 AC_CHECK_SIZEOF(long long)
 167 AC_CHECK_HEADERS(inttypes.h)
 168 AC_CHECK_TYPES(uint32_t)
 169
 170 dnl
 171 dnl Checks for headers
 172 dnl
 173 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 174 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 175 AC_CHECK_HEADERS(signal.h setjmp.h)
 176 AC_HEADER_TIME
 177
 178 dnl
 179 dnl Return type of signal-handlers
 180 dnl
 181 AC_TYPE_SIGNAL
 182
 183 dnl
 184 dnl Checks for library functions.
 185 dnl
 186 AC_FUNC_ALLOCA
 187 AC_FUNC_MMAP
 188 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 189 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 190 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 191 AC_CHECK_FUNCS(uname gethostname usleep)
 192
 193 dnl
 194 dnl Call Wget's local macros defined in aclocal.
 195 dnl
 196 WGET_STRUCT_UTIMBUF
 197 WGET_SOCKLEN_T
 198 WGET_FNMATCH
 199 WGET_NANOSLEEP
 200 WGET_NSL_SOCKET
 201
 202 dnl
 203 dnl Check if we need to compile in getopt.c.
 204 dnl
 205 AC_CHECK_FUNC(getopt_long, [], [
 206   GETOPT_OBJ='getopt$o'
 207 ])
 208 AC_SUBST(GETOPT_OBJ)
 209
 210 dnl
 211 dnl Checks for libraries.
 212 dnl
 213
 214 dnl #### This appears to be deficient with later versions of SOCKS.
 215 if test "x${with_socks}" = xyes
 216 then
 217   AC_CHECK_LIB(resolv, main)
 218   AC_CHECK_LIB(socks, Rconnect)
 219 fi
 220
 221 dnl $with_ssl can be one of:
 222 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 223 dnl  - "yes", meaning link with SSL or bail out.
 224 dnl  - "no", meaning don't link with SSL.
 225 dnl  - anything else, meaning use that as the SSL root, and bail out
 226 dnl    if it fails.
 227
 228 if test x"$with_ssl" = x; then
 229   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 230   dnl implements the "auto-detect by default" feature.  If you want to
 231   dnl change this to "ignore SSL by default", change "auto" to "no".
 232   with_ssl=auto
 233 fi
 234
 235 dnl Detection of OpenSSL is much hairier than the detection of other
 236 dnl libraries because OpenSSL can be compiled as a third-party
 237 dnl library, which means it will not be found without additional
 238 dnl linker magic.  It would be really nice to rework this check into
 239 dnl an AC_DEFUN so that we can reuse it for other third-party
 240 dnl libraries.
 241
 242 if test x"$with_ssl" != x"no"; then
 243
 244   wget_force_ssl=no
 245   if test x"$with_ssl" = x"yes"; then
 246     wget_force_ssl=yes
 247   fi
 248
 249   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 250     dnl OpenSSL's root was not specified, so we have to guess.  First
 251     dnl try the system default location, then "/usr/local/ssl" (where
 252     dnl OpenSSL installs by default), then "/usr/local" (traditional
 253     dnl choice for installation root), then "/opt".
 254     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 255   else
 256     dnl Root has been specified by the user.
 257     ssl_all_roots=$with_ssl
 258     wget_force_ssl=yes
 259   fi
 260
 261   wget_save_CC=$CC
 262   wget_save_LIBS=$LIBS
 263   wget_save_LDFLAGS=$LDFLAGS
 264   wget_save_CPPFLAGS=$CPPFLAGS
 265
 266   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 267   dnl without having to know how the linker handles it.
 268   CC="$SHELL ./libtool $CC"
 269
 270   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 271   dnl shared library doesn't record its dependency on libdl, so we
 272   dnl need to check for it ourselves so we won't fail to link due to a
 273   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 274   dnl shl_load().
 275   AC_CHECK_LIB(dl,dlopen)
 276   AC_CHECK_LIB(dl,shl_load)
 277
 278   ssl_success=no
 279
 280   dnl Now try to find SSL libraries in each of the likely SSL roots.
 281   for ssl_root in $ssl_all_roots
 282   do
 283     if test x"$ssl_root" = x"system-default"; then
 284       dnl Try the default include and library locations.
 285       SSL_INCLUDES=
 286     else
 287       dnl Try this specific root.
 288       SSL_INCLUDES=-I$ssl_root/include
 289       dnl It's OK to use -R directly because libtool will
 290       dnl interpret it for us.
 291       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 292     fi
 293
 294     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 295
 296     dnl Check whether the compiler can find the include files.  On
 297     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 298     dnl to find the includes in /usr/local/include.
 299
 300     ssl_found_includes=no
 301     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 302
 303     AC_MSG_CHECKING([for includes])
 304
 305     AC_TRY_CPP([#include <openssl/ssl.h>
 306 #include <openssl/rsa.h>
 307 ],
 308       AC_MSG_RESULT(found); ssl_found_includes=yes,
 309       AC_MSG_RESULT([not found])
 310     )
 311
 312     if test x"$ssl_found_includes" = xno; then
 313       continue
 314     fi
 315
 316     ssl_link_failure=no
 317
 318     dnl Make sure that the checks don't run afoul of the cache.  It
 319     dnl would be nicer to temporarily turn off the cache, but
 320     dnl apparently Autoconf doesn't allow that.
 321
 322     unset ac_cv_lib_crypto_RSA_new
 323     unset ac_cv_lib_ssl_SSL_new
 324
 325     dnl These checks need to be in this order, or you'll get a link
 326     dnl failure if you use a static libcrypto.a and libssl.a rather
 327     dnl than shared libraries.
 328
 329     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 330     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 331
 332     if test x"$ssl_link_failure" = xyes; then
 333       dnl One or both libs failed to link.
 334       continue
 335     fi
 336
 337     dnl The libraries link.  But we still need to check if the program
 338     dnl linked with those libraries under these settings with run.  On
 339     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 340     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 341     dnl executables that link, but fail to run.
 342
 343     dnl If we are cross-compiling, just assume that working linkage
 344     dnl implies working executable.
 345
 346     ssl_run_failure=no
 347
 348     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 349     AC_TRY_RUN([
 350 int RSA_new();
 351 int SSL_new();
 352 main(){return 0;}
 353 ],
 354       AC_MSG_RESULT(yes),
 355       AC_MSG_RESULT(no); ssl_run_failure=yes,
 356       AC_MSG_RESULT(cross)
 357     )
 358
 359     if test x"$ssl_run_failure" = xno; then
 360       ssl_success=yes
 361       break
 362     fi
 363   done
 364
 365   if test x"$ssl_success" = xyes; then
 366     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 367     dnl to use instead.
 368     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 369     AC_DEFINE(HAVE_SSL)
 370     AC_SUBST(SSL_INCLUDES)
 371     SSL_OBJ='gen_sslfunc$o'
 372     AC_SUBST(SSL_OBJ)
 373   else
 374     LDFLAGS=$wget_save_LDFLAGS
 375     LIBS=$wget_save_LIBS
 376
 377     dnl If linking with SSL was forced rather than auto-detected, then
 378     dnl bail out if SSL failed.
 379     if test x"$wget_force_ssl" = x"yes"; then
 380       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 381     fi
 382   fi
 383
 384   dnl Restore the compiler setting.
 385   CC=$wget_save_CC
 386
 387   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 388   dnl with SSL succeeded -- SSL includes will be handled using
 389   dnl @SSL_INCLUDES@.
 390   CPPFLAGS=$wget_save_CPPFLAGS
 391 fi
 392
 393 dnl
 394 dnl Find an md5 implementation.
 395 dnl
 396
 397 if test x"$wget_need_md5" = xyes
 398 then
 399   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 400   dnl manipulate MD5_OBJ from the defun.
 401
 402   MD5_OBJ='gen-md5$o'
 403   found_md5=no
 404
 405   dnl Check for the system MD5 library on Solaris.  We don't check for
 406   dnl something simple like "MD5Update" because there are a number of
 407   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 408   dnl specific to the Solaris MD5 library.
 409   if test x"$found_md5" = xno; then
 410     AC_CHECK_LIB(md5, md5_calc, [
 411       dnl Some installations have bogus <md5.h> in the compiler's
 412       dnl include path, making the system md5 library useless.
 413       AC_MSG_CHECKING([whether md5.h can be included])
 414       AC_COMPILE_IFELSE([#include <md5.h>
 415                         ], [
 416         AC_MSG_RESULT(yes)
 417         AC_DEFINE(HAVE_SOLARIS_MD5)
 418         LIBS="-lmd5 $LIBS"
 419         found_md5=yes
 420         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 421       ], [AC_MSG_RESULT(no)])
 422     ])
 423   fi
 424
 425   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 426   dnl implementation.
 427   if test x"$found_md5" = xno; then
 428     if test x"$ssl_success" = xyes; then
 429       AC_DEFINE(HAVE_OPENSSL_MD5)
 430       found_md5=yes
 431       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 432     fi
 433   fi
 434
 435   dnl If none of the above worked, use the one we ship with Wget.
 436   if test x"$found_md5" = xno; then
 437     AC_DEFINE(HAVE_BUILTIN_MD5)
 438     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 439     found_md5=yes
 440     AC_MSG_NOTICE([using the GNU MD5 implementation])
 441   fi
 442 fi
 443 AC_DEFINE(HAVE_MD5)
 444 AC_SUBST(MD5_OBJ)
 445
 446 dnl **********************************************************************
 447 dnl Checks for IPv6
 448 dnl **********************************************************************
 449
 450 dnl
 451 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 452 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 453 dnl don't use IPv6 or getaddrinfo.
 454 dnl
 455
 456 ipv6=
 457 check_for_ipv6=no
 458 AC_ARG_ENABLE(ipv6,
 459   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 460   [case "${enable_ipv6}" in
 461   no)
 462     AC_MSG_NOTICE([Disabling IPv6 at user request])
 463     ipv6=no
 464     ;;
 465   *)
 466     ipv6=yes
 467     ;;
 468   esac],
 469   dnl If unspecified, check for IPv6 and use it where available.
 470   [check_for_ipv6=yes]
 471 )
 472
 473 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 474   AC_CHECK_FUNCS(getaddrinfo,[
 475     GETADDRINFO_AI_ADDRCONFIG(
 476       AC_DEFINE(
 477         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 478         [Define if the system headers support the AI_ADDRCONFIG flag.]
 479       )
 480     )
 481     GETADDRINFO_AI_V4MAPPED(
 482       AC_DEFINE(
 483         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 484         [Define if the system headers support the AI_V4MAPPED flag.]
 485       )
 486     )
 487     GETADDRINFO_AI_ALL(
 488       AC_DEFINE(
 489         [HAVE_GETADDRINFO_AI_ALL], 1,
 490         [Define if the system headers support the AI_ALL flag.]
 491       )
 492     )
 493   ],[
 494     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 495     ipv6=no
 496   ])
 497 fi
 498
 499 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 500   PROTO_INET6(,[
 501     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 502     ipv6=no
 503   ])
 504 fi
 505
 506 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 507   TYPE_STRUCT_SOCKADDR_IN6([
 508     ipv6=yes
 509   ],[
 510     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 511     ipv6=no
 512   ])
 513   if test "X$ipv6" = "Xyes"; then
 514     MEMBER_SIN6_SCOPE_ID
 515   fi
 516 fi
 517
 518 if test "X$ipv6" = "Xyes"; then
 519   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 520 fi
 521
 522
 523 dnl
 524 dnl Set of available languages.
 525 dnl
 526 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 527
 528 dnl Originally this used to be static, looking like this:
 529 dnl     ALL_LINGUAS="cs de hr it ..."
 530 dnl The downside was that configure needed to be rebuilt whenever a
 531 dnl new language was added.
 532
 533 dnl internationalization macros
 534 WGET_WITH_NLS
 535
 536 dnl
 537 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 538 dnl Emacs cannot be found, look for XEmacs.
 539 dnl
 540
 541 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 542
 543 case "${MAKEINFO}" in
 544    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 545    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 546    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 547 esac
 548
 549 dnl
 550 dnl Find perl and pod2man
 551 dnl
 552
 553 AC_PATH_PROGS(PERL, perl5 perl, no)
 554 AC_PATH_PROG(POD2MAN, pod2man, no)
 555
 556 if test "x${POD2MAN}" = xno; then
 557   COMMENT_IF_NO_POD2MAN="# "
 558 else
 559   COMMENT_IF_NO_POD2MAN=
 560 fi
 561 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 562
 563 dnl
 564 dnl Create output
 565 dnl
 566 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 567            windows/Makefile],
 568 [WGET_PROCESS_PO
 569 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])