sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.57)
  34
  35 dnl
  36 dnl What version of Wget are we building?
  37 dnl
  38 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  39 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  40 AC_SUBST(VERSION)
  41 PACKAGE=wget
  42 AC_SUBST(PACKAGE)
  43
  44 dnl
  45 dnl Get cannonical host
  46 dnl
  47 AC_CANONICAL_HOST
  48 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  49                    [Define to be the name of the operating system.])
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54
  55 AC_ARG_WITH(ssl,
  56 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  57   --without-ssl           disable SSL autodetection]])
  58
  59 AC_ARG_ENABLE(opie,
  60 [  --disable-opie          disable support for opie or s/key FTP login],
  61 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  62 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  63    [Define if you want the Opie support for FTP compiled in.])
  64
  65 AC_ARG_ENABLE(digest,
  66 [  --disable-digest        disable support for HTTP digest authorization],
  67 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  68 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  69    [Define if you want the HTTP Digest Authorization compiled in.])
  70
  71 AC_ARG_ENABLE(ntlm,
  72 [  --disable-ntlm          disable support for NTLM authorization],
  73 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  74
  75 AC_ARG_ENABLE(debug,
  76 [  --disable-debug         disable support for debugging output],
  77 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  78 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  79    [Define if you want the debug output support compiled in.])
  80
  81 wget_need_md5=no
  82
  83 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  84 *yes*)
  85         wget_need_md5=yes
  86 esac
  87 if test x"$ENABLE_OPIE" = xyes; then
  88   OPIE_OBJ='ftp-opie.o'
  89 fi
  90 AC_SUBST(OPIE_OBJ)
  91
  92 dnl
  93 dnl Whether make sets $(MAKE)...
  94 dnl
  95 AC_PROG_MAKE_SET
  96
  97 dnl
  98 dnl Find a good install
  99 dnl
 100 AC_PROG_INSTALL
 101
 102 dnl
 103 dnl Find the compiler
 104 dnl
 105
 106 dnl We want these before the checks, so the checks can modify their values.
 107 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 108 test -z "$CC" && cc_specified=yes
 109
 110 AC_PROG_CC
 111 AC_AIX
 112
 113 dnl Turn on optimization by default.  Specifically:
 114 dnl
 115 dnl if the user hasn't specified CFLAGS, then
 116 dnl   if compiler is gcc, then
 117 dnl     use -O2 and some warning flags
 118 dnl   else
 119 dnl     use os-specific flags or -O
 120 if test -n "$auto_cflags"; then
 121   if test -n "$GCC"; then
 122     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 123   else
 124     case "$host_os" in
 125       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 126       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 127       *)       CFLAGS="$CFLAGS -O" ;;
 128     esac
 129   fi
 130 fi
 131
 132 dnl
 133 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 134 dnl Might also be erelevant for DJGPP.
 135 dnl
 136 case "$host_os" in
 137   *win32) exeext='.exe';;
 138   *) exeext='';;
 139 esac
 140 AC_SUBST(exeext)
 141
 142 dnl
 143 dnl Checks for basic compiler characteristics.
 144 dnl
 145 AC_C_CONST
 146 AC_C_INLINE
 147 AC_C_VOLATILE
 148 dnl Needed for GNU md5 code.
 149 AC_C_BIGENDIAN
 150
 151 dnl
 152 dnl Checks for header files that might be missing.
 153 dnl
 154
 155 dnl Check for basic headers, even though we expect their presence to
 156 dnl compile.  This is because test programs used by Autoconf macros
 157 dnl check for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before including
 158 dnl them.  Without these checks they will fail to be included in test
 159 dnl programs, which will subsequently fail.
 160 AC_HEADER_STDC
 161
 162 dnl Now the real checks:
 163 AC_HEADER_STDBOOL
 164 AC_CHECK_HEADERS(unistd.h sys/time.h)
 165 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 166 AC_CHECK_HEADERS(stdint.h inttypes.h setjmp.h pwd.h)
 167
 168 dnl
 169 dnl Check sizes of signed integer types.  These are used to find n-bit
 170 dnl integral types on older systems that fail to provide intN_t and
 171 dnl uintN_t typedefs.
 172 dnl
 173 AC_CHECK_SIZEOF(short)
 174 AC_CHECK_SIZEOF(int)
 175 AC_CHECK_SIZEOF(long)
 176 AC_CHECK_SIZEOF(long long)
 177
 178 dnl
 179 dnl Check for large file support.  This check needs to come fairly
 180 dnl early because it could (in principle) affect whether functions and
 181 dnl headers are available, whether they work, etc.
 182 dnl
 183 AC_SYS_LARGEFILE
 184 AC_CHECK_SIZEOF(off_t)
 185
 186 dnl
 187 dnl Checks for non-universal or system-specific types.
 188 dnl
 189 AC_TYPE_SIZE_T
 190 AC_TYPE_PID_T
 191 AC_CHECK_TYPES(uint32_t)
 192 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 193 #include <stdio.h>
 194 #include <sys/types.h>
 195 #if HAVE_INTTYPES_H
 196 # include <inttypes.h>
 197 #endif
 198 #include <signal.h>
 199 ])
 200
 201 dnl
 202 dnl Checks for library functions.
 203 dnl
 204 AC_FUNC_ALLOCA
 205 AC_FUNC_MMAP
 206 AC_FUNC_FSEEKO
 207 AC_CHECK_FUNCS(strptime snprintf vsnprintf)
 208 AC_CHECK_FUNCS(usleep ftello sigblock sigsetjmp symlink)
 209
 210 dnl We expect to have these functions on Unix-like systems configure
 211 dnl runs on.  The defines are provided to get them in config.h.in so
 212 dnl Wget can still be ported to non-Unix systems (such as Windows)
 213 dnl that lack some of these functions.
 214 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 215 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 216 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 217 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 218 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 219
 220 dnl
 221 dnl Call Wget-specific macros defined in aclocal.
 222 dnl
 223 WGET_STRUCT_UTIMBUF
 224 WGET_SOCKLEN_T
 225 WGET_FNMATCH
 226 WGET_NANOSLEEP
 227 WGET_POSIX_CLOCK
 228 WGET_NSL_SOCKET
 229
 230 dnl
 231 dnl Check if we need to compile in getopt.c.
 232 dnl
 233 AC_CHECK_FUNC(getopt_long, [], [
 234   GETOPT_OBJ='getopt.o'
 235 ])
 236 AC_SUBST(GETOPT_OBJ)
 237
 238 dnl
 239 dnl Checks for libraries.
 240 dnl
 241
 242 dnl Check for OpenSSL
 243
 244 dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 245 dnl doesn't record its dependency on libdl, so we need to make sure
 246 dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 247 dnl dlopen(), but HP-UX uses dnl shl_load().
 248 AC_CHECK_LIB(dl, dlopen, [], [
 249   AC_CHECK_LIB(dl, shl_load)
 250 ])
 251
 252 dnl Now actually check for -lssl
 253 AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 254 #include <openssl/ssl.h>
 255 #include <openssl/x509.h>
 256 #include <openssl/err.h>
 257 #include <openssl/rand.h>
 258 #include <openssl/des.h>
 259 #include <openssl/md4.h>
 260 #include <openssl/md5.h>
 261 ], [SSL_library_init ()])
 262 if test x"$LIBSSL" != x
 263 then
 264   AC_MSG_NOTICE([compiling in support for SSL])
 265   AC_DEFINE([HAVE_SSL], 1,
 266             [Define if SSL support should be compiled in.])
 267   SSL_OBJ='openssl.o'
 268 fi
 269 AC_SUBST(SSL_OBJ)
 270
 271 dnl Enable NTLM if requested and if SSL is available.
 272 NTLM_OBJ=''
 273 if test x"$LIBSSL" != x
 274 then
 275   if test x"$ENABLE_NTLM" != xno
 276   then
 277     AC_DEFINE([ENABLE_NTLM], 1,
 278      [Define if you want the NTLM authorization support compiled in.])
 279     NTLM_OBJ='http-ntlm.o'
 280   fi
 281 else
 282   dnl If SSL is unavailable and the user explicitly requested NTLM,
 283   dnl abort.
 284   if test x"$ENABLE_NTLM" = xyes
 285   then
 286     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 287   fi
 288 fi
 289 AC_SUBST(NTLM_OBJ)
 290
 291 dnl
 292 dnl Find an md5 implementation.
 293 dnl
 294
 295 if test x"$wget_need_md5" = xyes
 296 then
 297   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 298   dnl manipulate MD5_OBJ from the defun.
 299
 300   MD5_OBJ='gen-md5.o'
 301   found_md5=no
 302
 303   dnl Check for the system MD5 library on Solaris.  We don't check for
 304   dnl something simple like "MD5Update" because there are a number of
 305   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 306   dnl specific to the Solaris MD5 library.
 307   if test x"$found_md5" = xno; then
 308     AC_CHECK_LIB(md5, md5_calc, [
 309       dnl Some installations have bogus <md5.h> in the compiler's
 310       dnl include path, making the system md5 library useless.
 311       AC_MSG_CHECKING([for working md5.h])
 312       AC_COMPILE_IFELSE([#include <md5.h>
 313                         ], [
 314         AC_MSG_RESULT(yes)
 315         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define to use Solaris MD5.])
 316         LIBS="-lmd5 $LIBS"
 317         found_md5=yes
 318         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 319       ], [AC_MSG_RESULT(no)])
 320     ])
 321   fi
 322
 323   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 324   dnl implementation.
 325   if test x"$found_md5" = xno; then
 326     if test x"$ssl_success" = xyes; then
 327       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define to use OpenSSL MD5.])
 328       found_md5=yes
 329       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 330     fi
 331   fi
 332
 333   dnl If none of the above worked, use the one we ship with Wget.
 334   if test x"$found_md5" = xno; then
 335     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define to use built-in MD5.])
 336     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 337     found_md5=yes
 338     AC_MSG_NOTICE([using the GNU MD5 implementation])
 339   fi
 340 fi
 341 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 342 AC_SUBST(MD5_OBJ)
 343
 344 dnl **********************************************************************
 345 dnl Checks for IPv6
 346 dnl **********************************************************************
 347
 348 dnl
 349 dnl If --enable-ipv6 is specified, we try to use IPv6 (as long as
 350 dnl getaddrinfo is also present).  If --disable-ipv6 is specified, we
 351 dnl don't use IPv6 or getaddrinfo.  Otherwise we detect IPv6 and use
 352 dnl it where available.
 353 dnl
 354
 355 AC_ARG_ENABLE(ipv6,
 356   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 357   [case "${enable_ipv6}" in
 358     no)
 359       AC_MSG_NOTICE([disabling IPv6 at user request])
 360       dnl Disable IPv6 checking
 361       ipv6=no
 362       ;;
 363     yes)
 364       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 365       ipv6=yes
 366       force_ipv6=yes
 367       ;;
 368     auto)
 369       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 370       ipv6=yes
 371       ;;
 372     *)
 373       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 374       ;;
 375     esac
 376   ], [
 377     dnl If nothing is specified, assume auto-detection.
 378     ipv6=yes
 379   ]
 380 )
 381
 382 if test "X$ipv6" = "Xyes"; then
 383   AC_CHECK_FUNCS(getaddrinfo, [], [
 384     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 385     ipv6=no
 386   ])
 387 fi
 388
 389 if test "X$ipv6" = "Xyes"; then
 390   PROTO_INET6([], [
 391     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 392     ipv6=no
 393   ])
 394 fi
 395
 396 if test "X$ipv6" = "Xyes"; then
 397   TYPE_STRUCT_SOCKADDR_IN6([],[
 398     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 399     ipv6=no
 400   ])
 401   if test "X$ipv6" = "Xyes"; then
 402     WGET_STRUCT_SOCKADDR_STORAGE
 403     MEMBER_SIN6_SCOPE_ID
 404   fi
 405 fi
 406
 407 if test "X$ipv6" = "Xyes"; then
 408   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 409   AC_MSG_NOTICE([Enabling support for IPv6.])
 410 elif test "x$force_ipv6" = "xyes"; then
 411   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 412 fi
 413
 414
 415 dnl
 416 dnl Set of available languages.
 417 dnl
 418 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 419
 420 dnl Originally this used to be static, looking like this:
 421 dnl     ALL_LINGUAS="cs de hr it ..."
 422 dnl The downside was that configure needed to be rebuilt whenever a
 423 dnl new language was added.
 424
 425 dnl internationalization macros
 426 WGET_WITH_NLS
 427
 428 dnl
 429 dnl Find makeinfo.  We used to provide support for Emacs processing
 430 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 431 dnl unavailable, but that broke with the addition of makeinfo-specific
 432 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 433 dnl build the Info documentation.
 434 dnl
 435
 436 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 437
 438 dnl
 439 dnl Find perl and pod2man
 440 dnl
 441
 442 AC_PATH_PROGS(PERL, [perl5 perl], no)
 443 AC_PATH_PROG(POD2MAN, pod2man, no)
 444
 445 if test "x${POD2MAN}" = xno; then
 446   COMMENT_IF_NO_POD2MAN="# "
 447 else
 448   COMMENT_IF_NO_POD2MAN=
 449 fi
 450 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 451
 452 dnl
 453 dnl Create output
 454 dnl
 455 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 456                  po/Makefile.in windows/Makefile])
 457 AC_CONFIG_HEADERS([src/config.h])
 458 AH_BOTTOM([
 459 #include "config-post.h"
 460 ])
 461 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 462 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 463 AC_OUTPUT