sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl Include the M4 macros we use.
  36 builtin(include, [m4/wget.m4])dnl
  37 builtin(include, [m4/lib-ld.m4])dnl
  38 builtin(include, [m4/lib-link.m4])dnl
  39 builtin(include, [m4/lib-prefix.m4])dnl
  40
  41 dnl
  42 dnl What version of Wget are we building?
  43 dnl
  44 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  45 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  46 AC_SUBST(VERSION)
  47 PACKAGE=wget
  48 AC_SUBST(PACKAGE)
  49
  50 dnl
  51 dnl Get cannonical host
  52 dnl
  53 AC_CANONICAL_HOST
  54 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  55                    [Define to be the name of the operating system.])
  56
  57 dnl
  58 dnl Process features.
  59 dnl
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  63   --without-ssl           disable SSL autodetection]])
  64
  65 AC_ARG_ENABLE(opie,
  66 [  --disable-opie          disable support for opie or s/key FTP login],
  67 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  68 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  69    [Define if you want the Opie support for FTP compiled in.])
  70
  71 AC_ARG_ENABLE(digest,
  72 [  --disable-digest        disable support for HTTP digest authorization],
  73 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  74 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  75    [Define if you want the HTTP Digest Authorization compiled in.])
  76
  77 AC_ARG_ENABLE(ntlm,
  78 [  --disable-ntlm          disable support for NTLM authorization],
  79 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  80
  81 AC_ARG_ENABLE(debug,
  82 [  --disable-debug         disable support for debugging output],
  83 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  84 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  85    [Define if you want the debug output support compiled in.])
  86
  87 wget_need_md5=no
  88
  89 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  90 *yes*)
  91         wget_need_md5=yes
  92 esac
  93 if test x"$ENABLE_OPIE" = xyes; then
  94   OPIE_OBJ='ftp-opie.o'
  95 fi
  96 AC_SUBST(OPIE_OBJ)
  97
  98 dnl
  99 dnl Whether make sets $(MAKE)...
 100 dnl
 101 AC_PROG_MAKE_SET
 102
 103 dnl
 104 dnl Find a good install
 105 dnl
 106 AC_PROG_INSTALL
 107
 108 dnl
 109 dnl Find the compiler
 110 dnl
 111
 112 dnl We want these before the checks, so the checks can modify their values.
 113 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 114 test -z "$CC" && cc_specified=yes
 115
 116 AC_PROG_CC
 117 AC_AIX
 118
 119 dnl Turn on optimization by default.  Specifically:
 120 dnl
 121 dnl if the user hasn't specified CFLAGS, then
 122 dnl   if compiler is gcc, then
 123 dnl     use -O2 and some warning flags
 124 dnl   else
 125 dnl     use os-specific flags or -O
 126 if test -n "$auto_cflags"; then
 127   if test -n "$GCC"; then
 128     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 129   else
 130     case "$host_os" in
 131       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 132       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 133       *)       CFLAGS="$CFLAGS -O" ;;
 134     esac
 135   fi
 136 fi
 137
 138 dnl
 139 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 140 dnl Might also be erelevant for DJGPP.
 141 dnl
 142 case "$host_os" in
 143   *win32) exeext='.exe';;
 144   *) exeext='';;
 145 esac
 146 AC_SUBST(exeext)
 147
 148 dnl
 149 dnl Checks for basic compiler characteristics.
 150 dnl
 151 AC_C_CONST
 152 AC_C_INLINE
 153 AC_C_VOLATILE
 154 dnl Needed for GNU md5 code.
 155 AC_C_BIGENDIAN
 156
 157 dnl
 158 dnl Checks for header files that might be missing.
 159 dnl
 160
 161 dnl Check for basic headers, even though we expect their presence to
 162 dnl compile.  This is because test programs used by Autoconf macros
 163 dnl check for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before including
 164 dnl them.  Without these checks they will fail to be included in test
 165 dnl programs, which will subsequently fail.
 166 AC_HEADER_STDC
 167
 168 dnl Now the real checks:
 169 AC_HEADER_STDBOOL
 170 AC_CHECK_HEADERS(unistd.h sys/time.h)
 171 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 172 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 173
 174 dnl
 175 dnl Check sizes of signed integer types.  These are used to find n-bit
 176 dnl integral types on older systems that fail to provide intN_t and
 177 dnl uintN_t typedefs.
 178 dnl
 179 AC_CHECK_SIZEOF(short)
 180 AC_CHECK_SIZEOF(int)
 181 AC_CHECK_SIZEOF(long)
 182 AC_CHECK_SIZEOF(long long)
 183
 184 dnl
 185 dnl Check for large file support.  This check needs to come fairly
 186 dnl early because it could (in principle) affect whether functions and
 187 dnl headers are available, whether they work, etc.
 188 dnl
 189 AC_SYS_LARGEFILE
 190 AC_CHECK_SIZEOF(off_t)
 191
 192 dnl
 193 dnl Checks for non-universal or system-specific types.
 194 dnl
 195 AC_TYPE_SIZE_T
 196 AC_TYPE_PID_T
 197 AC_CHECK_TYPES(uint32_t)
 198 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 199 #include <stdio.h>
 200 #include <sys/types.h>
 201 #if HAVE_INTTYPES_H
 202 # include <inttypes.h>
 203 #endif
 204 #include <signal.h>
 205 ])
 206
 207 dnl
 208 dnl Checks for library functions.
 209 dnl
 210 AC_FUNC_ALLOCA
 211 AC_FUNC_MMAP
 212 AC_FUNC_FSEEKO
 213 AC_CHECK_FUNCS(strptime snprintf vsnprintf)
 214 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp symlink)
 215
 216 dnl We expect to have these functions on Unix-like systems configure
 217 dnl runs on.  The defines are provided to get them in config.h.in so
 218 dnl Wget can still be ported to non-Unix systems (such as Windows)
 219 dnl that lack some of these functions.
 220 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 221 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 222 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 223 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 224 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 225
 226 dnl
 227 dnl Call Wget-specific macros defined in aclocal.
 228 dnl
 229 WGET_STRUCT_UTIMBUF
 230 WGET_SOCKLEN_T
 231 WGET_FNMATCH
 232 WGET_NANOSLEEP
 233 WGET_POSIX_CLOCK
 234 WGET_NSL_SOCKET
 235
 236 dnl
 237 dnl Check if we need to compile in getopt.c.
 238 dnl
 239 AC_CHECK_FUNC(getopt_long, [], [
 240   GETOPT_OBJ='getopt.o'
 241 ])
 242 AC_SUBST(GETOPT_OBJ)
 243
 244 dnl
 245 dnl Checks for libraries.
 246 dnl
 247
 248 dnl Check for OpenSSL
 249
 250 dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 251 dnl doesn't record its dependency on libdl, so we need to make sure
 252 dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 253 dnl dlopen(), but HP-UX uses dnl shl_load().
 254 AC_CHECK_LIB(dl, dlopen, [], [
 255   AC_CHECK_LIB(dl, shl_load)
 256 ])
 257
 258 dnl Now actually check for -lssl
 259 AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 260 #include <openssl/ssl.h>
 261 #include <openssl/x509.h>
 262 #include <openssl/err.h>
 263 #include <openssl/rand.h>
 264 #include <openssl/des.h>
 265 #include <openssl/md4.h>
 266 #include <openssl/md5.h>
 267 ], [SSL_library_init ()])
 268 if test x"$LIBSSL" != x
 269 then
 270   AC_MSG_NOTICE([compiling in support for SSL])
 271   AC_DEFINE([HAVE_SSL], 1,
 272             [Define if SSL support should be compiled in.])
 273   SSL_OBJ='openssl.o'
 274 fi
 275 AC_SUBST(SSL_OBJ)
 276
 277 dnl Enable NTLM if requested and if SSL is available.
 278 NTLM_OBJ=''
 279 if test x"$LIBSSL" != x
 280 then
 281   if test x"$ENABLE_NTLM" != xno
 282   then
 283     AC_DEFINE([ENABLE_NTLM], 1,
 284      [Define if you want the NTLM authorization support compiled in.])
 285     NTLM_OBJ='http-ntlm.o'
 286   fi
 287 else
 288   dnl If SSL is unavailable and the user explicitly requested NTLM,
 289   dnl abort.
 290   if test x"$ENABLE_NTLM" = xyes
 291   then
 292     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 293   fi
 294 fi
 295 AC_SUBST(NTLM_OBJ)
 296
 297 dnl
 298 dnl Find an md5 implementation.
 299 dnl
 300
 301 if test x"$wget_need_md5" = xyes
 302 then
 303   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 304   dnl manipulate MD5_OBJ from the defun.
 305
 306   MD5_OBJ='gen-md5.o'
 307   found_md5=no
 308
 309   dnl Check for the system MD5 library on Solaris.  We don't check for
 310   dnl something simple like "MD5Update" because there are a number of
 311   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 312   dnl specific to the Solaris MD5 library.
 313   if test x"$found_md5" = xno; then
 314     AC_CHECK_LIB(md5, md5_calc, [
 315       dnl Some installations have bogus <md5.h> in the compiler's
 316       dnl include path, making the system md5 library useless.
 317       AC_MSG_CHECKING([for working md5.h])
 318       AC_COMPILE_IFELSE([#include <md5.h>
 319                         ], [
 320         AC_MSG_RESULT(yes)
 321         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 322         LIBS="-lmd5 $LIBS"
 323         found_md5=yes
 324         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 325       ], [AC_MSG_RESULT(no)])
 326     ])
 327   fi
 328
 329   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 330   dnl implementation.
 331   if test x"$found_md5" = xno; then
 332     if test x"$ssl_success" = xyes; then
 333       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 334       found_md5=yes
 335       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 336     fi
 337   fi
 338
 339   dnl If none of the above worked, use the one we ship with Wget.
 340   if test x"$found_md5" = xno; then
 341     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 342     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 343     found_md5=yes
 344     AC_MSG_NOTICE([using the GNU MD5 implementation])
 345   fi
 346 fi
 347 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 348 AC_SUBST(MD5_OBJ)
 349
 350 dnl **********************************************************************
 351 dnl Checks for IPv6
 352 dnl **********************************************************************
 353
 354 dnl
 355 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 356 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 357 dnl don't use IPv6 or getaddrinfo.  Otherwise we detect IPv6 and use
 358 dnl it where available.
 359 dnl
 360
 361 AC_ARG_ENABLE(ipv6,
 362   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 363   [case "${enable_ipv6}" in
 364     no)
 365       AC_MSG_NOTICE([disabling IPv6 at user request])
 366       dnl Disable IPv6 checking
 367       ipv6=no
 368       ;;
 369     yes)
 370       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 371       ipv6=yes
 372       force_ipv6=yes
 373       ;;
 374     auto)
 375       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 376       ipv6=yes
 377       ;;
 378     *)
 379       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 380       ;;
 381     esac
 382   ], [
 383     dnl If nothing is specified, assume auto-detection.
 384     ipv6=yes
 385   ]
 386 )
 387
 388 if test "X$ipv6" = "Xyes"; then
 389   AC_CHECK_FUNCS(getaddrinfo, [], [
 390     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 391     ipv6=no
 392   ])
 393 fi
 394
 395 if test "X$ipv6" = "Xyes"; then
 396   PROTO_INET6([], [
 397     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 398     ipv6=no
 399   ])
 400 fi
 401
 402 if test "X$ipv6" = "Xyes"; then
 403   TYPE_STRUCT_SOCKADDR_IN6([],[
 404     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 405     ipv6=no
 406   ])
 407   if test "X$ipv6" = "Xyes"; then
 408     WGET_STRUCT_SOCKADDR_STORAGE
 409     MEMBER_SIN6_SCOPE_ID
 410   fi
 411 fi
 412
 413 if test "X$ipv6" = "Xyes"; then
 414   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 415   AC_MSG_NOTICE([Enabling support for IPv6.])
 416 elif test "x$force_ipv6" = "xyes"; then
 417   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 418 fi
 419
 420
 421 dnl
 422 dnl Set of available languages.
 423 dnl
 424 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 425
 426 dnl Originally this used to be static, looking like this:
 427 dnl     ALL_LINGUAS="cs de hr it ..."
 428 dnl The downside was that configure needed to be rebuilt whenever a
 429 dnl new language was added.
 430
 431 dnl internationalization macros
 432 WGET_WITH_NLS
 433
 434 dnl
 435 dnl Find makeinfo.  We used to provide support for Emacs processing
 436 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 437 dnl unavailable, but that broke with the addition of makeinfo-specific
 438 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 439 dnl build the Info documentation.
 440 dnl
 441
 442 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 443
 444 dnl
 445 dnl Find perl and pod2man
 446 dnl
 447
 448 AC_PATH_PROGS(PERL, [perl5 perl], no)
 449 AC_PATH_PROG(POD2MAN, pod2man, no)
 450
 451 if test "x${POD2MAN}" = xno; then
 452   COMMENT_IF_NO_POD2MAN="# "
 453 else
 454   COMMENT_IF_NO_POD2MAN=
 455 fi
 456 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 457
 458 dnl
 459 dnl Create output
 460 dnl
 461 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 462                  po/Makefile.in windows/Makefile])
 463 AC_CONFIG_HEADERS([src/config.h])
 464 AH_BOTTOM([
 465 #include "config-post.h"
 466 ])
 467 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 468 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 469 AC_OUTPUT