sjero.net Git - wget/blob - configure.in

   1 dnl Template file for GNU Autoconf
   2 dnl Copyright (C) 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   3
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2 of the License, or
   7 dnl (at your option) any later version.
   8
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  17
  18 dnl In addition, as a special exception, the Free Software Foundation
  19 dnl gives permission to link the code of its release of Wget with the
  20 dnl OpenSSL project's "OpenSSL" library (or with modified versions of it
  21 dnl that use the same license as the "OpenSSL" library), and distribute
  22 dnl the linked executables.  You must obey the GNU General Public License
  23 dnl in all respects for all of the code used other than "OpenSSL".  If you
  24 dnl modify this file, you may extend this exception to your version of the
  25 dnl file, but you are not obligated to do so.  If you do not wish to do
  26 dnl so, delete this exception statement from your version.
  27
  28 dnl
  29 dnl Process this file with autoconf to produce a configure script.
  30 dnl
  31
  32 AC_INIT([src/version.c])
  33 AC_PREREQ(2.59)
  34
  35 dnl Include the M4 macros we use.
  36 builtin(include, [m4/wget.m4])dnl
  37 builtin(include, [m4/lib-ld.m4])dnl
  38 builtin(include, [m4/lib-link.m4])dnl
  39 builtin(include, [m4/lib-prefix.m4])dnl
  40
  41 dnl
  42 dnl What version of Wget are we building?
  43 dnl
  44 VERSION=`sed -e 's/^.*"\(.*\)";$/\1/' ${srcdir}/src/version.c`
  45 AC_MSG_NOTICE([configuring for GNU Wget $VERSION])
  46 AC_SUBST(VERSION)
  47 PACKAGE=wget
  48 AC_SUBST(PACKAGE)
  49
  50 dnl
  51 dnl Get cannonical host
  52 dnl
  53 AC_CANONICAL_HOST
  54 AC_DEFINE_UNQUOTED([OS_TYPE], "$host_os",
  55                    [Define to be the name of the operating system.])
  56
  57 dnl
  58 dnl Process features.
  59 dnl
  60
  61 AC_ARG_WITH(ssl,
  62 [[  --without-ssl           disable SSL autodetection]])
  63
  64 AC_ARG_ENABLE(opie,
  65 [  --disable-opie          disable support for opie or s/key FTP login],
  66 ENABLE_OPIE=$enableval, ENABLE_OPIE=yes)
  67 test x"${ENABLE_OPIE}" = xyes && AC_DEFINE([ENABLE_OPIE], 1,
  68    [Define if you want the Opie support for FTP compiled in.])
  69
  70 AC_ARG_ENABLE(digest,
  71 [  --disable-digest        disable support for HTTP digest authorization],
  72 ENABLE_DIGEST=$enableval, ENABLE_DIGEST=yes)
  73 test x"${ENABLE_DIGEST}" = xyes && AC_DEFINE([ENABLE_DIGEST], 1,
  74    [Define if you want the HTTP Digest Authorization compiled in.])
  75
  76 AC_ARG_ENABLE(ntlm,
  77 [  --disable-ntlm          disable support for NTLM authorization],
  78 [ENABLE_NTLM=$enableval], [ENABLE_NTLM=auto])
  79
  80 AC_ARG_ENABLE(debug,
  81 [  --disable-debug         disable support for debugging output],
  82 ENABLE_DEBUG=$enableval, ENABLE_DEBUG=yes)
  83 test x"${ENABLE_DEBUG}" = xyes && AC_DEFINE([ENABLE_DEBUG], 1,
  84    [Define if you want the debug output support compiled in.])
  85
  86 wget_need_md5=no
  87
  88 case "${ENABLE_OPIE}${ENABLE_DIGEST}" in
  89 *yes*)
  90         wget_need_md5=yes
  91 esac
  92 if test x"$ENABLE_OPIE" = xyes; then
  93   OPIE_OBJ='ftp-opie.o'
  94 fi
  95 AC_SUBST(OPIE_OBJ)
  96
  97 dnl
  98 dnl Whether make sets $(MAKE)...
  99 dnl
 100 AC_PROG_MAKE_SET
 101
 102 dnl
 103 dnl Find a good install
 104 dnl
 105 AC_PROG_INSTALL
 106
 107 dnl
 108 dnl Find the compiler
 109 dnl
 110
 111 dnl We want these before the checks, so the checks can modify their values.
 112 test -z "$CFLAGS"  && CFLAGS= auto_cflags=1
 113 test -z "$CC" && cc_specified=yes
 114
 115 AC_PROG_CC
 116 AC_AIX
 117
 118 YYTEXT_POINTER=1
 119 AC_PROG_LEX
 120
 121 dnl Turn on optimization by default.  Specifically:
 122 dnl
 123 dnl if the user hasn't specified CFLAGS, then
 124 dnl   if compiler is gcc, then
 125 dnl     use -O2 and some warning flags
 126 dnl   else
 127 dnl     use os-specific flags or -O
 128 if test -n "$auto_cflags"; then
 129   if test -n "$GCC"; then
 130     CFLAGS="$CFLAGS -O2 -Wall"
 131   else
 132     case "$host_os" in
 133       *hpux*)  CFLAGS="$CFLAGS +O3"                      ;;
 134       *ultrix* | *osf*) CFLAGS="$CFLAGS -O -Olimit 2000" ;;
 135       *)       CFLAGS="$CFLAGS -O" ;;
 136     esac
 137   fi
 138 fi
 139
 140 dnl
 141 dnl In case of {cyg,gnu}win32.  Should be a _target_ test.
 142 dnl Might also be erelevant for DJGPP.
 143 dnl
 144 case "$host_os" in
 145   *win32) exeext='.exe';;
 146   *) exeext='';;
 147 esac
 148 AC_SUBST(exeext)
 149
 150 dnl
 151 dnl Checks for basic compiler characteristics.
 152 dnl
 153 AC_C_CONST
 154 AC_C_INLINE
 155 AC_C_VOLATILE
 156
 157 dnl Check for basic headers, even though we expect them to exist and
 158 dnl #include them unconditionally in the code.  Their detection is
 159 dnl still needed because test programs used by Autoconf macros check
 160 dnl for STDC_HEADERS, HAVE_SYS_TYPES_H, etc. before using them.
 161 dnl Without the checks they will fail to be included in test programs,
 162 dnl which will subsequently fail.
 163 AC_HEADER_STDC
 164
 165 dnl Check for large file support.  This check needs to come fairly
 166 dnl early because it could (in principle) affect whether functions and
 167 dnl headers are available, whether they work, etc.
 168 AC_SYS_LARGEFILE
 169 AC_CHECK_SIZEOF(off_t)
 170
 171 dnl
 172 dnl Checks for system header files that might be missing.
 173 dnl
 174 AC_HEADER_STDBOOL
 175 AC_CHECK_HEADERS(unistd.h sys/time.h)
 176 AC_CHECK_HEADERS(termios.h sys/ioctl.h sys/select.h utime.h sys/utime.h)
 177 AC_CHECK_HEADERS(stdint.h inttypes.h pwd.h)
 178
 179 dnl
 180 dnl Check sizes of integer types.  These are used to find n-bit
 181 dnl integral types on older systems that fail to provide intN_t and
 182 dnl uintN_t typedefs.
 183 dnl
 184 AC_CHECK_SIZEOF(short)
 185 AC_CHECK_SIZEOF(int)
 186 AC_CHECK_SIZEOF(long)
 187 AC_CHECK_SIZEOF(long long)
 188 AC_CHECK_SIZEOF(void *)
 189
 190 dnl
 191 dnl Checks for non-universal or system-specific types.
 192 dnl
 193 AC_TYPE_SIZE_T
 194 AC_TYPE_PID_T
 195 AC_CHECK_TYPES([uint32_t, uintptr_t, intptr_t, int64_t])
 196 AC_CHECK_TYPES(sig_atomic_t, [], [], [
 197 #include <stdio.h>
 198 #include <sys/types.h>
 199 #if HAVE_INTTYPES_H
 200 # include <inttypes.h>
 201 #endif
 202 #include <signal.h>
 203 ])
 204
 205 dnl
 206 dnl Checks for library functions.
 207 dnl
 208 AC_FUNC_ALLOCA
 209 AC_FUNC_MMAP
 210 AC_FUNC_FSEEKO
 211 AC_CHECK_FUNCS(strptime timegm snprintf vsnprintf vasprintf drand48)
 212 AC_CHECK_FUNCS(strtoll usleep ftello sigblock sigsetjmp memrchr)
 213
 214 dnl We expect to have these functions on Unix-like systems configure
 215 dnl runs on.  The defines are provided to get them in config.h.in so
 216 dnl Wget can still be ported to non-Unix systems (such as Windows)
 217 dnl that lack some of these functions.
 218 AC_DEFINE([HAVE_STRCASECMP], 1, [Define to 1 if you have the `strcasecmp' function.])
 219 AC_DEFINE([HAVE_STRNCASECMP], 1, [Define to 1 if you have the `strncasecmp' function.])
 220 AC_DEFINE([HAVE_STRDUP], 1, [Define to 1 if you have the `strdup' function.])
 221 AC_DEFINE([HAVE_ISATTY], 1, [Define to 1 if you have the `isatty' function.])
 222 AC_DEFINE([HAVE_SYMLINK], 1, [Define to 1 if you have the `symlink' function.])
 223
 224 dnl
 225 dnl Call Wget-specific macros defined in aclocal.
 226 dnl
 227 WGET_STRUCT_UTIMBUF
 228 WGET_SOCKLEN_T
 229 WGET_FNMATCH
 230 WGET_NANOSLEEP
 231 WGET_POSIX_CLOCK
 232 WGET_NSL_SOCKET
 233
 234 dnl
 235 dnl Check if we need to compile in getopt.c.
 236 dnl
 237 AC_CHECK_FUNC(getopt_long, [], [
 238   GETOPT_OBJ='getopt.o'
 239 ])
 240 AC_SUBST(GETOPT_OBJ)
 241
 242 dnl
 243 dnl Checks for libraries.
 244 dnl
 245
 246 if test x"$with_ssl" = xgnutls
 247 then
 248   dnl Now actually check for -lssl
 249   AC_LIB_HAVE_LINKFLAGS([gnutls], [], [
 250 #include <gnutls/gnutls.h>
 251   ], [gnutls_global_init()])
 252   if test x"$LIBGNUTLS" != x
 253   then
 254     AC_MSG_NOTICE([compiling in support for SSL via GnuTLS])
 255     SSL_OBJ='gnutls.o'
 256   else
 257     AC_MSG_ERROR([--with-ssl=gnutls was given, but GNUTLS is not available.])
 258   fi
 259 elif test x"$with_ssl" != xno; then
 260   dnl As of this writing (OpenSSL 0.9.6), the libcrypto shared library
 261   dnl doesn't record its dependency on libdl, so we need to make sure
 262   dnl -ldl ends up in LIBS on systems that have it.  Most OSes use
 263   dnl dlopen(), but HP-UX uses shl_load().
 264   AC_CHECK_LIB(dl, dlopen, [], [
 265     AC_CHECK_LIB(dl, shl_load)
 266   ])
 267
 268   dnl Now actually check for -lssl
 269   AC_LIB_HAVE_LINKFLAGS([ssl], [crypto], [
 270 #include <openssl/ssl.h>
 271 #include <openssl/x509.h>
 272 #include <openssl/err.h>
 273 #include <openssl/rand.h>
 274 #include <openssl/des.h>
 275 #include <openssl/md4.h>
 276 #include <openssl/md5.h>
 277   ], [SSL_library_init ()])
 278   if test x"$LIBSSL" != x
 279   then
 280     AC_MSG_NOTICE([compiling in support for SSL via OpenSSL])
 281     SSL_OBJ='openssl.o'
 282   elif test x"$with_ssl" != x
 283   then
 284     AC_MSG_ERROR([--with-ssl was given, but SSL is not available.])
 285   fi
 286 fi
 287
 288 AC_SUBST(SSL_OBJ)
 289
 290 dnl Enable NTLM if requested and if SSL is available.
 291 NTLM_OBJ=''
 292 if test x"$LIBSSL" != x
 293 then
 294   if test x"$ENABLE_NTLM" != xno
 295   then
 296     AC_DEFINE([ENABLE_NTLM], 1,
 297      [Define if you want the NTLM authorization support compiled in.])
 298     NTLM_OBJ='http-ntlm.o'
 299   fi
 300 else
 301   dnl If SSL is unavailable and the user explicitly requested NTLM,
 302   dnl abort.
 303   if test x"$ENABLE_NTLM" = xyes
 304   then
 305     AC_MSG_ERROR([NTLM authorization requested and OpenSSL not found; aborting])
 306   fi
 307 fi
 308 AC_SUBST(NTLM_OBJ)
 309
 310 dnl
 311 dnl Find an MD5 implementation.  Since Wget rarely needs MD5, we try
 312 dnl to use an existing library implementation to save on code size.
 313 dnl
 314
 315 if test x"$wget_need_md5" = xyes
 316 then
 317   dnl This should be moved to an AC_DEFUN, but I'm not sure how to
 318   dnl manipulate MD5_OBJ from the defun.
 319
 320   MD5_OBJ='gen-md5.o'
 321   found_md5=no
 322
 323   dnl Check for the system MD5 library on Solaris.  We don't check for
 324   dnl something simple like "MD5Update" because there are a number of
 325   dnl MD5 implementations that use that name, but have an otherwise
 326   dnl incompatible interface.  md5_calc is, hopefully, specific to the
 327   dnl Solaris MD5 library.
 328   if test x"$found_md5" = xno; then
 329     AC_CHECK_LIB(md5, md5_calc, [
 330       dnl Some installations have bogus <md5.h> in the compiler's
 331       dnl include path, making the system md5 library useless.
 332       AC_MSG_CHECKING([for working md5.h])
 333       AC_COMPILE_IFELSE([#include <md5.h>
 334                         ], [
 335         AC_MSG_RESULT(yes)
 336         AC_DEFINE([HAVE_SOLARIS_MD5], 1, [Define when using Solaris MD5.])
 337         LIBS="-lmd5 $LIBS"
 338         found_md5=yes
 339         AC_MSG_NOTICE([using the Solaris MD5 implementation])
 340       ], [AC_MSG_RESULT(no)])
 341     ])
 342   fi
 343
 344   dnl Then see if we're linking OpenSSL anyway; if yes, use its md5
 345   dnl implementation.
 346   if test x"$found_md5" = xno; then
 347     if test x"$LIBSSL" != x; then
 348       AC_DEFINE([HAVE_OPENSSL_MD5], 1, [Define when using OpenSSL MD5.])
 349       found_md5=yes
 350       AC_MSG_NOTICE([using the OpenSSL MD5 implementation])
 351     fi
 352   fi
 353
 354   dnl If none of the above worked, use the one we ship with Wget.
 355   if test x"$found_md5" = xno; then
 356     AC_DEFINE([HAVE_BUILTIN_MD5], 1, [Define when using built-in MD5.])
 357     MD5_OBJ="$MD5_OBJ gnu-md5.o"
 358     found_md5=yes
 359     AC_MSG_NOTICE([using the built-in (GNU) MD5 implementation])
 360     AC_C_BIGENDIAN
 361   fi
 362 fi
 363 AC_DEFINE([HAVE_MD5], 1, [Define if we're compiling support for MD5.])
 364 AC_SUBST(MD5_OBJ)
 365
 366 dnl **********************************************************************
 367 dnl Checks for IPv6
 368 dnl **********************************************************************
 369
 370 dnl
 371 dnl We test for IPv6 by checking, in turn, for availability of
 372 dnl getaddrinfo, presence of the INET6 address/protocol family, and
 373 dnl the existence of struct sockaddr_in6.  If any of them is missing,
 374 dnl IPv6 is disabled, and the code reverts to old-style gethostbyname.
 375 dnl
 376 dnl If --enable-ipv6 is explicitly specified on the configure command
 377 dnl line, we check for IPv6 and abort if not found.  If --disable-ipv6
 378 dnl is specified, we disable IPv6 and don't check for it.  The default
 379 dnl is to autodetect IPv6 and use it where available.
 380 dnl
 381
 382 AC_ARG_ENABLE(ipv6,
 383   AC_HELP_STRING([--disable-ipv6],[disable IPv6 support]),
 384   [case "${enable_ipv6}" in
 385     no)
 386       AC_MSG_NOTICE([disabling IPv6 at user request])
 387       dnl Disable IPv6 checking
 388       ipv6=no
 389       ;;
 390     yes)
 391       dnl IPv6 explicitly enabled: force its use (abort if unavailable).
 392       ipv6=yes
 393       force_ipv6=yes
 394       ;;
 395     auto)
 396       dnl Auto-detect IPv6, i.e. check for IPv6, but don't force it.
 397       ipv6=yes
 398       ;;
 399     *)
 400       AC_MSG_ERROR([Invalid --enable-ipv6 argument \`$enable_ipv6'])
 401       ;;
 402     esac
 403   ], [
 404     dnl If nothing is specified, assume auto-detection.
 405     ipv6=yes
 406   ]
 407 )
 408
 409 if test "X$ipv6" = "Xyes"; then
 410   AC_CHECK_FUNCS(getaddrinfo, [], [
 411     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support getaddrinfo(3)])
 412     ipv6=no
 413   ])
 414 fi
 415
 416 if test "X$ipv6" = "Xyes"; then
 417   PROTO_INET6([], [
 418     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support the PF_INET6 protocol family])
 419     ipv6=no
 420   ])
 421 fi
 422
 423 if test "X$ipv6" = "Xyes"; then
 424   TYPE_STRUCT_SOCKADDR_IN6([],[
 425     AC_MSG_NOTICE([Disabling IPv6 support: your system does not support \`struct sockaddr_in6'])
 426     ipv6=no
 427   ])
 428   if test "X$ipv6" = "Xyes"; then
 429     WGET_STRUCT_SOCKADDR_STORAGE
 430     MEMBER_SIN6_SCOPE_ID
 431   fi
 432 fi
 433
 434 if test "X$ipv6" = "Xyes"; then
 435   AC_DEFINE([ENABLE_IPV6], 1, [Define if IPv6 support is enabled.])
 436   AC_MSG_NOTICE([Enabling support for IPv6.])
 437 elif test "x$force_ipv6" = "xyes"; then
 438   AC_MSG_ERROR([IPv6 support requested but not found; aborting])
 439 fi
 440
 441
 442 dnl
 443 dnl Set of available languages.
 444 dnl
 445 dnl Originally this used to be static, looking like this:
 446 dnl     ALL_LINGUAS="cs de hr it ..."
 447 dnl The downside was that configure needed to be rebuilt whenever a
 448 dnl new language was added.
 449 dnl
 450 ALL_LINGUAS=`(cd ${srcdir}/po && ls *.po | sed -e 's/\.po$//' | tr '\012' ' ')`
 451
 452 dnl internationalization macros
 453 WGET_WITH_NLS
 454
 455 dnl
 456 dnl Find makeinfo.  We used to provide support for Emacs processing
 457 dnl Texinfo using `emacs -batch -eval ...' where makeinfo is
 458 dnl unavailable, but that broke with the addition of makeinfo-specific
 459 dnl command-line options, such as `-I'.  Now we depend on makeinfo to
 460 dnl build the Info documentation.
 461 dnl
 462
 463 AC_CHECK_PROGS(MAKEINFO, [makeinfo], [true])
 464
 465 dnl
 466 dnl Find perl and pod2man
 467 dnl
 468
 469 AC_PATH_PROGS(PERL, [perl5 perl], no)
 470 AC_PATH_PROG(POD2MAN, pod2man, no)
 471
 472 if test "x${POD2MAN}" = xno; then
 473   COMMENT_IF_NO_POD2MAN="# "
 474 else
 475   COMMENT_IF_NO_POD2MAN=
 476 fi
 477 AC_SUBST(COMMENT_IF_NO_POD2MAN)
 478
 479 dnl
 480 dnl Create output
 481 dnl
 482 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile util/Makefile
 483                  po/Makefile.in tests/Makefile windows/Makefile])
 484 AC_CONFIG_HEADERS([src/config.h])
 485 AH_BOTTOM([
 486 #include "config-post.h"
 487 ])
 488 AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
 489 AC_CONFIG_COMMANDS([default], [WGET_PROCESS_PO])
 490 AC_OUTPUT