sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 3 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 dnl In addition, as a special exception, the Free Software Foundation
  18 dnl gives permission to link the code of its release of Wget with the
  19 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  20 dnl that use the same license as the "OpenSSL" library), and distribute
  21 dnl the linked executables.  You must obey the GNU General Public License
  22 dnl in all respects for all of the code used other than "OpenSSL".  If you
  23 dnl modify this file, you may extend this exception to your version of the
  24 dnl file, but you are not obligated to do so.  If you do not wish to do
  25 dnl so, delete this exception statement from your version.
  26
  27 dnl
  28 dnl Process this file with autoconf to produce a configure script.
  29 dnl
  30
  31 AC_INIT([src/version.c])
  32 AC_PREREQ(2.61)
  33
  34 dnl Include the M4 macros we use.
  35 builtin(include, [m4/wget.m4])dnl
  36 builtin(include, [m4/lib-ld.m4])dnl
  37 builtin(include, [m4/lib-link.m4])dnl
  38 builtin(include, [m4/lib-prefix.m4])dnl
  39
  40 dnl
  41 dnl What version of Wget are we building?
  42 dnl
  43 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  44 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  45 AC_SUBST(VERSION)
  46 PACKAGE=wget
  47 AC_SUBST(PACKAGE)
  48
  49 dnl
  50 dnl Get cannonical host
  51 dnl
  52 AC_CANONICAL_HOST
  53 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  54                    [Define to be the name of the operating system.])
  55
  56 dnl
  57 dnl Process features.
  58 dnl
  59
  60 AC_ARG_WITH(ssl,
  61 [[  --without-ssl           disable SSL autodetection]])
  62
  63 AC_ARG_ENABLE(opie,
  64 [  --disable-opie          disable support for opie or s/key FTP login],
  65 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  66 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  67    [Define if you want the Opie support for FTP compiled in.])
  68
  69 AC_ARG_ENABLE(digest,
  70 [  --disable-digest        disable support for HTTP digest authorization],
  71 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  72 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  73    [Define if you want the HTTP Digest Authorization compiled in.])
  74
  75 AC_ARG_ENABLE(ntlm,
  76 [  --disable-ntlm          disable support for NTLM authorization],
  77 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  78
  79 AC_ARG_ENABLE(debug,
  80 [  --disable-debug         disable support for debugging output],
  81 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  82 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  83    [Define if you want the debug output support compiled in.])
  84
  85 wget_need_md5=no
  86
  87 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  88 *yes*)
  89         wget_need_md5=yes
  90 esac
  91 if test x"$ENABLE_OPIE" = xyes; then
  92   OPIE_OBJ='ftp-opie.o'
  93 fi
  94 AC_SUBST(OPIE_OBJ)
  95
  96 dnl
  97 dnl Whether make sets $(MAKE)...
  98 dnl
  99 AC_PROG_MAKE_SET
 100
 101 dnl
 102 dnl Find a good install
 103 dnl
 104 AC_PROG_INSTALL
 105
 106 dnl
 107 dnl Find the compiler
 108 dnl
 109
 110 dnl We want these before the checks, so the checks can modify their values.
 111 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 112 test -z "$CC" && cc_specified=yes
 113
 114 AC_PROG_CC
 115 AC_AIX
 116
 117 dnl Turn on optimization by default.  Specifically:
 118 dnl
 119 dnl if the user hasn't specified CFLAGS, then
 120 dnl   if compiler is gcc, then
 121 dnl     use -O2 and some warning flags
 122 dnl   else
 123 dnl     use os-specific flags or -O
 124 if test -n "$auto_cflags"; then
 125   if test -n "$GCC"; then
 126     CFLAGS="$CFLAGS -O2 -Wall"
 127   else
 128     case "$host_os" in
 129       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 130       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 131       *)       CFLAGS="$CFLAGS -O" ;;
 132     esac
 133   fi
 134 fi
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Checks for basic compiler characteristics.
 148 dnl
 149 AC_C_CONST
 150 AC_C_INLINE
 151 AC_C_VOLATILE
 152
 153 dnl Check for basic headers, even though we expect them to exist and
 154 dnl #include them unconditionally in the code.  Their detection is
 155 dnl still needed because test programs used by Autoconf macros check
 156 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 157 dnl Without the checks they will fail to be included in test programs,
 158 dnl which will subsequently fail.
 159 AC_HEADER_STDC
 160
 161 dnl Check for large file support.  This check needs to come fairly
 162 dnl early because it could (in principle) affect whether functions and
 163 dnl headers are available, whether they work, etc.
 164 AC_SYS_LARGEFILE
 165 AC_CHECK_SIZEOF(off_t)
 166
 167 dnl
 168 dnl Checks for system header files that might be missing.
 169 dnl
 170 AC_HEADER_STDBOOL
 171 AC_CHECK_HEADERS(unistd.h sys/time.h)
 172 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 173 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 174
 175 dnl
 176 dnl Check sizes of integer types.  These are used to find n-bit
 177 dnl integral types on older systems that fail to provide intN_t and
 178 dnl uintN_t typedefs.
 179 dnl
 180 AC_CHECK_SIZEOF(short)
 181 AC_CHECK_SIZEOF(int)
 182 AC_CHECK_SIZEOF(long)
 183 AC_CHECK_SIZEOF(long long)
 184 AC_CHECK_SIZEOF(void *)
 185
 186 dnl
 187 dnl Checks for non-universal or system-specific types.
 188 dnl
 189 AC_TYPE_SIZE_T
 190 AC_TYPE_PID_T
 191 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 192 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 193 #include <stdio.h>
 194 #include <sys/types.h>
 195 #if HAVE_INTTYPES_H
 196 # include <inttypes.h>
 197 #endif
 198 #include <signal.h>
 199 ])
 200
 201 dnl
 202 dnl Checks for library functions.
 203 dnl
 204 AC_FUNC_ALLOCA
 205 AC_FUNC_MMAP
 206 AC_FUNC_FSEEKO
 207 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 208 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 209
 210 dnl We expect to have these functions on Unix-like systems configure
 211 dnl runs on.  The defines are provided to get them in config.h.in so
 212 dnl Wget can still be ported to non-Unix systems (such as Windows)
 213 dnl that lack some of these functions.
 214 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 215 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 216 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 217 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 218 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 219
 220 dnl
 221 dnl Call Wget-specific macros defined in aclocal.
 222 dnl
 223 WGET_STRUCT_UTIMBUF
 224 WGET_SOCKLEN_T
 225 WGET_FNMATCH
 226 WGET_NANOSLEEP
 227 WGET_POSIX_CLOCK
 228 WGET_NSL_SOCKET
 229
 230 dnl
 231 dnl Check if we need to compile in getopt.c.
 232 dnl
 233 AC_CHECK_FUNC(getopt_long, [], [
 234   GETOPT_OBJ='getopt.o'
 235 ])
 236 AC_SUBST(GETOPT_OBJ)
 237
 238 dnl
 239 dnl Checks for libraries.
 240 dnl
 241
 242 AS_IF([test x"$with_ssl" = xgnutls], [
 243   dnl Now actually check for -lssl
 244   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 245 #include <gnutls/gnutls.h>
 246   ], [gnutls_global_init()])
 247   if test x"$LIBGNUTLS" != x
 248   then
 249     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 250     SSL_OBJ='gnutls.o'
 251   else
 252     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 253   fi
 254 ], [
 255   # --with-ssl is not gnutls: check if it's no
 256   AS_IF([test x"$with_ssl" != xno], [
 257     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 258     dnl doesn't record its dependency on libdl, so we need to make sure
 259     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 260     dnl dlopen(), but HP-UX uses shl_load().
 261     AC_CHECK_LIB(dl, dlopen, [], [
 262       AC_CHECK_LIB(dl, shl_load)
 263     ])
 264
 265     dnl Now actually check for -lssl
 266     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 267   #include <openssl/ssl.h>
 268   #include <openssl/x509.h>
 269   #include <openssl/err.h>
 270   #include <openssl/rand.h>
 271   #include <openssl/des.h>
 272   #include <openssl/md4.h>
 273   #include <openssl/md5.h>
 274     ], [SSL_library_init ()])
 275     if test x"$LIBSSL" != x
 276     then
 277       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 278       SSL_OBJ='openssl.o'
 279     elif test x"$with_ssl" != x
 280     then
 281       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 282     fi
 283   ]) # endif: --with-ssl == no?
 284 ]) # endif: --with-ssl == gnutls?
 285
 286 AC_SUBST(SSL_OBJ)
 287
 288 dnl Enable NTLM if requested and if SSL is available.
 289 NTLM_OBJ=''
 290 if test x"$LIBSSL" != x
 291 then
 292   if test x"$ENABLE_NTLM" != xno
 293   then
 294     AC_DEFINE([ENABLE_NTLM], 1,
 295      [Define if you want the NTLM authorization support compiled in.])
 296     NTLM_OBJ='http-ntlm.o'
 297   fi
 298 else
 299   dnl If SSL is unavailable and the user explicitly requested NTLM,
 300   dnl abort.
 301   if test x"$ENABLE_NTLM" = xyes
 302   then
 303     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 304   fi
 305 fi
 306 AC_SUBST(NTLM_OBJ)
 307
 308 dnl
 309 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 310 dnl to use an existing library implementation to save on code size.
 311 dnl
 312
 313 if test x"$wget_need_md5" = xyes
 314 then
 315   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 316   dnl manipulate MD5_OBJ from the defun.
 317
 318   MD5_OBJ='gen-md5.o'
 319   found_md5=no
 320
 321   dnl Check for the system MD5 library on Solaris.  We don't check for
 322   dnl something simple like "MD5Update" because there are a number of
 323   dnl MD5 implementations that use that name, but have an otherwise
 324   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 325   dnl Solaris MD5 library.
 326   if test x"$found_md5" = xno; then
 327     AC_CHECK_LIB(md5, md5_calc, [
 328       dnl Some installations have bogus <md5.h> in the compiler's
 329       dnl include path, making the system md5 library useless.
 330       AC_MSG_CHECKING([for working md5.h])
 331       AC_COMPILE_IFELSE([#include <md5.h>
 332                         ], [
 333         AC_MSG_RESULT(yes)
 334         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 335         LIBS="-lmd5 $LIBS"
 336         found_md5=yes
 337         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 338       ], [AC_MSG_RESULT(no)])
 339     ])
 340   fi
 341
 342   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 343   dnl implementation.
 344   if test x"$found_md5" = xno; then
 345     if test x"$LIBSSL" != x; then
 346       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 347       found_md5=yes
 348       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 349     fi
 350   fi
 351
 352   dnl If none of the above worked, use the one we ship with Wget.
 353   if test x"$found_md5" = xno; then
 354     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 355     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 356     found_md5=yes
 357     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 358     AC_C_BIGENDIAN
 359   fi
 360 fi
 361 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 362 AC_SUBST(MD5_OBJ)
 363
 364 dnl **********************************************************************
 365 dnl Checks for IPv6
 366 dnl **********************************************************************
 367
 368 dnl
 369 dnl We test for IPv6 by checking, in turn, for availability of
 370 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 371 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 372 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 373 dnl
 374 dnl If --enable-ipv6 is explicitly specified on the configure command
 375 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 376 dnl is specified, we disable IPv6 and don't check for it.  The default
 377 dnl is to autodetect IPv6 and use it where available.
 378 dnl
 379
 380 AC_ARG_ENABLE(ipv6,
 381   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 382   [case "${enable_ipv6}" in
 383     no)
 384       AC_MSG_NOTICE([disabling IPv6 at user request])
 385       dnl Disable IPv6 checking
 386       ipv6=no
 387       ;;
 388     yes)
 389       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 390       ipv6=yes
 391       force_ipv6=yes
 392       ;;
 393     auto)
 394       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 395       ipv6=yes
 396       ;;
 397     *)
 398       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 399       ;;
 400     esac
 401   ], [
 402     dnl If nothing is specified, assume auto-detection.
 403     ipv6=yes
 404   ]
 405 )
 406
 407 if test "X$ipv6" = "Xyes"; then
 408   AC_CHECK_FUNCS(getaddrinfo, [], [
 409     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 410     ipv6=no
 411   ])
 412 fi
 413
 414 if test "X$ipv6" = "Xyes"; then
 415   PROTO_INET6([], [
 416     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 417     ipv6=no
 418   ])
 419 fi
 420
 421 if test "X$ipv6" = "Xyes"; then
 422   TYPE_STRUCT_SOCKADDR_IN6([],[
 423     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 424     ipv6=no
 425   ])
 426   if test "X$ipv6" = "Xyes"; then
 427     WGET_STRUCT_SOCKADDR_STORAGE
 428     MEMBER_SIN6_SCOPE_ID
 429   fi
 430 fi
 431
 432 if test "X$ipv6" = "Xyes"; then
 433   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 434   AC_MSG_NOTICE([Enabling support for IPv6.])
 435 elif test "x$force_ipv6" = "xyes"; then
 436   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 437 fi
 438
 439
 440 dnl
 441 dnl Set of available languages.
 442 dnl
 443 dnl Originally this used to be static, looking like this:
 444 dnl     ALL_LINGUAS="cs de hr it ..."
 445 dnl The downside was that configure needed to be rebuilt whenever a
 446 dnl new language was added.
 447 dnl
 448 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 449
 450 dnl internationalization macros
 451 WGET_WITH_NLS
 452
 453 dnl
 454 dnl Find makeinfo.  We used to provide support for Emacs processing
 455 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 456 dnl unavailable, but that broke with the addition of makeinfo-specific
 457 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 458 dnl build the Info documentation.
 459 dnl
 460
 461 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 462
 463 dnl
 464 dnl Find perl and pod2man
 465 dnl
 466
 467 AC_PATH_PROGS(PERL, [perl5 perl], no)
 468 AC_PATH_PROG(POD2MAN, pod2man, no)
 469
 470 if test "x${POD2MAN}" = xno; then
 471   COMMENT_IF_NO_POD2MAN="# "
 472 else
 473   COMMENT_IF_NO_POD2MAN=
 474 fi
 475 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 476
 477 dnl
 478 dnl Create output
 479 dnl
 480 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 481                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 482                  windows/Makefile])
 483 AC_CONFIG_HEADERS([src/config.h])
 484 AH_BOTTOM([
 485 #include "config-post.h"
 486 ])
 487 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 488 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 489 AC_OUTPUT