sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 USE_OPIE=$enableval, USE_OPIE=yes)
  62 test x"${USE_OPIE}" = xyes && AC_DEFINE([USE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 USE_DIGEST=$enableval, USE_DIGEST=yes)
  68 test x"${USE_DIGEST}" = xyes && AC_DEFINE([USE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(debug,
  72 [  --disable-debug         disable support for debugging output],
  73 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  74 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  75    [Define if you want the debug output support compiled in.])
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107 AC_AIX
 108 AM_PROG_CC_STDC
 109
 110 dnl Turn on optimization by default.  Specifically:
 111 dnl
 112 dnl if the user hasn't specified CFLAGS, then
 113 dnl   if compiler is gcc, then
 114 dnl     use -O2 and some warning flags
 115 dnl   else
 116 dnl     use os-specific flags or -O
 117 if test -n "$auto_cflags"; then
 118   if test -n "$GCC"; then
 119     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 120   else
 121     case "$host_os" in
 122       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 123       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 124       *)       CFLAGS="$CFLAGS -O" ;;
 125     esac
 126   fi
 127 fi
 128
 129 dnl
 130 dnl Configure our included libtool and make sure it's regenerated when needed
 131 dnl
 132 AC_PROG_LIBTOOL
 133 AC_SUBST(LIBTOOL_DEPS)
 134
 135 dnl
 136 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 137 dnl Might also be erelevant for DJGPP.
 138 dnl
 139 case "$host_os" in
 140   *win32) exeext='.exe';;
 141   *) exeext='';;
 142 esac
 143 AC_SUBST(exeext)
 144
 145 dnl
 146 dnl Checks for basic compiler characteristics.
 147 dnl
 148 AC_C_CONST
 149 AC_C_INLINE
 150 AC_C_VOLATILE
 151 AC_C_BIGENDIAN
 152 AC_C_PROTOTYPES
 153
 154 if test x"$am_cv_prog_cc_stdc" != xno; then :
 155   AC_SUBST(U, [])
 156   AC_SUBST(ANSI2KNR, [])
 157 else
 158   AC_SUBST(U, [_])
 159   AC_SUBST(ANSI2KNR, [./ansi2knr])
 160 fi
 161
 162 dnl
 163 dnl Checks for header files that might be missing.
 164 dnl
 165
 166 dnl Check for basic headers, even those we assume the presence of.
 167 dnl This is because Autoconf default includes check for STDC_HEADERS,
 168 dnl HAVE_SYS_TYPES_H, etc. before including them.
 169 AC_HEADER_STDC
 170 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 171 dnl Now check for the others.
 172 AC_CHECK_HEADERS(string.h strings.h stdarg.h limits.h unistd.h sys/time.h)
 173 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 174 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 175 AC_HEADER_TIME
 176
 177 dnl
 178 dnl Check integral type sizes.
 179 dnl
 180 AC_CHECK_SIZEOF(short)
 181 AC_CHECK_SIZEOF(int)
 182 AC_CHECK_SIZEOF(long)
 183 AC_CHECK_SIZEOF(long long)
 184
 185 dnl
 186 dnl Check for large file support.  This check needs to come fairly
 187 dnl early because it could (in principle) affect whether functions and
 188 dnl headers are available, whether they work, etc.
 189 dnl
 190 AC_SYS_LARGEFILE
 191 AC_CHECK_SIZEOF(off_t)
 192
 193 dnl
 194 dnl Checks for non-universal or system-specific types.
 195 dnl
 196 AC_TYPE_SIZE_T
 197 AC_TYPE_PID_T
 198 AC_CHECK_TYPES(uint32_t)
 199 AC_TYPE_SIGNAL
 200 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 201 #include <stdio.h>
 202 #include <sys/types.h>
 203 #if HAVE_INTTYPES_H
 204 # include <inttypes.h>
 205 #endif
 206 #ifdef HAVE_SIGNAL_H
 207 # include <signal.h>
 208 #endif
 209 ])
 210
 211 dnl
 212 dnl Checks for library functions.
 213 dnl
 214 AC_FUNC_ALLOCA
 215 AC_FUNC_MMAP
 216 AC_FUNC_FSEEKO
 217 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 218 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 219 AC_CHECK_FUNCS(usleep select ftello sigblock sigsetjmp signal)
 220 AC_CHECK_FUNCS(symlink access isatty)
 221
 222 dnl
 223 dnl Call Wget's local macros defined in aclocal.
 224 dnl
 225 WGET_STRUCT_UTIMBUF
 226 WGET_SOCKLEN_T
 227 WGET_FNMATCH
 228 WGET_NANOSLEEP
 229 WGET_NSL_SOCKET
 230
 231 dnl
 232 dnl Check if we need to compile in getopt.c.
 233 dnl
 234 AC_CHECK_FUNC(getopt_long, [], [
 235   GETOPT_OBJ='getopt$o'
 236 ])
 237 AC_SUBST(GETOPT_OBJ)
 238
 239 dnl
 240 dnl Checks for libraries.
 241 dnl
 242
 243 dnl $with_ssl can be one of:
 244 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 245 dnl  - "yes", meaning link with SSL or bail out.
 246 dnl  - "no", meaning don't link with SSL.
 247 dnl  - anything else, meaning use that as the SSL root, and bail out
 248 dnl    if it fails.
 249
 250 if test x"$with_ssl" = x; then
 251   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 252   dnl implements the "auto-detect by default" feature.  If you want to
 253   dnl change this to "ignore SSL by default", change "auto" to "no".
 254   with_ssl=auto
 255 fi
 256
 257 dnl Detection of OpenSSL is much hairier than the detection of other
 258 dnl libraries because OpenSSL can be compiled as a third-party
 259 dnl library, which means it will not be found without additional
 260 dnl linker magic.  It would be really nice to rework this check into
 261 dnl an AC_DEFUN so that we can reuse it for other third-party
 262 dnl libraries.
 263
 264 if test x"$with_ssl" != x"no"; then
 265
 266   wget_force_ssl=no
 267   if test x"$with_ssl" = x"yes"; then
 268     wget_force_ssl=yes
 269   fi
 270
 271   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 272     dnl OpenSSL's root was not specified, so we have to guess.  First
 273     dnl try the system default location, then "/usr/local/ssl" (where
 274     dnl OpenSSL installs by default), then "/usr/local" (traditional
 275     dnl choice for installation root), then "/opt".
 276     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 277   else
 278     dnl Root has been specified by the user.
 279     ssl_all_roots=$with_ssl
 280     wget_force_ssl=yes
 281   fi
 282
 283   wget_save_CC=$CC
 284   wget_save_LIBS=$LIBS
 285   wget_save_LDFLAGS=$LDFLAGS
 286   wget_save_CPPFLAGS=$CPPFLAGS
 287
 288   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 289   dnl without having to know how the linker handles it.
 290   CC="$SHELL ./libtool $CC"
 291
 292   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 293   dnl shared library doesn't record its dependency on libdl, so we
 294   dnl need to check for it ourselves so we won't fail to link due to a
 295   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 296   dnl shl_load().
 297   AC_CHECK_LIB(dl,dlopen)
 298   AC_CHECK_LIB(dl,shl_load)
 299
 300   ssl_success=no
 301
 302   dnl Now try to find SSL libraries in each of the likely SSL roots.
 303   for ssl_root in $ssl_all_roots
 304   do
 305     if test x"$ssl_root" = x"system-default"; then
 306       dnl Try the default include and library locations.
 307       SSL_INCLUDES=
 308     else
 309       dnl Try this specific root.
 310       SSL_INCLUDES=-I$ssl_root/include
 311       dnl It's OK to use -R directly because libtool will
 312       dnl interpret it for us.
 313       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 314     fi
 315
 316     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 317
 318     dnl Check whether the compiler can find the include files.  On
 319     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 320     dnl to find the includes in /usr/local/include.
 321
 322     ssl_found_includes=no
 323     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 324
 325     AC_MSG_CHECKING([for includes])
 326     AC_COMPILE_IFELSE([
 327 #include <openssl/ssl.h>
 328 #include <openssl/rsa.h>
 329     ], [
 330       AC_MSG_RESULT(found)
 331       ssl_found_includes=yes
 332     ], [
 333       AC_MSG_RESULT([not found])
 334     ])
 335
 336     if test x"$ssl_found_includes" = xno; then
 337       continue
 338     fi
 339
 340     ssl_link_failure=no
 341
 342     dnl Make sure that the checks don't run afoul of the cache.  It
 343     dnl would be nicer to temporarily turn off the cache, but
 344     dnl apparently Autoconf doesn't allow that.
 345
 346     unset ac_cv_lib_crypto_RSA_new
 347     unset ac_cv_lib_ssl_SSL_new
 348
 349     dnl These checks need to be in this order, or you'll get a link
 350     dnl failure if you use a static libcrypto.a and libssl.a rather
 351     dnl than shared libraries.
 352
 353     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 354     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 355
 356     if test x"$ssl_link_failure" = xyes; then
 357       dnl One or both libs failed to link.
 358       continue
 359     fi
 360
 361     dnl The libraries link.  But we still need to check if the program
 362     dnl linked with those libraries under these settings with run.  On
 363     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 364     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 365     dnl executables that link, but fail to run.
 366
 367     dnl If we are cross-compiling, just assume that working linkage
 368     dnl implies working executable.
 369
 370     ssl_run_failure=no
 371
 372     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 373     AC_TRY_RUN([
 374 int RSA_new();
 375 int SSL_new();
 376 main(){return 0;}
 377 ],
 378       AC_MSG_RESULT(yes),
 379       AC_MSG_RESULT(no); ssl_run_failure=yes,
 380       AC_MSG_RESULT(cross)
 381     )
 382
 383     if test x"$ssl_run_failure" = xno; then
 384       ssl_success=yes
 385       break
 386     fi
 387   done
 388
 389   if test x"$ssl_success" = xyes; then
 390     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 391     AC_DEFINE([HAVE_SSL], 1,
 392               [Define if SSL support should be compiled in.])
 393     AC_SUBST(SSL_INCLUDES)
 394     SSL_OBJ='gen_sslfunc$o'
 395     AC_SUBST(SSL_OBJ)
 396   else
 397     LDFLAGS=$wget_save_LDFLAGS
 398     LIBS=$wget_save_LIBS
 399
 400     dnl If linking with SSL was forced rather than auto-detected, then
 401     dnl bail out if SSL failed.
 402     if test x"$wget_force_ssl" = x"yes"; then
 403       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 404     fi
 405   fi
 406
 407   dnl Restore the compiler setting.
 408   CC=$wget_save_CC
 409
 410   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 411   dnl with SSL succeeded -- SSL includes will be handled using
 412   dnl @SSL_INCLUDES@.
 413   CPPFLAGS=$wget_save_CPPFLAGS
 414 fi
 415
 416 dnl
 417 dnl Find an md5 implementation.
 418 dnl
 419
 420 if test x"$wget_need_md5" = xyes
 421 then
 422   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 423   dnl manipulate MD5_OBJ from the defun.
 424
 425   MD5_OBJ='gen-md5$o'
 426   found_md5=no
 427
 428   dnl Check for the system MD5 library on Solaris.  We don't check for
 429   dnl something simple like "MD5Update" because there are a number of
 430   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 431   dnl specific to the Solaris MD5 library.
 432   if test x"$found_md5" = xno; then
 433     AC_CHECK_LIB(md5, md5_calc, [
 434       dnl Some installations have bogus <md5.h> in the compiler's
 435       dnl include path, making the system md5 library useless.
 436       AC_MSG_CHECKING([for working md5.h])
 437       AC_COMPILE_IFELSE([#include <md5.h>
 438                         ], [
 439         AC_MSG_RESULT(yes)
 440         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 441         LIBS="-lmd5 $LIBS"
 442         found_md5=yes
 443         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 444       ], [AC_MSG_RESULT(no)])
 445     ])
 446   fi
 447
 448   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 449   dnl implementation.
 450   if test x"$found_md5" = xno; then
 451     if test x"$ssl_success" = xyes; then
 452       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 453       found_md5=yes
 454       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 455     fi
 456   fi
 457
 458   dnl If none of the above worked, use the one we ship with Wget.
 459   if test x"$found_md5" = xno; then
 460     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 461     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 462     found_md5=yes
 463     AC_MSG_NOTICE([using the GNU MD5 implementation])
 464   fi
 465 fi
 466 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 467 AC_SUBST(MD5_OBJ)
 468
 469 dnl **********************************************************************
 470 dnl Checks for IPv6
 471 dnl **********************************************************************
 472
 473 dnl
 474 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 475 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 476 dnl don't use IPv6 or getaddrinfo.
 477 dnl
 478
 479 ipv6=
 480 check_for_ipv6=no
 481 AC_ARG_ENABLE(ipv6,
 482   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 483   [case "${enable_ipv6}" in
 484   no)
 485     AC_MSG_NOTICE([disabling IPv6 at user request])
 486     ipv6=no
 487     ;;
 488   *)
 489     ipv6=yes
 490     ;;
 491   esac],
 492   dnl If unspecified, check for IPv6 and use it where available.
 493   [check_for_ipv6=yes]
 494 )
 495
 496 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 497   AC_CHECK_FUNCS(getaddrinfo, [
 498     GETADDRINFO_AI_ADDRCONFIG([
 499       AC_DEFINE(
 500         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 501         [Define if the system headers support the AI_ADDRCONFIG flag.]
 502       )
 503     ])
 504   ], [
 505     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 506     ipv6=no
 507   ])
 508 fi
 509
 510 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 511   PROTO_INET6([], [
 512     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 513     ipv6=no
 514   ])
 515 fi
 516
 517 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 518   TYPE_STRUCT_SOCKADDR_IN6([
 519     ipv6=yes
 520   ],[
 521     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 522     ipv6=no
 523   ])
 524   if test "X$ipv6" = "Xyes"; then
 525     WGET_STRUCT_SOCKADDR_STORAGE
 526     MEMBER_SIN6_SCOPE_ID
 527   fi
 528 fi
 529
 530 if test "X$ipv6" = "Xyes"; then
 531   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 532 fi
 533
 534
 535 dnl
 536 dnl Set of available languages.
 537 dnl
 538 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 539
 540 dnl Originally this used to be static, looking like this:
 541 dnl     ALL_LINGUAS="cs de hr it ..."
 542 dnl The downside was that configure needed to be rebuilt whenever a
 543 dnl new language was added.
 544
 545 dnl internationalization macros
 546 WGET_WITH_NLS
 547
 548 dnl
 549 dnl Find makeinfo.  We used to provide support for Emacs processing
 550 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 551 dnl unavailable, but that broke with the addition of makeinfo-specific
 552 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 553 dnl build the Info documentation.
 554 dnl
 555
 556 AC_CHECK_PROGS(MAKEINFO, makeinfo)
 557
 558 dnl
 559 dnl Find perl and pod2man
 560 dnl
 561
 562 AC_PATH_PROGS(PERL, perl5 perl, no)
 563 AC_PATH_PROG(POD2MAN, pod2man, no)
 564
 565 if test "x${POD2MAN}" = xno; then
 566   COMMENT_IF_NO_POD2MAN="# "
 567 else
 568   COMMENT_IF_NO_POD2MAN=
 569 fi
 570 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 571
 572 dnl
 573 dnl Create output
 574 dnl
 575 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 576                  po/Makefile.in windows/Makefile])
 577 AC_CONFIG_HEADERS([src/config.h])
 578 AH_BOTTOM([
 579 #include "config-post.h"
 580 ])
 581 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 582 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 583 AC_OUTPUT