sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for basic compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_C_VOLATILE
 157 AC_C_BIGENDIAN
 158
 159 dnl
 160 dnl Checks for headers
 161 dnl
 162 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 164 AC_CHECK_HEADERS(inttypes.h signal.h setjmp.h pwd.h)
 165 AC_HEADER_TIME
 166
 167 dnl
 168 dnl Check integral type sizes.
 169 dnl
 170 AC_CHECK_SIZEOF(short)
 171 AC_CHECK_SIZEOF(int)
 172 AC_CHECK_SIZEOF(long)
 173 AC_CHECK_SIZEOF(long long)
 174
 175 dnl
 176 dnl Checks for non-universal or system-specific types.
 177 dnl
 178 AC_TYPE_SIZE_T
 179 AC_TYPE_PID_T
 180 AC_CHECK_TYPES(uint32_t)
 181 AC_TYPE_SIGNAL
 182 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 183 #include <stdio.h>
 184 #if HAVE_SYS_TYPES_H
 185 # include <sys/types.h>
 186 #endif
 187 #if HAVE_INTTYPES_H
 188 # include <inttypes.h>
 189 #endif
 190 #ifdef HAVE_SIGNAL_H
 191 # include <signal.h>
 192 #endif
 193 ])
 194
 195 dnl
 196 dnl Checks for library functions.
 197 dnl
 198 AC_FUNC_ALLOCA
 199 AC_FUNC_MMAP
 200 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 201 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 202 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 203
 204 dnl
 205 dnl Call Wget's local macros defined in aclocal.
 206 dnl
 207 WGET_STRUCT_UTIMBUF
 208 WGET_SOCKLEN_T
 209 WGET_FNMATCH
 210 WGET_NANOSLEEP
 211 WGET_NSL_SOCKET
 212
 213 dnl
 214 dnl Check if we need to compile in getopt.c.
 215 dnl
 216 AC_CHECK_FUNC(getopt_long, [], [
 217   GETOPT_OBJ='getopt$o'
 218 ])
 219 AC_SUBST(GETOPT_OBJ)
 220
 221 dnl
 222 dnl Checks for libraries.
 223 dnl
 224
 225 dnl #### This appears to be deficient with later versions of SOCKS.
 226 if test "x${with_socks}" = xyes
 227 then
 228   AC_CHECK_LIB(resolv, main)
 229   AC_CHECK_LIB(socks, Rconnect)
 230 fi
 231
 232 dnl $with_ssl can be one of:
 233 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 234 dnl  - "yes", meaning link with SSL or bail out.
 235 dnl  - "no", meaning don't link with SSL.
 236 dnl  - anything else, meaning use that as the SSL root, and bail out
 237 dnl    if it fails.
 238
 239 if test x"$with_ssl" = x; then
 240   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 241   dnl implements the "auto-detect by default" feature.  If you want to
 242   dnl change this to "ignore SSL by default", change "auto" to "no".
 243   with_ssl=auto
 244 fi
 245
 246 dnl Detection of OpenSSL is much hairier than the detection of other
 247 dnl libraries because OpenSSL can be compiled as a third-party
 248 dnl library, which means it will not be found without additional
 249 dnl linker magic.  It would be really nice to rework this check into
 250 dnl an AC_DEFUN so that we can reuse it for other third-party
 251 dnl libraries.
 252
 253 if test x"$with_ssl" != x"no"; then
 254
 255   wget_force_ssl=no
 256   if test x"$with_ssl" = x"yes"; then
 257     wget_force_ssl=yes
 258   fi
 259
 260   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 261     dnl OpenSSL's root was not specified, so we have to guess.  First
 262     dnl try the system default location, then "/usr/local/ssl" (where
 263     dnl OpenSSL installs by default), then "/usr/local" (traditional
 264     dnl choice for installation root), then "/opt".
 265     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 266   else
 267     dnl Root has been specified by the user.
 268     ssl_all_roots=$with_ssl
 269     wget_force_ssl=yes
 270   fi
 271
 272   wget_save_CC=$CC
 273   wget_save_LIBS=$LIBS
 274   wget_save_LDFLAGS=$LDFLAGS
 275   wget_save_CPPFLAGS=$CPPFLAGS
 276
 277   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 278   dnl without having to know how the linker handles it.
 279   CC="$SHELL ./libtool $CC"
 280
 281   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 282   dnl shared library doesn't record its dependency on libdl, so we
 283   dnl need to check for it ourselves so we won't fail to link due to a
 284   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 285   dnl shl_load().
 286   AC_CHECK_LIB(dl,dlopen)
 287   AC_CHECK_LIB(dl,shl_load)
 288
 289   ssl_success=no
 290
 291   dnl Now try to find SSL libraries in each of the likely SSL roots.
 292   for ssl_root in $ssl_all_roots
 293   do
 294     if test x"$ssl_root" = x"system-default"; then
 295       dnl Try the default include and library locations.
 296       SSL_INCLUDES=
 297     else
 298       dnl Try this specific root.
 299       SSL_INCLUDES=-I$ssl_root/include
 300       dnl It's OK to use -R directly because libtool will
 301       dnl interpret it for us.
 302       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 303     fi
 304
 305     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 306
 307     dnl Check whether the compiler can find the include files.  On
 308     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 309     dnl to find the includes in /usr/local/include.
 310
 311     ssl_found_includes=no
 312     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 313
 314     AC_MSG_CHECKING([for includes])
 315
 316     AC_TRY_CPP([#include <openssl/ssl.h>
 317 #include <openssl/rsa.h>
 318 ],
 319       AC_MSG_RESULT(found); ssl_found_includes=yes,
 320       AC_MSG_RESULT([not found])
 321     )
 322
 323     if test x"$ssl_found_includes" = xno; then
 324       continue
 325     fi
 326
 327     ssl_link_failure=no
 328
 329     dnl Make sure that the checks don't run afoul of the cache.  It
 330     dnl would be nicer to temporarily turn off the cache, but
 331     dnl apparently Autoconf doesn't allow that.
 332
 333     unset ac_cv_lib_crypto_RSA_new
 334     unset ac_cv_lib_ssl_SSL_new
 335
 336     dnl These checks need to be in this order, or you'll get a link
 337     dnl failure if you use a static libcrypto.a and libssl.a rather
 338     dnl than shared libraries.
 339
 340     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 341     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 342
 343     if test x"$ssl_link_failure" = xyes; then
 344       dnl One or both libs failed to link.
 345       continue
 346     fi
 347
 348     dnl The libraries link.  But we still need to check if the program
 349     dnl linked with those libraries under these settings with run.  On
 350     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 351     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 352     dnl executables that link, but fail to run.
 353
 354     dnl If we are cross-compiling, just assume that working linkage
 355     dnl implies working executable.
 356
 357     ssl_run_failure=no
 358
 359     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 360     AC_TRY_RUN([
 361 int RSA_new();
 362 int SSL_new();
 363 main(){return 0;}
 364 ],
 365       AC_MSG_RESULT(yes),
 366       AC_MSG_RESULT(no); ssl_run_failure=yes,
 367       AC_MSG_RESULT(cross)
 368     )
 369
 370     if test x"$ssl_run_failure" = xno; then
 371       ssl_success=yes
 372       break
 373     fi
 374   done
 375
 376   if test x"$ssl_success" = xyes; then
 377     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 378     dnl to use instead.
 379     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 380     AC_DEFINE(HAVE_SSL)
 381     AC_SUBST(SSL_INCLUDES)
 382     SSL_OBJ='gen_sslfunc$o'
 383     AC_SUBST(SSL_OBJ)
 384   else
 385     LDFLAGS=$wget_save_LDFLAGS
 386     LIBS=$wget_save_LIBS
 387
 388     dnl If linking with SSL was forced rather than auto-detected, then
 389     dnl bail out if SSL failed.
 390     if test x"$wget_force_ssl" = x"yes"; then
 391       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 392     fi
 393   fi
 394
 395   dnl Restore the compiler setting.
 396   CC=$wget_save_CC
 397
 398   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 399   dnl with SSL succeeded -- SSL includes will be handled using
 400   dnl @SSL_INCLUDES@.
 401   CPPFLAGS=$wget_save_CPPFLAGS
 402 fi
 403
 404 dnl
 405 dnl Find an md5 implementation.
 406 dnl
 407
 408 if test x"$wget_need_md5" = xyes
 409 then
 410   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 411   dnl manipulate MD5_OBJ from the defun.
 412
 413   MD5_OBJ='gen-md5$o'
 414   found_md5=no
 415
 416   dnl Check for the system MD5 library on Solaris.  We don't check for
 417   dnl something simple like "MD5Update" because there are a number of
 418   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 419   dnl specific to the Solaris MD5 library.
 420   if test x"$found_md5" = xno; then
 421     AC_CHECK_LIB(md5, md5_calc, [
 422       dnl Some installations have bogus <md5.h> in the compiler's
 423       dnl include path, making the system md5 library useless.
 424       AC_MSG_CHECKING([whether md5.h can be included])
 425       AC_COMPILE_IFELSE([#include <md5.h>
 426                         ], [
 427         AC_MSG_RESULT(yes)
 428         AC_DEFINE(HAVE_SOLARIS_MD5)
 429         LIBS="-lmd5 $LIBS"
 430         found_md5=yes
 431         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 432       ], [AC_MSG_RESULT(no)])
 433     ])
 434   fi
 435
 436   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 437   dnl implementation.
 438   if test x"$found_md5" = xno; then
 439     if test x"$ssl_success" = xyes; then
 440       AC_DEFINE(HAVE_OPENSSL_MD5)
 441       found_md5=yes
 442       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 443     fi
 444   fi
 445
 446   dnl If none of the above worked, use the one we ship with Wget.
 447   if test x"$found_md5" = xno; then
 448     AC_DEFINE(HAVE_BUILTIN_MD5)
 449     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 450     found_md5=yes
 451     AC_MSG_NOTICE([using the GNU MD5 implementation])
 452   fi
 453 fi
 454 AC_DEFINE(HAVE_MD5)
 455 AC_SUBST(MD5_OBJ)
 456
 457 dnl **********************************************************************
 458 dnl Checks for IPv6
 459 dnl **********************************************************************
 460
 461 dnl
 462 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 463 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 464 dnl don't use IPv6 or getaddrinfo.
 465 dnl
 466
 467 ipv6=
 468 check_for_ipv6=no
 469 AC_ARG_ENABLE(ipv6,
 470   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 471   [case "${enable_ipv6}" in
 472   no)
 473     AC_MSG_NOTICE([Disabling IPv6 at user request])
 474     ipv6=no
 475     ;;
 476   *)
 477     ipv6=yes
 478     ;;
 479   esac],
 480   dnl If unspecified, check for IPv6 and use it where available.
 481   [check_for_ipv6=yes]
 482 )
 483
 484 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 485   AC_CHECK_FUNCS(getaddrinfo,[
 486     GETADDRINFO_AI_ADDRCONFIG(
 487       AC_DEFINE(
 488         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 489         [Define if the system headers support the AI_ADDRCONFIG flag.]
 490       )
 491     )
 492     GETADDRINFO_AI_V4MAPPED(
 493       AC_DEFINE(
 494         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 495         [Define if the system headers support the AI_V4MAPPED flag.]
 496       )
 497     )
 498     GETADDRINFO_AI_ALL(
 499       AC_DEFINE(
 500         [HAVE_GETADDRINFO_AI_ALL], 1,
 501         [Define if the system headers support the AI_ALL flag.]
 502       )
 503     )
 504   ],[
 505     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 506     ipv6=no
 507   ])
 508 fi
 509
 510 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 511   PROTO_INET6(,[
 512     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 513     ipv6=no
 514   ])
 515 fi
 516
 517 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 518   TYPE_STRUCT_SOCKADDR_IN6([
 519     ipv6=yes
 520   ],[
 521     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 522     ipv6=no
 523   ])
 524   if test "X$ipv6" = "Xyes"; then
 525     MEMBER_SIN6_SCOPE_ID
 526   fi
 527 fi
 528
 529 if test "X$ipv6" = "Xyes"; then
 530   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 531 fi
 532
 533
 534 dnl
 535 dnl Set of available languages.
 536 dnl
 537 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 538
 539 dnl Originally this used to be static, looking like this:
 540 dnl     ALL_LINGUAS="cs de hr it ..."
 541 dnl The downside was that configure needed to be rebuilt whenever a
 542 dnl new language was added.
 543
 544 dnl internationalization macros
 545 WGET_WITH_NLS
 546
 547 dnl
 548 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 549 dnl Emacs cannot be found, look for XEmacs.
 550 dnl
 551
 552 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 553
 554 case "${MAKEINFO}" in
 555    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 556    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 557    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 558 esac
 559
 560 dnl
 561 dnl Find perl and pod2man
 562 dnl
 563
 564 AC_PATH_PROGS(PERL, perl5 perl, no)
 565 AC_PATH_PROG(POD2MAN, pod2man, no)
 566
 567 if test "x${POD2MAN}" = xno; then
 568   COMMENT_IF_NO_POD2MAN="# "
 569 else
 570   COMMENT_IF_NO_POD2MAN=
 571 fi
 572 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 573
 574 dnl
 575 dnl Create output
 576 dnl
 577 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 578            windows/Makefile],
 579 [WGET_PROCESS_PO
 580 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])