sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for basic compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_C_VOLATILE
 157 AC_C_BIGENDIAN
 158
 159 dnl
 160 dnl Checks for headers
 161 dnl
 162 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 164 AC_CHECK_HEADERS(inttypes.h signal.h setjmp.h pwd.h)
 165 AC_HEADER_TIME
 166
 167 dnl
 168 dnl Check integral type sizes.
 169 dnl
 170 AC_CHECK_SIZEOF(short)
 171 AC_CHECK_SIZEOF(int)
 172 AC_CHECK_SIZEOF(long)
 173 AC_CHECK_SIZEOF(long long)
 174
 175 dnl
 176 dnl Checks for system-specific types.
 177 dnl
 178 AC_TYPE_SIZE_T
 179 AC_TYPE_PID_T
 180 AC_CHECK_TYPES(uint32_t)
 181 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 182 #include <stdio.h>
 183 #if HAVE_SYS_TYPES_H
 184 # include <sys/types.h>
 185 #endif
 186 #if HAVE_INTTYPES_H
 187 # include <inttypes.h>
 188 #endif
 189 #ifdef HAVE_SIGNAL_H
 190 # include <signal.h>
 191 #endif
 192 ])
 193
 194 dnl
 195 dnl Return type of signal-handlers
 196 dnl
 197 AC_TYPE_SIGNAL
 198
 199 dnl
 200 dnl Checks for library functions.
 201 dnl
 202 AC_FUNC_ALLOCA
 203 AC_FUNC_MMAP
 204 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 205 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 206 AC_CHECK_FUNCS(usleep select sigblock sigsetjmp signal symlink access isatty)
 207
 208 dnl
 209 dnl Call Wget's local macros defined in aclocal.
 210 dnl
 211 WGET_STRUCT_UTIMBUF
 212 WGET_SOCKLEN_T
 213 WGET_FNMATCH
 214 WGET_NANOSLEEP
 215 WGET_NSL_SOCKET
 216
 217 dnl
 218 dnl Check if we need to compile in getopt.c.
 219 dnl
 220 AC_CHECK_FUNC(getopt_long, [], [
 221   GETOPT_OBJ='getopt$o'
 222 ])
 223 AC_SUBST(GETOPT_OBJ)
 224
 225 dnl
 226 dnl Checks for libraries.
 227 dnl
 228
 229 dnl #### This appears to be deficient with later versions of SOCKS.
 230 if test "x${with_socks}" = xyes
 231 then
 232   AC_CHECK_LIB(resolv, main)
 233   AC_CHECK_LIB(socks, Rconnect)
 234 fi
 235
 236 dnl $with_ssl can be one of:
 237 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 238 dnl  - "yes", meaning link with SSL or bail out.
 239 dnl  - "no", meaning don't link with SSL.
 240 dnl  - anything else, meaning use that as the SSL root, and bail out
 241 dnl    if it fails.
 242
 243 if test x"$with_ssl" = x; then
 244   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 245   dnl implements the "auto-detect by default" feature.  If you want to
 246   dnl change this to "ignore SSL by default", change "auto" to "no".
 247   with_ssl=auto
 248 fi
 249
 250 dnl Detection of OpenSSL is much hairier than the detection of other
 251 dnl libraries because OpenSSL can be compiled as a third-party
 252 dnl library, which means it will not be found without additional
 253 dnl linker magic.  It would be really nice to rework this check into
 254 dnl an AC_DEFUN so that we can reuse it for other third-party
 255 dnl libraries.
 256
 257 if test x"$with_ssl" != x"no"; then
 258
 259   wget_force_ssl=no
 260   if test x"$with_ssl" = x"yes"; then
 261     wget_force_ssl=yes
 262   fi
 263
 264   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 265     dnl OpenSSL's root was not specified, so we have to guess.  First
 266     dnl try the system default location, then "/usr/local/ssl" (where
 267     dnl OpenSSL installs by default), then "/usr/local" (traditional
 268     dnl choice for installation root), then "/opt".
 269     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 270   else
 271     dnl Root has been specified by the user.
 272     ssl_all_roots=$with_ssl
 273     wget_force_ssl=yes
 274   fi
 275
 276   wget_save_CC=$CC
 277   wget_save_LIBS=$LIBS
 278   wget_save_LDFLAGS=$LDFLAGS
 279   wget_save_CPPFLAGS=$CPPFLAGS
 280
 281   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 282   dnl without having to know how the linker handles it.
 283   CC="$SHELL ./libtool $CC"
 284
 285   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 286   dnl shared library doesn't record its dependency on libdl, so we
 287   dnl need to check for it ourselves so we won't fail to link due to a
 288   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 289   dnl shl_load().
 290   AC_CHECK_LIB(dl,dlopen)
 291   AC_CHECK_LIB(dl,shl_load)
 292
 293   ssl_success=no
 294
 295   dnl Now try to find SSL libraries in each of the likely SSL roots.
 296   for ssl_root in $ssl_all_roots
 297   do
 298     if test x"$ssl_root" = x"system-default"; then
 299       dnl Try the default include and library locations.
 300       SSL_INCLUDES=
 301     else
 302       dnl Try this specific root.
 303       SSL_INCLUDES=-I$ssl_root/include
 304       dnl It's OK to use -R directly because libtool will
 305       dnl interpret it for us.
 306       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 307     fi
 308
 309     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 310
 311     dnl Check whether the compiler can find the include files.  On
 312     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 313     dnl to find the includes in /usr/local/include.
 314
 315     ssl_found_includes=no
 316     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 317
 318     AC_MSG_CHECKING([for includes])
 319
 320     AC_TRY_CPP([#include <openssl/ssl.h>
 321 #include <openssl/rsa.h>
 322 ],
 323       AC_MSG_RESULT(found); ssl_found_includes=yes,
 324       AC_MSG_RESULT([not found])
 325     )
 326
 327     if test x"$ssl_found_includes" = xno; then
 328       continue
 329     fi
 330
 331     ssl_link_failure=no
 332
 333     dnl Make sure that the checks don't run afoul of the cache.  It
 334     dnl would be nicer to temporarily turn off the cache, but
 335     dnl apparently Autoconf doesn't allow that.
 336
 337     unset ac_cv_lib_crypto_RSA_new
 338     unset ac_cv_lib_ssl_SSL_new
 339
 340     dnl These checks need to be in this order, or you'll get a link
 341     dnl failure if you use a static libcrypto.a and libssl.a rather
 342     dnl than shared libraries.
 343
 344     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 345     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 346
 347     if test x"$ssl_link_failure" = xyes; then
 348       dnl One or both libs failed to link.
 349       continue
 350     fi
 351
 352     dnl The libraries link.  But we still need to check if the program
 353     dnl linked with those libraries under these settings with run.  On
 354     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 355     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 356     dnl executables that link, but fail to run.
 357
 358     dnl If we are cross-compiling, just assume that working linkage
 359     dnl implies working executable.
 360
 361     ssl_run_failure=no
 362
 363     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 364     AC_TRY_RUN([
 365 int RSA_new();
 366 int SSL_new();
 367 main(){return 0;}
 368 ],
 369       AC_MSG_RESULT(yes),
 370       AC_MSG_RESULT(no); ssl_run_failure=yes,
 371       AC_MSG_RESULT(cross)
 372     )
 373
 374     if test x"$ssl_run_failure" = xno; then
 375       ssl_success=yes
 376       break
 377     fi
 378   done
 379
 380   if test x"$ssl_success" = xyes; then
 381     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 382     dnl to use instead.
 383     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 384     AC_DEFINE(HAVE_SSL)
 385     AC_SUBST(SSL_INCLUDES)
 386     SSL_OBJ='gen_sslfunc$o'
 387     AC_SUBST(SSL_OBJ)
 388   else
 389     LDFLAGS=$wget_save_LDFLAGS
 390     LIBS=$wget_save_LIBS
 391
 392     dnl If linking with SSL was forced rather than auto-detected, then
 393     dnl bail out if SSL failed.
 394     if test x"$wget_force_ssl" = x"yes"; then
 395       AC_MSG_ERROR([failed to find OpenSSL libraries], 2)
 396     fi
 397   fi
 398
 399   dnl Restore the compiler setting.
 400   CC=$wget_save_CC
 401
 402   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 403   dnl with SSL succeeded -- SSL includes will be handled using
 404   dnl @SSL_INCLUDES@.
 405   CPPFLAGS=$wget_save_CPPFLAGS
 406 fi
 407
 408 dnl
 409 dnl Find an md5 implementation.
 410 dnl
 411
 412 if test x"$wget_need_md5" = xyes
 413 then
 414   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 415   dnl manipulate MD5_OBJ from the defun.
 416
 417   MD5_OBJ='gen-md5$o'
 418   found_md5=no
 419
 420   dnl Check for the system MD5 library on Solaris.  We don't check for
 421   dnl something simple like "MD5Update" because there are a number of
 422   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 423   dnl specific to the Solaris MD5 library.
 424   if test x"$found_md5" = xno; then
 425     AC_CHECK_LIB(md5, md5_calc, [
 426       dnl Some installations have bogus <md5.h> in the compiler's
 427       dnl include path, making the system md5 library useless.
 428       AC_MSG_CHECKING([whether md5.h can be included])
 429       AC_COMPILE_IFELSE([#include <md5.h>
 430                         ], [
 431         AC_MSG_RESULT(yes)
 432         AC_DEFINE(HAVE_SOLARIS_MD5)
 433         LIBS="-lmd5 $LIBS"
 434         found_md5=yes
 435         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 436       ], [AC_MSG_RESULT(no)])
 437     ])
 438   fi
 439
 440   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 441   dnl implementation.
 442   if test x"$found_md5" = xno; then
 443     if test x"$ssl_success" = xyes; then
 444       AC_DEFINE(HAVE_OPENSSL_MD5)
 445       found_md5=yes
 446       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 447     fi
 448   fi
 449
 450   dnl If none of the above worked, use the one we ship with Wget.
 451   if test x"$found_md5" = xno; then
 452     AC_DEFINE(HAVE_BUILTIN_MD5)
 453     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 454     found_md5=yes
 455     AC_MSG_NOTICE([using the GNU MD5 implementation])
 456   fi
 457 fi
 458 AC_DEFINE(HAVE_MD5)
 459 AC_SUBST(MD5_OBJ)
 460
 461 dnl **********************************************************************
 462 dnl Checks for IPv6
 463 dnl **********************************************************************
 464
 465 dnl
 466 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 467 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 468 dnl don't use IPv6 or getaddrinfo.
 469 dnl
 470
 471 ipv6=
 472 check_for_ipv6=no
 473 AC_ARG_ENABLE(ipv6,
 474   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 475   [case "${enable_ipv6}" in
 476   no)
 477     AC_MSG_NOTICE([Disabling IPv6 at user request])
 478     ipv6=no
 479     ;;
 480   *)
 481     ipv6=yes
 482     ;;
 483   esac],
 484   dnl If unspecified, check for IPv6 and use it where available.
 485   [check_for_ipv6=yes]
 486 )
 487
 488 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 489   AC_CHECK_FUNCS(getaddrinfo,[
 490     GETADDRINFO_AI_ADDRCONFIG(
 491       AC_DEFINE(
 492         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 493         [Define if the system headers support the AI_ADDRCONFIG flag.]
 494       )
 495     )
 496     GETADDRINFO_AI_V4MAPPED(
 497       AC_DEFINE(
 498         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 499         [Define if the system headers support the AI_V4MAPPED flag.]
 500       )
 501     )
 502     GETADDRINFO_AI_ALL(
 503       AC_DEFINE(
 504         [HAVE_GETADDRINFO_AI_ALL], 1,
 505         [Define if the system headers support the AI_ALL flag.]
 506       )
 507     )
 508   ],[
 509     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 510     ipv6=no
 511   ])
 512 fi
 513
 514 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 515   PROTO_INET6(,[
 516     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 517     ipv6=no
 518   ])
 519 fi
 520
 521 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 522   TYPE_STRUCT_SOCKADDR_IN6([
 523     ipv6=yes
 524   ],[
 525     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 526     ipv6=no
 527   ])
 528   if test "X$ipv6" = "Xyes"; then
 529     MEMBER_SIN6_SCOPE_ID
 530   fi
 531 fi
 532
 533 if test "X$ipv6" = "Xyes"; then
 534   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 535 fi
 536
 537
 538 dnl
 539 dnl Set of available languages.
 540 dnl
 541 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 542
 543 dnl Originally this used to be static, looking like this:
 544 dnl     ALL_LINGUAS="cs de hr it ..."
 545 dnl The downside was that configure needed to be rebuilt whenever a
 546 dnl new language was added.
 547
 548 dnl internationalization macros
 549 WGET_WITH_NLS
 550
 551 dnl
 552 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 553 dnl Emacs cannot be found, look for XEmacs.
 554 dnl
 555
 556 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 557
 558 case "${MAKEINFO}" in
 559    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 560    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 561    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 562 esac
 563
 564 dnl
 565 dnl Find perl and pod2man
 566 dnl
 567
 568 AC_PATH_PROGS(PERL, perl5 perl, no)
 569 AC_PATH_PROG(POD2MAN, pod2man, no)
 570
 571 if test "x${POD2MAN}" = xno; then
 572   COMMENT_IF_NO_POD2MAN="# "
 573 else
 574   COMMENT_IF_NO_POD2MAN=
 575 fi
 576 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 577
 578 dnl
 579 dnl Create output
 580 dnl
 581 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 582            windows/Makefile],
 583 [WGET_PROCESS_PO
 584 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])