sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT(src/version.c)
  33 AC_PREREQ(2.50)
  34 AC_CONFIG_HEADER(src/config.h)
  35
  36 dnl
  37 dnl What version of Wget are we building?
  38 dnl
  39 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  40 echo "configuring for GNU Wget $VERSION"
  41 AC_SUBST(VERSION)
  42 PACKAGE=wget
  43 AC_SUBST(PACKAGE)
  44
  45 dnl
  46 dnl Get cannonical host
  47 dnl
  48 AC_CANONICAL_HOST
  49 AC_DEFINE_UNQUOTED(OS_TYPE, "$host_os")
  50
  51 dnl
  52 dnl Process features.
  53 dnl
  54 AC_ARG_WITH(socks,
  55 [  --with-socks            use the socks library],
  56 [AC_DEFINE(HAVE_SOCKS)])
  57
  58 AC_ARG_WITH(ssl,
  59 [[  --with-ssl[=SSL-ROOT]   link with SSL support [default=auto]
  60   --without-ssl           disable SSL autodetection]])
  61
  62 AC_ARG_ENABLE(opie,
  63 [  --disable-opie          disable support for opie or s/key FTP login],
  64 USE_OPIE=$enableval, USE_OPIE=yes)
  65 test x"${USE_OPIE}" = xyes && AC_DEFINE(USE_OPIE)
  66
  67 AC_ARG_ENABLE(digest,
  68 [  --disable-digest        disable support for HTTP digest authorization],
  69 USE_DIGEST=$enableval, USE_DIGEST=yes)
  70 test x"${USE_DIGEST}" = xyes && AC_DEFINE(USE_DIGEST)
  71
  72 AC_ARG_ENABLE(debug,
  73 [  --disable-debug         disable support for debugging output],
  74 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  75 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE(ENABLE_DEBUG)
  76
  77 wget_need_md5=no
  78
  79 case "${USE_OPIE}${USE_DIGEST}" in
  80 *yes*)
  81         wget_need_md5=yes
  82 esac
  83 if test x"$USE_OPIE" = xyes; then
  84   OPIE_OBJ='ftp-opie$o'
  85 fi
  86 AC_SUBST(OPIE_OBJ)
  87
  88 dnl
  89 dnl Whether make sets $(MAKE)...
  90 dnl
  91 AC_PROG_MAKE_SET
  92
  93 dnl
  94 dnl Find a good install
  95 dnl
  96 AC_PROG_INSTALL
  97
  98 dnl
  99 dnl Find the compiler
 100 dnl
 101
 102 dnl We want these before the checks, so the checks can modify their values.
 103 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 104 test -z "$CC" && cc_specified=yes
 105
 106 AC_PROG_CC
 107
 108 dnl
 109 dnl if the user hasn't specified CFLAGS, then
 110 dnl   if compiler is gcc, then use -O2 and some warning flags
 111 dnl   else use os-specific flags or -O
 112 dnl
 113 if test -n "$auto_cflags"; then
 114   if test -n "$GCC"; then
 115     CFLAGS="$CFLAGS -O2 -Wall -Wno-implicit"
 116   else
 117     case "$host_os" in
 118       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 119       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 120       *)       CFLAGS="$CFLAGS -O" ;;
 121     esac
 122   fi
 123 fi
 124
 125 dnl
 126 dnl Handle AIX
 127 dnl
 128 AC_AIX
 129
 130 dnl
 131 dnl Configure our included libtool and make sure it's regenerated when needed
 132 dnl
 133 AC_PROG_LIBTOOL
 134 AC_SUBST(LIBTOOL_DEPS)
 135
 136 dnl
 137 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 138 dnl Might also be erelevant for DJGPP.
 139 dnl
 140 case "$host_os" in
 141   *win32) exeext='.exe';;
 142   *) exeext='';;
 143 esac
 144 AC_SUBST(exeext)
 145
 146 dnl
 147 dnl Check if we can handle prototypes.
 148 dnl
 149 AM_C_PROTOTYPES
 150
 151 dnl
 152 dnl Checks for typedefs, structures, and compiler characteristics.
 153 dnl
 154 AC_C_CONST
 155 AC_C_INLINE
 156 AC_TYPE_SIZE_T
 157 AC_TYPE_PID_T
 158 AC_C_BIGENDIAN
 159
 160 dnl
 161 dnl Check integral type sizes.
 162 dnl
 163 AC_CHECK_SIZEOF(short)
 164 AC_CHECK_SIZEOF(int)
 165 AC_CHECK_SIZEOF(long)
 166 AC_CHECK_SIZEOF(long long)
 167 AC_CHECK_TYPES(u_int32_t)
 168
 169 dnl
 170 dnl Checks for headers
 171 dnl
 172 AC_CHECK_HEADERS(string.h stdarg.h unistd.h sys/time.h utime.h sys/utime.h pwd.h)
 173 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h sys/utsname.h)
 174 AC_CHECK_HEADERS(signal.h setjmp.h)
 175 AC_HEADER_TIME
 176
 177 dnl
 178 dnl Return type of signal-handlers
 179 dnl
 180 AC_TYPE_SIGNAL
 181
 182 dnl
 183 dnl Call several of Wget's macros.
 184 dnl
 185 WGET_STRUCT_UTIMBUF
 186 WGET_SOCKLEN_T
 187
 188 dnl
 189 dnl Checks for library functions.
 190 dnl
 191 AC_FUNC_ALLOCA
 192 AC_FUNC_MMAP
 193 AC_CHECK_FUNCS(strdup strstr strcasecmp strncasecmp strpbrk memmove)
 194 AC_CHECK_FUNCS(gettimeofday mktime strptime strerror snprintf vsnprintf)
 195 AC_CHECK_FUNCS(select sigblock sigsetjmp signal symlink access isatty)
 196 AC_CHECK_FUNCS(uname gethostname usleep)
 197
 198 dnl
 199 dnl Check if we need to compile in getopt.c.
 200 dnl
 201 AC_CHECK_FUNC(getopt_long, [], [
 202   GETOPT_OBJ='getopt$o'
 203 ])
 204 AC_SUBST(GETOPT_OBJ)
 205
 206 dnl
 207 dnl Checks for libraries.
 208 dnl
 209
 210 dnl On Solaris, -lnsl is needed to use gethostbyname.  On "NCR MP-RAS
 211 dnl 3.0", however, gethostbyname is in libc, but -lnsl is still needed
 212 dnl to use -lsocket, as well as for functions such as inet_ntoa.  We
 213 dnl look for such known offenders and if one of them is not found, we
 214 dnl check if -lnsl is needed.
 215
 216 wget_check_in_nsl=NONE
 217 AC_CHECK_FUNCS(gethostbyname, [], [
 218   wget_check_in_nsl=gethostbyname
 219 ])
 220 AC_CHECK_FUNCS(inet_ntoa, [], [
 221   wget_check_in_nsl=inet_ntoa
 222 ])
 223 if test $wget_check_in_nsl != NONE; then
 224   AC_CHECK_LIB(nsl, $wget_check_in_nsl)
 225 fi
 226
 227 AC_CHECK_LIB(socket, socket)
 228
 229 dnl #### This appears to be deficient with later versions of SOCKS.
 230 if test "x${with_socks}" = xyes
 231 then
 232   AC_CHECK_LIB(resolv, main)
 233   AC_CHECK_LIB(socks, Rconnect)
 234 fi
 235
 236 dnl $with_ssl can be one of:
 237 dnl  - empty string or "auto", meaning autodetect SSL and use it if found.
 238 dnl  - "yes", meaning link with SSL or bail out.
 239 dnl  - "no", meaning don't link with SSL.
 240 dnl  - anything else, meaning use that as the SSL root, and bail out
 241 dnl    if it fails.
 242
 243 if test x"$with_ssl" = x; then
 244   dnl Canonicalize unspecified with-ssl setting to "auto".  This
 245   dnl implements the "auto-detect by default" feature.  If you want to
 246   dnl change this to "ignore SSL by default", change "auto" to "no".
 247   with_ssl=auto
 248 fi
 249
 250 dnl Detection of OpenSSL is much hairier than the detection of other
 251 dnl libraries because OpenSSL can be compiled as a third-party
 252 dnl library, which means it will not be found without additional
 253 dnl linker magic.  It would be really nice to rework this check into
 254 dnl an AC_DEFUN so that we can reuse it for other third-party
 255 dnl libraries.
 256
 257 if test x"$with_ssl" != x"no"; then
 258
 259   wget_force_ssl=no
 260   if test x"$with_ssl" = x"yes"; then
 261     wget_force_ssl=yes
 262   fi
 263
 264   if test x"$with_ssl" = x"yes" || test x"$with_ssl" = x"auto"; then
 265     dnl OpenSSL's root was not specified, so we have to guess.  First
 266     dnl try the system default location, then "/usr/local/ssl" (where
 267     dnl OpenSSL installs by default), then "/usr/local" (traditional
 268     dnl choice for installation root), then "/opt".
 269     ssl_all_roots="system-default /usr/local/ssl /usr/local /opt"
 270   else
 271     dnl Root has been specified by the user.
 272     ssl_all_roots=$with_ssl
 273     wget_force_ssl=yes
 274   fi
 275
 276   wget_save_CC=$CC
 277   wget_save_LIBS=$LIBS
 278   wget_save_LDFLAGS=$LDFLAGS
 279   wget_save_CPPFLAGS=$CPPFLAGS
 280
 281   dnl Use libtool for OpenSSL tests so we can specify "-R<rpath>"
 282   dnl without having to know how the linker handles it.
 283   CC="$SHELL ./libtool $CC"
 284
 285   dnl Unfortunately, as of this writing (OpenSSL 0.9.6), the libcrypto
 286   dnl shared library doesn't record its dependency on libdl, so we
 287   dnl need to check for it ourselves so we won't fail to link due to a
 288   dnl lack of -ldl.  Most OSes use dlopen(), but HP-UX uses
 289   dnl shl_load().
 290   AC_CHECK_LIB(dl,dlopen)
 291   AC_CHECK_LIB(dl,shl_load)
 292
 293   ssl_success=no
 294
 295   dnl Now try to find SSL libraries in each of the likely SSL roots.
 296   for ssl_root in $ssl_all_roots
 297   do
 298     if test x"$ssl_root" = x"system-default"; then
 299       dnl Try the default include and library locations.
 300       SSL_INCLUDES=
 301     else
 302       dnl Try this specific root.
 303       SSL_INCLUDES=-I$ssl_root/include
 304       dnl It's OK to use -R directly because libtool will
 305       dnl interpret it for us.
 306       LDFLAGS="-L$ssl_root/lib -R$ssl_root/lib $wget_save_LDFLAGS"
 307     fi
 308
 309     AC_MSG_RESULT([Looking for SSL libraries in $ssl_root])
 310
 311     dnl Check whether the compiler can find the include files.  On
 312     dnl some systems Gcc finds libraries in /usr/local/lib, but fails
 313     dnl to find the includes in /usr/local/include.
 314
 315     ssl_found_includes=no
 316     CPPFLAGS="$SSL_INCLUDES $wget_save_CPPFLAGS"
 317
 318     AC_MSG_CHECKING([for includes])
 319
 320     AC_TRY_CPP([#include <openssl/ssl.h>
 321 #include <openssl/rsa.h>
 322 ],
 323       AC_MSG_RESULT(found); ssl_found_includes=yes,
 324       AC_MSG_RESULT([not found])
 325     )
 326
 327     if test x"$ssl_found_includes" = xno; then
 328       continue
 329     fi
 330
 331     ssl_link_failure=no
 332
 333     dnl Make sure that the checks don't run afoul of the cache.  It
 334     dnl would be nicer to temporarily turn off the cache, but
 335     dnl apparently Autoconf doesn't allow that.
 336
 337     unset ac_cv_lib_crypto_RSA_new
 338     unset ac_cv_lib_ssl_SSL_new
 339
 340     dnl These checks need to be in this order, or you'll get a link
 341     dnl failure if you use a static libcrypto.a and libssl.a rather
 342     dnl than shared libraries.
 343
 344     AC_CHECK_LIB(crypto, RSA_new, , ssl_link_failure=yes)
 345     AC_CHECK_LIB(ssl, SSL_new, , ssl_link_failure=yes)
 346
 347     if test x"$ssl_link_failure" = xyes; then
 348       dnl One or both libs failed to link.
 349       continue
 350     fi
 351
 352     dnl The libraries link.  But we still need to check if the program
 353     dnl linked with those libraries under these settings with run.  On
 354     dnl some systems (Solaris), Gcc adds -L/usr/local/lib to the
 355     dnl linking line, but fails to add -R/usr/local/lib, thus creating
 356     dnl executables that link, but fail to run.
 357
 358     dnl If we are cross-compiling, just assume that working linkage
 359     dnl implies working executable.
 360
 361     ssl_run_failure=no
 362
 363     AC_MSG_CHECKING([whether SSL libs are resolved at runtime])
 364     AC_TRY_RUN([
 365 int RSA_new();
 366 int SSL_new();
 367 main(){return 0;}
 368 ],
 369       AC_MSG_RESULT(yes),
 370       AC_MSG_RESULT(no); ssl_run_failure=yes,
 371       AC_MSG_RESULT(cross)
 372     )
 373
 374     if test x"$ssl_run_failure" = xno; then
 375       ssl_success=yes
 376       break
 377     fi
 378   done
 379
 380   if test x"$ssl_success" = xyes; then
 381     dnl AC_MSG_RESULT doesn't look right here, but I'm not sure what
 382     dnl to use instead.
 383     AC_MSG_RESULT([Compiling in support for SSL in $ssl_root])
 384     AC_DEFINE(HAVE_SSL)
 385     AC_SUBST(SSL_INCLUDES)
 386     SSL_OBJ='gen_sslfunc$o'
 387     AC_SUBST(SSL_OBJ)
 388   else
 389     LDFLAGS=$wget_save_LDFLAGS
 390     LIBS=$wget_save_LIBS
 391
 392     dnl If linking with SSL was forced rather than auto-detected, then
 393     dnl bail out if SSL failed.
 394     if test x"$wget_force_ssl" = x"yes"; then
 395       exec >&2
 396       echo "ERROR: Failed to find OpenSSL libraries."
 397       exit 2
 398     fi
 399   fi
 400
 401   dnl Restore the compiler setting.
 402   CC=$wget_save_CC
 403
 404   dnl Restore the CPPFLAGS.  Do this regardless of whether linking
 405   dnl with SSL succeeded -- SSL includes will be handled using
 406   dnl @SSL_INCLUDES@.
 407   CPPFLAGS=$wget_save_CPPFLAGS
 408 fi
 409
 410 dnl
 411 dnl Find an md5 implementation.
 412 dnl
 413
 414 if test x"$wget_need_md5" = xyes
 415 then
 416   MD5_OBJ='gen-md5$o'
 417
 418   found_md5=no
 419
 420   dnl Check for the system MD5 library on Solaris.  We don't check for
 421   dnl something simple like "MD5Update" because there are a number of
 422   dnl MD5 implementations that use that name.  md5_calc is, hopefully,
 423   dnl specific to the Solaris MD5 library.
 424   if test x"$found_md5" = xno; then
 425     AC_CHECK_LIB(md5, md5_calc, [
 426       AC_DEFINE(HAVE_SOLARIS_MD5)
 427       LIBS="-lmd5 $LIBS"
 428       found_md5=yes
 429     ])
 430   fi
 431
 432   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 433   dnl implementation.
 434   if test x"$found_md5" = xno; then
 435     if test x"$ssl_success" = xyes; then
 436       AC_DEFINE(HAVE_OPENSSL_MD5)
 437       found_md5=yes
 438     fi
 439   fi
 440
 441   dnl If none of the above worked, use the one we ship with Wget.
 442   if test x"$found_md5" = xno; then
 443     AC_DEFINE(HAVE_BUILTIN_MD5)
 444     found_md5=yes
 445     MD5_OBJ="$MD5_OBJ gnu-md5\$o"
 446   fi
 447 fi
 448 AC_DEFINE(HAVE_MD5)
 449 AC_SUBST(MD5_OBJ)
 450
 451 dnl **********************************************************************
 452 dnl Checks for IPv6
 453 dnl **********************************************************************
 454
 455 ipv6=
 456 check_for_ipv6=no
 457 AC_ARG_ENABLE(ipv6,
 458   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 459   [case "${enable_ipv6}" in
 460   no)
 461     AC_MSG_NOTICE([Disabling IPv6 at user request])
 462     ipv6=no
 463     ;;
 464   *)
 465     ipv6=yes
 466     ;;
 467   esac],
 468   [check_for_ipv6=no]
 469 )
 470
 471 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 472   AC_CHECK_FUNCS(getaddrinfo,[
 473     GETADDRINFO_AI_ADDRCONFIG(
 474       AC_DEFINE(
 475         [HAVE_GETADDRINFO_AI_ADDRCONFIG], 1,
 476         [Define if the system headers support the AI_ADDRCONFIG flag.]
 477       )
 478     )
 479     GETADDRINFO_AI_V4MAPPED(
 480       AC_DEFINE(
 481         [HAVE_GETADDRINFO_AI_V4MAPPED], 1,
 482         [Define if the system headers support the AI_V4MAPPED flag.]
 483       )
 484     )
 485     GETADDRINFO_AI_ALL(
 486       AC_DEFINE(
 487         [HAVE_GETADDRINFO_AI_ALL], 1,
 488         [Define if the system headers support the AI_ALL flag.]
 489       )
 490     )
 491   ],[
 492     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 493     ipv6=no
 494   ])
 495 fi
 496
 497 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 498   PROTO_INET6(,[
 499     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 500     ipv6=no
 501   ])
 502 fi
 503
 504 if test "X$ipv6" = "Xyes" || test "X$check_for_ipv6" = "Xyes"; then
 505   TYPE_STRUCT_SOCKADDR_IN6([
 506     ipv6=yes
 507   ],[
 508     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support 'struct sockaddr_in6'])
 509     ipv6=no
 510   ])
 511   if test "X$ipv6" = "Xyes"; then
 512     MEMBER_SIN6_SCOPE_ID
 513   fi
 514 fi
 515
 516 if test "X$ipv6" = "Xyes"; then
 517   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 518 fi
 519
 520
 521 dnl
 522 dnl Set of available languages.
 523 dnl
 524 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 525
 526 dnl Originally this used to be static, looking like this:
 527 dnl     ALL_LINGUAS="cs de hr it ..."
 528 dnl The downside was that configure needed to be rebuilt whenever a
 529 dnl new language was added.
 530
 531 dnl internationalization macros
 532 WGET_WITH_NLS
 533
 534 dnl
 535 dnl Find makeinfo.  If makeinfo is not found, look for Emacs.  If
 536 dnl Emacs cannot be found, look for XEmacs.
 537 dnl
 538
 539 AC_CHECK_PROGS(MAKEINFO, makeinfo emacs xemacs)
 540
 541 case "${MAKEINFO}" in
 542    *makeinfo) MAKEINFO="${MAKEINFO} \$(srcdir)/wget.texi"  ;;
 543    *emacs | *xemacs) MAKEINFO="${MAKEINFO} -batch -q -no-site-file -eval '(find-file \"\$(srcdir)/wget.texi\")' -l texinfmt -f texinfo-format-buffer -f save-buffer"  ;;
 544    *) MAKEINFO="makeinfo \$(srcdir)/wget.texi"            ;;
 545 esac
 546
 547 dnl
 548 dnl Find perl and pod2man
 549 dnl
 550
 551 AC_PATH_PROGS(PERL, perl5 perl, no)
 552 AC_PATH_PROG(POD2MAN, pod2man, no)
 553
 554 if test "x${POD2MAN}" = xno; then
 555   COMMENT_IF_NO_POD2MAN="# "
 556 else
 557   COMMENT_IF_NO_POD2MAN=
 558 fi
 559 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 560
 561 dnl
 562 dnl Create output
 563 dnl
 564 AC_OUTPUT([Makefile src/Makefile doc/Makefile util/Makefile po/Makefile.in
 565            windows/Makefile],
 566 [WGET_PROCESS_PO
 567 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])