sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 USE_OPIE=$enableval, USE_OPIE=yes)
  62 test x"${USE_OPIE}" = xyes && AC_DEFINE([USE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 USE_DIGEST=$enableval, USE_DIGEST=yes)
  68 test x"${USE_DIGEST}" = xyes && AC_DEFINE([USE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(debug,
  72 [  --disable-debug         disable support for debugging output],
  73 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  74 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  75    [Define if you want the debug output support compiled in.])
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107 AC_AIX
 108 AM_PROG_CC_STDC
 109
 110 dnl Turn on optimization by default.  Specifically:
 111 dnl
 112 dnl if the user hasn't specified CFLAGS, then
 113 dnl   if compiler is gcc, then
 114 dnl     use -O2 and some warning flags
 115 dnl   else
 116 dnl     use os-specific flags or -O
 117 if test -n "$auto_cflags"; then
 118   if test -n "$GCC"; then
 119     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 120   else
 121     case "$host_os" in
 122       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 123       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 124       *)       CFLAGS="$CFLAGS -O" ;;
 125     esac
 126   fi
 127 fi
 128
 129 dnl
 130 dnl Configure our included libtool and make sure it's regenerated when needed
 131 dnl
 132 AC_PROG_LIBTOOL
 133 AC_SUBST(LIBTOOL_DEPS)
 134
 135 dnl
 136 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 137 dnl Might also be erelevant for DJGPP.
 138 dnl
 139 case "$host_os" in
 140   *win32) exeext='.exe';;
 141   *) exeext='';;
 142 esac
 143 AC_SUBST(exeext)
 144
 145 dnl
 146 dnl Checks for basic compiler characteristics.
 147 dnl
 148 AC_C_CONST
 149 AC_C_INLINE
 150 AC_C_VOLATILE
 151 AC_C_BIGENDIAN
 152 AC_C_PROTOTYPES
 153
 154 if test x"$am_cv_prog_cc_stdc" != xno; then :
 155   AC_SUBST(U, [])
 156   AC_SUBST(ANSI2KNR, [])
 157 else
 158   AC_SUBST(U, [_])
 159   AC_SUBST(ANSI2KNR, [./ansi2knr])
 160 fi
 161
 162 dnl
 163 dnl Checks for header files that might be missing.
 164 dnl
 165
 166 dnl Check for basic headers, even those we assume the presence of.
 167 dnl This is because Autoconf default includes check for STDC_HEADERS,
 168 dnl HAVE_SYS_TYPES_H, etc. before including them.
 169 AC_HEADER_STDC
 170 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 171 dnl Now check for the others.
 172 AC_CHECK_HEADERS(string.h strings.h stdarg.h limits.h unistd.h sys/time.h)
 173 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 174 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 175 AC_HEADER_TIME
 176
 177 dnl
 178 dnl Check integral type sizes.
 179 dnl
 180 AC_CHECK_SIZEOF(short)
 181 AC_CHECK_SIZEOF(int)
 182 AC_CHECK_SIZEOF(long)
 183 AC_CHECK_SIZEOF(long long)
 184
 185 dnl
 186 dnl Checks for non-universal or system-specific types.
 187 dnl
 188 AC_TYPE_SIZE_T
 189 AC_TYPE_PID_T
 190 AC_CHECK_TYPES(uint32_t)
 191 AC_TYPE_SIGNAL
 192 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 193 #include <stdio.h>
 194 #include <sys/types.h>
 195 #if HAVE_INTTYPES_H
 196 # include <inttypes.h>
 197 #endif
 198 #ifdef HAVE_SIGNAL_H
 199 # include <signal.h>
 200 #endif
 201 ])
 202
 203 dnl
 204 dnl Checks for library functions.
 205 dnl
 206 AC_FUNC_ALLOCA
 207 AC_FUNC_MMAP
 208 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 209 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 210 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 211
 212 dnl
 213 dnl Call Wget's local macros defined in aclocal.
 214 dnl
 215 WGET_STRUCT_UTIMBUF
 216 WGET_SOCKLEN_T
 217 WGET_FNMATCH
 218 WGET_NANOSLEEP
 219 WGET_NSL_SOCKET
 220
 221 dnl
 222 dnl Check if we need to compile in getopt.c.
 223 dnl
 224 AC_CHECK_FUNC(getopt_long, [], [
 225   GETOPT_OBJ='getopt$o'
 226 ])
 227 AC_SUBST(GETOPT_OBJ)
 228
 229 dnl
 230 dnl Checks for libraries.
 231 dnl
 232
 233 dnl $with_ssl can be one of:
 234 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 235 dnl  - "yes", meaning link with SSL or bail out.
 236 dnl  - "no", meaning don't link with SSL.
 237 dnl  - anything else, meaning use that as the SSL root, and bail out
 238 dnl    if it fails.
 239
 240 if test x"$with_ssl" = x; then
 241   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 242   dnl implements the "auto-detect by default" feature.  If you want to
 243   dnl change this to "ignore SSL by default", change "auto" to "no".
 244   with_ssl=auto
 245 fi
 246
 247 dnl Detection of OpenSSL is much hairier than the detection of other
 248 dnl libraries because OpenSSL can be compiled as a third-party
 249 dnl library, which means it will not be found without additional
 250 dnl linker magic.  It would be really nice to rework this check into
 251 dnl an AC_DEFUN so that we can reuse it for other third-party
 252 dnl libraries.
 253
 254 if test x"$with_ssl" != x"no"; then
 255
 256   wget_force_ssl=no
 257   if test x"$with_ssl" = x"yes"; then
 258     wget_force_ssl=yes
 259   fi
 260
 261   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 262     dnl OpenSSL's root was not specified, so we have to guess.  First
 263     dnl try the system default location, then "/usr/local/ssl" (where
 264     dnl OpenSSL installs by default), then "/usr/local" (traditional
 265     dnl choice for installation root), then "/opt".
 266     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 267   else
 268     dnl Root has been specified by the user.
 269     ssl_all_roots=$with_ssl
 270     wget_force_ssl=yes
 271   fi
 272
 273   wget_save_CC=$CC
 274   wget_save_LIBS=$LIBS
 275   wget_save_LDFLAGS=$LDFLAGS
 276   wget_save_CPPFLAGS=$CPPFLAGS
 277
 278   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 279   dnl without having to know how the linker handles it.
 280   CC="$SHELL ./libtool $CC"
 281
 282   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 283   dnl shared library doesn't record its dependency on libdl, so we
 284   dnl need to check for it ourselves so we won't fail to link due to a
 285   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 286   dnl shl_load().
 287   AC_CHECK_LIB(dl,dlopen)
 288   AC_CHECK_LIB(dl,shl_load)
 289
 290   ssl_success=no
 291
 292   dnl Now try to find SSL libraries in each of the likely SSL roots.
 293   for ssl_root in $ssl_all_roots
 294   do
 295     if test x"$ssl_root" = x"system-default"; then
 296       dnl Try the default include and library locations.
 297       SSL_INCLUDES=
 298     else
 299       dnl Try this specific root.
 300       SSL_INCLUDES=-I$ssl_root/include
 301       dnl It's OK to use -R directly because libtool will
 302       dnl interpret it for us.
 303       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 304     fi
 305
 306     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 307
 308     dnl Check whether the compiler can find the include files.  On
 309     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 310     dnl to find the includes in /usr/local/include.
 311
 312     ssl_found_includes=no
 313     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 314
 315     AC_MSG_CHECKING([for includes])
 316     AC_COMPILE_IFELSE([
 317 #include <openssl/ssl.h>
 318 #include <openssl/rsa.h>
 319     ], [
 320       AC_MSG_RESULT(found)
 321       ssl_found_includes=yes
 322     ], [
 323       AC_MSG_RESULT([not found])
 324     ])
 325
 326     if test x"$ssl_found_includes" = xno; then
 327       continue
 328     fi
 329
 330     ssl_link_failure=no
 331
 332     dnl Make sure that the checks don't run afoul of the cache.  It
 333     dnl would be nicer to temporarily turn off the cache, but
 334     dnl apparently Autoconf doesn't allow that.
 335
 336     unset ac_cv_lib_crypto_RSA_new
 337     unset ac_cv_lib_ssl_SSL_new
 338
 339     dnl These checks need to be in this order, or you'll get a link
 340     dnl failure if you use a static libcrypto.a and libssl.a rather
 341     dnl than shared libraries.
 342
 343     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 344     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 345
 346     if test x"$ssl_link_failure" = xyes; then
 347       dnl One or both libs failed to link.
 348       continue
 349     fi
 350
 351     dnl The libraries link.  But we still need to check if the program
 352     dnl linked with those libraries under these settings with run.  On
 353     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 354     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 355     dnl executables that link, but fail to run.
 356
 357     dnl If we are cross-compiling, just assume that working linkage
 358     dnl implies working executable.
 359
 360     ssl_run_failure=no
 361
 362     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 363     AC_TRY_RUN([
 364 int RSA_new();
 365 int SSL_new();
 366 main(){return 0;}
 367 ],
 368       AC_MSG_RESULT(yes),
 369       AC_MSG_RESULT(no); ssl_run_failure=yes,
 370       AC_MSG_RESULT(cross)
 371     )
 372
 373     if test x"$ssl_run_failure" = xno; then
 374       ssl_success=yes
 375       break
 376     fi
 377   done
 378
 379   if test x"$ssl_success" = xyes; then
 380     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 381     AC_DEFINE([HAVE_SSL], 1,
 382               [Define if SSL support should be compiled in.])
 383     AC_SUBST(SSL_INCLUDES)
 384     SSL_OBJ='gen_sslfunc$o'
 385     AC_SUBST(SSL_OBJ)
 386   else
 387     LDFLAGS=$wget_save_LDFLAGS
 388     LIBS=$wget_save_LIBS
 389
 390     dnl If linking with SSL was forced rather than auto-detected, then
 391     dnl bail out if SSL failed.
 392     if test x"$wget_force_ssl" = x"yes"; then
 393       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 394     fi
 395   fi
 396
 397   dnl Restore the compiler setting.
 398   CC=$wget_save_CC
 399
 400   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 401   dnl with SSL succeeded -- SSL includes will be handled using
 402   dnl @SSL_INCLUDES@.
 403   CPPFLAGS=$wget_save_CPPFLAGS
 404 fi
 405
 406 dnl
 407 dnl Find an md5 implementation.
 408 dnl
 409
 410 if test x"$wget_need_md5" = xyes
 411 then
 412   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 413   dnl manipulate MD5_OBJ from the defun.
 414
 415   MD5_OBJ='gen-md5$o'
 416   found_md5=no
 417
 418   dnl Check for the system MD5 library on Solaris.  We don't check for
 419   dnl something simple like "MD5Update" because there are a number of
 420   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 421   dnl specific to the Solaris MD5 library.
 422   if test x"$found_md5" = xno; then
 423     AC_CHECK_LIB(md5, md5_calc, [
 424       dnl Some installations have bogus <md5.h> in the compiler's
 425       dnl include path, making the system md5 library useless.
 426       AC_MSG_CHECKING([for working md5.h])
 427       AC_COMPILE_IFELSE([#include <md5.h>
 428                         ], [
 429         AC_MSG_RESULT(yes)
 430         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 431         LIBS="-lmd5 $LIBS"
 432         found_md5=yes
 433         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 434       ], [AC_MSG_RESULT(no)])
 435     ])
 436   fi
 437
 438   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 439   dnl implementation.
 440   if test x"$found_md5" = xno; then
 441     if test x"$ssl_success" = xyes; then
 442       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 443       found_md5=yes
 444       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 445     fi
 446   fi
 447
 448   dnl If none of the above worked, use the one we ship with Wget.
 449   if test x"$found_md5" = xno; then
 450     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 451     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 452     found_md5=yes
 453     AC_MSG_NOTICE([using the GNU MD5 implementation])
 454   fi
 455 fi
 456 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 457 AC_SUBST(MD5_OBJ)
 458
 459 dnl **********************************************************************
 460 dnl Checks for IPv6
 461 dnl **********************************************************************
 462
 463 dnl
 464 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 465 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 466 dnl don't use IPv6 or getaddrinfo.
 467 dnl
 468
 469 ipv6=
 470 check_for_ipv6=no
 471 AC_ARG_ENABLE(ipv6,
 472   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 473   [case "${enable_ipv6}" in
 474   no)
 475     AC_MSG_NOTICE([disabling IPv6 at user request])
 476     ipv6=no
 477     ;;
 478   *)
 479     ipv6=yes
 480     ;;
 481   esac],
 482   dnl If unspecified, check for IPv6 and use it where available.
 483   [check_for_ipv6=yes]
 484 )
 485
 486 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 487   AC_CHECK_FUNCS(getaddrinfo, [
 488     GETADDRINFO_AI_ADDRCONFIG([
 489       AC_DEFINE(
 490         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 491         [Define if the system headers support the AI_ADDRCONFIG flag.]
 492       )
 493     ])
 494   ], [
 495     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 496     ipv6=no
 497   ])
 498 fi
 499
 500 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 501   PROTO_INET6([], [
 502     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 503     ipv6=no
 504   ])
 505 fi
 506
 507 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 508   TYPE_STRUCT_SOCKADDR_IN6([
 509     ipv6=yes
 510   ],[
 511     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 512     ipv6=no
 513   ])
 514   if test "X$ipv6" = "Xyes"; then
 515     WGET_STRUCT_SOCKADDR_STORAGE
 516     MEMBER_SIN6_SCOPE_ID
 517   fi
 518 fi
 519
 520 if test "X$ipv6" = "Xyes"; then
 521   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 522 fi
 523
 524
 525 dnl
 526 dnl Set of available languages.
 527 dnl
 528 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 529
 530 dnl Originally this used to be static, looking like this:
 531 dnl     ALL_LINGUAS="cs de hr it ..."
 532 dnl The downside was that configure needed to be rebuilt whenever a
 533 dnl new language was added.
 534
 535 dnl internationalization macros
 536 WGET_WITH_NLS
 537
 538 dnl
 539 dnl Find makeinfo.  We used to provide support for Emacs processing
 540 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 541 dnl unavailable, but that broke with the addition of makeinfo-specific
 542 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 543 dnl build the Info documentation.
 544 dnl
 545
 546 AC_CHECK_PROGS(MAKEINFO, makeinfo)
 547
 548 dnl
 549 dnl Find perl and pod2man
 550 dnl
 551
 552 AC_PATH_PROGS(PERL, perl5 perl, no)
 553 AC_PATH_PROG(POD2MAN, pod2man, no)
 554
 555 if test "x${POD2MAN}" = xno; then
 556   COMMENT_IF_NO_POD2MAN="# "
 557 else
 558   COMMENT_IF_NO_POD2MAN=
 559 fi
 560 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 561
 562 dnl
 563 dnl Create output
 564 dnl
 565 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 566                  po/Makefile.in windows/Makefile])
 567 AC_CONFIG_HEADERS([src/config.h])
 568 AH_BOTTOM([
 569 #include "config-post.h"
 570 ])
 571 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 572 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 573 AC_OUTPUT