sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 USE_OPIE=$enableval, USE_OPIE=yes)
  62 test x"${USE_OPIE}" = xyes && AC_DEFINE([USE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 USE_DIGEST=$enableval, USE_DIGEST=yes)
  68 test x"${USE_DIGEST}" = xyes && AC_DEFINE([USE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(debug,
  72 [  --disable-debug         disable support for debugging output],
  73 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  74 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  75    [Define if you want the debug output support compiled in.])
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107 AC_AIX
 108 AM_PROG_CC_STDC
 109
 110 dnl Turn on optimization by default.  Specifically:
 111 dnl
 112 dnl if the user hasn't specified CFLAGS, then
 113 dnl   if compiler is gcc, then
 114 dnl     use -O2 and some warning flags
 115 dnl   else
 116 dnl     use os-specific flags or -O
 117 if test -n "$auto_cflags"; then
 118   if test -n "$GCC"; then
 119     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 120   else
 121     case "$host_os" in
 122       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 123       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 124       *)       CFLAGS="$CFLAGS -O" ;;
 125     esac
 126   fi
 127 fi
 128
 129 dnl
 130 dnl Configure our included libtool and make sure it's regenerated when needed
 131 dnl
 132 AC_PROG_LIBTOOL
 133 AC_SUBST(LIBTOOL_DEPS)
 134
 135 dnl
 136 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 137 dnl Might also be erelevant for DJGPP.
 138 dnl
 139 case "$host_os" in
 140   *win32) exeext='.exe';;
 141   *) exeext='';;
 142 esac
 143 AC_SUBST(exeext)
 144
 145 dnl
 146 dnl Checks for basic compiler characteristics.
 147 dnl
 148 AC_C_CONST
 149 AC_C_INLINE
 150 AC_C_VOLATILE
 151 AC_C_BIGENDIAN
 152 AC_C_PROTOTYPES
 153
 154 if test x"$am_cv_prog_cc_stdc" != xno; then
 155   true
 156   AC_SUBST(U, [])
 157   AC_SUBST(ANSI2KNR, [])
 158 else
 159   AC_SUBST(U, [_])
 160   AC_SUBST(ANSI2KNR, [./ansi2knr])
 161 fi
 162
 163 dnl
 164 dnl Checks for header files that might be missing.
 165 dnl
 166
 167 dnl Check for basic headers, even those we assume the presence of.
 168 dnl This is because Autoconf default includes check for STDC_HEADERS,
 169 dnl HAVE_SYS_TYPES_H, etc. before including them.
 170 AC_HEADER_STDC
 171 AC_CHECK_HEADERS(sys/types.h sys/stat.h)
 172 dnl Now check for the others.
 173 AC_CHECK_HEADERS(string.h strings.h stdarg.h unistd.h sys/time.h)
 174 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 175 AC_CHECK_HEADERS(stdint.h inttypes.h signal.h setjmp.h pwd.h)
 176 AC_HEADER_TIME
 177
 178 dnl
 179 dnl Check integral type sizes.
 180 dnl
 181 AC_CHECK_SIZEOF(short)
 182 AC_CHECK_SIZEOF(int)
 183 AC_CHECK_SIZEOF(long)
 184 AC_CHECK_SIZEOF(long long)
 185
 186 dnl
 187 dnl Checks for non-universal or system-specific types.
 188 dnl
 189 AC_TYPE_SIZE_T
 190 AC_TYPE_PID_T
 191 AC_CHECK_TYPES(uint32_t)
 192 AC_TYPE_SIGNAL
 193 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 194 #include <stdio.h>
 195 #include <sys/types.h>
 196 #if HAVE_INTTYPES_H
 197 # include <inttypes.h>
 198 #endif
 199 #ifdef HAVE_SIGNAL_H
 200 # include <signal.h>
 201 #endif
 202 ])
 203
 204 dnl
 205 dnl Checks for library functions.
 206 dnl
 207 AC_FUNC_ALLOCA
 208 AC_FUNC_MMAP
 209 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 210 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 211 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 212
 213 dnl
 214 dnl Call Wget's local macros defined in aclocal.
 215 dnl
 216 WGET_STRUCT_UTIMBUF
 217 WGET_SOCKLEN_T
 218 WGET_FNMATCH
 219 WGET_NANOSLEEP
 220 WGET_NSL_SOCKET
 221
 222 dnl
 223 dnl Check if we need to compile in getopt.c.
 224 dnl
 225 AC_CHECK_FUNC(getopt_long, [], [
 226   GETOPT_OBJ='getopt$o'
 227 ])
 228 AC_SUBST(GETOPT_OBJ)
 229
 230 dnl
 231 dnl Checks for libraries.
 232 dnl
 233
 234 dnl $with_ssl can be one of:
 235 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 236 dnl  - "yes", meaning link with SSL or bail out.
 237 dnl  - "no", meaning don't link with SSL.
 238 dnl  - anything else, meaning use that as the SSL root, and bail out
 239 dnl    if it fails.
 240
 241 if test x"$with_ssl" = x; then
 242   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 243   dnl implements the "auto-detect by default" feature.  If you want to
 244   dnl change this to "ignore SSL by default", change "auto" to "no".
 245   with_ssl=auto
 246 fi
 247
 248 dnl Detection of OpenSSL is much hairier than the detection of other
 249 dnl libraries because OpenSSL can be compiled as a third-party
 250 dnl library, which means it will not be found without additional
 251 dnl linker magic.  It would be really nice to rework this check into
 252 dnl an AC_DEFUN so that we can reuse it for other third-party
 253 dnl libraries.
 254
 255 if test x"$with_ssl" != x"no"; then
 256
 257   wget_force_ssl=no
 258   if test x"$with_ssl" = x"yes"; then
 259     wget_force_ssl=yes
 260   fi
 261
 262   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 263     dnl OpenSSL's root was not specified, so we have to guess.  First
 264     dnl try the system default location, then "/usr/local/ssl" (where
 265     dnl OpenSSL installs by default), then "/usr/local" (traditional
 266     dnl choice for installation root), then "/opt".
 267     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 268   else
 269     dnl Root has been specified by the user.
 270     ssl_all_roots=$with_ssl
 271     wget_force_ssl=yes
 272   fi
 273
 274   wget_save_CC=$CC
 275   wget_save_LIBS=$LIBS
 276   wget_save_LDFLAGS=$LDFLAGS
 277   wget_save_CPPFLAGS=$CPPFLAGS
 278
 279   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 280   dnl without having to know how the linker handles it.
 281   CC="$SHELL ./libtool $CC"
 282
 283   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 284   dnl shared library doesn't record its dependency on libdl, so we
 285   dnl need to check for it ourselves so we won't fail to link due to a
 286   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 287   dnl shl_load().
 288   AC_CHECK_LIB(dl,dlopen)
 289   AC_CHECK_LIB(dl,shl_load)
 290
 291   ssl_success=no
 292
 293   dnl Now try to find SSL libraries in each of the likely SSL roots.
 294   for ssl_root in $ssl_all_roots
 295   do
 296     if test x"$ssl_root" = x"system-default"; then
 297       dnl Try the default include and library locations.
 298       SSL_INCLUDES=
 299     else
 300       dnl Try this specific root.
 301       SSL_INCLUDES=-I$ssl_root/include
 302       dnl It's OK to use -R directly because libtool will
 303       dnl interpret it for us.
 304       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 305     fi
 306
 307     AC_MSG_NOTICE([looking for SSL libraries in $ssl_root])
 308
 309     dnl Check whether the compiler can find the include files.  On
 310     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 311     dnl to find the includes in /usr/local/include.
 312
 313     ssl_found_includes=no
 314     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 315
 316     AC_MSG_CHECKING([for includes])
 317
 318     AC_TRY_CPP([#include <openssl/ssl.h>
 319 #include <openssl/rsa.h>
 320 ],
 321       AC_MSG_RESULT(found); ssl_found_includes=yes,
 322       AC_MSG_RESULT([not found])
 323     )
 324
 325     if test x"$ssl_found_includes" = xno; then
 326       continue
 327     fi
 328
 329     ssl_link_failure=no
 330
 331     dnl Make sure that the checks don't run afoul of the cache.  It
 332     dnl would be nicer to temporarily turn off the cache, but
 333     dnl apparently Autoconf doesn't allow that.
 334
 335     unset ac_cv_lib_crypto_RSA_new
 336     unset ac_cv_lib_ssl_SSL_new
 337
 338     dnl These checks need to be in this order, or you'll get a link
 339     dnl failure if you use a static libcrypto.a and libssl.a rather
 340     dnl than shared libraries.
 341
 342     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 343     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 344
 345     if test x"$ssl_link_failure" = xyes; then
 346       dnl One or both libs failed to link.
 347       continue
 348     fi
 349
 350     dnl The libraries link.  But we still need to check if the program
 351     dnl linked with those libraries under these settings with run.  On
 352     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 353     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 354     dnl executables that link, but fail to run.
 355
 356     dnl If we are cross-compiling, just assume that working linkage
 357     dnl implies working executable.
 358
 359     ssl_run_failure=no
 360
 361     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 362     AC_TRY_RUN([
 363 int RSA_new();
 364 int SSL_new();
 365 main(){return 0;}
 366 ],
 367       AC_MSG_RESULT(yes),
 368       AC_MSG_RESULT(no); ssl_run_failure=yes,
 369       AC_MSG_RESULT(cross)
 370     )
 371
 372     if test x"$ssl_run_failure" = xno; then
 373       ssl_success=yes
 374       break
 375     fi
 376   done
 377
 378   if test x"$ssl_success" = xyes; then
 379     AC_MSG_NOTICE([compiling in support for SSL in $ssl_root])
 380     AC_DEFINE([HAVE_SSL], 1,
 381               [Define if SSL support should be compiled in.])
 382     AC_SUBST(SSL_INCLUDES)
 383     SSL_OBJ='gen_sslfunc$o'
 384     AC_SUBST(SSL_OBJ)
 385   else
 386     LDFLAGS=$wget_save_LDFLAGS
 387     LIBS=$wget_save_LIBS
 388
 389     dnl If linking with SSL was forced rather than auto-detected, then
 390     dnl bail out if SSL failed.
 391     if test x"$wget_force_ssl" = x"yes"; then
 392       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 393     fi
 394   fi
 395
 396   dnl Restore the compiler setting.
 397   CC=$wget_save_CC
 398
 399   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 400   dnl with SSL succeeded -- SSL includes will be handled using
 401   dnl @SSL_INCLUDES@.
 402   CPPFLAGS=$wget_save_CPPFLAGS
 403 fi
 404
 405 dnl
 406 dnl Find an md5 implementation.
 407 dnl
 408
 409 if test x"$wget_need_md5" = xyes
 410 then
 411   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 412   dnl manipulate MD5_OBJ from the defun.
 413
 414   MD5_OBJ='gen-md5$o'
 415   found_md5=no
 416
 417   dnl Check for the system MD5 library on Solaris.  We don't check for
 418   dnl something simple like "MD5Update" because there are a number of
 419   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 420   dnl specific to the Solaris MD5 library.
 421   if test x"$found_md5" = xno; then
 422     AC_CHECK_LIB(md5, md5_calc, [
 423       dnl Some installations have bogus <md5.h> in the compiler's
 424       dnl include path, making the system md5 library useless.
 425       AC_MSG_CHECKING([whether md5.h can be included])
 426       AC_COMPILE_IFELSE([#include <md5.h>
 427                         ], [
 428         AC_MSG_RESULT(yes)
 429         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 430         LIBS="-lmd5 $LIBS"
 431         found_md5=yes
 432         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 433       ], [AC_MSG_RESULT(no)])
 434     ])
 435   fi
 436
 437   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 438   dnl implementation.
 439   if test x"$found_md5" = xno; then
 440     if test x"$ssl_success" = xyes; then
 441       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 442       found_md5=yes
 443       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 444     fi
 445   fi
 446
 447   dnl If none of the above worked, use the one we ship with Wget.
 448   if test x"$found_md5" = xno; then
 449     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 450     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 451     found_md5=yes
 452     AC_MSG_NOTICE([using the GNU MD5 implementation])
 453   fi
 454 fi
 455 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 456 AC_SUBST(MD5_OBJ)
 457
 458 dnl **********************************************************************
 459 dnl Checks for IPv6
 460 dnl **********************************************************************
 461
 462 dnl
 463 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 464 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 465 dnl don't use IPv6 or getaddrinfo.
 466 dnl
 467
 468 ipv6=
 469 check_for_ipv6=no
 470 AC_ARG_ENABLE(ipv6,
 471   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 472   [case "${enable_ipv6}" in
 473   no)
 474     AC_MSG_NOTICE([disabling IPv6 at user request])
 475     ipv6=no
 476     ;;
 477   *)
 478     ipv6=yes
 479     ;;
 480   esac],
 481   dnl If unspecified, check for IPv6 and use it where available.
 482   [check_for_ipv6=yes]
 483 )
 484
 485 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 486   AC_CHECK_FUNCS(getaddrinfo,[
 487     GETADDRINFO_AI_ADDRCONFIG(
 488       AC_DEFINE(
 489         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 490         [Define if the system headers support the AI_ADDRCONFIG flag.]
 491       )
 492     )
 493     GETADDRINFO_AI_V4MAPPED(
 494       AC_DEFINE(
 495         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 496         [Define if the system headers support the AI_V4MAPPED flag.]
 497       )
 498     )
 499     GETADDRINFO_AI_ALL(
 500       AC_DEFINE(
 501         [HAVE_GETADDRINFO_AI_ALL], 1,
 502         [Define if the system headers support the AI_ALL flag.]
 503       )
 504     )
 505   ],[
 506     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 507     ipv6=no
 508   ])
 509 fi
 510
 511 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 512   PROTO_INET6(,[
 513     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 514     ipv6=no
 515   ])
 516 fi
 517
 518 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 519   TYPE_STRUCT_SOCKADDR_IN6([
 520     ipv6=yes
 521   ],[
 522     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 523     ipv6=no
 524   ])
 525   if test "X$ipv6" = "Xyes"; then
 526     MEMBER_SIN6_SCOPE_ID
 527   fi
 528 fi
 529
 530 if test "X$ipv6" = "Xyes"; then
 531   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 532 fi
 533
 534
 535 dnl
 536 dnl Set of available languages.
 537 dnl
 538 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 539
 540 dnl Originally this used to be static, looking like this:
 541 dnl     ALL_LINGUAS="cs de hr it ..."
 542 dnl The downside was that configure needed to be rebuilt whenever a
 543 dnl new language was added.
 544
 545 dnl internationalization macros
 546 WGET_WITH_NLS
 547
 548 dnl
 549 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 550 dnl Emacs cannot be found, look for XEmacs.
 551 dnl
 552
 553 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 554
 555 case "${MAKEINFO}" in
 556    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 557    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 558    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 559 esac
 560
 561 dnl
 562 dnl Find perl and pod2man
 563 dnl
 564
 565 AC_PATH_PROGS(PERL, perl5 perl, no)
 566 AC_PATH_PROG(POD2MAN, pod2man, no)
 567
 568 if test "x${POD2MAN}" = xno; then
 569   COMMENT_IF_NO_POD2MAN="# "
 570 else
 571   COMMENT_IF_NO_POD2MAN=
 572 fi
 573 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 574
 575 dnl
 576 dnl Create output
 577 dnl
 578 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 579                  po/Makefile.in windows/Makefile])
 580 AC_CONFIG_HEADERS([src/config.h])
 581 AH_BOTTOM([
 582 #include "config-post.h"
 583 ])
 584 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 585 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 586 AC_OUTPUT