sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001, 2007 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 3 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 dnl In addition, as a special exception, the Free Software Foundation
  18 dnl gives permission to link the code of its release of Wget with the
  19 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  20 dnl that use the same license as the "OpenSSL" library), and distribute
  21 dnl the linked executables.  You must obey the GNU General Public License
  22 dnl in all respects for all of the code used other than "OpenSSL".  If you
  23 dnl modify this file, you may extend this exception to your version of the
  24 dnl file, but you are not obligated to do so.  If you do not wish to do
  25 dnl so, delete this exception statement from your version.
  26
  27 dnl
  28 dnl Process this file with autoconf to produce a configure script.
  29 dnl
  30
  31 AC_INIT([wget],
  32         [m4_normalize(esyscmd([sed -e 's/^.*"\(.*\)";$/\1/' src/version.c]))],
  33         [bug-wget@gnu.org])
  34 AC_PREREQ(2.61)
  35
  36 # Make configure depend on the VERSION file, since it's used in AC_INIT
  37 AC_SUBST([CONFIGURE_DEPENDENCIES], ['$(top_srcdir)/src/version.c'])
  38
  39 dnl
  40 dnl What version of Wget are we building?
  41 dnl
  42 AC_MSG_NOTICE([configuring for GNU Wget $PACKAGE_VERSION])
  43
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CONFIG_AUX_DIR([.])
  46
  47 dnl
  48 dnl Automake setup
  49 dnl
  50 AM_INIT_AUTOMAKE(1.9)
  51
  52 dnl
  53 dnl Gettext
  54 dnl
  55 AM_GNU_GETTEXT([external],[need-ngettext])
  56
  57 dnl
  58 dnl Get cannonical host
  59 dnl
  60 AC_CANONICAL_HOST
  61 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  62                    [Define to be the name of the operating system.])
  63
  64 dnl
  65 dnl Process features.
  66 dnl
  67
  68 AC_ARG_WITH(ssl,
  69 [[  --without-ssl           disable SSL autodetection]])
  70
  71 AC_ARG_ENABLE(opie,
  72 [  --disable-opie          disable support for opie or s/key FTP login],
  73 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  74 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  75    [Define if you want the Opie support for FTP compiled in.])
  76
  77 AC_ARG_ENABLE(digest,
  78 [  --disable-digest        disable support for HTTP digest authorization],
  79 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  80 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  81    [Define if you want the HTTP Digest Authorization compiled in.])
  82
  83 AC_ARG_ENABLE(ntlm,
  84 [  --disable-ntlm          disable support for NTLM authorization],
  85 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  86
  87 AC_ARG_ENABLE(debug,
  88 [  --disable-debug         disable support for debugging output],
  89 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  90 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  91    [Define if you want the debug output support compiled in.])
  92
  93 wget_need_md5=no
  94
  95 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  96 *yes*)
  97         wget_need_md5=yes
  98 esac
  99
 100 dnl
 101 dnl Find the compiler
 102 dnl
 103
 104 dnl We want these before the checks, so the checks can modify their values.
 105 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 106 test -z "$CC" && cc_specified=yes
 107
 108 AC_PROG_CC
 109 AM_PROG_CC_C_O
 110 AC_AIX
 111
 112 AC_PROG_RANLIB
 113
 114 dnl Turn on optimization by default.  Specifically:
 115 dnl
 116 dnl if the user hasn't specified CFLAGS, then
 117 dnl   if compiler is gcc, then
 118 dnl     use -O2 and some warning flags
 119 dnl   else
 120 dnl     use os-specific flags or -O
 121 if test -n "$auto_cflags"; then
 122   if test -n "$GCC"; then
 123     CFLAGS="$CFLAGS -O2 -Wall"
 124   else
 125     case "$host_os" in
 126       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 127       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 128       *)       CFLAGS="$CFLAGS -O" ;;
 129     esac
 130   fi
 131 fi
 132
 133 dnl
 134 dnl Checks for basic compiler characteristics.
 135 dnl
 136 AC_C_CONST
 137 AC_C_INLINE
 138 AC_C_VOLATILE
 139
 140 dnl Check for basic headers, even though we expect them to exist and
 141 dnl #include them unconditionally in the code.  Their detection is
 142 dnl still needed because test programs used by Autoconf macros check
 143 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 144 dnl Without the checks they will fail to be included in test programs,
 145 dnl which will subsequently fail.
 146 AC_HEADER_STDC
 147
 148 dnl Check for large file support.  This check needs to come fairly
 149 dnl early because it could (in principle) affect whether functions and
 150 dnl headers are available, whether they work, etc.
 151 AC_SYS_LARGEFILE
 152 AC_CHECK_SIZEOF(off_t)
 153
 154 dnl
 155 dnl Checks for system header files that might be missing.
 156 dnl
 157 AC_HEADER_STDBOOL
 158 AC_CHECK_HEADERS(unistd.h sys/time.h)
 159 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 160 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 161
 162 dnl
 163 dnl Check sizes of integer types.  These are used to find n-bit
 164 dnl integral types on older systems that fail to provide intN_t and
 165 dnl uintN_t typedefs.
 166 dnl
 167 AC_CHECK_SIZEOF(short)
 168 AC_CHECK_SIZEOF(int)
 169 AC_CHECK_SIZEOF(long)
 170 AC_CHECK_SIZEOF(long long)
 171 AC_CHECK_SIZEOF(void *)
 172
 173 dnl
 174 dnl Checks for non-universal or system-specific types.
 175 dnl
 176 AC_TYPE_SIZE_T
 177 AC_TYPE_PID_T
 178 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 179 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 180 #include <stdio.h>
 181 #include <sys/types.h>
 182 #if HAVE_INTTYPES_H
 183 # include <inttypes.h>
 184 #endif
 185 #include <signal.h>
 186 ])
 187
 188 dnl
 189 dnl Checks for library functions.
 190 dnl
 191 AC_FUNC_ALLOCA
 192 AC_FUNC_MMAP
 193 AC_FUNC_FSEEKO
 194 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 195 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 196
 197 if test x"$ENABLE_OPIE" = xyes; then
 198   AC_LIBOBJ([ftp-opie])
 199 fi
 200
 201 dnl We expect to have these functions on Unix-like systems configure
 202 dnl runs on.  The defines are provided to get them in config.h.in so
 203 dnl Wget can still be ported to non-Unix systems (such as Windows)
 204 dnl that lack some of these functions.
 205 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 206 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 207 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 208 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 209 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 210
 211 dnl
 212 dnl Call Wget-specific macros defined in aclocal.
 213 dnl
 214 WGET_STRUCT_UTIMBUF
 215 WGET_SOCKLEN_T
 216 WGET_FNMATCH
 217 WGET_NANOSLEEP
 218 WGET_POSIX_CLOCK
 219 WGET_NSL_SOCKET
 220
 221 dnl
 222 dnl Check if we need to compile in getopt.c.
 223 dnl
 224 AC_CHECK_FUNC(getopt_long, [], [
 225   AC_LIBOBJ([getopt])
 226 ])
 227
 228 dnl
 229 dnl Checks for libraries.
 230 dnl
 231
 232 AS_IF([test x"$with_ssl" = xgnutls], [
 233   dnl Now actually check for -lssl
 234   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 235 #include <gnutls/gnutls.h>
 236   ], [gnutls_global_init()])
 237   if test x"$LIBGNUTLS" != x
 238   then
 239     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 240     AC_LIBOBJ([gnutls])
 241   else
 242     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 243   fi
 244 ], [
 245   # --with-ssl is not gnutls: check if it's no
 246   AS_IF([test x"$with_ssl" != xno], [
 247     dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 248     dnl doesn't record its dependency on libdl, so we need to make sure
 249     dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 250     dnl dlopen(), but HP-UX uses shl_load().
 251     AC_CHECK_LIB(dl, dlopen, [], [
 252       AC_CHECK_LIB(dl, shl_load)
 253     ])
 254
 255     dnl Now actually check for -lssl
 256     AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 257   #include <openssl/ssl.h>
 258   #include <openssl/x509.h>
 259   #include <openssl/err.h>
 260   #include <openssl/rand.h>
 261   #include <openssl/des.h>
 262   #include <openssl/md4.h>
 263   #include <openssl/md5.h>
 264     ], [SSL_library_init ()])
 265     if test x"$LIBSSL" != x
 266     then
 267       AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 268       AC_LIBOBJ([openssl])
 269     elif test x"$with_ssl" != x
 270     then
 271       AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 272     fi
 273   ]) # endif: --with-ssl == no?
 274 ]) # endif: --with-ssl == gnutls?
 275
 276
 277 dnl Enable NTLM if requested and if SSL is available.
 278 if test x"$LIBSSL" != x
 279 then
 280   if test x"$ENABLE_NTLM" != xno
 281   then
 282     AC_DEFINE([ENABLE_NTLM], 1,
 283      [Define if you want the NTLM authorization support compiled in.])
 284     AC_LIBOBJ([http-ntlm])
 285   fi
 286 else
 287   dnl If SSL is unavailable and the user explicitly requested NTLM,
 288   dnl abort.
 289   if test x"$ENABLE_NTLM" = xyes
 290   then
 291     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 292   fi
 293 fi
 294
 295 dnl
 296 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 297 dnl to use an existing library implementation to save on code size.
 298 dnl
 299
 300 if test x"$wget_need_md5" = xyes
 301 then
 302   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 303   dnl manipulate MD5_OBJ from the defun.
 304
 305   AC_LIBOBJ([gen-md5])
 306   found_md5=no
 307
 308   dnl Check for the system MD5 library on Solaris.  We don't check for
 309   dnl something simple like "MD5Update" because there are a number of
 310   dnl MD5 implementations that use that name, but have an otherwise
 311   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 312   dnl Solaris MD5 library.
 313   if test x"$found_md5" = xno; then
 314     AC_CHECK_LIB(md5, md5_calc, [
 315       dnl Some installations have bogus <md5.h> in the compiler's
 316       dnl include path, making the system md5 library useless.
 317       AC_MSG_CHECKING([for working md5.h])
 318       AC_COMPILE_IFELSE([#include <md5.h>
 319                         ], [
 320         AC_MSG_RESULT(yes)
 321         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 322         LIBS="-lmd5 $LIBS"
 323         found_md5=yes
 324         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 325       ], [AC_MSG_RESULT(no)])
 326     ])
 327   fi
 328
 329   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 330   dnl implementation.
 331   if test x"$found_md5" = xno; then
 332     if test x"$LIBSSL" != x; then
 333       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 334       found_md5=yes
 335       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 336     fi
 337   fi
 338
 339   dnl If none of the above worked, use the one we ship with Wget.
 340   if test x"$found_md5" = xno; then
 341     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 342     AC_LIBOBJ([gnu-md5])
 343     found_md5=yes
 344     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 345     AC_C_BIGENDIAN
 346   fi
 347 fi
 348 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 349
 350 dnl **********************************************************************
 351 dnl Checks for IPv6
 352 dnl **********************************************************************
 353
 354 dnl
 355 dnl We test for IPv6 by checking, in turn, for availability of
 356 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 357 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 358 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 359 dnl
 360 dnl If --enable-ipv6 is explicitly specified on the configure command
 361 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 362 dnl is specified, we disable IPv6 and don't check for it.  The default
 363 dnl is to autodetect IPv6 and use it where available.
 364 dnl
 365
 366 AC_ARG_ENABLE(ipv6,
 367   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 368   [case "${enable_ipv6}" in
 369     no)
 370       AC_MSG_NOTICE([disabling IPv6 at user request])
 371       dnl Disable IPv6 checking
 372       ipv6=no
 373       ;;
 374     yes)
 375       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 376       ipv6=yes
 377       force_ipv6=yes
 378       ;;
 379     auto)
 380       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 381       ipv6=yes
 382       ;;
 383     *)
 384       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 385       ;;
 386     esac
 387   ], [
 388     dnl If nothing is specified, assume auto-detection.
 389     ipv6=yes
 390   ]
 391 )
 392
 393 if test "X$ipv6" = "Xyes"; then
 394   AC_CHECK_FUNCS(getaddrinfo, [], [
 395     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 396     ipv6=no
 397   ])
 398 fi
 399
 400 if test "X$ipv6" = "Xyes"; then
 401   PROTO_INET6([], [
 402     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 403     ipv6=no
 404   ])
 405 fi
 406
 407 if test "X$ipv6" = "Xyes"; then
 408   TYPE_STRUCT_SOCKADDR_IN6([],[
 409     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 410     ipv6=no
 411   ])
 412   if test "X$ipv6" = "Xyes"; then
 413     WGET_STRUCT_SOCKADDR_STORAGE
 414     MEMBER_SIN6_SCOPE_ID
 415   fi
 416 fi
 417
 418 if test "X$ipv6" = "Xyes"; then
 419   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 420   AC_MSG_NOTICE([Enabling support for IPv6.])
 421 elif test "x$force_ipv6" = "xyes"; then
 422   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 423 fi
 424
 425
 426 dnl
 427 dnl Set of available languages.
 428 dnl
 429 dnl Originally this used to be static, looking like this:
 430 dnl     ALL_LINGUAS="cs de hr it ..."
 431 dnl The downside was that configure needed to be rebuilt whenever a
 432 dnl new language was added.
 433 dnl
 434 dnl ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 435
 436 dnl internationalization macros
 437 dnl WGET_WITH_NLS
 438
 439 dnl
 440 dnl Find makeinfo.  We used to provide support for Emacs processing
 441 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 442 dnl unavailable, but that broke with the addition of makeinfo-specific
 443 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 444 dnl build the Info documentation.
 445 dnl
 446
 447 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 448
 449 dnl
 450 dnl Find perl and pod2man
 451 dnl
 452
 453 AC_PATH_PROGS(PERL, [perl5 perl], no)
 454 AC_PATH_PROG(POD2MAN, pod2man, no)
 455
 456 if test "x${POD2MAN}" = xno; then
 457   COMMENT_IF_NO_POD2MAN="# "
 458 else
 459   COMMENT_IF_NO_POD2MAN=
 460 fi
 461 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 462
 463 dnl
 464 dnl Create output
 465 dnl
 466 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 467                  po/Makefile.in tests/Makefile tests/WgetTest.pm
 468                  windows/Makefile])
 469 AC_CONFIG_HEADERS([src/config.h])
 470 AH_BOTTOM([
 471 #include "config-post.h"
 472 ])
 473 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 474 AC_OUTPUT