sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.12)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 echo "configuring for GNU Wget $VERSION"
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 DEBUG=$enableval, DEBUG=yes)
  75 test x"${DEBUG}" = xyes && AC_DEFINE(DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for typedefs, structures, and compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_PID_T
 158 dnl #### This generates a warning.  What do I do to shut it up?
 159 AC_C_BIGENDIAN
 160
 161 # Check size of long.
 162 AC_CHECK_SIZEOF(long)
 163 AC_CHECK_SIZEOF(long long)
 164
 165 dnl
 166 dnl Checks for headers
 167 dnl
 168 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 169 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 170 AC_CHECK_HEADERS(signal.h setjmp.h)
 171 AC_HEADER_TIME
 172
 173 dnl
 174 dnl Return type of signal-handlers
 175 dnl
 176 AC_TYPE_SIGNAL
 177
 178 dnl
 179 dnl Check for struct utimbuf
 180 WGET_STRUCT_UTIMBUF
 181
 182 dnl
 183 dnl Checks for library functions.
 184 dnl
 185 AC_FUNC_ALLOCA
 186 AC_FUNC_MMAP
 187 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 188 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 189 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 190 AC_CHECK_FUNCS(uname gethostname usleep)
 191
 192 dnl
 193 dnl Check if we need to compile in getopt.c.
 194 dnl
 195 AC_CHECK_FUNC(getopt_long, [], [
 196   GETOPT_OBJ='getopt$o'
 197 ])
 198 AC_SUBST(GETOPT_OBJ)
 199
 200 dnl
 201 dnl Checks for libraries.
 202 dnl
 203
 204 dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
 205 dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
 206 dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
 207 dnl look for such known offenders and if one of them is not found, we
 208 dnl check if -lnsl is needed.
 209
 210 wget_check_in_nsl=NONE
 211 AC_CHECK_FUNCS(gethostbyname, [], [
 212   wget_check_in_nsl=gethostbyname
 213 ])
 214 AC_CHECK_FUNCS(inet_ntoa, [], [
 215   wget_check_in_nsl=inet_ntoa
 216 ])
 217 if test $wget_check_in_nsl != NONE; then
 218   AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 219 fi
 220
 221 AC_CHECK_LIB(socket, socket)
 222
 223 dnl #### This appears to be deficient with later versions of SOCKS.
 224 if test "x${with_socks}" = xyes
 225 then
 226   AC_CHECK_LIB(resolv, main)
 227   AC_CHECK_LIB(socks, Rconnect)
 228 fi
 229
 230 dnl $with_ssl can be one of:
 231 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 232 dnl  - "yes", meaning link with SSL or bail out.
 233 dnl  - "no", meaning don't link with SSL.
 234 dnl  - anything else, meaning use that as the SSL root, and bail out
 235 dnl    if it fails.
 236
 237 if test x"$with_ssl" = x; then
 238   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 239   dnl implements the "auto-detect by default" feature.  If you want to
 240   dnl change this to "ignore SSL by default", change "auto" to "no".
 241   with_ssl=auto
 242 fi
 243
 244 dnl Detection of OpenSSL is much hairier than the detection of other
 245 dnl libraries because OpenSSL can be compiled as a third-party
 246 dnl library, which means it will not be found without additional
 247 dnl linker magic.  It would be really nice to rework this check into
 248 dnl an AC_DEFUN so that we can reuse it for other third-party
 249 dnl libraries.
 250
 251 if test x"$with_ssl" != x"no"; then
 252
 253   wget_force_ssl=no
 254   if test x"$with_ssl" = x"yes"; then
 255     wget_force_ssl=yes
 256   fi
 257
 258   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 259     dnl OpenSSL's root was not specified, so we have to guess.  First
 260     dnl try the system default location, then "/usr/local/ssl" (where
 261     dnl OpenSSL installs by default), then "/usr/local" (traditional
 262     dnl choice for installation root), then "/opt".
 263     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 264   else
 265     dnl Root has been specified by the user.
 266     ssl_all_roots=$with_ssl
 267     wget_force_ssl=yes
 268   fi
 269
 270   wget_save_CC=$CC
 271   wget_save_LIBS=$LIBS
 272   wget_save_LDFLAGS=$LDFLAGS
 273   wget_save_CPPFLAGS=$CPPFLAGS
 274
 275   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 276   dnl without having to know how the linker handles it.
 277   CC="$SHELL ./libtool $CC"
 278
 279   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 280   dnl shared library doesn't record its dependency on libdl, so we
 281   dnl need to check for it ourselves so we won't fail to link due to a
 282   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 283   dnl shl_load().
 284   AC_CHECK_LIB(dl,dlopen)
 285   AC_CHECK_LIB(dl,shl_load)
 286
 287   ssl_success=no
 288
 289   dnl Now try to find SSL libraries in each of the likely SSL roots.
 290   for ssl_root in $ssl_all_roots
 291   do
 292     if test x"$ssl_root" = x"system-default"; then
 293       dnl Try the default include and library locations.
 294       SSL_INCLUDES=
 295     else
 296       dnl Try this specific root.
 297       SSL_INCLUDES=-I$ssl_root/include
 298       dnl It's OK to use -R directly because libtool will
 299       dnl interpret it for us.
 300       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 301     fi
 302
 303     AC_MSG_RESULT(["Looking for SSL libraries in $ssl_root"])
 304
 305     dnl Check whether the compiler can find the include files.  On
 306     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 307     dnl to find the includes in /usr/local/include.
 308
 309     ssl_found_includes=no
 310     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 311
 312     AC_MSG_CHECKING(["for includes"])
 313
 314     AC_TRY_CPP([#include <openssl/ssl.h>
 315 #include <openssl/rsa.h>
 316 ],
 317       AC_MSG_RESULT("found"); ssl_found_includes=yes,
 318       AC_MSG_RESULT("not found")
 319     )
 320
 321     if test x"$ssl_found_includes" = xno; then
 322       continue
 323     fi
 324
 325     ssl_link_failure=no
 326
 327     dnl Make sure that the checks don't run afoul of the cache.  It
 328     dnl would be nicer to temporarily turn off the cache, but
 329     dnl apparently Autoconf doesn't allow that.
 330
 331     unset ac_cv_lib_crypto_RSA_new
 332     unset ac_cv_lib_ssl_SSL_new
 333
 334     dnl These checks need to be in this order, or you'll get a link
 335     dnl failure if you use a static libcrypto.a and libssl.a rather
 336     dnl than shared libraries.
 337
 338     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 339     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 340
 341     if test x"$ssl_link_failure" = xyes; then
 342       dnl One or both libs failed to link.
 343       continue
 344     fi
 345
 346     dnl The libraries link.  But we still need to check if the program
 347     dnl linked with those libraries under these settings with run.  On
 348     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 349     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 350     dnl executables that link, but fail to run.
 351
 352     dnl If we are cross-compiling, just assume that working linkage
 353     dnl implies working executable.
 354
 355     ssl_run_failure=no
 356
 357     AC_MSG_CHECKING("whether SSL libs are resolved at runtime")
 358     AC_TRY_RUN([
 359 int RSA_new();
 360 int SSL_new();
 361 main(){return 0;}
 362 ],
 363       AC_MSG_RESULT("yes"),
 364       AC_MSG_RESULT("no"); ssl_run_failure=yes,
 365       AC_MSG_RESULT("cross")
 366     )
 367
 368     if test x"$ssl_run_failure" = xno; then
 369       ssl_success=yes
 370       break
 371     fi
 372   done
 373
 374   if test x"$ssl_success" = xyes; then
 375     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 376     dnl to use instead.
 377     AC_MSG_RESULT("Compiling in support for SSL in $ssl_root")
 378     AC_DEFINE(HAVE_SSL)
 379     AC_SUBST(SSL_INCLUDES)
 380     SSL_OBJ='gen_sslfunc$o'
 381     AC_SUBST(SSL_OBJ)
 382   else
 383     LDFLAGS=$wget_save_LDFLAGS
 384     LIBS=$wget_save_LIBS
 385
 386     dnl If linking with SSL was forced rather than auto-detected, then
 387     dnl bail out if SSL failed.
 388     if test x"$wget_force_ssl" = x"yes"; then
 389       exec >&2
 390       echo "ERROR: Failed to find OpenSSL libraries."
 391       exit 2
 392     fi
 393   fi
 394
 395   dnl Restore the compiler setting.
 396   CC=$wget_save_CC
 397
 398   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 399   dnl with SSL succeeded -- SSL includes will be handled using
 400   dnl @SSL_INCLUDES@.
 401   CPPFLAGS=$wget_save_CPPFLAGS
 402 fi
 403
 404 dnl
 405 dnl Find an md5 implementation.
 406 dnl
 407
 408 if test x"$wget_need_md5" = xyes
 409 then
 410   MD5_OBJ='gen-md5$o'
 411
 412   found_md5=no
 413
 414   dnl Check for the system MD5 library on Solaris.  We don't check for
 415   dnl something simple like "MD5Update" because there are a number of
 416   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 417   dnl specific to the Solaris MD5 library.
 418   if test x"$found_md5" = xno; then
 419     AC_CHECK_LIB(md5, md5_calc, [
 420       AC_DEFINE(HAVE_SOLARIS_MD5)
 421       LIBS="-lmd5 $LIBS"
 422       found_md5=yes
 423     ])
 424   fi
 425
 426   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 427   dnl implementation.
 428   if test x"$found_md5" = xno; then
 429     if test x"$ssl_success" = xyes; then
 430       AC_DEFINE(HAVE_OPENSSL_MD5)
 431       found_md5=yes
 432     fi
 433   fi
 434
 435   dnl If none of the above worked, use the one we ship with Wget.
 436   if test x"$found_md5" = xno; then
 437     AC_DEFINE(HAVE_BUILTIN_MD5)
 438     found_md5=yes
 439     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 440   fi
 441 fi
 442 AC_DEFINE(HAVE_MD5)
 443 AC_SUBST(MD5_OBJ)
 444
 445 dnl
 446 dnl Set of available languages.
 447 dnl
 448 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//')`
 449
 450 dnl Originally this used to be static, looking like this:
 451 dnl     ALL_LINGUAS="cs de hr it ..."
 452 dnl The downside was that configure needed to be rebuilt whenever a
 453 dnl new language was added.
 454
 455 dnl internationalization macros
 456 WGET_WITH_NLS
 457
 458 dnl
 459 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 460 dnl Emacs cannot be found, look for XEmacs.
 461 dnl
 462
 463 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 464
 465 case "${MAKEINFO}" in
 466    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 467    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 468    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 469 esac
 470
 471 dnl
 472 dnl Find perl and pod2man
 473 dnl
 474
 475 AC_PATH_PROGS(PERL, perl5 perl, no)
 476 AC_PATH_PROG(POD2MAN, pod2man, no)
 477
 478 if test "x${POD2MAN}" = xno; then
 479   COMMENT_IF_NO_POD2MAN="# "
 480 else
 481   COMMENT_IF_NO_POD2MAN=
 482 fi
 483 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 484
 485 dnl
 486 dnl Create output
 487 dnl
 488 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 489            windows/Makefile],
 490 [WGET_PROCESS_PO
 491 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])