sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 3 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 dnl Additional permission under GNU GPL version 3 section 7
  18
  19 dnl If you modify this program, or any covered work, by linking or
  20 dnl combining it with the OpenSSL project's OpenSSL library (or a
  21 dnl modified version of that library), containing parts covered by the
  22 dnl terms of the OpenSSL or SSLeay licenses, the Free Software Foundation
  23 dnl grants you additional permission to convey the resulting work.
  24 dnl Corresponding Source for a non-source form of such a combination
  25 dnl shall include the source code for the parts of OpenSSL used as well
  26 dnl as that of the covered work.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.61)
  34
  35 dnl Include the M4 macros we use.
  36 builtin(include, [m4/wget.m4])dnl
  37 builtin(include, [m4/lib-ld.m4])dnl
  38 builtin(include, [m4/lib-link.m4])dnl
  39 builtin(include, [m4/lib-prefix.m4])dnl
  40
  41 dnl
  42 dnl What version of Wget are we building?
  43 dnl
  44 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  45 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  46 AC_SUBST(VERSION)
  47 PACKAGE=wget
  48 AC_SUBST(PACKAGE)
  49
  50 dnl
  51 dnl Get cannonical host
  52 dnl
  53 AC_CANONICAL_HOST
  54 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  55                    [Define to be the name of the operating system.])
  56
  57 dnl
  58 dnl Process features.
  59 dnl
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  67 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  73 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(ntlm,
  77 [  --disable-ntlm          disable support for NTLM authorization],
  78 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  79
  80 AC_ARG_ENABLE(debug,
  81 [  --disable-debug         disable support for debugging output],
  82 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  83 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  84    [Define if you want the debug output support compiled in.])
  85
  86 wget_need_md5=no
  87
  88 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  89 *yes*)
  90         wget_need_md5=yes
  91 esac
  92 if test x"$ENABLE_OPIE" = xyes; then
  93   OPIE_OBJ='ftp-opie.o'
  94 fi
  95 AC_SUBST(OPIE_OBJ)
  96
  97 dnl
  98 dnl Whether make sets $(MAKE)...
  99 dnl
 100 AC_PROG_MAKE_SET
 101
 102 dnl
 103 dnl Find a good install
 104 dnl
 105 AC_PROG_INSTALL
 106
 107 dnl
 108 dnl Find the compiler
 109 dnl
 110
 111 dnl We want these before the checks, so the checks can modify their values.
 112 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 113 test -z "$CC" && cc_specified=yes
 114
 115 AC_PROG_CC
 116 AC_AIX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl Checks for basic compiler characteristics.
 139 dnl
 140 AC_C_CONST
 141 AC_C_INLINE
 142 AC_C_VOLATILE
 143
 144 dnl Check for basic headers, even though we expect them to exist and
 145 dnl #include them unconditionally in the code.  Their detection is
 146 dnl still needed because test programs used by Autoconf macros check
 147 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 148 dnl Without the checks they will fail to be included in test programs,
 149 dnl which will subsequently fail.
 150 AC_HEADER_STDC
 151
 152 dnl Check for large file support.  This check needs to come fairly
 153 dnl early because it could (in principle) affect whether functions and
 154 dnl headers are available, whether they work, etc.
 155 AC_SYS_LARGEFILE
 156 AC_CHECK_SIZEOF(off_t)
 157
 158 dnl
 159 dnl Checks for system header files that might be missing.
 160 dnl
 161 AC_HEADER_STDBOOL
 162 AC_CHECK_HEADERS(unistd.h sys/time.h)
 163 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 164 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 165
 166 dnl
 167 dnl Check sizes of integer types.  These are used to find n-bit
 168 dnl integral types on older systems that fail to provide intN_t and
 169 dnl uintN_t typedefs.
 170 dnl
 171 AC_CHECK_SIZEOF(short)
 172 AC_CHECK_SIZEOF(int)
 173 AC_CHECK_SIZEOF(long)
 174 AC_CHECK_SIZEOF(long long)
 175 AC_CHECK_SIZEOF(void *)
 176
 177 dnl
 178 dnl Checks for non-universal or system-specific types.
 179 dnl
 180 AC_TYPE_SIZE_T
 181 AC_TYPE_PID_T
 182 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 183 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 184 #include <stdio.h>
 185 #include <sys/types.h>
 186 #if HAVE_INTTYPES_H
 187 # include <inttypes.h>
 188 #endif
 189 #include <signal.h>
 190 ])
 191
 192 dnl
 193 dnl Checks for library functions.
 194 dnl
 195 AC_FUNC_ALLOCA
 196 AC_FUNC_MMAP
 197 AC_FUNC_FSEEKO
 198 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 199 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 200
 201 dnl We expect to have these functions on Unix-like systems configure
 202 dnl runs on.  The defines are provided to get them in config.h.in so
 203 dnl Wget can still be ported to non-Unix systems (such as Windows)
 204 dnl that lack some of these functions.
 205 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 206 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 207 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 208 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 209 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 210
 211 dnl
 212 dnl Call Wget-specific macros defined in aclocal.
 213 dnl
 214 WGET_STRUCT_UTIMBUF
 215 WGET_SOCKLEN_T
 216 WGET_FNMATCH
 217 WGET_NANOSLEEP
 218 WGET_POSIX_CLOCK
 219 WGET_NSL_SOCKET
 220
 221 dnl
 222 dnl Check if we need to compile in getopt.c.
 223 dnl
 224 AC_CHECK_FUNC(getopt_long, [], [
 225   GETOPT_OBJ='getopt.o'
 226 ])
 227 AC_SUBST(GETOPT_OBJ)
 228
 229 dnl
 230 dnl Checks for libraries.
 231 dnl
 232
 233 AS_IF([test x"$with_ssl" = xgnutls], [
 234   dnl Now actually check for -lssl
 235   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 236 #include <gnutls/gnutls.h>
 237   ], [gnutls_global_init()])
 238   if test x"$LIBGNUTLS" != x
 239   then
 240     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 241     SSL_OBJ='gnutls.o'
 242   else
 243     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 244   fi
 245 ], [
 246   # --with-ssl is not gnutls: check if it's no
 247   AS_IF([test x"$with_ssl" != xno], [
 248     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 249     dnl doesn't record its dependency on libdl, so we need to make sure
 250     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 251     dnl dlopen(), but HP-UX uses shl_load().
 252     AC_CHECK_LIB(dl, dlopen, [], [
 253       AC_CHECK_LIB(dl, shl_load)
 254     ])
 255
 256     dnl Now actually check for -lssl
 257     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 258   #include <openssl/ssl.h>
 259   #include <openssl/x509.h>
 260   #include <openssl/err.h>
 261   #include <openssl/rand.h>
 262   #include <openssl/des.h>
 263   #include <openssl/md4.h>
 264   #include <openssl/md5.h>
 265     ], [SSL_library_init ()])
 266     if test x"$LIBSSL" != x
 267     then
 268       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 269       SSL_OBJ='openssl.o'
 270     elif test x"$with_ssl" != x
 271     then
 272       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 273     fi
 274   ]) # endif: --with-ssl == no?
 275 ]) # endif: --with-ssl == gnutls?
 276
 277 AC_SUBST(SSL_OBJ)
 278
 279 dnl Enable NTLM if requested and if SSL is available.
 280 NTLM_OBJ=''
 281 if test x"$LIBSSL" != x
 282 then
 283   if test x"$ENABLE_NTLM" != xno
 284   then
 285     AC_DEFINE([ENABLE_NTLM], 1,
 286      [Define if you want the NTLM authorization support compiled in.])
 287     NTLM_OBJ='http-ntlm.o'
 288   fi
 289 else
 290   dnl If SSL is unavailable and the user explicitly requested NTLM,
 291   dnl abort.
 292   if test x"$ENABLE_NTLM" = xyes
 293   then
 294     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 295   fi
 296 fi
 297 AC_SUBST(NTLM_OBJ)
 298
 299 dnl
 300 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 301 dnl to use an existing library implementation to save on code size.
 302 dnl
 303
 304 if test x"$wget_need_md5" = xyes
 305 then
 306   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 307   dnl manipulate MD5_OBJ from the defun.
 308
 309   MD5_OBJ='gen-md5.o'
 310   found_md5=no
 311
 312   dnl Check for the system MD5 library on Solaris.  We don't check for
 313   dnl something simple like "MD5Update" because there are a number of
 314   dnl MD5 implementations that use that name, but have an otherwise
 315   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 316   dnl Solaris MD5 library.
 317   if test x"$found_md5" = xno; then
 318     AC_CHECK_LIB(md5, md5_calc, [
 319       dnl Some installations have bogus <md5.h> in the compiler's
 320       dnl include path, making the system md5 library useless.
 321       AC_MSG_CHECKING([for working md5.h])
 322       AC_COMPILE_IFELSE([#include <md5.h>
 323                         ], [
 324         AC_MSG_RESULT(yes)
 325         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 326         LIBS="-lmd5 $LIBS"
 327         found_md5=yes
 328         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 329       ], [AC_MSG_RESULT(no)])
 330     ])
 331   fi
 332
 333   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 334   dnl implementation.
 335   if test x"$found_md5" = xno; then
 336     if test x"$LIBSSL" != x; then
 337       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 338       found_md5=yes
 339       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 340     fi
 341   fi
 342
 343   dnl If none of the above worked, use the one we ship with Wget.
 344   if test x"$found_md5" = xno; then
 345     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 346     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 347     found_md5=yes
 348     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 349     AC_C_BIGENDIAN
 350   fi
 351 fi
 352 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 353 AC_SUBST(MD5_OBJ)
 354
 355 dnl **********************************************************************
 356 dnl Checks for IPv6
 357 dnl **********************************************************************
 358
 359 dnl
 360 dnl We test for IPv6 by checking, in turn, for availability of
 361 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 362 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 363 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 364 dnl
 365 dnl If --enable-ipv6 is explicitly specified on the configure command
 366 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 367 dnl is specified, we disable IPv6 and don't check for it.  The default
 368 dnl is to autodetect IPv6 and use it where available.
 369 dnl
 370
 371 AC_ARG_ENABLE(ipv6,
 372   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 373   [case "${enable_ipv6}" in
 374     no)
 375       AC_MSG_NOTICE([disabling IPv6 at user request])
 376       dnl Disable IPv6 checking
 377       ipv6=no
 378       ;;
 379     yes)
 380       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 381       ipv6=yes
 382       force_ipv6=yes
 383       ;;
 384     auto)
 385       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 386       ipv6=yes
 387       ;;
 388     *)
 389       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 390       ;;
 391     esac
 392   ], [
 393     dnl If nothing is specified, assume auto-detection.
 394     ipv6=yes
 395   ]
 396 )
 397
 398 if test "X$ipv6" = "Xyes"; then
 399   AC_CHECK_FUNCS(getaddrinfo, [], [
 400     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 401     ipv6=no
 402   ])
 403 fi
 404
 405 if test "X$ipv6" = "Xyes"; then
 406   PROTO_INET6([], [
 407     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 408     ipv6=no
 409   ])
 410 fi
 411
 412 if test "X$ipv6" = "Xyes"; then
 413   TYPE_STRUCT_SOCKADDR_IN6([],[
 414     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 415     ipv6=no
 416   ])
 417   if test "X$ipv6" = "Xyes"; then
 418     WGET_STRUCT_SOCKADDR_STORAGE
 419     MEMBER_SIN6_SCOPE_ID
 420   fi
 421 fi
 422
 423 if test "X$ipv6" = "Xyes"; then
 424   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 425   AC_MSG_NOTICE([Enabling support for IPv6.])
 426 elif test "x$force_ipv6" = "xyes"; then
 427   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 428 fi
 429
 430
 431 dnl
 432 dnl Set of available languages.
 433 dnl
 434 dnl Originally this used to be static, looking like this:
 435 dnl     ALL_LINGUAS="cs de hr it ..."
 436 dnl The downside was that configure needed to be rebuilt whenever a
 437 dnl new language was added.
 438 dnl
 439 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 440
 441 dnl internationalization macros
 442 WGET_WITH_NLS
 443
 444 dnl
 445 dnl Find makeinfo.  We used to provide support for Emacs processing
 446 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 447 dnl unavailable, but that broke with the addition of makeinfo-specific
 448 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 449 dnl build the Info documentation.
 450 dnl
 451
 452 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 453
 454 dnl
 455 dnl Find perl and pod2man
 456 dnl
 457
 458 AC_PATH_PROGS(PERL, [perl5 perl], no)
 459 AC_PATH_PROG(POD2MAN, pod2man, no)
 460
 461 if test "x${POD2MAN}" = xno; then
 462   COMMENT_IF_NO_POD2MAN="# "
 463 else
 464   COMMENT_IF_NO_POD2MAN=
 465 fi
 466 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 467
 468 dnl
 469 dnl Create output
 470 dnl
 471 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 472                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 473                  windows/Makefile])
 474 AC_CONFIG_HEADERS([src/config.h])
 475 AH_BOTTOM([
 476 #include "config-post.h"
 477 ])
 478 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 479 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 480 AC_OUTPUT