sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 echo "configuring for GNU Wget $VERSION"
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for typedefs, structures, and compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_PID_T
 158 AC_C_BIGENDIAN
 159
 160 # Check size of long.
 161 AC_CHECK_SIZEOF(long)
 162 AC_CHECK_SIZEOF(long long)
 163
 164 dnl
 165 dnl Checks for headers
 166 dnl
 167 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 168 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 169 AC_CHECK_HEADERS(signal.h setjmp.h)
 170 AC_HEADER_TIME
 171
 172 dnl
 173 dnl Return type of signal-handlers
 174 dnl
 175 AC_TYPE_SIGNAL
 176
 177 dnl
 178 dnl Call several of Wget's macros.
 179 dnl
 180 WGET_STRUCT_UTIMBUF
 181 WGET_SOCKLEN_T
 182
 183 dnl
 184 dnl Checks for library functions.
 185 dnl
 186 AC_FUNC_ALLOCA
 187 AC_FUNC_MMAP
 188 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 189 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 190 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 191 AC_CHECK_FUNCS(uname gethostname usleep)
 192
 193 dnl
 194 dnl Check if we need to compile in getopt.c.
 195 dnl
 196 AC_CHECK_FUNC(getopt_long, [], [
 197   GETOPT_OBJ='getopt$o'
 198 ])
 199 AC_SUBST(GETOPT_OBJ)
 200
 201 dnl
 202 dnl Checks for libraries.
 203 dnl
 204
 205 dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
 206 dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
 207 dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
 208 dnl look for such known offenders and if one of them is not found, we
 209 dnl check if -lnsl is needed.
 210
 211 wget_check_in_nsl=NONE
 212 AC_CHECK_FUNCS(gethostbyname, [], [
 213   wget_check_in_nsl=gethostbyname
 214 ])
 215 AC_CHECK_FUNCS(inet_ntoa, [], [
 216   wget_check_in_nsl=inet_ntoa
 217 ])
 218 if test $wget_check_in_nsl != NONE; then
 219   AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 220 fi
 221
 222 AC_CHECK_LIB(socket, socket)
 223
 224 dnl #### This appears to be deficient with later versions of SOCKS.
 225 if test "x${with_socks}" = xyes
 226 then
 227   AC_CHECK_LIB(resolv, main)
 228   AC_CHECK_LIB(socks, Rconnect)
 229 fi
 230
 231 dnl $with_ssl can be one of:
 232 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 233 dnl  - "yes", meaning link with SSL or bail out.
 234 dnl  - "no", meaning don't link with SSL.
 235 dnl  - anything else, meaning use that as the SSL root, and bail out
 236 dnl    if it fails.
 237
 238 if test x"$with_ssl" = x; then
 239   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 240   dnl implements the "auto-detect by default" feature.  If you want to
 241   dnl change this to "ignore SSL by default", change "auto" to "no".
 242   with_ssl=auto
 243 fi
 244
 245 dnl Detection of OpenSSL is much hairier than the detection of other
 246 dnl libraries because OpenSSL can be compiled as a third-party
 247 dnl library, which means it will not be found without additional
 248 dnl linker magic.  It would be really nice to rework this check into
 249 dnl an AC_DEFUN so that we can reuse it for other third-party
 250 dnl libraries.
 251
 252 if test x"$with_ssl" != x"no"; then
 253
 254   wget_force_ssl=no
 255   if test x"$with_ssl" = x"yes"; then
 256     wget_force_ssl=yes
 257   fi
 258
 259   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 260     dnl OpenSSL's root was not specified, so we have to guess.  First
 261     dnl try the system default location, then "/usr/local/ssl" (where
 262     dnl OpenSSL installs by default), then "/usr/local" (traditional
 263     dnl choice for installation root), then "/opt".
 264     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 265   else
 266     dnl Root has been specified by the user.
 267     ssl_all_roots=$with_ssl
 268     wget_force_ssl=yes
 269   fi
 270
 271   wget_save_CC=$CC
 272   wget_save_LIBS=$LIBS
 273   wget_save_LDFLAGS=$LDFLAGS
 274   wget_save_CPPFLAGS=$CPPFLAGS
 275
 276   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 277   dnl without having to know how the linker handles it.
 278   CC="$SHELL ./libtool $CC"
 279
 280   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 281   dnl shared library doesn't record its dependency on libdl, so we
 282   dnl need to check for it ourselves so we won't fail to link due to a
 283   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 284   dnl shl_load().
 285   AC_CHECK_LIB(dl,dlopen)
 286   AC_CHECK_LIB(dl,shl_load)
 287
 288   ssl_success=no
 289
 290   dnl Now try to find SSL libraries in each of the likely SSL roots.
 291   for ssl_root in $ssl_all_roots
 292   do
 293     if test x"$ssl_root" = x"system-default"; then
 294       dnl Try the default include and library locations.
 295       SSL_INCLUDES=
 296     else
 297       dnl Try this specific root.
 298       SSL_INCLUDES=-I$ssl_root/include
 299       dnl It's OK to use -R directly because libtool will
 300       dnl interpret it for us.
 301       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 302     fi
 303
 304     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 305
 306     dnl Check whether the compiler can find the include files.  On
 307     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 308     dnl to find the includes in /usr/local/include.
 309
 310     ssl_found_includes=no
 311     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 312
 313     AC_MSG_CHECKING([for includes])
 314
 315     AC_TRY_CPP([#include <openssl/ssl.h>
 316 #include <openssl/rsa.h>
 317 ],
 318       AC_MSG_RESULT(found); ssl_found_includes=yes,
 319       AC_MSG_RESULT([not found])
 320     )
 321
 322     if test x"$ssl_found_includes" = xno; then
 323       continue
 324     fi
 325
 326     ssl_link_failure=no
 327
 328     dnl Make sure that the checks don't run afoul of the cache.  It
 329     dnl would be nicer to temporarily turn off the cache, but
 330     dnl apparently Autoconf doesn't allow that.
 331
 332     unset ac_cv_lib_crypto_RSA_new
 333     unset ac_cv_lib_ssl_SSL_new
 334
 335     dnl These checks need to be in this order, or you'll get a link
 336     dnl failure if you use a static libcrypto.a and libssl.a rather
 337     dnl than shared libraries.
 338
 339     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 340     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 341
 342     if test x"$ssl_link_failure" = xyes; then
 343       dnl One or both libs failed to link.
 344       continue
 345     fi
 346
 347     dnl The libraries link.  But we still need to check if the program
 348     dnl linked with those libraries under these settings with run.  On
 349     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 350     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 351     dnl executables that link, but fail to run.
 352
 353     dnl If we are cross-compiling, just assume that working linkage
 354     dnl implies working executable.
 355
 356     ssl_run_failure=no
 357
 358     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 359     AC_TRY_RUN([
 360 int RSA_new();
 361 int SSL_new();
 362 main(){return 0;}
 363 ],
 364       AC_MSG_RESULT(yes),
 365       AC_MSG_RESULT(no); ssl_run_failure=yes,
 366       AC_MSG_RESULT(cross)
 367     )
 368
 369     if test x"$ssl_run_failure" = xno; then
 370       ssl_success=yes
 371       break
 372     fi
 373   done
 374
 375   if test x"$ssl_success" = xyes; then
 376     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 377     dnl to use instead.
 378     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 379     AC_DEFINE(HAVE_SSL)
 380     AC_SUBST(SSL_INCLUDES)
 381     SSL_OBJ='gen_sslfunc$o'
 382     AC_SUBST(SSL_OBJ)
 383   else
 384     LDFLAGS=$wget_save_LDFLAGS
 385     LIBS=$wget_save_LIBS
 386
 387     dnl If linking with SSL was forced rather than auto-detected, then
 388     dnl bail out if SSL failed.
 389     if test x"$wget_force_ssl" = x"yes"; then
 390       exec >&2
 391       echo "ERROR: Failed to find OpenSSL libraries."
 392       exit 2
 393     fi
 394   fi
 395
 396   dnl Restore the compiler setting.
 397   CC=$wget_save_CC
 398
 399   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 400   dnl with SSL succeeded -- SSL includes will be handled using
 401   dnl @SSL_INCLUDES@.
 402   CPPFLAGS=$wget_save_CPPFLAGS
 403 fi
 404
 405 dnl
 406 dnl Find an md5 implementation.
 407 dnl
 408
 409 if test x"$wget_need_md5" = xyes
 410 then
 411   MD5_OBJ='gen-md5$o'
 412
 413   found_md5=no
 414
 415   dnl Check for the system MD5 library on Solaris.  We don't check for
 416   dnl something simple like "MD5Update" because there are a number of
 417   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 418   dnl specific to the Solaris MD5 library.
 419   if test x"$found_md5" = xno; then
 420     AC_CHECK_LIB(md5, md5_calc, [
 421       AC_DEFINE(HAVE_SOLARIS_MD5)
 422       LIBS="-lmd5 $LIBS"
 423       found_md5=yes
 424     ])
 425   fi
 426
 427   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 428   dnl implementation.
 429   if test x"$found_md5" = xno; then
 430     if test x"$ssl_success" = xyes; then
 431       AC_DEFINE(HAVE_OPENSSL_MD5)
 432       found_md5=yes
 433     fi
 434   fi
 435
 436   dnl If none of the above worked, use the one we ship with Wget.
 437   if test x"$found_md5" = xno; then
 438     AC_DEFINE(HAVE_BUILTIN_MD5)
 439     found_md5=yes
 440     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 441   fi
 442 fi
 443 AC_DEFINE(HAVE_MD5)
 444 AC_SUBST(MD5_OBJ)
 445
 446 dnl **********************************************************************
 447 dnl Checks for IPv6
 448 dnl **********************************************************************
 449
 450 ipv6=
 451 check_for_ipv6=no
 452 AC_ARG_ENABLE(ipv6,
 453   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 454   [case "${enable_ipv6}" in
 455   no)
 456     AC_MSG_NOTICE([Disabling IPv6 at user request])
 457     ipv6=no
 458     ;;
 459   *)
 460     ipv6=yes
 461     ;;
 462   esac],
 463   [check_for_ipv6=no]
 464 )
 465
 466 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 467   AC_CHECK_FUNCS(getaddrinfo,[
 468     GETADDRINFO_AI_ADDRCONFIG(
 469       AC_DEFINE(
 470         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 471         [Define if the system headers support the AI_ADDRCONFIG flag.]
 472       )
 473     )
 474     GETADDRINFO_AI_V4MAPPED(
 475       AC_DEFINE(
 476         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 477         [Define if the system headers support the AI_V4MAPPED flag.]
 478       )
 479     )
 480     GETADDRINFO_AI_ALL(
 481       AC_DEFINE(
 482         [HAVE_GETADDRINFO_AI_ALL], 1,
 483         [Define if the system headers support the AI_ALL flag.]
 484       )
 485     )
 486   ],[
 487     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 488     ipv6=no
 489   ])
 490 fi
 491
 492 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 493   PROTO_INET6(,[
 494     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 495     ipv6=no
 496   ])
 497 fi
 498
 499 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 500   TYPE_STRUCT_SOCKADDR_IN6([
 501     ipv6=yes
 502   ],[
 503     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 504     ipv6=no
 505   ])
 506   if test "X$ipv6" = "Xyes"; then
 507     MEMBER_SIN6_SCOPE_ID
 508   fi
 509 fi
 510
 511 if test "X$ipv6" = "Xyes"; then
 512   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 513 fi
 514
 515
 516 dnl
 517 dnl Set of available languages.
 518 dnl
 519 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 520
 521 dnl Originally this used to be static, looking like this:
 522 dnl     ALL_LINGUAS="cs de hr it ..."
 523 dnl The downside was that configure needed to be rebuilt whenever a
 524 dnl new language was added.
 525
 526 dnl internationalization macros
 527 WGET_WITH_NLS
 528
 529 dnl
 530 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 531 dnl Emacs cannot be found, look for XEmacs.
 532 dnl
 533
 534 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 535
 536 case "${MAKEINFO}" in
 537    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 538    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 539    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 540 esac
 541
 542 dnl
 543 dnl Find perl and pod2man
 544 dnl
 545
 546 AC_PATH_PROGS(PERL, perl5 perl, no)
 547 AC_PATH_PROG(POD2MAN, pod2man, no)
 548
 549 if test "x${POD2MAN}" = xno; then
 550   COMMENT_IF_NO_POD2MAN="# "
 551 else
 552   COMMENT_IF_NO_POD2MAN=
 553 fi
 554 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 555
 556 dnl
 557 dnl Create output
 558 dnl
 559 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 560            windows/Makefile],
 561 [WGET_PROCESS_PO
 562 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])