sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  62 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  68 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(ntlm,
  72 [  --disable-ntlm          disable support for NTLM authorization],
  73 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  74
  75 AC_ARG_ENABLE(debug,
  76 [  --disable-debug         disable support for debugging output],
  77 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  78 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  79    [Define if you want the debug output support compiled in.])
  80
  81 wget_need_md5=no
  82
  83 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  84 *yes*)
  85         wget_need_md5=yes
  86 esac
  87 if test x"$ENABLE_OPIE" = xyes; then
  88   OPIE_OBJ='ftp-opie$o'
  89 fi
  90 AC_SUBST(OPIE_OBJ)
  91
  92 dnl
  93 dnl Whether make sets $(MAKE)...
  94 dnl
  95 AC_PROG_MAKE_SET
  96
  97 dnl
  98 dnl Find a good install
  99 dnl
 100 AC_PROG_INSTALL
 101
 102 dnl
 103 dnl Find the compiler
 104 dnl
 105
 106 dnl We want these before the checks, so the checks can modify their values.
 107 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 108 test -z "$CC" && cc_specified=yes
 109
 110 AC_PROG_CC
 111 AC_AIX
 112 AM_PROG_CC_STDC
 113
 114 dnl Turn on optimization by default.  Specifically:
 115 dnl
 116 dnl if the user hasn't specified CFLAGS, then
 117 dnl   if compiler is gcc, then
 118 dnl     use -O2 and some warning flags
 119 dnl   else
 120 dnl     use os-specific flags or -O
 121 if test -n "$auto_cflags"; then
 122   if test -n "$GCC"; then
 123     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 124   else
 125     case "$host_os" in
 126       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 127       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 128       *)       CFLAGS="$CFLAGS -O" ;;
 129     esac
 130   fi
 131 fi
 132
 133 dnl
 134 dnl Configure our included libtool and make sure it's regenerated when needed
 135 dnl
 136 AC_PROG_LIBTOOL
 137 AC_SUBST(LIBTOOL_DEPS)
 138
 139 dnl
 140 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 141 dnl Might also be erelevant for DJGPP.
 142 dnl
 143 case "$host_os" in
 144   *win32) exeext='.exe';;
 145   *) exeext='';;
 146 esac
 147 AC_SUBST(exeext)
 148
 149 dnl
 150 dnl Checks for basic compiler characteristics.
 151 dnl
 152 AC_C_CONST
 153 AC_C_INLINE
 154 AC_C_VOLATILE
 155 AC_C_BIGENDIAN
 156 AC_C_PROTOTYPES
 157
 158 if test x"$am_cv_prog_cc_stdc" != xno; then :
 159   AC_SUBST(U, [])
 160   AC_SUBST(ANSI2KNR, [])
 161 else
 162   AC_SUBST(U, [_])
 163   AC_SUBST(ANSI2KNR, [./ansi2knr])
 164 fi
 165
 166 dnl
 167 dnl Checks for header files that might be missing.
 168 dnl
 169
 170 dnl Check for basic headers, even those we assume the presence of.
 171 dnl This is because Autoconf default includes check for STDC_HEADERS,
 172 dnl HAVE_SYS_TYPES_H, etc. before including them.
 173 AC_HEADER_STDC
 174 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 175 dnl Now check for the others.
 176 AC_CHECK_HEADERS(string.h strings.h stdarg.h limits.h unistd.h sys/time.h)
 177 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 178 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 179 AC_HEADER_TIME
 180
 181 dnl
 182 dnl Check integral type sizes.
 183 dnl
 184 AC_CHECK_SIZEOF(short)
 185 AC_CHECK_SIZEOF(int)
 186 AC_CHECK_SIZEOF(long)
 187 AC_CHECK_SIZEOF(long long)
 188
 189 dnl
 190 dnl Check for large file support.  This check needs to come fairly
 191 dnl early because it could (in principle) affect whether functions and
 192 dnl headers are available, whether they work, etc.
 193 dnl
 194 AC_SYS_LARGEFILE
 195 AC_CHECK_SIZEOF(off_t)
 196
 197 dnl
 198 dnl Checks for non-universal or system-specific types.
 199 dnl
 200 AC_TYPE_SIZE_T
 201 AC_TYPE_PID_T
 202 AC_CHECK_TYPES(uint32_t)
 203 AC_TYPE_SIGNAL
 204 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 205 #include <stdio.h>
 206 #include <sys/types.h>
 207 #if HAVE_INTTYPES_H
 208 # include <inttypes.h>
 209 #endif
 210 #ifdef HAVE_SIGNAL_H
 211 # include <signal.h>
 212 #endif
 213 ])
 214
 215 dnl
 216 dnl Checks for library functions.
 217 dnl
 218 AC_FUNC_ALLOCA
 219 AC_FUNC_MMAP
 220 AC_FUNC_FSEEKO
 221 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 222 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 223 AC_CHECK_FUNCS(usleep select ftello sigblock sigsetjmp signal)
 224 AC_CHECK_FUNCS(symlink access isatty)
 225
 226 dnl
 227 dnl Call Wget's local macros defined in aclocal.
 228 dnl
 229 WGET_STRUCT_UTIMBUF
 230 WGET_SOCKLEN_T
 231 WGET_FNMATCH
 232 WGET_NANOSLEEP
 233 WGET_POSIX_CLOCK
 234 WGET_NSL_SOCKET
 235
 236 dnl
 237 dnl Check if we need to compile in getopt.c.
 238 dnl
 239 AC_CHECK_FUNC(getopt_long, [], [
 240   GETOPT_OBJ='getopt$o'
 241 ])
 242 AC_SUBST(GETOPT_OBJ)
 243
 244 dnl
 245 dnl Checks for libraries.
 246 dnl
 247
 248 dnl $with_ssl can be one of:
 249 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 250 dnl  - "yes", meaning link with SSL or bail out.
 251 dnl  - "no", meaning don't link with SSL.
 252 dnl  - anything else, meaning use that as the SSL root, and bail out
 253 dnl    if it fails.
 254
 255 if test x"$with_ssl" = x; then
 256   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 257   dnl implements the "auto-detect by default" feature.  If you want to
 258   dnl change this to "ignore SSL by default", change "auto" to "no".
 259   with_ssl=auto
 260 fi
 261
 262 dnl Detection of OpenSSL is much hairier than the detection of other
 263 dnl libraries because OpenSSL can be compiled as a third-party
 264 dnl library, which means it will not be found without additional
 265 dnl linker magic.  It would be really nice to rework this check into
 266 dnl an AC_DEFUN so that we can reuse it for other third-party
 267 dnl libraries.
 268
 269 if test x"$with_ssl" != x"no"; then
 270
 271   wget_force_ssl=no
 272   if test x"$with_ssl" = x"yes"; then
 273     wget_force_ssl=yes
 274   fi
 275
 276   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 277     dnl OpenSSL's root was not specified, so we have to guess.  First
 278     dnl try the system default location, then "/usr/local/ssl" (where
 279     dnl OpenSSL installs by default), then "/usr/local" (traditional
 280     dnl choice for installation root), then "/opt".
 281     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 282   else
 283     dnl Root has been specified by the user.
 284     ssl_all_roots=$with_ssl
 285     wget_force_ssl=yes
 286   fi
 287
 288   wget_save_CC=$CC
 289   wget_save_LIBS=$LIBS
 290   wget_save_LDFLAGS=$LDFLAGS
 291   wget_save_CPPFLAGS=$CPPFLAGS
 292
 293   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 294   dnl without having to know how the linker handles it.
 295   CC="$SHELL ./libtool $CC"
 296
 297   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 298   dnl shared library doesn't record its dependency on libdl, so we
 299   dnl need to check for it ourselves so we won't fail to link due to a
 300   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 301   dnl shl_load().
 302   AC_CHECK_LIB(dl,dlopen)
 303   AC_CHECK_LIB(dl,shl_load)
 304
 305   ssl_success=no
 306
 307   dnl Now try to find SSL libraries in each of the likely SSL roots.
 308   for ssl_root in $ssl_all_roots
 309   do
 310     if test x"$ssl_root" = x"system-default"; then
 311       dnl Try the default include and library locations.
 312       SSL_INCLUDES=
 313     else
 314       dnl Try this specific root.
 315       SSL_INCLUDES=-I$ssl_root/include
 316       dnl It's OK to use -R directly because libtool will
 317       dnl interpret it for us.
 318       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 319     fi
 320
 321     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 322
 323     dnl Check whether the compiler can find the include files.  On
 324     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 325     dnl to find the includes in /usr/local/include.
 326
 327     ssl_found_includes=no
 328     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 329
 330     dnl Check for all the OpenSSL includes that Wget actually uses.
 331     dnl This will prune both invalid installations and ancient
 332     dnl versions of OpenSSL that we can't use.
 333     AC_MSG_CHECKING([for includes])
 334     AC_COMPILE_IFELSE([
 335 #include <openssl/ssl.h>
 336 #include <openssl/bio.h>
 337 #include <openssl/crypto.h>
 338 #include <openssl/des.h>
 339 #include <openssl/err.h>
 340 #include <openssl/md4.h>
 341 #include <openssl/pem.h>
 342 #include <openssl/rand.h>
 343 #include <openssl/x509.h>
 344     ], [
 345       AC_MSG_RESULT(found)
 346       ssl_found_includes=yes
 347     ], [
 348       AC_MSG_RESULT([not found])
 349     ])
 350
 351     if test x"$ssl_found_includes" = xno; then
 352       continue
 353     fi
 354
 355     ssl_link_failure=no
 356
 357     dnl Make sure that the checks don't run afoul of the cache.  It
 358     dnl would be nicer to temporarily turn off the cache, but
 359     dnl apparently Autoconf doesn't allow that.
 360
 361     unset ac_cv_lib_crypto_RSA_new
 362     unset ac_cv_lib_ssl_SSL_new
 363
 364     dnl These checks need to be in this order, or you'll get a link
 365     dnl failure if you use a static libcrypto.a and libssl.a rather
 366     dnl than shared libraries.
 367
 368     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 369     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 370
 371     if test x"$ssl_link_failure" = xyes; then
 372       dnl One or both libs failed to link.
 373       continue
 374     fi
 375
 376     dnl The libraries link.  But we still need to check if the program
 377     dnl linked with those libraries under these settings with run.  On
 378     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 379     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 380     dnl executables that link, but fail to run.
 381
 382     dnl If we are cross-compiling, just assume that working linkage
 383     dnl implies working executable.
 384
 385     ssl_run_failure=no
 386
 387     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 388     AC_TRY_RUN([
 389 int RSA_new();
 390 int SSL_new();
 391 main(){return 0;}
 392 ],
 393       AC_MSG_RESULT(yes),
 394       AC_MSG_RESULT(no); ssl_run_failure=yes,
 395       AC_MSG_RESULT(cross)
 396     )
 397
 398     if test x"$ssl_run_failure" = xno; then
 399       ssl_success=yes
 400       break
 401     fi
 402   done
 403
 404   if test x"$ssl_success" = xyes; then
 405     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 406     AC_DEFINE([HAVE_SSL], 1,
 407               [Define if SSL support should be compiled in.])
 408     AC_SUBST(SSL_INCLUDES)
 409     SSL_OBJ='openssl$o'
 410     AC_SUBST(SSL_OBJ)
 411   else
 412     LDFLAGS=$wget_save_LDFLAGS
 413     LIBS=$wget_save_LIBS
 414
 415     dnl If linking with SSL was forced rather than auto-detected, then
 416     dnl bail out if SSL failed.
 417     if test x"$wget_force_ssl" = x"yes"; then
 418       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 419     fi
 420   fi
 421
 422   dnl Restore the compiler setting.
 423   CC=$wget_save_CC
 424
 425   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 426   dnl with SSL succeeded -- SSL includes will be handled using
 427   dnl @SSL_INCLUDES@.
 428   CPPFLAGS=$wget_save_CPPFLAGS
 429 fi
 430
 431 dnl Enable NTLM if requested and if SSL is available.
 432 NTLM_OBJ=''
 433 if test x"$ssl_success" = xyes
 434 then
 435   if test x"$ENABLE_NTLM" != xno
 436   then
 437     AC_DEFINE([ENABLE_NTLM], 1,
 438      [Define if you want the NTLM authorization support compiled in.])
 439     NTLM_OBJ='http-ntlm$o'
 440   fi
 441 else
 442   dnl If SSL is unavailable and the user explicitly requested NTLM,
 443   dnl abort.
 444   if test x"$ENABLE_NTLM" = xyes
 445   then
 446     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 447   fi
 448 fi
 449 AC_SUBST(NTLM_OBJ)
 450
 451 dnl
 452 dnl Find an md5 implementation.
 453 dnl
 454
 455 if test x"$wget_need_md5" = xyes
 456 then
 457   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 458   dnl manipulate MD5_OBJ from the defun.
 459
 460   MD5_OBJ='gen-md5$o'
 461   found_md5=no
 462
 463   dnl Check for the system MD5 library on Solaris.  We don't check for
 464   dnl something simple like "MD5Update" because there are a number of
 465   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 466   dnl specific to the Solaris MD5 library.
 467   if test x"$found_md5" = xno; then
 468     AC_CHECK_LIB(md5, md5_calc, [
 469       dnl Some installations have bogus <md5.h> in the compiler's
 470       dnl include path, making the system md5 library useless.
 471       AC_MSG_CHECKING([for working md5.h])
 472       AC_COMPILE_IFELSE([#include <md5.h>
 473                         ], [
 474         AC_MSG_RESULT(yes)
 475         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 476         LIBS="-lmd5 $LIBS"
 477         found_md5=yes
 478         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 479       ], [AC_MSG_RESULT(no)])
 480     ])
 481   fi
 482
 483   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 484   dnl implementation.
 485   if test x"$found_md5" = xno; then
 486     if test x"$ssl_success" = xyes; then
 487       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 488       found_md5=yes
 489       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 490     fi
 491   fi
 492
 493   dnl If none of the above worked, use the one we ship with Wget.
 494   if test x"$found_md5" = xno; then
 495     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 496     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 497     found_md5=yes
 498     AC_MSG_NOTICE([using the GNU MD5 implementation])
 499   fi
 500 fi
 501 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 502 AC_SUBST(MD5_OBJ)
 503
 504 dnl **********************************************************************
 505 dnl Checks for IPv6
 506 dnl **********************************************************************
 507
 508 dnl
 509 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 510 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 511 dnl don't use IPv6 or getaddrinfo.
 512 dnl
 513
 514 ipv6=
 515 check_for_ipv6=no
 516 AC_ARG_ENABLE(ipv6,
 517   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 518   [case "${enable_ipv6}" in
 519   no)
 520     AC_MSG_NOTICE([disabling IPv6 at user request])
 521     ipv6=no
 522     ;;
 523   *)
 524     ipv6=yes
 525     ;;
 526   esac],
 527   dnl If unspecified, check for IPv6 and use it where available.
 528   [check_for_ipv6=yes]
 529 )
 530
 531 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 532   AC_CHECK_FUNCS(getaddrinfo, [], [
 533     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 534     ipv6=no
 535   ])
 536 fi
 537
 538 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 539   PROTO_INET6([], [
 540     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 541     ipv6=no
 542   ])
 543 fi
 544
 545 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 546   TYPE_STRUCT_SOCKADDR_IN6([
 547     ipv6=yes
 548   ],[
 549     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 550     ipv6=no
 551   ])
 552   if test "X$ipv6" = "Xyes"; then
 553     WGET_STRUCT_SOCKADDR_STORAGE
 554     MEMBER_SIN6_SCOPE_ID
 555   fi
 556 fi
 557
 558 if test "X$ipv6" = "Xyes"; then
 559   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 560 fi
 561
 562
 563 dnl
 564 dnl Set of available languages.
 565 dnl
 566 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 567
 568 dnl Originally this used to be static, looking like this:
 569 dnl     ALL_LINGUAS="cs de hr it ..."
 570 dnl The downside was that configure needed to be rebuilt whenever a
 571 dnl new language was added.
 572
 573 dnl internationalization macros
 574 WGET_WITH_NLS
 575
 576 dnl
 577 dnl Find makeinfo.  We used to provide support for Emacs processing
 578 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 579 dnl unavailable, but that broke with the addition of makeinfo-specific
 580 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 581 dnl build the Info documentation.
 582 dnl
 583
 584 AC_CHECK_PROGS(MAKEINFO, makeinfo)
 585
 586 dnl
 587 dnl Find perl and pod2man
 588 dnl
 589
 590 AC_PATH_PROGS(PERL, perl5 perl, no)
 591 AC_PATH_PROG(POD2MAN, pod2man, no)
 592
 593 if test "x${POD2MAN}" = xno; then
 594   COMMENT_IF_NO_POD2MAN="# "
 595 else
 596   COMMENT_IF_NO_POD2MAN=
 597 fi
 598 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 599
 600 dnl
 601 dnl Create output
 602 dnl
 603 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 604                  po/Makefile.in windows/Makefile])
 605 AC_CONFIG_HEADERS([src/config.h])
 606 AH_BOTTOM([
 607 #include "config-post.h"
 608 ])
 609 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 610 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 611 AC_OUTPUT