sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.59)
  34
  35 dnl Include the M4 macros we use.
  36 builtin(include, [m4/wget.m4])dnl
  37 builtin(include, [m4/lib-ld.m4])dnl
  38 builtin(include, [m4/lib-link.m4])dnl
  39 builtin(include, [m4/lib-prefix.m4])dnl
  40
  41 dnl
  42 dnl What version of Wget are we building?
  43 dnl
  44 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  45 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  46 AC_SUBST(VERSION)
  47 PACKAGE=wget
  48 AC_SUBST(PACKAGE)
  49
  50 dnl
  51 dnl Get cannonical host
  52 dnl
  53 AC_CANONICAL_HOST
  54 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  55                    [Define to be the name of the operating system.])
  56
  57 dnl
  58 dnl Process features.
  59 dnl
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  67 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  73 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(ntlm,
  77 [  --disable-ntlm          disable support for NTLM authorization],
  78 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  79
  80 AC_ARG_ENABLE(debug,
  81 [  --disable-debug         disable support for debugging output],
  82 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  83 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  84    [Define if you want the debug output support compiled in.])
  85
  86 wget_need_md5=no
  87
  88 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  89 *yes*)
  90         wget_need_md5=yes
  91 esac
  92 if test x"$ENABLE_OPIE" = xyes; then
  93   OPIE_OBJ='ftp-opie.o'
  94 fi
  95 AC_SUBST(OPIE_OBJ)
  96
  97 dnl
  98 dnl Whether make sets $(MAKE)...
  99 dnl
 100 AC_PROG_MAKE_SET
 101
 102 dnl
 103 dnl Find a good install
 104 dnl
 105 AC_PROG_INSTALL
 106
 107 dnl
 108 dnl Find the compiler
 109 dnl
 110
 111 dnl We want these before the checks, so the checks can modify their values.
 112 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 113 test -z "$CC" && cc_specified=yes
 114
 115 AC_PROG_CC
 116 AC_AIX
 117
 118 dnl Turn on optimization by default.  Specifically:
 119 dnl
 120 dnl if the user hasn't specified CFLAGS, then
 121 dnl   if compiler is gcc, then
 122 dnl     use -O2 and some warning flags
 123 dnl   else
 124 dnl     use os-specific flags or -O
 125 if test -n "$auto_cflags"; then
 126   if test -n "$GCC"; then
 127     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 128   else
 129     case "$host_os" in
 130       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 131       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 132       *)       CFLAGS="$CFLAGS -O" ;;
 133     esac
 134   fi
 135 fi
 136
 137 dnl
 138 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 139 dnl Might also be erelevant for DJGPP.
 140 dnl
 141 case "$host_os" in
 142   *win32) exeext='.exe';;
 143   *) exeext='';;
 144 esac
 145 AC_SUBST(exeext)
 146
 147 dnl
 148 dnl Checks for basic compiler characteristics.
 149 dnl
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_VOLATILE
 153
 154 dnl Check for basic headers, even though we expect them to exist and
 155 dnl #include them unconditionally in the code.  Their detection is
 156 dnl still needed because test programs used by Autoconf macros check
 157 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 158 dnl Without the checks they will fail to be included in test programs,
 159 dnl which will subsequently fail.
 160 AC_HEADER_STDC
 161
 162 dnl Check for large file support.  This check needs to come fairly
 163 dnl early because it could (in principle) affect whether functions and
 164 dnl headers are available, whether they work, etc.
 165 AC_SYS_LARGEFILE
 166 AC_CHECK_SIZEOF(off_t)
 167
 168 dnl
 169 dnl Checks for system header files that might be missing.
 170 dnl
 171 AC_HEADER_STDBOOL
 172 AC_CHECK_HEADERS(unistd.h sys/time.h)
 173 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 174 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 175
 176 dnl
 177 dnl Check sizes of integer types.  These are used to find n-bit
 178 dnl integral types on older systems that fail to provide intN_t and
 179 dnl uintN_t typedefs.
 180 dnl
 181 AC_CHECK_SIZEOF(short)
 182 AC_CHECK_SIZEOF(int)
 183 AC_CHECK_SIZEOF(long)
 184 AC_CHECK_SIZEOF(long long)
 185
 186 dnl
 187 dnl Checks for non-universal or system-specific types.
 188 dnl
 189 AC_TYPE_SIZE_T
 190 AC_TYPE_PID_T
 191 AC_CHECK_TYPES(uint32_t)
 192 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 193 #include <stdio.h>
 194 #include <sys/types.h>
 195 #if HAVE_INTTYPES_H
 196 # include <inttypes.h>
 197 #endif
 198 #include <signal.h>
 199 ])
 200
 201 dnl
 202 dnl Checks for library functions.
 203 dnl
 204 AC_FUNC_ALLOCA
 205 AC_FUNC_MMAP
 206 AC_FUNC_FSEEKO
 207 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf drand48)
 208 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp symlink)
 209
 210 dnl We expect to have these functions on Unix-like systems configure
 211 dnl runs on.  The defines are provided to get them in config.h.in so
 212 dnl Wget can still be ported to non-Unix systems (such as Windows)
 213 dnl that lack some of these functions.
 214 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 215 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 216 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 217 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 218 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 219
 220 dnl
 221 dnl Call Wget-specific macros defined in aclocal.
 222 dnl
 223 WGET_STRUCT_UTIMBUF
 224 WGET_SOCKLEN_T
 225 WGET_FNMATCH
 226 WGET_NANOSLEEP
 227 WGET_POSIX_CLOCK
 228 WGET_NSL_SOCKET
 229
 230 dnl
 231 dnl Check if we need to compile in getopt.c.
 232 dnl
 233 AC_CHECK_FUNC(getopt_long, [], [
 234   GETOPT_OBJ='getopt.o'
 235 ])
 236 AC_SUBST(GETOPT_OBJ)
 237
 238 dnl
 239 dnl Checks for libraries.
 240 dnl
 241
 242 dnl Check for OpenSSL
 243 if test x"$with_ssl" != x"no"
 244 then
 245   dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 246   dnl doesn't record its dependency on libdl, so we need to make sure
 247   dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 248   dnl dlopen(), but HP-UX uses dnl shl_load().
 249   AC_CHECK_LIB(dl, dlopen, [], [
 250     AC_CHECK_LIB(dl, shl_load)
 251   ])
 252
 253   dnl Now actually check for -lssl
 254   AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 255 #include <openssl/ssl.h>
 256 #include <openssl/x509.h>
 257 #include <openssl/err.h>
 258 #include <openssl/rand.h>
 259 #include <openssl/des.h>
 260 #include <openssl/md4.h>
 261 #include <openssl/md5.h>
 262   ], [SSL_library_init ()])
 263   if test x"$LIBSSL" != x
 264   then
 265     AC_MSG_NOTICE([compiling in support for SSL])
 266     AC_DEFINE([HAVE_SSL], 1,
 267               [Define if SSL support is being compiled in.])
 268     SSL_OBJ='openssl.o'
 269   fi
 270 fi
 271 AC_SUBST(SSL_OBJ)
 272
 273 dnl Enable NTLM if requested and if SSL is available.
 274 NTLM_OBJ=''
 275 if test x"$LIBSSL" != x
 276 then
 277   if test x"$ENABLE_NTLM" != xno
 278   then
 279     AC_DEFINE([ENABLE_NTLM], 1,
 280      [Define if you want the NTLM authorization support compiled in.])
 281     NTLM_OBJ='http-ntlm.o'
 282   fi
 283 else
 284   dnl If SSL is unavailable and the user explicitly requested NTLM,
 285   dnl abort.
 286   if test x"$ENABLE_NTLM" = xyes
 287   then
 288     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 289   fi
 290 fi
 291 AC_SUBST(NTLM_OBJ)
 292
 293 dnl
 294 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 295 dnl to use an existing library implementation to save on code size.
 296 dnl
 297
 298 if test x"$wget_need_md5" = xyes
 299 then
 300   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 301   dnl manipulate MD5_OBJ from the defun.
 302
 303   MD5_OBJ='gen-md5.o'
 304   found_md5=no
 305
 306   dnl Check for the system MD5 library on Solaris.  We don't check for
 307   dnl something simple like "MD5Update" because there are a number of
 308   dnl MD5 implementations that use that name, but have an otherwise
 309   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 310   dnl Solaris MD5 library.
 311   if test x"$found_md5" = xno; then
 312     AC_CHECK_LIB(md5, md5_calc, [
 313       dnl Some installations have bogus <md5.h> in the compiler's
 314       dnl include path, making the system md5 library useless.
 315       AC_MSG_CHECKING([for working md5.h])
 316       AC_COMPILE_IFELSE([#include <md5.h>
 317                         ], [
 318         AC_MSG_RESULT(yes)
 319         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 320         LIBS="-lmd5 $LIBS"
 321         found_md5=yes
 322         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 323       ], [AC_MSG_RESULT(no)])
 324     ])
 325   fi
 326
 327   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 328   dnl implementation.
 329   if test x"$found_md5" = xno; then
 330     if test x"$LIBSSL" != x; then
 331       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 332       found_md5=yes
 333       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 334     fi
 335   fi
 336
 337   dnl If none of the above worked, use the one we ship with Wget.
 338   if test x"$found_md5" = xno; then
 339     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 340     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 341     found_md5=yes
 342     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 343     AC_C_BIGENDIAN
 344   fi
 345 fi
 346 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 347 AC_SUBST(MD5_OBJ)
 348
 349 dnl **********************************************************************
 350 dnl Checks for IPv6
 351 dnl **********************************************************************
 352
 353 dnl
 354 dnl We test for IPv6 by checking, in turn, for availability of
 355 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 356 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 357 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 358 dnl
 359 dnl If --enable-ipv6 is explicitly specified on the configure command
 360 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 361 dnl is specified, we disable IPv6 and don't check for it.  The default
 362 dnl is to autodetect IPv6 and use it where available.
 363 dnl
 364
 365 AC_ARG_ENABLE(ipv6,
 366   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 367   [case "${enable_ipv6}" in
 368     no)
 369       AC_MSG_NOTICE([disabling IPv6 at user request])
 370       dnl Disable IPv6 checking
 371       ipv6=no
 372       ;;
 373     yes)
 374       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 375       ipv6=yes
 376       force_ipv6=yes
 377       ;;
 378     auto)
 379       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 380       ipv6=yes
 381       ;;
 382     *)
 383       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 384       ;;
 385     esac
 386   ], [
 387     dnl If nothing is specified, assume auto-detection.
 388     ipv6=yes
 389   ]
 390 )
 391
 392 if test "X$ipv6" = "Xyes"; then
 393   AC_CHECK_FUNCS(getaddrinfo, [], [
 394     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 395     ipv6=no
 396   ])
 397 fi
 398
 399 if test "X$ipv6" = "Xyes"; then
 400   PROTO_INET6([], [
 401     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 402     ipv6=no
 403   ])
 404 fi
 405
 406 if test "X$ipv6" = "Xyes"; then
 407   TYPE_STRUCT_SOCKADDR_IN6([],[
 408     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 409     ipv6=no
 410   ])
 411   if test "X$ipv6" = "Xyes"; then
 412     WGET_STRUCT_SOCKADDR_STORAGE
 413     MEMBER_SIN6_SCOPE_ID
 414   fi
 415 fi
 416
 417 if test "X$ipv6" = "Xyes"; then
 418   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 419   AC_MSG_NOTICE([Enabling support for IPv6.])
 420 elif test "x$force_ipv6" = "xyes"; then
 421   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 422 fi
 423
 424
 425 dnl
 426 dnl Set of available languages.
 427 dnl
 428 dnl Originally this used to be static, looking like this:
 429 dnl     ALL_LINGUAS="cs de hr it ..."
 430 dnl The downside was that configure needed to be rebuilt whenever a
 431 dnl new language was added.
 432 dnl
 433 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 434
 435 dnl internationalization macros
 436 WGET_WITH_NLS
 437
 438 dnl
 439 dnl Find makeinfo.  We used to provide support for Emacs processing
 440 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 441 dnl unavailable, but that broke with the addition of makeinfo-specific
 442 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 443 dnl build the Info documentation.
 444 dnl
 445
 446 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 447
 448 dnl
 449 dnl Find perl and pod2man
 450 dnl
 451
 452 AC_PATH_PROGS(PERL, [perl5 perl], no)
 453 AC_PATH_PROG(POD2MAN, pod2man, no)
 454
 455 if test "x${POD2MAN}" = xno; then
 456   COMMENT_IF_NO_POD2MAN="# "
 457 else
 458   COMMENT_IF_NO_POD2MAN=
 459 fi
 460 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 461
 462 dnl
 463 dnl Create output
 464 dnl
 465 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 466                  po/Makefile.in windows/Makefile])
 467 AC_CONFIG_HEADERS([src/config.h])
 468 AH_BOTTOM([
 469 #include "config-post.h"
 470 ])
 471 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 472 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 473 AC_OUTPUT