sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  62 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  68 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(ntlm,
  72 [  --disable-ntlm          disable support for NTLM authorization],
  73 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  74
  75 AC_ARG_ENABLE(debug,
  76 [  --disable-debug         disable support for debugging output],
  77 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  78 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  79    [Define if you want the debug output support compiled in.])
  80
  81 wget_need_md5=no
  82
  83 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  84 *yes*)
  85         wget_need_md5=yes
  86 esac
  87 if test x"$ENABLE_OPIE" = xyes; then
  88   OPIE_OBJ='ftp-opie.o'
  89 fi
  90 AC_SUBST(OPIE_OBJ)
  91
  92 dnl
  93 dnl Whether make sets $(MAKE)...
  94 dnl
  95 AC_PROG_MAKE_SET
  96
  97 dnl
  98 dnl Find a good install
  99 dnl
 100 AC_PROG_INSTALL
 101
 102 dnl
 103 dnl Find the compiler
 104 dnl
 105
 106 dnl We want these before the checks, so the checks can modify their values.
 107 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 108 test -z "$CC" && cc_specified=yes
 109
 110 AC_PROG_CC
 111 AC_AIX
 112
 113 dnl Turn on optimization by default.  Specifically:
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then
 117 dnl     use -O2 and some warning flags
 118 dnl   else
 119 dnl     use os-specific flags or -O
 120 if test -n "$auto_cflags"; then
 121   if test -n "$GCC"; then
 122     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 123   else
 124     case "$host_os" in
 125       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 126       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 127       *)       CFLAGS="$CFLAGS -O" ;;
 128     esac
 129   fi
 130 fi
 131
 132 dnl
 133 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 134 dnl Might also be erelevant for DJGPP.
 135 dnl
 136 case "$host_os" in
 137   *win32) exeext='.exe';;
 138   *) exeext='';;
 139 esac
 140 AC_SUBST(exeext)
 141
 142 dnl
 143 dnl Checks for basic compiler characteristics.
 144 dnl
 145 AC_C_CONST
 146 AC_C_INLINE
 147 AC_C_VOLATILE
 148 dnl Needed for GNU md5 code.
 149 AC_C_BIGENDIAN
 150
 151 dnl
 152 dnl Checks for header files that might be missing.
 153 dnl
 154
 155 dnl Check for basic headers, even those we assume the presence of.
 156 dnl This is because test programs used by Autoconf macros check for
 157 dnl STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before including them.
 158 dnl Without these checks they will fail to be included in test
 159 dnl programs, which will subsequently fail.
 160 AC_HEADER_STDC
 161 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 162
 163 dnl Now the real checks:
 164 AC_HEADER_STDBOOL
 165 AC_CHECK_HEADERS(string.h strings.h limits.h unistd.h sys/time.h)
 166 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 167 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 168
 169 dnl
 170 dnl Check sizes of signed integer types.  These are used to find n-bit
 171 dnl integral types on older systems that fail to provide intN_t and
 172 dnl uintN_t typedefs.
 173 dnl
 174 AC_CHECK_SIZEOF(short)
 175 AC_CHECK_SIZEOF(int)
 176 AC_CHECK_SIZEOF(long)
 177 AC_CHECK_SIZEOF(long long)
 178
 179 dnl
 180 dnl Check for large file support.  This check needs to come fairly
 181 dnl early because it could (in principle) affect whether functions and
 182 dnl headers are available, whether they work, etc.
 183 dnl
 184 AC_SYS_LARGEFILE
 185 AC_CHECK_SIZEOF(off_t)
 186
 187 dnl
 188 dnl Checks for non-universal or system-specific types.
 189 dnl
 190 AC_TYPE_SIZE_T
 191 AC_TYPE_PID_T
 192 AC_CHECK_TYPES(uint32_t)
 193 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 194 #include <stdio.h>
 195 #include <sys/types.h>
 196 #if HAVE_INTTYPES_H
 197 # include <inttypes.h>
 198 #endif
 199 #include <signal.h>
 200 ])
 201
 202 dnl
 203 dnl Checks for library functions.
 204 dnl
 205 AC_FUNC_ALLOCA
 206 AC_FUNC_MMAP
 207 AC_FUNC_FSEEKO
 208 AC_CHECK_FUNCS(strdup strcasecmp strncasecmp)
 209 AC_CHECK_FUNCS(strptime snprintf vsnprintf)
 210 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp)
 211 AC_CHECK_FUNCS(symlink isatty)
 212
 213 dnl
 214 dnl Call Wget-specific macros defined in aclocal.
 215 dnl
 216 WGET_STRUCT_UTIMBUF
 217 WGET_SOCKLEN_T
 218 WGET_FNMATCH
 219 WGET_NANOSLEEP
 220 WGET_POSIX_CLOCK
 221 WGET_NSL_SOCKET
 222
 223 dnl
 224 dnl Check if we need to compile in getopt.c.
 225 dnl
 226 AC_CHECK_FUNC(getopt_long, [], [
 227   GETOPT_OBJ='getopt.o'
 228 ])
 229 AC_SUBST(GETOPT_OBJ)
 230
 231 dnl
 232 dnl Checks for libraries.
 233 dnl
 234 AC_CHECK_LIB(dl,dlopen)
 235 AC_CHECK_LIB(dl,shl_load)
 236
 237 dnl Check for OpenSSL
 238 AC_LIB_LINKFLAGS([crypto])
 239 AC_LIB_LINKFLAGS([ssl],[crypto],[
 240 #include <openssl/ssl.h>
 241 #include <openssl/x509.h>
 242 #include <openssl/err.h>
 243 #include <openssl/rand.h>
 244 #include <openssl/des.h>
 245 #include <openssl/md4.h>
 246 #include <openssl/md5.h>
 247 ])
 248 if test x"$LIBSSL" != x
 249 then
 250   AC_MSG_NOTICE([compiling in support for SSL])
 251   AC_DEFINE([HAVE_SSL], 1,
 252             [Define if SSL support should be compiled in.])
 253   SSL_OBJ='openssl.o'
 254 fi
 255 AC_SUBST(SSL_OBJ)
 256
 257 dnl Enable NTLM if requested and if SSL is available.
 258 NTLM_OBJ=''
 259 if test x"$ssl_success" = xyes
 260 then
 261   if test x"$ENABLE_NTLM" != xno
 262   then
 263     AC_DEFINE([ENABLE_NTLM], 1,
 264      [Define if you want the NTLM authorization support compiled in.])
 265     NTLM_OBJ='http-ntlm.o'
 266   fi
 267 else
 268   dnl If SSL is unavailable and the user explicitly requested NTLM,
 269   dnl abort.
 270   if test x"$ENABLE_NTLM" = xyes
 271   then
 272     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 273   fi
 274 fi
 275 AC_SUBST(NTLM_OBJ)
 276
 277 dnl
 278 dnl Find an md5 implementation.
 279 dnl
 280
 281 if test x"$wget_need_md5" = xyes
 282 then
 283   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 284   dnl manipulate MD5_OBJ from the defun.
 285
 286   MD5_OBJ='gen-md5.o'
 287   found_md5=no
 288
 289   dnl Check for the system MD5 library on Solaris.  We don't check for
 290   dnl something simple like "MD5Update" because there are a number of
 291   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 292   dnl specific to the Solaris MD5 library.
 293   if test x"$found_md5" = xno; then
 294     AC_CHECK_LIB(md5, md5_calc, [
 295       dnl Some installations have bogus <md5.h> in the compiler's
 296       dnl include path, making the system md5 library useless.
 297       AC_MSG_CHECKING([for working md5.h])
 298       AC_COMPILE_IFELSE([#include <md5.h>
 299                         ], [
 300         AC_MSG_RESULT(yes)
 301         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 302         LIBS="-lmd5 $LIBS"
 303         found_md5=yes
 304         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 305       ], [AC_MSG_RESULT(no)])
 306     ])
 307   fi
 308
 309   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 310   dnl implementation.
 311   if test x"$found_md5" = xno; then
 312     if test x"$ssl_success" = xyes; then
 313       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 314       found_md5=yes
 315       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 316     fi
 317   fi
 318
 319   dnl If none of the above worked, use the one we ship with Wget.
 320   if test x"$found_md5" = xno; then
 321     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 322     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 323     found_md5=yes
 324     AC_MSG_NOTICE([using the GNU MD5 implementation])
 325   fi
 326 fi
 327 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 328 AC_SUBST(MD5_OBJ)
 329
 330 dnl **********************************************************************
 331 dnl Checks for IPv6
 332 dnl **********************************************************************
 333
 334 dnl
 335 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 336 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 337 dnl don't use IPv6 or getaddrinfo.  Otherwise we detect IPv6 and use
 338 dnl it where available.
 339 dnl
 340
 341 AC_ARG_ENABLE(ipv6,
 342   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 343   [case "${enable_ipv6}" in
 344     no)
 345       AC_MSG_NOTICE([disabling IPv6 at user request])
 346       dnl Disable IPv6 checking
 347       ipv6=no
 348       ;;
 349     yes)
 350       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 351       ipv6=yes
 352       force_ipv6=yes
 353       ;;
 354     auto)
 355       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 356       ipv6=yes
 357       ;;
 358     *)
 359       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 360       ;;
 361     esac
 362   ], [
 363     dnl If nothing is specified, assume auto-detection.
 364     ipv6=yes
 365   ]
 366 )
 367
 368 if test "X$ipv6" = "Xyes"; then
 369   AC_CHECK_FUNCS(getaddrinfo, [], [
 370     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 371     ipv6=no
 372   ])
 373 fi
 374
 375 if test "X$ipv6" = "Xyes"; then
 376   PROTO_INET6([], [
 377     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 378     ipv6=no
 379   ])
 380 fi
 381
 382 if test "X$ipv6" = "Xyes"; then
 383   TYPE_STRUCT_SOCKADDR_IN6([],[
 384     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 385     ipv6=no
 386   ])
 387   if test "X$ipv6" = "Xyes"; then
 388     WGET_STRUCT_SOCKADDR_STORAGE
 389     MEMBER_SIN6_SCOPE_ID
 390   fi
 391 fi
 392
 393 if test "X$ipv6" = "Xyes"; then
 394   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 395   AC_MSG_NOTICE([Enabling support for IPv6.])
 396 elif test "x$force_ipv6" = "xyes"; then
 397   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 398 fi
 399
 400
 401 dnl
 402 dnl Set of available languages.
 403 dnl
 404 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 405
 406 dnl Originally this used to be static, looking like this:
 407 dnl     ALL_LINGUAS="cs de hr it ..."
 408 dnl The downside was that configure needed to be rebuilt whenever a
 409 dnl new language was added.
 410
 411 dnl internationalization macros
 412 WGET_WITH_NLS
 413
 414 dnl
 415 dnl Find makeinfo.  We used to provide support for Emacs processing
 416 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 417 dnl unavailable, but that broke with the addition of makeinfo-specific
 418 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 419 dnl build the Info documentation.
 420 dnl
 421
 422 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 423
 424 dnl
 425 dnl Find perl and pod2man
 426 dnl
 427
 428 AC_PATH_PROGS(PERL, [perl5 perl], no)
 429 AC_PATH_PROG(POD2MAN, pod2man, no)
 430
 431 if test "x${POD2MAN}" = xno; then
 432   COMMENT_IF_NO_POD2MAN="# "
 433 else
 434   COMMENT_IF_NO_POD2MAN=
 435 fi
 436 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 437
 438 dnl
 439 dnl Create output
 440 dnl
 441 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 442                  po/Makefile.in windows/Makefile])
 443 AC_CONFIG_HEADERS([src/config.h])
 444 AH_BOTTOM([
 445 #include "config-post.h"
 446 ])
 447 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 448 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 449 AC_OUTPUT