sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl
  19 dnl Process this file with autoconf to produce a configure script.
  20 dnl
  21
  22 AC_INIT(src/version.c)
  23 AC_PREREQ(2.12)
  24 AC_CONFIG_HEADER(src/config.h)
  25
  26 dnl
  27 dnl What version of Wget are we building?
  28 dnl
  29 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  30 echo "configuring for GNU Wget $VERSION"
  31 AC_SUBST(VERSION)
  32 PACKAGE=wget
  33 AC_SUBST(PACKAGE)
  34
  35 dnl
  36 dnl Get cannonical host
  37 dnl
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  40
  41 dnl
  42 dnl Process features.
  43 dnl
  44 AC_ARG_WITH(socks,
  45 [  --with-socks            use the socks library],
  46 [AC_DEFINE(HAVE_SOCKS)])
  47
  48 AC_ARG_WITH(ssl,
  49 [  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  50   --without-ssl           disable SSL autodetection])
  51
  52 AC_ARG_ENABLE(opie,
  53 [  --disable-opie          disable support for opie or s/key FTP login],
  54 USE_OPIE=$enableval, USE_OPIE=yes)
  55 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  56
  57 AC_ARG_ENABLE(digest,
  58 [  --disable-digest        disable support for HTTP digest authorization],
  59 USE_DIGEST=$enableval, USE_DIGEST=yes)
  60 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  61
  62 AC_ARG_ENABLE(debug,
  63 [  --disable-debug         disable support for debugging output],
  64 DEBUG=$enableval, DEBUG=yes)
  65 test x"${DEBUG}" = xyes && AC_DEFINE(DEBUG)
  66
  67 wget_need_md5=no
  68
  69 case "${USE_OPIE}${USE_DIGEST}" in
  70 *yes*)
  71         wget_need_md5=yes
  72 esac
  73 if test x"$USE_OPIE" = xyes; then
  74   OPIE_OBJ='ftp-opie$o'
  75 fi
  76 AC_SUBST(OPIE_OBJ)
  77
  78 dnl
  79 dnl Whether make sets $(MAKE)...
  80 dnl
  81 AC_PROG_MAKE_SET
  82
  83 dnl
  84 dnl Find a good install
  85 dnl
  86 AC_PROG_INSTALL
  87
  88 dnl
  89 dnl Find the compiler
  90 dnl
  91
  92 dnl We want these before the checks, so the checks can modify their values.
  93 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
  94 test -z "$CC" && cc_specified=yes
  95
  96 AC_PROG_CC
  97
  98 dnl
  99 dnl if the user hasn't specified CFLAGS, then
 100 dnl   if compiler is gcc, then use -O2 and some warning flags
 101 dnl   else use os-specific flags or -O
 102 dnl
 103 if test -n "$auto_cflags"; then
 104   if test -n "$GCC"; then
 105     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 106   else
 107     case "$host_os" in
 108       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 109       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 110       *)       CFLAGS="$CFLAGS -O" ;;
 111     esac
 112   fi
 113 fi
 114
 115 dnl
 116 dnl Handle AIX
 117 dnl
 118 AC_AIX
 119
 120 dnl
 121 dnl Configure our included libtool and make sure it's regenerated when needed
 122 dnl
 123 AC_PROG_LIBTOOL
 124 AC_SUBST(LIBTOOL_DEPS)
 125
 126 dnl
 127 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 128 dnl Might also be erelevant for DJGPP.
 129 dnl
 130 case "$host_os" in
 131   *win32) exeext='.exe';;
 132   *) exeext='';;
 133 esac
 134 AC_SUBST(exeext)
 135
 136 dnl
 137 dnl Check if we can handle prototypes.
 138 dnl
 139 AM_C_PROTOTYPES
 140
 141 dnl
 142 dnl Checks for typedefs, structures, and compiler characteristics.
 143 dnl
 144 AC_C_CONST
 145 AC_C_INLINE
 146 AC_TYPE_SIZE_T
 147 AC_TYPE_PID_T
 148 dnl #### This generates a warning.  What do I do to shut it up?
 149 AC_C_BIGENDIAN
 150
 151 # Check size of long.
 152 AC_CHECK_SIZEOF(long)
 153 AC_CHECK_SIZEOF(long long)
 154
 155 dnl
 156 dnl Checks for headers
 157 dnl
 158 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 159 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 160 AC_CHECK_HEADERS(signal.h setjmp.h)
 161 AC_HEADER_TIME
 162
 163 dnl
 164 dnl Return type of signal-handlers
 165 dnl
 166 AC_TYPE_SIGNAL
 167
 168 dnl
 169 dnl Check for struct utimbuf
 170 WGET_STRUCT_UTIMBUF
 171
 172 dnl
 173 dnl Checks for library functions.
 174 dnl
 175 AC_FUNC_ALLOCA
 176 AC_FUNC_MMAP
 177 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 178 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 179 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 180 AC_CHECK_FUNCS(uname gethostname usleep)
 181
 182 dnl
 183 dnl Check if we need to compile in getopt.c.
 184 dnl
 185 AC_CHECK_FUNC(getopt_long, [], [
 186   GETOPT_OBJ='getopt$o'
 187 ])
 188 AC_SUBST(GETOPT_OBJ)
 189
 190 dnl
 191 dnl Checks for libraries.
 192 dnl
 193
 194 dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
 195 dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
 196 dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
 197 dnl look for such known offenders and if one of them is not found, we
 198 dnl check if -lnsl is needed.
 199
 200 wget_check_in_nsl=NONE
 201 AC_CHECK_FUNCS(gethostbyname, [], [
 202   wget_check_in_nsl=gethostbyname
 203 ])
 204 AC_CHECK_FUNCS(inet_ntoa, [], [
 205   wget_check_in_nsl=inet_ntoa
 206 ])
 207 if test $wget_check_in_nsl != NONE; then
 208   AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 209 fi
 210
 211 AC_CHECK_LIB(socket, socket)
 212
 213 dnl #### This appears to be deficient with later versions of SOCKS.
 214 if test "x${with_socks}" = xyes
 215 then
 216   AC_CHECK_LIB(resolv, main)
 217   AC_CHECK_LIB(socks, Rconnect)
 218 fi
 219
 220 dnl $with_ssl can be one of:
 221 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 222 dnl  - "yes", meaning link with SSL or bail out.
 223 dnl  - "no", meaning don't link with SSL.
 224 dnl  - anything else, meaning use that as the SSL root, and bail out
 225 dnl    if it fails.
 226
 227 if test x"$with_ssl" = x; then
 228   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 229   dnl implements the "auto-detect by default" feature.  If you want to
 230   dnl change this to "ignore SSL by default", change "auto" to "no".
 231   with_ssl=auto
 232 fi
 233
 234 dnl Detection of OpenSSL is much hairier than the detection of other
 235 dnl libraries because OpenSSL can be compiled as a third-party
 236 dnl library, which means it will not be found without additional
 237 dnl linker magic.  It would be really nice to rework this check into
 238 dnl an AC_DEFUN so that we can reuse it for other third-party
 239 dnl libraries.
 240
 241 if test x"$with_ssl" != x"no"; then
 242
 243   wget_force_ssl=no
 244   if test x"$with_ssl" = x"yes"; then
 245     wget_force_ssl=yes
 246   fi
 247
 248   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 249     dnl OpenSSL's root was not specified, so we have to guess.  First
 250     dnl try the system default location, then "/usr/local/ssl" (where
 251     dnl OpenSSL installs by default), then "/usr/local" (traditional
 252     dnl choice for installation root), then "/opt".
 253     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 254   else
 255     dnl Root has been specified by the user.
 256     ssl_all_roots=$with_ssl
 257     wget_force_ssl=yes
 258   fi
 259
 260   wget_save_CC=$CC
 261   wget_save_LIBS=$LIBS
 262   wget_save_LDFLAGS=$LDFLAGS
 263   wget_save_CPPFLAGS=$CPPFLAGS
 264
 265   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 266   dnl without having to know how the linker handles it.
 267   CC="$SHELL ./libtool $CC"
 268
 269   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 270   dnl shared library doesn't record its dependency on libdl, so we
 271   dnl need to check for it ourselves so we won't fail to link due to a
 272   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 273   dnl shl_load().
 274   AC_CHECK_LIB(dl,dlopen)
 275   AC_CHECK_LIB(dl,shl_load)
 276
 277   ssl_success=no
 278
 279   dnl Now try to find SSL libraries in each of the likely SSL roots.
 280   for ssl_root in $ssl_all_roots
 281   do
 282     if test x"$ssl_root" = x"system-default"; then
 283       dnl Try the default include and library locations.
 284       SSL_INCLUDES=
 285     else
 286       dnl Try this specific root.
 287       SSL_INCLUDES=-I$ssl_root/include
 288       dnl It's OK to use -R directly because libtool will
 289       dnl interpret it for us.
 290       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 291     fi
 292
 293     AC_MSG_RESULT(["Looking for SSL libraries in $ssl_root"])
 294
 295     dnl Check whether the compiler can find the include files.  On
 296     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 297     dnl to find the includes in /usr/local/include.
 298
 299     ssl_found_includes=no
 300     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 301
 302     AC_MSG_CHECKING(["for includes"])
 303
 304     AC_TRY_CPP([#include <openssl/ssl.h>
 305 #include <openssl/rsa.h>
 306 ],
 307       AC_MSG_RESULT("found"); ssl_found_includes=yes,
 308       AC_MSG_RESULT("not found")
 309     )
 310
 311     if test x"$ssl_found_includes" = xno; then
 312       continue
 313     fi
 314
 315     ssl_link_failure=no
 316
 317     dnl Make sure that the checks don't run afoul of the cache.  It
 318     dnl would be nicer to temporarily turn off the cache, but
 319     dnl apparently Autoconf doesn't allow that.
 320
 321     unset ac_cv_lib_crypto_RSA_new
 322     unset ac_cv_lib_ssl_SSL_new
 323
 324     dnl These checks need to be in this order, or you'll get a link
 325     dnl failure if you use a static libcrypto.a and libssl.a rather
 326     dnl than shared libraries.
 327
 328     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 329     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 330
 331     if test x"$ssl_link_failure" = xyes; then
 332       dnl One or both libs failed to link.
 333       continue
 334     fi
 335
 336     dnl The libraries link.  But we still need to check if the program
 337     dnl linked with those libraries under these settings with run.  On
 338     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 339     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 340     dnl executables that link, but fail to run.
 341
 342     dnl If we are cross-compiling, just assume that working linkage
 343     dnl implies working executable.
 344
 345     ssl_run_failure=no
 346
 347     AC_MSG_CHECKING("whether SSL libs are resolved at runtime")
 348     AC_TRY_RUN([
 349 int RSA_new();
 350 int SSL_new();
 351 main(){return 0;}
 352 ],
 353       AC_MSG_RESULT("yes"),
 354       AC_MSG_RESULT("no"); ssl_run_failure=yes,
 355       AC_MSG_RESULT("cross")
 356     )
 357
 358     if test x"$ssl_run_failure" = xno; then
 359       ssl_success=yes
 360       break
 361     fi
 362   done
 363
 364   if test x"$ssl_success" = xyes; then
 365     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 366     dnl to use instead.
 367     AC_MSG_RESULT("Compiling in support for SSL in $ssl_root")
 368     AC_DEFINE(HAVE_SSL)
 369     AC_SUBST(SSL_INCLUDES)
 370     SSL_OBJ='gen_sslfunc$o'
 371     AC_SUBST(SSL_OBJ)
 372   else
 373     LDFLAGS=$wget_save_LDFLAGS
 374     LIBS=$wget_save_LIBS
 375
 376     dnl If linking with SSL was forced rather than auto-detected, then
 377     dnl bail out if SSL failed.
 378     if test x"$wget_force_ssl" = x"yes"; then
 379       exec >&2
 380       echo "ERROR: Failed to find OpenSSL libraries."
 381       exit 2
 382     fi
 383   fi
 384
 385   dnl Restore the compiler setting.
 386   CC=$wget_save_CC
 387
 388   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 389   dnl with SSL succeeded -- SSL includes will be handled using
 390   dnl @SSL_INCLUDES@.
 391   CPPFLAGS=$wget_save_CPPFLAGS
 392 fi
 393
 394 dnl
 395 dnl Find an md5 implementation.
 396 dnl
 397
 398 if test x"$wget_need_md5" = xyes
 399 then
 400   MD5_OBJ='gen-md5$o'
 401
 402   found_md5=no
 403
 404   dnl Check for the system MD5 library on Solaris.  We don't check for
 405   dnl something simple like "MD5Update" because there are a number of
 406   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 407   dnl specific to the Solaris MD5 library.
 408   if test x"$found_md5" = xno; then
 409     AC_CHECK_LIB(md5, md5_calc, [
 410       AC_DEFINE(HAVE_SOLARIS_MD5)
 411       LIBS="-lmd5 $LIBS"
 412       found_md5=yes
 413     ])
 414   fi
 415
 416   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 417   dnl implementation.
 418   if test x"$found_md5" = xno; then
 419     if test x"$ssl_success" = xyes; then
 420       AC_DEFINE(HAVE_OPENSSL_MD5)
 421       found_md5=yes
 422     fi
 423   fi
 424
 425   dnl If none of the above worked, use the one we ship with Wget.
 426   if test x"$found_md5" = xno; then
 427     AC_DEFINE(HAVE_BUILTIN_MD5)
 428     found_md5=yes
 429     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 430   fi
 431 fi
 432 AC_DEFINE(HAVE_MD5)
 433 AC_SUBST(MD5_OBJ)
 434
 435 dnl
 436 dnl Set of available languages.
 437 dnl
 438 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//')`
 439
 440 dnl Originally this used to be static, looking like this:
 441 dnl     ALL_LINGUAS="cs de hr it ..."
 442 dnl The downside was that configure needed to be rebuilt whenever a
 443 dnl new language was added.
 444
 445 dnl internationalization macros
 446 WGET_WITH_NLS
 447
 448 dnl
 449 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 450 dnl Emacs cannot be found, look for XEmacs.
 451 dnl
 452
 453 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 454
 455 case "${MAKEINFO}" in
 456    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 457    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 458    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 459 esac
 460
 461 dnl
 462 dnl Find perl and pod2man
 463 dnl
 464
 465 AC_PATH_PROGS(PERL, perl5 perl, no)
 466 AC_PATH_PROG(POD2MAN, pod2man, no)
 467
 468 if test "x${POD2MAN}" = xno; then
 469   COMMENT_IF_NO_POD2MAN="# "
 470 else
 471   COMMENT_IF_NO_POD2MAN=
 472 fi
 473 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 474
 475 dnl
 476 dnl Create output
 477 dnl
 478 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 479            windows/Makefile],
 480 [WGET_PROCESS_PO
 481 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])