sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  62 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  68 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(ntlm,
  72 [  --disable-ntlm          disable support for NTLM authorization],
  73 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  74
  75 AC_ARG_ENABLE(debug,
  76 [  --disable-debug         disable support for debugging output],
  77 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  78 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  79    [Define if you want the debug output support compiled in.])
  80
  81 wget_need_md5=no
  82
  83 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  84 *yes*)
  85         wget_need_md5=yes
  86 esac
  87 if test x"$ENABLE_OPIE" = xyes; then
  88   OPIE_OBJ='ftp-opie.o'
  89 fi
  90 AC_SUBST(OPIE_OBJ)
  91
  92 dnl
  93 dnl Whether make sets $(MAKE)...
  94 dnl
  95 AC_PROG_MAKE_SET
  96
  97 dnl
  98 dnl Find a good install
  99 dnl
 100 AC_PROG_INSTALL
 101
 102 dnl
 103 dnl Find the compiler
 104 dnl
 105
 106 dnl We want these before the checks, so the checks can modify their values.
 107 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 108 test -z "$CC" && cc_specified=yes
 109
 110 AC_PROG_CC
 111 AC_AIX
 112
 113 dnl Turn on optimization by default.  Specifically:
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then
 117 dnl     use -O2 and some warning flags
 118 dnl   else
 119 dnl     use os-specific flags or -O
 120 if test -n "$auto_cflags"; then
 121   if test -n "$GCC"; then
 122     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 123   else
 124     case "$host_os" in
 125       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 126       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 127       *)       CFLAGS="$CFLAGS -O" ;;
 128     esac
 129   fi
 130 fi
 131
 132 dnl
 133 dnl Configure our included libtool and make sure it's regenerated when needed
 134 dnl
 135 AC_PROG_LIBTOOL
 136 AC_SUBST(LIBTOOL_DEPS)
 137
 138 dnl
 139 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 140 dnl Might also be erelevant for DJGPP.
 141 dnl
 142 case "$host_os" in
 143   *win32) exeext='.exe';;
 144   *) exeext='';;
 145 esac
 146 AC_SUBST(exeext)
 147
 148 dnl
 149 dnl Checks for basic compiler characteristics.
 150 dnl
 151 AC_C_CONST
 152 AC_C_INLINE
 153 AC_C_VOLATILE
 154 AC_C_BIGENDIAN
 155 AC_C_PROTOTYPES
 156
 157 dnl
 158 dnl Checks for header files that might be missing.
 159 dnl
 160
 161 dnl Check for basic headers, even those we assume the presence of.
 162 dnl This is because Autoconf default includes check for STDC_HEADERS,
 163 dnl HAVE_SYS_TYPES_H, etc. before including them.
 164 AC_HEADER_STDC
 165 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 166 dnl Now check for the others.
 167 AC_CHECK_HEADERS(string.h strings.h limits.h unistd.h sys/time.h)
 168 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 169 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 170 AC_HEADER_TIME
 171
 172 dnl
 173 dnl Check integral type sizes.
 174 dnl
 175 AC_CHECK_SIZEOF(short)
 176 AC_CHECK_SIZEOF(int)
 177 AC_CHECK_SIZEOF(long)
 178 AC_CHECK_SIZEOF(long long)
 179
 180 dnl
 181 dnl Check for large file support.  This check needs to come fairly
 182 dnl early because it could (in principle) affect whether functions and
 183 dnl headers are available, whether they work, etc.
 184 dnl
 185 AC_SYS_LARGEFILE
 186 AC_CHECK_SIZEOF(off_t)
 187
 188 dnl
 189 dnl Checks for non-universal or system-specific types.
 190 dnl
 191 AC_TYPE_SIZE_T
 192 AC_TYPE_PID_T
 193 AC_CHECK_TYPES(uint32_t)
 194 AC_TYPE_SIGNAL
 195 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 196 #include <stdio.h>
 197 #include <sys/types.h>
 198 #if HAVE_INTTYPES_H
 199 # include <inttypes.h>
 200 #endif
 201 #ifdef HAVE_SIGNAL_H
 202 # include <signal.h>
 203 #endif
 204 ])
 205
 206 dnl
 207 dnl Checks for library functions.
 208 dnl
 209 AC_FUNC_ALLOCA
 210 AC_FUNC_MMAP
 211 AC_FUNC_FSEEKO
 212 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 213 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 214 AC_CHECK_FUNCS(usleep select ftello sigblock sigsetjmp signal)
 215 AC_CHECK_FUNCS(symlink access isatty)
 216
 217 dnl
 218 dnl Call Wget's local macros defined in aclocal.
 219 dnl
 220 WGET_STRUCT_UTIMBUF
 221 WGET_SOCKLEN_T
 222 WGET_FNMATCH
 223 WGET_NANOSLEEP
 224 WGET_POSIX_CLOCK
 225 WGET_NSL_SOCKET
 226
 227 dnl
 228 dnl Check if we need to compile in getopt.c.
 229 dnl
 230 AC_CHECK_FUNC(getopt_long, [], [
 231   GETOPT_OBJ='getopt.o'
 232 ])
 233 AC_SUBST(GETOPT_OBJ)
 234
 235 dnl
 236 dnl Checks for libraries.
 237 dnl
 238
 239 dnl $with_ssl can be one of:
 240 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 241 dnl  - "yes", meaning link with SSL or bail out.
 242 dnl  - "no", meaning don't link with SSL.
 243 dnl  - anything else, meaning use that as the SSL root, and bail out
 244 dnl    if it fails.
 245
 246 if test x"$with_ssl" = x; then
 247   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 248   dnl implements the "auto-detect by default" feature.  If you want to
 249   dnl change this to "ignore SSL by default", change "auto" to "no".
 250   with_ssl=auto
 251 fi
 252
 253 dnl Detection of OpenSSL is much hairier than the detection of other
 254 dnl libraries because OpenSSL can be compiled as a third-party
 255 dnl library, which means it will not be found without additional
 256 dnl linker magic.  It would be really nice to rework this check into
 257 dnl an AC_DEFUN so that we can reuse it for other third-party
 258 dnl libraries.
 259
 260 if test x"$with_ssl" != x"no"; then
 261
 262   wget_force_ssl=no
 263   if test x"$with_ssl" = x"yes"; then
 264     wget_force_ssl=yes
 265   fi
 266
 267   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 268     dnl OpenSSL's root was not specified, so we have to guess.  First
 269     dnl try the system default location, then "/usr/local/ssl" (where
 270     dnl OpenSSL installs by default), then "/usr/local" (traditional
 271     dnl choice for installation root), then "/opt".
 272     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 273   else
 274     dnl Root has been specified by the user.
 275     ssl_all_roots=$with_ssl
 276     wget_force_ssl=yes
 277   fi
 278
 279   wget_save_CC=$CC
 280   wget_save_LIBS=$LIBS
 281   wget_save_LDFLAGS=$LDFLAGS
 282   wget_save_CPPFLAGS=$CPPFLAGS
 283
 284   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 285   dnl without having to know how the linker handles it.
 286   CC="$SHELL ./libtool $CC"
 287
 288   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 289   dnl shared library doesn't record its dependency on libdl, so we
 290   dnl need to check for it ourselves so we won't fail to link due to a
 291   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 292   dnl shl_load().
 293   AC_CHECK_LIB(dl,dlopen)
 294   AC_CHECK_LIB(dl,shl_load)
 295
 296   ssl_success=no
 297
 298   dnl Now try to find SSL libraries in each of the likely SSL roots.
 299   for ssl_root in $ssl_all_roots
 300   do
 301     if test x"$ssl_root" = x"system-default"; then
 302       dnl Try the default include and library locations.
 303       SSL_INCLUDES=
 304     else
 305       dnl Try this specific root.
 306       SSL_INCLUDES=-I$ssl_root/include
 307       dnl It's OK to use -R directly because libtool will
 308       dnl interpret it for us.
 309       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 310     fi
 311
 312     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 313
 314     dnl Check whether the compiler can find the include files.  On
 315     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 316     dnl to find the includes in /usr/local/include.
 317
 318     ssl_found_includes=no
 319     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 320
 321     dnl Check for all the OpenSSL includes that Wget actually uses.
 322     dnl This will prune both invalid installations and ancient
 323     dnl versions of OpenSSL that we can't use.
 324     AC_MSG_CHECKING([for includes])
 325     AC_COMPILE_IFELSE([
 326 #include <openssl/ssl.h>
 327 #include <openssl/x509.h>
 328 #include <openssl/err.h>
 329 #include <openssl/rand.h>
 330 #include <openssl/des.h>
 331 #include <openssl/md4.h>
 332 #include <openssl/md5.h>
 333     ], [
 334       AC_MSG_RESULT(found)
 335       ssl_found_includes=yes
 336     ], [
 337       AC_MSG_RESULT([not found])
 338     ])
 339
 340     if test x"$ssl_found_includes" = xno; then
 341       continue
 342     fi
 343
 344     ssl_link_failure=no
 345
 346     dnl Make sure that the checks don't run afoul of the cache.  It
 347     dnl would be nicer to temporarily turn off the cache, but
 348     dnl apparently Autoconf doesn't allow that.
 349
 350     unset ac_cv_lib_crypto_RSA_new
 351     unset ac_cv_lib_ssl_SSL_new
 352
 353     dnl These checks need to be in this order, or you'll get a link
 354     dnl failure if you use a static libcrypto.a and libssl.a rather
 355     dnl than shared libraries.
 356
 357     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 358     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 359
 360     if test x"$ssl_link_failure" = xyes; then
 361       dnl One or both libs failed to link.
 362       continue
 363     fi
 364
 365     dnl The libraries link.  But we still need to check if the program
 366     dnl linked with those libraries under these settings with run.  On
 367     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 368     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 369     dnl executables that link, but fail to run.
 370
 371     dnl If we are cross-compiling, just assume that working linkage
 372     dnl implies working executable.
 373
 374     ssl_run_failure=no
 375
 376     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 377     AC_TRY_RUN([
 378 int RSA_new();
 379 int SSL_new();
 380 main(){return 0;}
 381 ],
 382       AC_MSG_RESULT(yes),
 383       AC_MSG_RESULT(no); ssl_run_failure=yes,
 384       AC_MSG_RESULT(cross)
 385     )
 386
 387     if test x"$ssl_run_failure" = xno; then
 388       ssl_success=yes
 389       break
 390     fi
 391   done
 392
 393   if test x"$ssl_success" = xyes; then
 394     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 395     AC_DEFINE([HAVE_SSL], 1,
 396               [Define if SSL support should be compiled in.])
 397     AC_SUBST(SSL_INCLUDES)
 398     SSL_OBJ='openssl.o'
 399     AC_SUBST(SSL_OBJ)
 400   else
 401     LDFLAGS=$wget_save_LDFLAGS
 402     LIBS=$wget_save_LIBS
 403
 404     dnl If linking with SSL was forced rather than auto-detected, then
 405     dnl bail out if SSL failed.
 406     if test x"$wget_force_ssl" = x"yes"; then
 407       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 408     fi
 409   fi
 410
 411   dnl Restore the compiler setting.
 412   CC=$wget_save_CC
 413
 414   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 415   dnl with SSL succeeded -- SSL includes will be handled using
 416   dnl @SSL_INCLUDES@.
 417   CPPFLAGS=$wget_save_CPPFLAGS
 418 fi
 419
 420 dnl Enable NTLM if requested and if SSL is available.
 421 NTLM_OBJ=''
 422 if test x"$ssl_success" = xyes
 423 then
 424   if test x"$ENABLE_NTLM" != xno
 425   then
 426     AC_DEFINE([ENABLE_NTLM], 1,
 427      [Define if you want the NTLM authorization support compiled in.])
 428     NTLM_OBJ='http-ntlm.o'
 429   fi
 430 else
 431   dnl If SSL is unavailable and the user explicitly requested NTLM,
 432   dnl abort.
 433   if test x"$ENABLE_NTLM" = xyes
 434   then
 435     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 436   fi
 437 fi
 438 AC_SUBST(NTLM_OBJ)
 439
 440 dnl
 441 dnl Find an md5 implementation.
 442 dnl
 443
 444 if test x"$wget_need_md5" = xyes
 445 then
 446   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 447   dnl manipulate MD5_OBJ from the defun.
 448
 449   MD5_OBJ='gen-md5.o'
 450   found_md5=no
 451
 452   dnl Check for the system MD5 library on Solaris.  We don't check for
 453   dnl something simple like "MD5Update" because there are a number of
 454   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 455   dnl specific to the Solaris MD5 library.
 456   if test x"$found_md5" = xno; then
 457     AC_CHECK_LIB(md5, md5_calc, [
 458       dnl Some installations have bogus <md5.h> in the compiler's
 459       dnl include path, making the system md5 library useless.
 460       AC_MSG_CHECKING([for working md5.h])
 461       AC_COMPILE_IFELSE([#include <md5.h>
 462                         ], [
 463         AC_MSG_RESULT(yes)
 464         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 465         LIBS="-lmd5 $LIBS"
 466         found_md5=yes
 467         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 468       ], [AC_MSG_RESULT(no)])
 469     ])
 470   fi
 471
 472   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 473   dnl implementation.
 474   if test x"$found_md5" = xno; then
 475     if test x"$ssl_success" = xyes; then
 476       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 477       found_md5=yes
 478       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 479     fi
 480   fi
 481
 482   dnl If none of the above worked, use the one we ship with Wget.
 483   if test x"$found_md5" = xno; then
 484     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 485     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 486     found_md5=yes
 487     AC_MSG_NOTICE([using the GNU MD5 implementation])
 488   fi
 489 fi
 490 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 491 AC_SUBST(MD5_OBJ)
 492
 493 dnl **********************************************************************
 494 dnl Checks for IPv6
 495 dnl **********************************************************************
 496
 497 dnl
 498 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 499 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 500 dnl don't use IPv6 or getaddrinfo.  Otherwise we detect IPv6 and use
 501 dnl it where available.
 502 dnl
 503
 504 AC_ARG_ENABLE(ipv6,
 505   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 506   [case "${enable_ipv6}" in
 507     no)
 508       AC_MSG_NOTICE([disabling IPv6 at user request])
 509       dnl Disable IPv6 checking
 510       ipv6=no
 511       ;;
 512     yes)
 513       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 514       ipv6=yes
 515       force_ipv6=yes
 516       ;;
 517     auto)
 518       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 519       ipv6=yes
 520       ;;
 521     *)
 522       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 523       ;;
 524     esac
 525   ], [
 526     dnl If nothing is specified, assume auto-detection.
 527     ipv6=yes
 528   ]
 529 )
 530
 531 if test "X$ipv6" = "Xyes"; then
 532   AC_CHECK_FUNCS(getaddrinfo, [], [
 533     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 534     ipv6=no
 535   ])
 536 fi
 537
 538 if test "X$ipv6" = "Xyes"; then
 539   PROTO_INET6([], [
 540     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 541     ipv6=no
 542   ])
 543 fi
 544
 545 if test "X$ipv6" = "Xyes"; then
 546   TYPE_STRUCT_SOCKADDR_IN6([],[
 547     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 548     ipv6=no
 549   ])
 550   if test "X$ipv6" = "Xyes"; then
 551     WGET_STRUCT_SOCKADDR_STORAGE
 552     MEMBER_SIN6_SCOPE_ID
 553   fi
 554 fi
 555
 556 if test "X$ipv6" = "Xyes"; then
 557   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 558   AC_MSG_NOTICE([Enabling support for IPv6.])
 559 elif test "x$force_ipv6" = "xyes"; then
 560   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 561 fi
 562
 563
 564 dnl
 565 dnl Set of available languages.
 566 dnl
 567 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 568
 569 dnl Originally this used to be static, looking like this:
 570 dnl     ALL_LINGUAS="cs de hr it ..."
 571 dnl The downside was that configure needed to be rebuilt whenever a
 572 dnl new language was added.
 573
 574 dnl internationalization macros
 575 WGET_WITH_NLS
 576
 577 dnl
 578 dnl Find makeinfo.  We used to provide support for Emacs processing
 579 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 580 dnl unavailable, but that broke with the addition of makeinfo-specific
 581 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 582 dnl build the Info documentation.
 583 dnl
 584
 585 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 586
 587 dnl
 588 dnl Find perl and pod2man
 589 dnl
 590
 591 AC_PATH_PROGS(PERL, [perl5 perl], no)
 592 AC_PATH_PROG(POD2MAN, pod2man, no)
 593
 594 if test "x${POD2MAN}" = xno; then
 595   COMMENT_IF_NO_POD2MAN="# "
 596 else
 597   COMMENT_IF_NO_POD2MAN=
 598 fi
 599 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 600
 601 dnl
 602 dnl Create output
 603 dnl
 604 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 605                  po/Makefile.in windows/Makefile])
 606 AC_CONFIG_HEADERS([src/config.h])
 607 AH_BOTTOM([
 608 #include "config-post.h"
 609 ])
 610 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 611 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 612 AC_OUTPUT