sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  62 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  68 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(ntlm,
  72 [  --disable-ntlm          disable support for NTLM authorization],
  73 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  74
  75 AC_ARG_ENABLE(debug,
  76 [  --disable-debug         disable support for debugging output],
  77 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  78 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  79    [Define if you want the debug output support compiled in.])
  80
  81 wget_need_md5=no
  82
  83 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  84 *yes*)
  85         wget_need_md5=yes
  86 esac
  87 if test x"$ENABLE_OPIE" = xyes; then
  88   OPIE_OBJ='ftp-opie.o'
  89 fi
  90 AC_SUBST(OPIE_OBJ)
  91
  92 dnl
  93 dnl Whether make sets $(MAKE)...
  94 dnl
  95 AC_PROG_MAKE_SET
  96
  97 dnl
  98 dnl Find a good install
  99 dnl
 100 AC_PROG_INSTALL
 101
 102 dnl
 103 dnl Find the compiler
 104 dnl
 105
 106 dnl We want these before the checks, so the checks can modify their values.
 107 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 108 test -z "$CC" && cc_specified=yes
 109
 110 AC_PROG_CC
 111 AC_AIX
 112
 113 dnl Turn on optimization by default.  Specifically:
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then
 117 dnl     use -O2 and some warning flags
 118 dnl   else
 119 dnl     use os-specific flags or -O
 120 if test -n "$auto_cflags"; then
 121   if test -n "$GCC"; then
 122     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 123   else
 124     case "$host_os" in
 125       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 126       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 127       *)       CFLAGS="$CFLAGS -O" ;;
 128     esac
 129   fi
 130 fi
 131
 132 dnl
 133 dnl Configure our included libtool and make sure it's regenerated when needed
 134 dnl
 135 AC_PROG_LIBTOOL
 136 AC_SUBST(LIBTOOL_DEPS)
 137
 138 dnl
 139 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 140 dnl Might also be erelevant for DJGPP.
 141 dnl
 142 case "$host_os" in
 143   *win32) exeext='.exe';;
 144   *) exeext='';;
 145 esac
 146 AC_SUBST(exeext)
 147
 148 dnl
 149 dnl Checks for basic compiler characteristics.
 150 dnl
 151 AC_C_CONST
 152 AC_C_INLINE
 153 AC_C_VOLATILE
 154 dnl Needed for GNU md5 code.
 155 AC_C_BIGENDIAN
 156
 157 dnl
 158 dnl Checks for header files that might be missing.
 159 dnl
 160
 161 dnl Check for basic headers, even those we assume the presence of.
 162 dnl This is because test programs used by Autoconf macros check for
 163 dnl STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before including them.
 164 dnl Without these checks they will fail to be included in test
 165 dnl programs, which will subsequently fail.
 166 AC_HEADER_STDC
 167 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 168
 169 dnl Now the real checks:
 170 AC_HEADER_STDBOOL
 171 AC_CHECK_HEADERS(string.h strings.h limits.h unistd.h sys/time.h)
 172 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 173 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 174
 175 dnl
 176 dnl Check sizes of signed integer types.  These are used to find n-bit
 177 dnl integral types on older systems that fail to provide intN_t and
 178 dnl uintN_t typedefs.
 179 dnl
 180 AC_CHECK_SIZEOF(short)
 181 AC_CHECK_SIZEOF(int)
 182 AC_CHECK_SIZEOF(long)
 183 AC_CHECK_SIZEOF(long long)
 184
 185 dnl
 186 dnl Check for large file support.  This check needs to come fairly
 187 dnl early because it could (in principle) affect whether functions and
 188 dnl headers are available, whether they work, etc.
 189 dnl
 190 AC_SYS_LARGEFILE
 191 AC_CHECK_SIZEOF(off_t)
 192
 193 dnl
 194 dnl Checks for non-universal or system-specific types.
 195 dnl
 196 AC_TYPE_SIZE_T
 197 AC_TYPE_PID_T
 198 AC_CHECK_TYPES(uint32_t)
 199 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 200 #include <stdio.h>
 201 #include <sys/types.h>
 202 #if HAVE_INTTYPES_H
 203 # include <inttypes.h>
 204 #endif
 205 #include <signal.h>
 206 ])
 207
 208 dnl
 209 dnl Checks for library functions.
 210 dnl
 211 AC_FUNC_ALLOCA
 212 AC_FUNC_MMAP
 213 AC_FUNC_FSEEKO
 214 AC_CHECK_FUNCS(strdup strcasecmp strncasecmp)
 215 AC_CHECK_FUNCS(strptime snprintf vsnprintf)
 216 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp)
 217 AC_CHECK_FUNCS(symlink isatty)
 218
 219 dnl
 220 dnl Call Wget-specific macros defined in aclocal.
 221 dnl
 222 WGET_STRUCT_UTIMBUF
 223 WGET_SOCKLEN_T
 224 WGET_FNMATCH
 225 WGET_NANOSLEEP
 226 WGET_POSIX_CLOCK
 227 WGET_NSL_SOCKET
 228
 229 dnl
 230 dnl Check if we need to compile in getopt.c.
 231 dnl
 232 AC_CHECK_FUNC(getopt_long, [], [
 233   GETOPT_OBJ='getopt.o'
 234 ])
 235 AC_SUBST(GETOPT_OBJ)
 236
 237 dnl
 238 dnl Checks for libraries.
 239 dnl
 240
 241 dnl $with_ssl can be one of:
 242 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 243 dnl  - "yes", meaning link with SSL or bail out.
 244 dnl  - "no", meaning don't link with SSL.
 245 dnl  - anything else, meaning use that as the SSL root, and bail out
 246 dnl    if it fails.
 247
 248 if test x"$with_ssl" = x; then
 249   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 250   dnl implements the "auto-detect by default" feature.  If you want to
 251   dnl change this to "ignore SSL by default", change "auto" to "no".
 252   with_ssl=auto
 253 fi
 254
 255 dnl Detection of OpenSSL is much hairier than the detection of other
 256 dnl libraries because OpenSSL can be compiled as a third-party
 257 dnl library, which means it will not be found without additional
 258 dnl linker magic.  It would be really nice to rework this check into
 259 dnl an AC_DEFUN so that we can reuse it for other third-party
 260 dnl libraries.
 261
 262 if test x"$with_ssl" != x"no"; then
 263
 264   wget_force_ssl=no
 265   if test x"$with_ssl" = x"yes"; then
 266     wget_force_ssl=yes
 267   fi
 268
 269   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 270     dnl OpenSSL's root was not specified, so we have to guess.  First
 271     dnl try the system default location, then "/usr/local/ssl" (where
 272     dnl OpenSSL installs by default), then "/usr/local" (traditional
 273     dnl choice for installation root), then "/opt".
 274     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 275   else
 276     dnl Root has been specified by the user.
 277     ssl_all_roots=$with_ssl
 278     wget_force_ssl=yes
 279   fi
 280
 281   wget_save_CC=$CC
 282   wget_save_LIBS=$LIBS
 283   wget_save_LDFLAGS=$LDFLAGS
 284   wget_save_CPPFLAGS=$CPPFLAGS
 285
 286   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 287   dnl without having to know how the linker handles it.
 288   CC="$SHELL ./libtool $CC"
 289
 290   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 291   dnl shared library doesn't record its dependency on libdl, so we
 292   dnl need to check for it ourselves so we won't fail to link due to a
 293   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 294   dnl shl_load().
 295   AC_CHECK_LIB(dl,dlopen)
 296   AC_CHECK_LIB(dl,shl_load)
 297
 298   ssl_success=no
 299
 300   dnl Now try to find SSL libraries in each of the likely SSL roots.
 301   for ssl_root in $ssl_all_roots
 302   do
 303     if test x"$ssl_root" = x"system-default"; then
 304       dnl Try the default include and library locations.
 305       SSL_INCLUDES=
 306     else
 307       dnl Try this specific root.
 308       SSL_INCLUDES=-I$ssl_root/include
 309       dnl It's OK to use -R directly because libtool will
 310       dnl interpret it for us.
 311       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 312     fi
 313
 314     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 315
 316     dnl Check whether the compiler can find the include files.  On
 317     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 318     dnl to find the includes in /usr/local/include.
 319
 320     ssl_found_includes=no
 321     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 322
 323     dnl Check for all the OpenSSL includes that Wget actually uses.
 324     dnl This will prune both invalid installations and ancient
 325     dnl versions of OpenSSL that we can't use.
 326     AC_MSG_CHECKING([for includes])
 327     AC_COMPILE_IFELSE([
 328 #include <openssl/ssl.h>
 329 #include <openssl/x509.h>
 330 #include <openssl/err.h>
 331 #include <openssl/rand.h>
 332 #include <openssl/des.h>
 333 #include <openssl/md4.h>
 334 #include <openssl/md5.h>
 335     ], [
 336       AC_MSG_RESULT(found)
 337       ssl_found_includes=yes
 338     ], [
 339       AC_MSG_RESULT([not found])
 340     ])
 341
 342     if test x"$ssl_found_includes" = xno; then
 343       continue
 344     fi
 345
 346     ssl_link_failure=no
 347
 348     dnl Make sure that the checks don't run afoul of the cache.  It
 349     dnl would be nicer to temporarily turn off the cache, but
 350     dnl apparently Autoconf doesn't allow that.
 351
 352     unset ac_cv_lib_crypto_RSA_new
 353     unset ac_cv_lib_ssl_SSL_new
 354
 355     dnl These checks need to be in this order, or you'll get a link
 356     dnl failure if you use a static libcrypto.a and libssl.a rather
 357     dnl than shared libraries.
 358
 359     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 360     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 361
 362     if test x"$ssl_link_failure" = xyes; then
 363       dnl One or both libs failed to link.
 364       continue
 365     fi
 366
 367     dnl The libraries link.  But we still need to check if the program
 368     dnl linked with those libraries under these settings with run.  On
 369     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 370     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 371     dnl executables that link, but fail to run.
 372
 373     dnl If we are cross-compiling, just assume that working linkage
 374     dnl implies working executable.
 375
 376     ssl_run_failure=no
 377
 378     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 379     AC_TRY_RUN([
 380 int RSA_new();
 381 int SSL_new();
 382 main(){return 0;}
 383 ],
 384       AC_MSG_RESULT(yes),
 385       AC_MSG_RESULT(no); ssl_run_failure=yes,
 386       AC_MSG_RESULT(cross)
 387     )
 388
 389     if test x"$ssl_run_failure" = xno; then
 390       ssl_success=yes
 391       break
 392     fi
 393   done
 394
 395   if test x"$ssl_success" = xyes; then
 396     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 397     AC_DEFINE([HAVE_SSL], 1,
 398               [Define if SSL support should be compiled in.])
 399     AC_SUBST(SSL_INCLUDES)
 400     SSL_OBJ='openssl.o'
 401     AC_SUBST(SSL_OBJ)
 402   else
 403     LDFLAGS=$wget_save_LDFLAGS
 404     LIBS=$wget_save_LIBS
 405
 406     dnl If linking with SSL was forced rather than auto-detected, then
 407     dnl bail out if SSL failed.
 408     if test x"$wget_force_ssl" = x"yes"; then
 409       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 410     fi
 411   fi
 412
 413   dnl Restore the compiler setting.
 414   CC=$wget_save_CC
 415
 416   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 417   dnl with SSL succeeded -- SSL includes will be handled using
 418   dnl @SSL_INCLUDES@.
 419   CPPFLAGS=$wget_save_CPPFLAGS
 420 fi
 421
 422 dnl Enable NTLM if requested and if SSL is available.
 423 NTLM_OBJ=''
 424 if test x"$ssl_success" = xyes
 425 then
 426   if test x"$ENABLE_NTLM" != xno
 427   then
 428     AC_DEFINE([ENABLE_NTLM], 1,
 429      [Define if you want the NTLM authorization support compiled in.])
 430     NTLM_OBJ='http-ntlm.o'
 431   fi
 432 else
 433   dnl If SSL is unavailable and the user explicitly requested NTLM,
 434   dnl abort.
 435   if test x"$ENABLE_NTLM" = xyes
 436   then
 437     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 438   fi
 439 fi
 440 AC_SUBST(NTLM_OBJ)
 441
 442 dnl
 443 dnl Find an md5 implementation.
 444 dnl
 445
 446 if test x"$wget_need_md5" = xyes
 447 then
 448   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 449   dnl manipulate MD5_OBJ from the defun.
 450
 451   MD5_OBJ='gen-md5.o'
 452   found_md5=no
 453
 454   dnl Check for the system MD5 library on Solaris.  We don't check for
 455   dnl something simple like "MD5Update" because there are a number of
 456   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 457   dnl specific to the Solaris MD5 library.
 458   if test x"$found_md5" = xno; then
 459     AC_CHECK_LIB(md5, md5_calc, [
 460       dnl Some installations have bogus <md5.h> in the compiler's
 461       dnl include path, making the system md5 library useless.
 462       AC_MSG_CHECKING([for working md5.h])
 463       AC_COMPILE_IFELSE([#include <md5.h>
 464                         ], [
 465         AC_MSG_RESULT(yes)
 466         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 467         LIBS="-lmd5 $LIBS"
 468         found_md5=yes
 469         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 470       ], [AC_MSG_RESULT(no)])
 471     ])
 472   fi
 473
 474   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 475   dnl implementation.
 476   if test x"$found_md5" = xno; then
 477     if test x"$ssl_success" = xyes; then
 478       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 479       found_md5=yes
 480       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 481     fi
 482   fi
 483
 484   dnl If none of the above worked, use the one we ship with Wget.
 485   if test x"$found_md5" = xno; then
 486     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 487     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 488     found_md5=yes
 489     AC_MSG_NOTICE([using the GNU MD5 implementation])
 490   fi
 491 fi
 492 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 493 AC_SUBST(MD5_OBJ)
 494
 495 dnl **********************************************************************
 496 dnl Checks for IPv6
 497 dnl **********************************************************************
 498
 499 dnl
 500 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 501 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 502 dnl don't use IPv6 or getaddrinfo.  Otherwise we detect IPv6 and use
 503 dnl it where available.
 504 dnl
 505
 506 AC_ARG_ENABLE(ipv6,
 507   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 508   [case "${enable_ipv6}" in
 509     no)
 510       AC_MSG_NOTICE([disabling IPv6 at user request])
 511       dnl Disable IPv6 checking
 512       ipv6=no
 513       ;;
 514     yes)
 515       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 516       ipv6=yes
 517       force_ipv6=yes
 518       ;;
 519     auto)
 520       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 521       ipv6=yes
 522       ;;
 523     *)
 524       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 525       ;;
 526     esac
 527   ], [
 528     dnl If nothing is specified, assume auto-detection.
 529     ipv6=yes
 530   ]
 531 )
 532
 533 if test "X$ipv6" = "Xyes"; then
 534   AC_CHECK_FUNCS(getaddrinfo, [], [
 535     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 536     ipv6=no
 537   ])
 538 fi
 539
 540 if test "X$ipv6" = "Xyes"; then
 541   PROTO_INET6([], [
 542     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 543     ipv6=no
 544   ])
 545 fi
 546
 547 if test "X$ipv6" = "Xyes"; then
 548   TYPE_STRUCT_SOCKADDR_IN6([],[
 549     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 550     ipv6=no
 551   ])
 552   if test "X$ipv6" = "Xyes"; then
 553     WGET_STRUCT_SOCKADDR_STORAGE
 554     MEMBER_SIN6_SCOPE_ID
 555   fi
 556 fi
 557
 558 if test "X$ipv6" = "Xyes"; then
 559   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 560   AC_MSG_NOTICE([Enabling support for IPv6.])
 561 elif test "x$force_ipv6" = "xyes"; then
 562   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 563 fi
 564
 565
 566 dnl
 567 dnl Set of available languages.
 568 dnl
 569 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 570
 571 dnl Originally this used to be static, looking like this:
 572 dnl     ALL_LINGUAS="cs de hr it ..."
 573 dnl The downside was that configure needed to be rebuilt whenever a
 574 dnl new language was added.
 575
 576 dnl internationalization macros
 577 WGET_WITH_NLS
 578
 579 dnl
 580 dnl Find makeinfo.  We used to provide support for Emacs processing
 581 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 582 dnl unavailable, but that broke with the addition of makeinfo-specific
 583 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 584 dnl build the Info documentation.
 585 dnl
 586
 587 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 588
 589 dnl
 590 dnl Find perl and pod2man
 591 dnl
 592
 593 AC_PATH_PROGS(PERL, [perl5 perl], no)
 594 AC_PATH_PROG(POD2MAN, pod2man, no)
 595
 596 if test "x${POD2MAN}" = xno; then
 597   COMMENT_IF_NO_POD2MAN="# "
 598 else
 599   COMMENT_IF_NO_POD2MAN=
 600 fi
 601 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 602
 603 dnl
 604 dnl Create output
 605 dnl
 606 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 607                  po/Makefile.in windows/Makefile])
 608 AC_CONFIG_HEADERS([src/config.h])
 609 AH_BOTTOM([
 610 #include "config-post.h"
 611 ])
 612 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 613 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 614 AC_OUTPUT