sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.59)
  34
  35 dnl Include the M4 macros we use.
  36 builtin(include, [m4/wget.m4])dnl
  37 builtin(include, [m4/lib-ld.m4])dnl
  38 builtin(include, [m4/lib-link.m4])dnl
  39 builtin(include, [m4/lib-prefix.m4])dnl
  40
  41 dnl
  42 dnl What version of Wget are we building?
  43 dnl
  44 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  45 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  46 AC_SUBST(VERSION)
  47 PACKAGE=wget
  48 AC_SUBST(PACKAGE)
  49
  50 dnl
  51 dnl Get cannonical host
  52 dnl
  53 AC_CANONICAL_HOST
  54 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  55                    [Define to be the name of the operating system.])
  56
  57 dnl
  58 dnl Process features.
  59 dnl
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  67 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  73 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(ntlm,
  77 [  --disable-ntlm          disable support for NTLM authorization],
  78 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  79
  80 AC_ARG_ENABLE(debug,
  81 [  --disable-debug         disable support for debugging output],
  82 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  83 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  84    [Define if you want the debug output support compiled in.])
  85
  86 wget_need_md5=no
  87
  88 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  89 *yes*)
  90         wget_need_md5=yes
  91 esac
  92 if test x"$ENABLE_OPIE" = xyes; then
  93   OPIE_OBJ='ftp-opie.o'
  94 fi
  95 AC_SUBST(OPIE_OBJ)
  96
  97 dnl
  98 dnl Whether make sets $(MAKE)...
  99 dnl
 100 AC_PROG_MAKE_SET
 101
 102 dnl
 103 dnl Find a good install
 104 dnl
 105 AC_PROG_INSTALL
 106
 107 dnl
 108 dnl Find the compiler
 109 dnl
 110
 111 dnl We want these before the checks, so the checks can modify their values.
 112 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 113 test -z "$CC" && cc_specified=yes
 114
 115 AC_PROG_CC
 116 AC_AIX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 139 dnl Might also be erelevant for DJGPP.
 140 dnl
 141 case "$host_os" in
 142   *win32) exeext='.exe';;
 143   *) exeext='';;
 144 esac
 145 AC_SUBST(exeext)
 146
 147 dnl
 148 dnl Checks for basic compiler characteristics.
 149 dnl
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_VOLATILE
 153
 154 dnl Check for basic headers, even though we expect them to exist and
 155 dnl #include them unconditionally in the code.  Their detection is
 156 dnl still needed because test programs used by Autoconf macros check
 157 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 158 dnl Without the checks they will fail to be included in test programs,
 159 dnl which will subsequently fail.
 160 AC_HEADER_STDC
 161
 162 dnl Check for large file support.  This check needs to come fairly
 163 dnl early because it could (in principle) affect whether functions and
 164 dnl headers are available, whether they work, etc.
 165 AC_SYS_LARGEFILE
 166 AC_CHECK_SIZEOF(off_t)
 167
 168 dnl
 169 dnl Checks for system header files that might be missing.
 170 dnl
 171 AC_HEADER_STDBOOL
 172 AC_CHECK_HEADERS(unistd.h sys/time.h)
 173 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 174 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 175
 176 dnl
 177 dnl Check sizes of integer types.  These are used to find n-bit
 178 dnl integral types on older systems that fail to provide intN_t and
 179 dnl uintN_t typedefs.
 180 dnl
 181 AC_CHECK_SIZEOF(short)
 182 AC_CHECK_SIZEOF(int)
 183 AC_CHECK_SIZEOF(long)
 184 AC_CHECK_SIZEOF(long long)
 185
 186 dnl
 187 dnl Checks for non-universal or system-specific types.
 188 dnl
 189 AC_TYPE_SIZE_T
 190 AC_TYPE_PID_T
 191 AC_CHECK_TYPES(uint32_t)
 192 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 193 #include <stdio.h>
 194 #include <sys/types.h>
 195 #if HAVE_INTTYPES_H
 196 # include <inttypes.h>
 197 #endif
 198 #include <signal.h>
 199 ])
 200
 201 dnl
 202 dnl Checks for library functions.
 203 dnl
 204 AC_FUNC_ALLOCA
 205 AC_FUNC_MMAP
 206 AC_FUNC_FSEEKO
 207 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf drand48)
 208 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp symlink)
 209
 210 dnl We expect to have these functions on Unix-like systems configure
 211 dnl runs on.  The defines are provided to get them in config.h.in so
 212 dnl Wget can still be ported to non-Unix systems (such as Windows)
 213 dnl that lack some of these functions.
 214 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 215 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 216 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 217 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 218 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 219
 220 dnl
 221 dnl Call Wget-specific macros defined in aclocal.
 222 dnl
 223 WGET_STRUCT_UTIMBUF
 224 WGET_SOCKLEN_T
 225 WGET_FNMATCH
 226 WGET_NANOSLEEP
 227 WGET_POSIX_CLOCK
 228 WGET_NSL_SOCKET
 229
 230 dnl
 231 dnl Check if we need to compile in getopt.c.
 232 dnl
 233 AC_CHECK_FUNC(getopt_long, [], [
 234   GETOPT_OBJ='getopt.o'
 235 ])
 236 AC_SUBST(GETOPT_OBJ)
 237
 238 dnl
 239 dnl Checks for libraries.
 240 dnl
 241
 242 if test x"$with_ssl" = xgnutls
 243 then
 244   dnl Now actually check for -lssl
 245   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 246 #include <gnutls/gnutls.h>
 247   ], [gnutls_global_init()])
 248   if test x"$LIBGNUTLS" != x
 249   then
 250     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 251     AC_DEFINE([HAVE_GNUTLS], 1,
 252               [Define if support for the GnuTLS library is being compiled in.])
 253     SSL_OBJ='gnutls.o'
 254   fi
 255 else
 256   dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 257   dnl doesn't record its dependency on libdl, so we need to make sure
 258   dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 259   dnl dlopen(), but HP-UX uses dnl shl_load().
 260   AC_CHECK_LIB(dl, dlopen, [], [
 261     AC_CHECK_LIB(dl, shl_load)
 262   ])
 263
 264   dnl Now actually check for -lssl
 265   AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 266 #include <openssl/ssl.h>
 267 #include <openssl/x509.h>
 268 #include <openssl/err.h>
 269 #include <openssl/rand.h>
 270 #include <openssl/des.h>
 271 #include <openssl/md4.h>
 272 #include <openssl/md5.h>
 273   ], [SSL_library_init ()])
 274   if test x"$LIBSSL" != x
 275   then
 276     AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 277     AC_DEFINE([HAVE_OPENSSL], 1,
 278               [Define if support for the OpenSSL library is being compiled in.])
 279     SSL_OBJ='openssl.o'
 280   fi
 281 fi
 282
 283 AC_SUBST(SSL_OBJ)
 284
 285 dnl Enable NTLM if requested and if SSL is available.
 286 NTLM_OBJ=''
 287 if test x"$LIBSSL" != x
 288 then
 289   if test x"$ENABLE_NTLM" != xno
 290   then
 291     AC_DEFINE([ENABLE_NTLM], 1,
 292      [Define if you want the NTLM authorization support compiled in.])
 293     NTLM_OBJ='http-ntlm.o'
 294   fi
 295 else
 296   dnl If SSL is unavailable and the user explicitly requested NTLM,
 297   dnl abort.
 298   if test x"$ENABLE_NTLM" = xyes
 299   then
 300     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 301   fi
 302 fi
 303 AC_SUBST(NTLM_OBJ)
 304
 305 dnl
 306 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 307 dnl to use an existing library implementation to save on code size.
 308 dnl
 309
 310 if test x"$wget_need_md5" = xyes
 311 then
 312   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 313   dnl manipulate MD5_OBJ from the defun.
 314
 315   MD5_OBJ='gen-md5.o'
 316   found_md5=no
 317
 318   dnl Check for the system MD5 library on Solaris.  We don't check for
 319   dnl something simple like "MD5Update" because there are a number of
 320   dnl MD5 implementations that use that name, but have an otherwise
 321   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 322   dnl Solaris MD5 library.
 323   if test x"$found_md5" = xno; then
 324     AC_CHECK_LIB(md5, md5_calc, [
 325       dnl Some installations have bogus <md5.h> in the compiler's
 326       dnl include path, making the system md5 library useless.
 327       AC_MSG_CHECKING([for working md5.h])
 328       AC_COMPILE_IFELSE([#include <md5.h>
 329                         ], [
 330         AC_MSG_RESULT(yes)
 331         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 332         LIBS="-lmd5 $LIBS"
 333         found_md5=yes
 334         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 335       ], [AC_MSG_RESULT(no)])
 336     ])
 337   fi
 338
 339   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 340   dnl implementation.
 341   if test x"$found_md5" = xno; then
 342     if test x"$LIBSSL" != x; then
 343       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 344       found_md5=yes
 345       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 346     fi
 347   fi
 348
 349   dnl If none of the above worked, use the one we ship with Wget.
 350   if test x"$found_md5" = xno; then
 351     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 352     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 353     found_md5=yes
 354     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 355     AC_C_BIGENDIAN
 356   fi
 357 fi
 358 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 359 AC_SUBST(MD5_OBJ)
 360
 361 dnl **********************************************************************
 362 dnl Checks for IPv6
 363 dnl **********************************************************************
 364
 365 dnl
 366 dnl We test for IPv6 by checking, in turn, for availability of
 367 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 368 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 369 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 370 dnl
 371 dnl If --enable-ipv6 is explicitly specified on the configure command
 372 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 373 dnl is specified, we disable IPv6 and don't check for it.  The default
 374 dnl is to autodetect IPv6 and use it where available.
 375 dnl
 376
 377 AC_ARG_ENABLE(ipv6,
 378   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 379   [case "${enable_ipv6}" in
 380     no)
 381       AC_MSG_NOTICE([disabling IPv6 at user request])
 382       dnl Disable IPv6 checking
 383       ipv6=no
 384       ;;
 385     yes)
 386       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 387       ipv6=yes
 388       force_ipv6=yes
 389       ;;
 390     auto)
 391       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 392       ipv6=yes
 393       ;;
 394     *)
 395       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 396       ;;
 397     esac
 398   ], [
 399     dnl If nothing is specified, assume auto-detection.
 400     ipv6=yes
 401   ]
 402 )
 403
 404 if test "X$ipv6" = "Xyes"; then
 405   AC_CHECK_FUNCS(getaddrinfo, [], [
 406     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 407     ipv6=no
 408   ])
 409 fi
 410
 411 if test "X$ipv6" = "Xyes"; then
 412   PROTO_INET6([], [
 413     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 414     ipv6=no
 415   ])
 416 fi
 417
 418 if test "X$ipv6" = "Xyes"; then
 419   TYPE_STRUCT_SOCKADDR_IN6([],[
 420     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 421     ipv6=no
 422   ])
 423   if test "X$ipv6" = "Xyes"; then
 424     WGET_STRUCT_SOCKADDR_STORAGE
 425     MEMBER_SIN6_SCOPE_ID
 426   fi
 427 fi
 428
 429 if test "X$ipv6" = "Xyes"; then
 430   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 431   AC_MSG_NOTICE([Enabling support for IPv6.])
 432 elif test "x$force_ipv6" = "xyes"; then
 433   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 434 fi
 435
 436
 437 dnl
 438 dnl Set of available languages.
 439 dnl
 440 dnl Originally this used to be static, looking like this:
 441 dnl     ALL_LINGUAS="cs de hr it ..."
 442 dnl The downside was that configure needed to be rebuilt whenever a
 443 dnl new language was added.
 444 dnl
 445 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 446
 447 dnl internationalization macros
 448 WGET_WITH_NLS
 449
 450 dnl
 451 dnl Find makeinfo.  We used to provide support for Emacs processing
 452 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 453 dnl unavailable, but that broke with the addition of makeinfo-specific
 454 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 455 dnl build the Info documentation.
 456 dnl
 457
 458 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 459
 460 dnl
 461 dnl Find perl and pod2man
 462 dnl
 463
 464 AC_PATH_PROGS(PERL, [perl5 perl], no)
 465 AC_PATH_PROG(POD2MAN, pod2man, no)
 466
 467 if test "x${POD2MAN}" = xno; then
 468   COMMENT_IF_NO_POD2MAN="# "
 469 else
 470   COMMENT_IF_NO_POD2MAN=
 471 fi
 472 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 473
 474 dnl
 475 dnl Create output
 476 dnl
 477 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 478                  po/Makefile.in windows/Makefile])
 479 AC_CONFIG_HEADERS([src/config.h])
 480 AH_BOTTOM([
 481 #include "config-post.h"
 482 ])
 483 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 484 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 485 AC_OUTPUT